configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.61 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.  (Also, some files
  11 dnl in Autoconf 2.62 and 2.63 sources are not GPLv2 compatible.)
  12 AC_PREREQ(2.61)
  13 AC_INIT
  14 AC_CONFIG_SRCDIR([src/main/main.c])
  15 AC_CONFIG_AUX_DIR(config)
  16
  17 PACKAGE=elinks
  18 VERSION=0.13.GIT
  19 AC_SUBST(PACKAGE)
  20 AC_SUBST(VERSION)
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  23 AC_CONFIG_HEADERS(config.h)
  24
  25 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  26 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  27 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  28
  29 MAKE=
  30
  31 for make in gnumake gmake make false; do
  32         if test "x$MAKE" = x; then
  33                 AC_PATH_PROGS(MAKE, "$make")
  34         fi
  35 done
  36
  37 builddir="`pwd`"
  38
  39 # Cleanup if we are configuring with a previous build in the tree
  40 if test -e Makefile.config; then
  41         AC_MSG_CHECKING([for previous build to clean])
  42         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  43         AC_MSG_RESULT(done)
  44 fi
  45
  46 # ===================================================================
  47 # Load feature configuration file and start logging features.
  48 # ===================================================================
  49
  50 features="features.conf"
  51 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  52 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  53 echo "Feature summary:" > features.log
  54
  55 # ===================================================================
  56 # Checks for programs.
  57 # ===================================================================
  58
  59 AC_PROG_CC
  60 AC_PROG_AWK
  61 AC_PATH_PROGS(AWK, "$AWK")
  62 AC_PROG_RANLIB
  63 AC_PROG_INSTALL
  64
  65 AC_PATH_PROGS(GIT, "git")
  66 AC_PATH_PROGS(SPARSE, "sparse")
  67
  68 CONFIG_ASCIIDOC="no"
  69 CONFIG_POD2HTML="no"
  70 CONFIG_XMLTO="no"
  71 CONFIG_JW="no"
  72
  73 if test "x$CONFIG_DOC" != xno; then
  74         AC_PATH_PROGS(PYTHON, "python")
  75         if test "x$PYTHON" != "x"; then
  76                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  77                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  78                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  79         fi
  80
  81         AC_PATH_PROGS(XMLTO, "xmlto")
  82         if test "x$XMLTO" != "x"; then
  83                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  84                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  85                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  86         fi
  87
  88         AC_PATH_PROGS(JW, "jw")
  89         if test "x$JW" != "x"; then
  90                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  91                 EL_CONFIG(MANUAL_JW, [PDF])
  92         fi
  93
  94         AC_PATH_PROGS(POD2HTML, "pod2html")
  95         if test "x$POD2HTML" != "x"; then
  96                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  97         fi
  98
  99         AC_PATH_PROGS(DOXYGEN, "doxygen")
 100         if test "x$DOXYGEN" != "x"; then
 101                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 102                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 103                 AC_SUBST(api_srcdir)
 104         fi
 105 fi
 106
 107 AC_SUBST(CONFIG_ASCIIDOC)
 108 AC_SUBST(CONFIG_DOXYGEN)
 109 AC_SUBST(CONFIG_POD2HTML)
 110 AC_SUBST(CONFIG_XMLTO)
 111 AC_SUBST(CONFIG_JW)
 112
 113 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 114 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 115 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 116 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 117
 118 # gcc specific options (to be continued at the bottom of configure)
 119 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 120   # We want to see all warnings and live with none.
 121   # We can't set up -Werror here as there may be some warnings in test
 122   # suite of configure, and we don't want to fail them.
 123   CFLAGS="$CFLAGS -Wall"
 124 fi
 125
 126 # ===================================================================
 127 # Checks for special OSes.
 128 # ===================================================================
 129
 130 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 131 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 132 [
 133         AC_MSG_CHECKING([for $2])
 134
 135         for flag in $3; do
 136                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 137 kill me!
 138 #endif ]])],[$1=yes],[$1=no])
 139                 if test "[$]$1" = yes; then
 140                         EL_CONFIG([$1], [$2])
 141                         break
 142                 fi
 143         done
 144
 145         AC_MSG_RESULT([$]$1)
 146 ])
 147
 148 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 149 AC_SUBST(CONFIG_OS_BEOS)
 150
 151 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 152 AC_SUBST(CONFIG_OS_RISCOS)
 153
 154 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 155 AC_SUBST(CONFIG_OS_WIN32)
 156
 157 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 158 AC_SUBST(CONFIG_OS_OS2)
 159 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 160
 161 AC_MSG_CHECKING([for UNIX])
 162 dnl FIXME: some depend kind of mechanism
 163 if test "$CONFIG_OS_BEOS" = no && \
 164    test "$CONFIG_OS_RISCOS" = no && \
 165    test "$CONFIG_OS_WIN32" = no && \
 166    test "$CONFIG_OS_OS2" = no; then
 167         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 168 else
 169         CONFIG_OS_UNIX=no
 170 fi
 171 AC_MSG_RESULT($CONFIG_OS_UNIX)
 172 AC_SUBST(CONFIG_OS_UNIX)
 173
 174 # ===================================================================
 175 # Checks for header files.
 176 # ===================================================================
 177
 178 AC_HEADER_DIRENT
 179 AC_HEADER_STDC
 180 AC_HEADER_SYS_WAIT
 181 AC_HEADER_TIME
 182
 183 AC_CHECK_HEADERS(wchar.h wctype.h)
 184 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 185 AC_CHECK_HEADERS(sigaction.h)
 186 AC_CHECK_HEADERS(arpa/inet.h)
 187 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 188 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 189 AC_CHECK_HEADERS(ifaddrs.h)
 190 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 191 AC_CHECK_HEADERS(sys/fmutex.h)
 192 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 193 AC_CHECK_HEADERS(sys/resource.h)
 194 AC_CHECK_HEADERS(sys/select.h)
 195 AC_CHECK_HEADERS(sys/signal.h)
 196 AC_CHECK_HEADERS(sys/socket.h)
 197 AC_CHECK_HEADERS(sys/time.h)
 198 AC_CHECK_HEADERS(sys/utsname.h)
 199 AC_CHECK_HEADERS([net/if.h], [], [],
 200 [[#ifdef HAVE_SYS_SOCKET_H
 201 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 202 #endif
 203 ]])
 204 AC_CHECK_HEADERS(stdint.h inttypes.h)
 205 AC_CHECK_HEADERS(locale.h pwd.h)
 206 AC_CHECK_HEADERS(termios.h)
 207
 208
 209 AC_CHECK_HEADERS(sys/un.h,
 210         [CONFIG_INTERLINK=yes
 211          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 212         [CONFIG_INTERLINK=no])
 213 AC_SUBST(CONFIG_INTERLINK)
 214
 215 # ===================================================================
 216 # Checks for typedefs, structures, and compiler characteristics.
 217 # ===================================================================
 218
 219 AC_STRUCT_TM
 220 AC_C_CONST
 221 AC_C_INLINE
 222 AC_MSG_CHECKING([[for C99-conforming inline]])
 223 AC_COMPILE_IFELSE([[
 224         int add(int change);
 225
 226         static int sum;
 227
 228         inline int
 229         add(int change)
 230         {
 231                 sum += change;
 232                 return sum;
 233         }
 234
 235         int
 236         sub(int change)
 237         {
 238                 return add(-change);
 239         }]],
 240         [AC_MSG_RESULT([[yes]])
 241          AC_DEFINE([NONSTATIC_INLINE], [inline],
 242                 [Define as inline if the compiler lets you declare a function without inline, then define it with inline, and have that definition refer to identifiers with internal linkage.  This is allowed by C99 6.7.4p6 and 6.7.4p3 together.  Otherwise define as nothing.])],
 243         [AC_MSG_RESULT([[no]])
 244          AC_DEFINE([NONSTATIC_INLINE], [])])
 245 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 246
 247 AC_SYS_LARGEFILE
 248 AC_TYPE_SIZE_T
 249 AC_TYPE_OFF_T
 250 EL_CHECK_TYPE(ssize_t, int)
 251 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 252 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 253 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 254 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 255 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 256
 257 AC_CHECK_SIZEOF(char, 1)
 258 AC_CHECK_SIZEOF(short, 2)
 259 AC_CHECK_SIZEOF(int, 4)
 260 AC_CHECK_SIZEOF(long, 4)
 261 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 262 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 263
 264 # Check for variadic macros
 265 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 266                 [#include <stdio.h>
 267                  #define a(b,c...) printf(b,##c)],
 268                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 269
 270 # ===================================================================
 271 # Checks for library functions.
 272 # ===================================================================
 273
 274 AC_PROG_GCC_TRADITIONAL
 275 AC_FUNC_MEMCMP
 276 AC_FUNC_MMAP
 277 AC_FUNC_STRFTIME
 278 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 279 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 280 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 281 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 282 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 283 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 284 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 285 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 286 AC_CHECK_FUNCS(setitimer, HAVE_SETITIMER=yes)
 287
 288 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 289
 290 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 291 AC_CHECK_FUNCS(unsetenv)
 292 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 293 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 294
 295 AC_CHECK_FUNCS(wcwidth, HAVE_WCWIDTH=yes)
 296
 297 # These aren't probably needed now, as they are commented in links.h.
 298 # I've no idea about their historical background, but I keep them here
 299 # just in the case they will help later. --pasky
 300 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 301 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 302 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 303 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 304
 305 AC_CHECK_FUNCS(fpathconf, HAVE_FPATHCONF=yes)
 306
 307 if test x"$HAVE_RAISE" = x; then
 308         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 309                 AC_MSG_ERROR([Unable to emulate raise()])
 310         fi
 311 fi
 312
 313 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 314 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 315 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 316 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 317         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 318 fi
 319
 320 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 321 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 322 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 323 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 324         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 325 fi
 326
 327 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 328 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 329 #include <stdio.h>
 330 #include <stdarg.h>
 331 #include <stdlib.h>
 332 #include <string.h>
 333
 334 char buf[8];
 335
 336 int bar(char *buf, const char *format, va_list ap)
 337 {
 338        return vsnprintf(buf, 0, format, ap);
 339 }
 340
 341 void foo(const char *format, ...) {
 342        va_list ap;
 343        int len;
 344
 345        va_start(ap, format);
 346        len = bar(buf, format, ap);
 347        va_end(ap);
 348        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 349
 350        va_start(ap, format);
 351        len = bar(buf, format, ap);
 352        va_end(ap);
 353        if ((len != 6) && (len != 7)) exit(1);
 354
 355        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 356
 357        exit(0);
 358 }
 359 main() { foo("hello\n"); }
 360 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 361 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 362         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 363 fi
 364
 365 # OpenSSL and Lua frequently need dlopen
 366 AC_CHECK_LIB(dl, dlopen)
 367
 368 # ===================================================================
 369 # Checks for libraries.
 370 # ===================================================================
 371
 372 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 373 if test "$cf_result" = no; then
 374         AC_CHECK_LIB(socket, socket)
 375 fi
 376
 377 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 378 if test "$cf_result" = no; then
 379         AC_CHECK_LIB(socket, setsockopt)
 380 fi
 381
 382 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 383 if test "$cf_result" = no; then
 384         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 385         if test "$cf_result" = no; then
 386                 AC_CHECK_LIB(nsl, gethostbyname)
 387         else
 388                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 389         fi
 390 fi
 391
 392 # ===================================================================
 393 # Checks for packaging specific options.
 394 # ===================================================================
 395
 396 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 397             [ if test "$withval" != no && test "$withval" != yes; then
 398                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 399               fi ])
 400
 401 # ===================================================================
 402 # Checks for a libraries, optional even if installed.
 403 # ===================================================================
 404
 405 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 406 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 407 [
 408         AC_MSG_CHECKING([for $2 support])
 409
 410         if test "[$]$1" != no; then
 411                 AC_MSG_RESULT(yes)
 412                 EL_SAVE_FLAGS
 413                 if test -n "$withval" && test -d "$withval"; then
 414                         # Be a little more careful when setting
 415                         # include and lib directories. This way
 416                         # $withval will work when includes are
 417                         # there but the library is in the common
 418                         # /usr/lib ... Does the right thing when
 419                         # looking for gc on Debian.
 420                         if test -d "$withval/include"; then
 421                                 CFLAGS="$CFLAGS -I$withval/include"
 422                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 423                         else
 424                                 CFLAGS="$CFLAGS -I$withval"
 425                                 CPPFLAGS="$CPPFLAGS -I$withval"
 426                         fi
 427                         if test -d "$withval/lib"; then
 428                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 429                         fi
 430                 fi
 431
 432                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 433                 if test "[$]$1" = yes; then
 434                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 435                 fi
 436
 437                 if test "[$]$1" = yes; then
 438                         EL_CONFIG([$1], [$2])
 439                         LIBS="$LIBS -l$4"
 440                 else
 441                         if test -n "[$]WITHVAL_$1" &&
 442                            test "[$]WITHVAL_$1" != xno; then
 443                                 AC_MSG_ERROR([$2 not found])
 444                         fi
 445                         EL_RESTORE_FLAGS
 446                 fi
 447         else
 448                 AC_MSG_RESULT(disabled)
 449         fi
 450 ])
 451
 452 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 453 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 454 [
 455         if test "x[$]$1" != xno; then $1=yes; fi
 456         WITHVAL_$1=
 457
 458         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 459         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 460         if test "x[$]WITHVAL_$1" = xyes; then $1=yes; fi
 461
 462         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 463
 464         EL_LOG_CONFIG([$1], [$2], [])
 465 ])
 466
 467 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 468         [  --without-gpm           disable gpm (mouse) support])
 469
 470 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 471 # enable automatic decoding of both zlib and gzip headers.  This
 472 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 473 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 474 # that, even though ELinks does not actually call gzclearerr.
 475 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 476         [  --without-zlib          disable zlib support])
 477
 478 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 479         [  --without-bzlib         disable bzlib support])
 480
 481 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 482         [  --without-idn           disable international domain names support])
 483
 484 if test "x${with_gc}" != xno; then
 485         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 486                 [  --with-gc               enable Boehm's garbage collector])
 487 fi
 488
 489 # LZMA disabled by default, because of little usability and compilation problems
 490 # with new xz
 491 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code,
 492         [  --with-lzma             enable lzma encoding support])
 493
 494 # ===================================================================
 495 # Check for GSSAPI, optional even if installed.
 496 # ===================================================================
 497
 498 enable_gssapi="no";
 499
 500 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 501             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 502
 503 AC_MSG_CHECKING([for GSSAPI])
 504
 505 if test "$enable_gssapi" = "yes"; then
 506         AC_MSG_RESULT(yes)
 507         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 508         GSSAPI_LIBS=`krb5-config --libs gssapi`
 509         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 510         LIBS="$GSSAPI_LIBS $LIBS"
 511         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 512 else
 513         AC_MSG_RESULT(no)
 514 fi
 515
 516 AC_SUBST(CONFIG_GSSAPI)
 517
 518 # ===================================================================
 519 # Bookmark and XBEL support
 520 # ===================================================================
 521
 522 EL_SAVE_FLAGS
 523
 524 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 525               [  --disable-bookmarks     disable bookmark support])
 526
 527 # Check whether --enable-xbel or --disable-xbel was given.
 528 if test "x${enable_xbel}" != xno; then
 529         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 530
 531         if test "$HAVE_LIBEXPAT" = yes; then
 532                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 533                 if test "$HAVE_LIBEXPAT" = yes; then
 534                         LIBS="$LIBS -lexpat"
 535                 fi
 536         fi
 537 fi
 538
 539
 540 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 541               [XBEL bookmarks],
 542               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 543
 544 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 545         EL_RESTORE_FLAGS
 546 fi
 547
 548 # ===================================================================
 549 # Checks for BSD sysmouse
 550 # ===================================================================
 551
 552 HAVE_SYSMOUSE_HEADER="no"
 553
 554 # Either of these header files provides the (same) sysmouse interface
 555 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 556
 557 # ===================================================================
 558 # Checks for OS/2
 559 # ===================================================================
 560
 561 if test "$CONFIG_OS_OS2" = yes; then
 562         EL_CONFIG_OS_OS2
 563 fi
 564
 565 # ===================================================================
 566 # Checks for Win32
 567 # ===================================================================
 568
 569 if test "$CONFIG_OS_WIN32" = yes; then
 570         EL_CONFIG_OS_WIN32
 571 fi
 572
 573 # ===================================================================
 574 # Check for SEE (Simple Ecmascript Engine)
 575 # ===================================================================
 576 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 577             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 578
 579 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 580 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 581 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 582 # for Guile in $PATH etc. --pasky
 583
 584 CONFIG_ECMASCRIPT_SEE=no
 585
 586 if test "$enable_see" = "yes"; then
 587         if test -d "$withval"; then
 588                 SEE_PATH="$withval:$PATH"
 589         else
 590                 SEE_PATH="$PATH"
 591         fi
 592
 593         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 594         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 595         if test "$SEE_CONFIG" != no; then
 596                 EL_SAVE_FLAGS
 597                 SEE_LIBS="`$SEE_CONFIG --libs`"
 598                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 599                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 600                 LIBS="$SEE_LIBS $LIBS_X"
 601                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <see/see.h>]], [[#if SEE_VERSION_API_MAJOR < 2
 602                         #error SEE too old
 603                         #endif
 604                 ]])],[cf_result=yes],[cf_result=no])
 605                 EL_RESTORE_FLAGS
 606                 if test "$cf_result" = yes; then
 607                         LIBS="$SEE_LIBS $LIBS"
 608                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 609                         AC_SUBST(SEE_CFLAGS)
 610                 fi
 611                 AC_MSG_RESULT($cf_result)
 612         else
 613                 if test -n "$withval" && test "x$withval" != xno; then
 614                         AC_MSG_ERROR([SEE not found])
 615                 else
 616                         AC_MSG_WARN([SEE support disabled])
 617                 fi
 618         fi
 619 fi
 620
 621 # ===================================================================
 622 # Check for SpiderMonkey, optional even if installed.
 623 # ===================================================================
 624
 625 xulrunner_includes=
 626 xulrunner_libs=
 627 AC_ARG_WITH(xulrunner_includes, [  --with-xulrunner_includes=DIR
 628                           When set, the libmozjs of xulrunner is used instead of "standalone" SpiderMonkey],
 629             [xulrunner_includes="$withval"])
 630 AC_ARG_WITH(xulrunner_libs, [  --with-xulrunner_libs=OPTIONS
 631                           Linker options for xulrunner,
 632                           eg. --with-xulrunner_libs="-Wl,-R/usr/lib/xulrunner -L/usr/lib/xulrunner -lmozjs"],
 633             [xulrunner_libs="$withval"])
 634 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 635             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 636
 637 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 638
 639 EL_SAVE_FLAGS
 640 cf_result=no
 641
 642 if test -z "$disable_spidermonkey"; then
 643         if test ! -d "$withval"; then
 644                 withval="";
 645         fi
 646         if test ! -z "$xulrunner_includes"; then
 647                 SPIDERMONKEY_LIBS="$xulrunner_libs"
 648                 SPIDERMONKEY_CFLAGS="-I$xulrunner_includes"
 649                 LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 650                 CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 651                 CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 652
 653                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 654                 #include <jsapi.h>]], [[JS_GetReservedSlot(NULL, NULL, 0, NULL)]])],[cf_result=yes],[cf_result=no])
 655         else
 656                 for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 657                         for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 658                                 for spidermonkeylib in js smjs mozjs; do
 659                                         if test "$cf_result" = no; then
 660                                                 SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib -l$spidermonkeylib"
 661                                                 SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 662
 663                                                 LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 664                                                 CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 665                                                 CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 666
 667                                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 668                                                      #include <jsapi.h>]], [[JS_GetReservedSlot(NULL, NULL, 0, NULL)]])],[cf_result=yes],[cf_result=no])
 669                                         fi
 670                                 done
 671                         done
 672                 done
 673         fi
 674 fi
 675
 676 AC_MSG_RESULT($cf_result)
 677 CONFIG_SPIDERMONKEY="$cf_result"
 678 if test "$cf_result" = "yes"; then
 679         AC_CHECK_FUNCS([[JS_ReportAllocationOverflow]])
 680         AC_CHECK_FUNCS(JS_SetBranchCallback)
 681         AC_CHECK_FUNCS(JS_TriggerOperationCallback, HAVE_JS_TRIGGEROPERATIONCALLBACK=yes)
 682 fi
 683 EL_RESTORE_FLAGS
 684
 685 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 686    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 687         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 688 else
 689         CONFIG_ECMASCRIPT_SMJS=no
 690 fi
 691
 692 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 693 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 694 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 695
 696 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes &&
 697    test "x$HAVE_JS_TRIGGEROPERATIONCALLBACK" = xyes &&
 698    test "x$HAVE_SETITIMER" = xyes; then
 699         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT, [ECMAScript heartbeat support])
 700 else
 701         CONFIG_ECMASCRIPT_SMJS_HEARTBEAT=no
 702 fi
 703 AC_SUBST(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT)
 704
 705
 706 # ===================================================================
 707 # Optional Spidermonkey-based ECMAScript browser scripting
 708 # ===================================================================
 709
 710 AC_ARG_ENABLE(sm-scripting,
 711               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 712               [if test "$enableval" != no; then enableval="yes"; fi
 713                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 714
 715 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 716    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 717         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 718 else
 719         CONFIG_SCRIPTING_SPIDERMONKEY=no
 720 fi
 721
 722 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 723    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 724         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 725         AC_SUBST(SPIDERMONKEY_LIBS)
 726         AC_SUBST(SPIDERMONKEY_CFLAGS)
 727         AC_SUBST(CONFIG_SPIDERMONKEY)
 728 fi
 729
 730 # ===================================================================
 731 # Check for Guile, optional even if installed.
 732 # ===================================================================
 733
 734 enable_guile="no";
 735
 736 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 737             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 738
 739 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 740 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 741 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 742 # for Guile in $PATH etc. --pasky
 743
 744 AC_MSG_CHECKING([for Guile])
 745
 746 if test "$enable_guile" = "yes"; then
 747         AC_MSG_RESULT(yes);
 748         ## Based on the GUILE_FLAGS macro.
 749
 750         if test -d "$withval"; then
 751                 GUILE_PATH="$withval:$PATH"
 752         else
 753                 GUILE_PATH="$PATH"
 754         fi
 755
 756         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 757
 758         ## First, let's just see if we can find Guile at all.
 759         if test "$GUILE_CONFIG" != no; then
 760                 cf_result="yes";
 761
 762                 GUILE_LIBS="`guile-config link`"
 763                 GUILE_CFLAGS="`guile-config compile`"
 764                 LIBS="$GUILE_LIBS $LIBS"
 765                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 766                 AC_SUBST(GUILE_CFLAGS)
 767                 cat <<EOF
 768 ***********************************************************************
 769 The Guile support is incomplete and not so well integrated to ELinks
 770 yet. That means, e.g., that you have no Guile console and there might
 771 not be all the necessary hooks. Also, the Guile interface is not too
 772 well tested (success stories heartily welcomed!).  See
 773 src/scripting/guile/README for further details and hints.
 774 ***********************************************************************
 775 EOF
 776         else
 777                 if test -n "$withval" && test "x$withval" != xno; then
 778                         AC_MSG_ERROR([Guile not found])
 779                 else
 780                         AC_MSG_WARN([Guile support disabled])
 781                 fi
 782         fi
 783 else
 784         AC_MSG_RESULT(no);
 785 fi
 786
 787 # ===================================================================
 788 # Check for Perl
 789 # ===================================================================
 790 enable_perl="no";
 791
 792 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 793             [
 794 if test "$withval" = yes; then
 795         # FIXME: If withval is a valid directory append it to PATH
 796         # so that you can specify one of several perl installations.
 797         withval="";
 798         enable_perl=yes;
 799 fi
 800             ])
 801
 802 AC_MSG_CHECKING([for Perl])
 803
 804 cf_result=no
 805
 806 EL_SAVE_FLAGS
 807
 808 if test "$enable_perl" = "yes"; then
 809         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 810         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 811         LIBS="$PERL_LIBS $LIBS"
 812         CFLAGS="$PERL_CFLAGS $CFLAGS"
 813         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 814         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 815 #include <EXTERN.h>
 816 #include <perl.h>
 817 #include <perlapi.h>
 818 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 819 fi
 820
 821 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 822
 823 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 824 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 825 #include <EXTERN.h>
 826 #include <perl.h>
 827 extern PerlInterpreter *my_perl;
 828 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 829 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 830                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 831 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 832
 833 if test "$cf_result" != "yes"; then
 834         EL_RESTORE_FLAGS
 835 else
 836         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 837
 838         CFLAGS="$CFLAGS_X"
 839         CPPFLAGS="$CPPFLAGS_X"
 840         AC_SUBST(PERL_LIBS)
 841         AC_SUBST(PERL_CFLAGS)
 842 fi
 843
 844 # ===================================================================
 845 # Check for Python
 846 # ===================================================================
 847 enable_python="no";
 848
 849 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 850             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 851
 852 EL_SAVE_FLAGS
 853 cf_result=no
 854
 855 AC_MSG_CHECKING([for Python])
 856
 857 if test "$enable_python" = "yes"; then
 858         AC_MSG_RESULT(yes);
 859
 860         if test -d "$withval"; then
 861                 PYTHON_PATH="$withval:$PATH"
 862         else
 863                 PYTHON_PATH="$PATH"
 864         fi
 865
 866         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 867
 868         if test "$PYTHON" != no; then
 869                 cf_result="yes";
 870
 871                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 872                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 873                 LIBS="$PYTHON_LIBS $LIBS"
 874                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 875                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 876
 877                 if test "$cf_result" != "yes"; then
 878                         EL_RESTORE_FLAGS
 879                 else
 880                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 881                         AC_SUBST(PYTHON_LIBS)
 882                         AC_SUBST(PYTHON_CFLAGS)
 883                         CPPFLAGS="$CPPFLAGS_X"
 884                         cat <<EOF
 885 ***********************************************************************
 886 The Python support is incomplete and not so well integrated to ELinks
 887 yet. That means, e.g., that you have no Python console and there might
 888 not be all the necessary hooks. Also, the Python interface is not too
 889 well tested (success stories heartily welcomed!).
 890 ***********************************************************************
 891 EOF
 892                 fi
 893         else
 894                 if test -n "$withval" && test "x$withval" != xno; then
 895                         AC_MSG_ERROR([Python not found])
 896                 else
 897                         AC_MSG_WARN([Python support disabled])
 898                 fi
 899         fi
 900 else
 901         AC_MSG_RESULT(no);
 902 fi
 903
 904
 905 # ===================================================================
 906 # Check for Lua, optional even if installed.
 907 # ===================================================================
 908
 909 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 910 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 911
 912 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 913             [if test "$withval" = no; then disable_lua=yes; fi])
 914 AC_MSG_CHECKING([for Lua])
 915
 916 EL_SAVE_FLAGS
 917 cf_result=no
 918
 919 if test -z "$disable_lua"; then
 920         if test ! -d "$withval"; then
 921                 withval="";
 922         fi
 923         for luadir in "$withval" "" /usr /usr/local; do
 924                 for suffix in "" 51; do
 925                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 926                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 927                                 LUA_LIBS="-L$luadir/lib -llua$suffix -lm"
 928                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 929
 930                                 LIBS="$LUA_LIBS $LIBS_X"
 931                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 932                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 933
 934                                 # Check that it is a compatible Lua version
 935                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lauxlib.h>]
 936                                                 #include <lua.h>
 937                                                 #include <lualib.h>
 938                                                 ], [[   lua_State *L = luaL_newstate();
 939                                                 luaL_openlibs(L);
 940                                                 lua_pushboolean(L, 1);
 941                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 942                         fi
 943                 done
 944         done
 945 fi
 946
 947 AC_MSG_RESULT($cf_result)
 948
 949 if test "$cf_result" != yes; then
 950         EL_RESTORE_FLAGS
 951 else
 952         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 953         AC_CHECK_HEADERS(lauxlib.h)
 954
 955         CFLAGS="$CFLAGS_X"
 956         CPPFLAGS="$CPPFLAGS_X"
 957         AC_SUBST(LUA_LIBS)
 958         AC_SUBST(LUA_CFLAGS)
 959 fi
 960
 961 # ===================================================================
 962 # Check for TRE library
 963 # ===================================================================
 964 #
 965 # This section only checks that --without-tre is not given and the
 966 # library seems to work, and sets TRE_CFLAGS, TRE_LIBS, and
 967 # tre_log.  It does not define CONFIG_TRE, and always resets
 968 # LIBS and CFLAGS back to their original values.
 969 #
 970 # After any --enable-utf-8 and --disable-utf-8 options have been
 971 # handled, a separate section decides whether to actually use TRE.
 972 #
 973 # tre version 0.8.0 or higher is required which have the "tre_" prefix
 974 # for functions.
 975
 976 AC_ARG_WITH([[tre]], [[  --without-tre           disable TRE regex search support]])
 977 if test "$with_tre" = no; then
 978         AC_MSG_CHECKING([[for TRE]])
 979         AC_MSG_RESULT([[disabled]])
 980         tre_log="no (explicitly disabled)"
 981 else
 982         AC_MSG_CHECKING([[for TRE in pkg-config]])
 983         if pkg-config tre; then
 984                 TRE_CFLAGS=`pkg-config --cflags tre`
 985                 TRE_LIBS=`pkg-config --libs tre`
 986                 AC_MSG_RESULT([[yes]])
 987         else
 988                 # <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=513055>
 989                 # "libtre-dev: /usr/lib/pkgconfig/tre.pc missing"
 990                 # so we look for the library even if pkg-config doesn't know about it.
 991                 TRE_CFLAGS=
 992                 TRE_LIBS=-ltre
 993                 AC_MSG_RESULT([[no, but let's try defaults]])
 994         fi
 995
 996         AC_MSG_CHECKING([[for TRE header and library]])
 997         EL_SAVE_FLAGS
 998         CFLAGS="$TRE_CFLAGS $CFLAGS"
 999         LIBS="$TRE_LIBS $LIBS" # must be first, because of regfree conflict
1000         AC_TRY_LINK([#include <tre/tre.h>],
1001                     [regex_t re;
1002                      regmatch_t match[1];
1003                      tre_regwcomp(&re, L"zap", REG_ICASE);
1004                      tre_regwexec(&re, L"ELIZAPROGRAM", 1, match, 0);],
1005                     [AC_MSG_RESULT([[yes]])
1006                      tre_log="available"],
1007                     [AC_MSG_RESULT([[no]])
1008                      tre_log="no (TRE not found)"])
1009         EL_RESTORE_FLAGS
1010 fi
1011
1012 # ===================================================================
1013 # Check for Ruby, optional even if installed.
1014 # ===================================================================
1015
1016 EL_CONFIG_SCRIPTING_RUBY
1017
1018 # ===================================================================
1019 # Setup global scripting
1020 # ===================================================================
1021
1022 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
1023 AC_SUBST(CONFIG_SCRIPTING_GUILE)
1024 AC_SUBST(CONFIG_SCRIPTING_LUA)
1025 AC_SUBST(CONFIG_SCRIPTING_PERL)
1026 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
1027 AC_SUBST(CONFIG_SCRIPTING_RUBY)
1028 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
1029 AC_SUBST(CONFIG_SCRIPTING)
1030
1031
1032 # ===================================================================
1033 # Check for SSL support.
1034 # ===================================================================
1035
1036 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
1037 # is enabled, we won't try to use OpenSSL anymore.
1038
1039 # For wiping SSL hooks..
1040 #ifdef CONFIG_SSL
1041
1042 chosen_ssl_library=""
1043
1044 AC_ARG_WITH(gnutls, [[  --without-gnutls        disable GNUTLS SSL support]])
1045 AC_ARG_WITH(gnutls, [[  --with-gnutls           enable GNUTLS SSL support]],
1046             [case "$with_gnutls" in
1047                 "no")   : ;;
1048                 "yes")  chosen_ssl_library="GNUTLS" ;;
1049                 *)      chosen_ssl_library="GNUTLS"
1050                         AC_MSG_WARN([[Support for --with-gnutls=DIR has been removed.
1051 You may have to set the PKG_CONFIG_PATH environment variable instead.]]) ;;
1052              esac])
1053
1054 AC_ARG_WITH(openssl, [[  --without-openssl       disable OpenSSL support]])
1055 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]],
1056             [case "$with_openssl" in
1057                 "no")   : ;;
1058                 *)      chosen_ssl_library="OpenSSL" ;;
1059              esac])
1060
1061 AC_ARG_WITH(nss_compat_ossl, [[  --with-nss_compat_ossl[=DIR]
1062                           NSS compatibility SSL libraries/include files]],
1063             [case "$with_nss_compat_ossl" in
1064                 "no")   : ;;
1065                 *)      chosen_ssl_library="nss_compat_ossl" ;;
1066              esac])
1067
1068 # ---- nss_compat_ossl
1069
1070 if test "$with_nss_compat_ossl" = no; then
1071         # explicitly disabled
1072         :
1073 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "nss_compat_ossl"; then
1074         # not used, because $chosen_ssl_library was chosen
1075         :
1076 elif test -z "${with_nss_compat_ossl+set}"; then
1077         # SSL_library_init() in nss_compat_ossl 0.9.2 calls exit(1)
1078         # with no error message if there is no certificate database.
1079         # https://bugzilla.redhat.com/show_bug.cgi?id=463437
1080         # So ELinks uses nss_compat_ossl only if explicitly requested.
1081         :
1082 else
1083         EL_SAVE_FLAGS
1084         if test "$with_nss_compat_ossl" = yes; then
1085                 if pkg-config nss; then
1086                         CFLAGS="$CFLAGS_X `pkg-config --cflags nss`"
1087                         LIBS="$LIBS_X `pkg-config --libs nss`"
1088                 else
1089                         with_nss_compat_ossl=no
1090                 fi
1091         else
1092                 # Without pkg-config, we'll kludge in some defaults
1093                 CFLAGS="$CFLAGS_X -I$with_nss_compat_ossl/include -I/usr/include/nss3 -I/usr/include/nspr4"
1094                 LIBS="$LIBS_X -L$with_nss_compat_ossl/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
1095         fi
1096         AC_CHECK_HEADERS(nss_compat_ossl/nss_compat_ossl.h,, [with_nss_compat_ossl=no], [#define NSS_COMPAT_OSSL_H])
1097         AC_CHECK_LIB(nss_compat_ossl, X509_free,, [with_nss_compat_ossl=no])
1098
1099         if test "$with_nss_compat_ossl" = "no"; then
1100                 EL_RESTORE_FLAGS
1101         else
1102                 LIBS="$LIBS -lnss_compat_ossl"
1103                 EL_CONFIG(CONFIG_NSS_COMPAT_OSSL, [nss_compat_ossl])
1104                 chosen_ssl_library="nss_compat_ossl"
1105         fi
1106 fi
1107
1108 # ---- OpenSSL
1109
1110 AC_MSG_CHECKING([for OpenSSL])
1111
1112 EL_SAVE_FLAGS
1113
1114 if test "$with_openssl" = no; then
1115         cf_result="explicitly disabled"
1116
1117 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "OpenSSL"; then
1118         cf_result="not used, because $chosen_ssl_library was chosen"
1119
1120 else
1121         cf_result=no
1122         for ssldir in "$with_openssl" "" /usr /usr/local/openssl \
1123                          /usr/lib/openssl /usr/local/ssl \
1124                          /usr/local/www /usr/lib/ssl /usr/local \
1125                          /usr/pkg /opt /opt/openssl; do
1126                 if test "$cf_result" = no; then
1127                         if test -d "$ssldir"; then
1128                                 OPENSSL_CFLAGS="-I$ssldir/include"
1129                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1130                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1131                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1132 #                               # FIXME: This created serious portability problems. --pasky
1133 #                               if test "$CC" == "gcc"; then
1134 #                                       # I'm not sure about compatibility here. --pasky
1135 #                                       LIBS="$LIBS -R$ssldir/lib"
1136 #                               fi
1137                         else
1138                                 LIBS="-lssl -lcrypto $LIBS_X"
1139                         fi
1140                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1141                         if test "$cf_result" != yes; then
1142                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1143                         fi
1144                 fi
1145         done
1146
1147         if test "$cf_result" != yes; then
1148                 if test "${with_openssl-no}" != "no"; then
1149                         AC_MSG_ERROR([OpenSSL not found])
1150                 fi
1151                 EL_RESTORE_FLAGS
1152         else
1153                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1154                 chosen_ssl_library="OpenSSL"
1155
1156                 CFLAGS="$CFLAGS_X"
1157                 AC_SUBST(OPENSSL_CFLAGS)
1158         fi
1159 fi
1160
1161 AC_MSG_RESULT($cf_result)
1162
1163 # ---- GNU TLS
1164
1165 # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1166 # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1167 # ELinks will use its internal MD5 code instead.
1168 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1169
1170 if test "$with_gnutls" = no; then
1171         AC_MSG_CHECKING([[for GNUTLS]])
1172         AC_MSG_RESULT([[explicitly disabled]])
1173
1174 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "GNUTLS"; then
1175         AC_MSG_CHECKING([[for GNUTLS]])
1176         AC_MSG_RESULT([[not used, because $chosen_ssl_library was chosen]])
1177
1178 else
1179         cf_result=no
1180         AC_MSG_CHECKING([[for GNUTLS (1.2 or later) in pkg-config]])
1181         if pkg-config --atleast-version=1.2 gnutls; then
1182                 GNUTLS_CFLAGS=`pkg-config --cflags gnutls`
1183                 GNUTLS_LIBS=`pkg-config --libs gnutls`
1184                 AC_MSG_RESULT([[yes: $GNUTLS_CFLAGS $GNUTLS_LIBS]])
1185
1186                 EL_SAVE_FLAGS
1187                 LIBS="$GNUTLS_LIBS $LIBS"
1188                 CFLAGS="$CFLAGS $GNUTLS_CFLAGS"
1189                 CPPFLAGS="$CPPFLAGS $GNUTLS_CFLAGS"
1190
1191                 # Verify if it's really usable.  gnutls_session was
1192                 # renamed to gnutls_session_t before GNU TLS 1.2.0
1193                 # (on 2004-06-13); ELinks now requires this.
1194                 AC_MSG_CHECKING([[whether GNUTLS can be linked with]])
1195                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]],
1196                                                 [[gnutls_session_t dummy;
1197                                                   gnutls_check_version(NULL)]])],
1198                                [cf_result=yes],
1199                                [cf_result=no])
1200                 AC_MSG_RESULT([[$cf_result]])
1201
1202                 if test "$cf_result" = yes; then
1203                         # According to gnutls/NEWS, the function was originally
1204                         # added as gnutls_set_default_priority2 in GNUTLS 2.1.4
1205                         # (released 2007-10-27) and then renamed to
1206                         # gnutls_priority_set_direct in GNUTLS 2.1.7 (released
1207                         # 2007-11-29).
1208                         AC_CHECK_FUNCS([gnutls_priority_set_direct])
1209                 fi
1210
1211                 EL_RESTORE_FLAGS
1212         else
1213                 AC_MSG_RESULT([[$cf_result]])
1214         fi
1215
1216         if test "$cf_result" = yes; then
1217                 EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1218                 chosen_ssl_library="GNUTLS"
1219
1220                 LIBS="$GNUTLS_LIBS $LIBS"
1221                 AC_SUBST(GNUTLS_CFLAGS)
1222
1223         elif test "${with_gnutls-no}" != "no"; then
1224                 AC_MSG_ERROR([[GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.]])
1225         fi
1226 fi
1227
1228 # Final SSL setup
1229
1230 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS CONFIG_NSS_COMPAT_OSSL], [SSL])
1231 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1232 AC_SUBST(CONFIG_OPENSSL)
1233 AC_SUBST(CONFIG_GNUTLS)
1234 AC_SUBST(CONFIG_NSS_COMPAT_OSSL)
1235
1236 #endif
1237
1238 AC_MSG_CHECKING([whether to be or not to be])
1239 AC_MSG_RESULT([needs to be determined experimentally])
1240
1241 # ===================================================================
1242 # Check for IPv6 support and related functions.
1243 # ===================================================================
1244
1245 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1246 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1247 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1248
1249 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1250 if test "$HAVE_GETADDRINFO" != yes; then
1251         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1252         if test "$HAVE_GETADDRINFO" = yes; then
1253                 LIBS="$LIBS -linet6"
1254         fi
1255 fi
1256
1257
1258 # ===================================================================
1259 # Checking for X11 (window title restoring).
1260 # ===================================================================
1261
1262 AC_PATH_X
1263 if test x"$no_x" != xyes; then
1264         EL_SAVE_FLAGS
1265         if test -n "$x_includes"; then
1266                 X_CFLAGS="-I$x_includes"
1267                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1268                 CFLAGS="$CFLAGS $X_CFLAGS"
1269         fi
1270         if test -n "$x_libraries"; then
1271                 LDFLAGS="$LDFLAGS -L$x_libraries"
1272         fi
1273         LIBS="-lX11 $LIBS"
1274         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1275         EL_RESTORE_FLAGS
1276         if test "$cf_result" = yes; then
1277                 if test -n "$x_libraries"; then
1278                         LDFLAGS="$LDFLAGS -L$x_libraries"
1279                 fi
1280                 LIBS="-lX11 $LIBS"
1281                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1282                 AC_SUBST(X_CFLAGS)
1283         fi
1284 fi
1285
1286
1287 # ===================================================================
1288 # Backtraces displaying support.
1289 # ===================================================================
1290
1291 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1292 # possible checks for other system-specific means go here
1293
1294
1295 # ===================================================================
1296 # Gettext grey zone. Beware.
1297 # ===================================================================
1298
1299 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1300
1301 AM_GNU_GETTEXT
1302
1303 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1304 dnl # f33r d4 l33t... I hope it's portable. :)
1305 dnl cf_result=$((48#z - 48#a + 1));
1306 dnl AC_MSG_RESULT($cf_result)
1307
1308
1309 # ===================================================================
1310 # Compile-time features control
1311 # ===================================================================
1312
1313 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1314               [  --disable-cookies       disable cookie support])
1315
1316 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1317               [  --disable-formhist      disable form history support])
1318
1319 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1320               [  --disable-globhist      disable global history support])
1321
1322
1323 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1324               [  --disable-mailcap       disable mailcap support])
1325
1326 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1327               [  --disable-mimetypes     disable mimetypes files support])
1328
1329
1330 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1331               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1332               [IPv6],
1333               [  --disable-ipv6          disable IPv6 support])
1334
1335 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1336               [  --enable-bittorrent     enable BitTorrent protocol support])
1337
1338 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1339               [  --disable-data          disable data protocol support])
1340
1341 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1342               [  --disable-uri-rewrite   disable URI rewrite support])
1343
1344 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1345               [  --enable-cgi            enable local CGI support])
1346
1347 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1348               [  --enable-finger         enable finger protocol support])
1349
1350 # ===================================================================
1351 # FSP protocol
1352 # ===================================================================
1353 EL_SAVE_FLAGS
1354
1355 if test "x${enable_fsp}" != xno; then
1356         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1357
1358         if test "$HAVE_FSPLIB" = yes; then
1359                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1360                 if test "$HAVE_FSPLIB" = yes; then
1361                         LIBS="$LIBS -lfsplib"
1362                 else
1363                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1364                         if test "$HAVE_FSPLIB" = yes; then
1365                                 LIBS="$LIBS -lfsp"
1366                         fi
1367                 fi
1368         fi
1369 fi
1370
1371 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1372               [  --enable-fsp            enable FSP protocol support])
1373
1374 if test "x$CONFIG_FSP" = xno; then
1375         EL_RESTORE_FLAGS
1376 fi
1377
1378 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1379               [  --disable-ftp           disable ftp protocol support])
1380
1381 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1382               [  --enable-gopher         enable gopher protocol support])
1383
1384 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1385               [  --enable-nntp           enable nntp protocol support])
1386
1387 # ===================================================================
1388 # SMB protocol support.
1389 # ===================================================================
1390 EL_SAVE_FLAGS
1391
1392 if test "x${enable_smb}" != xno; then
1393         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1394
1395         if test "$HAVE_SMBCLIENT" = yes; then
1396                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1397                 if test "$HAVE_SMBCLIENT" = yes; then
1398                         LIBS="$LIBS -lsmbclient"
1399                 fi
1400         fi
1401 fi
1402
1403 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1404               [  --enable-smb            enable Samba protocol support])
1405
1406 if test "x$CONFIG_SMB" = xno; then
1407         EL_RESTORE_FLAGS
1408 fi
1409
1410
1411 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1412               [  --disable-mouse         disable mouse support])
1413
1414 # GPM mouse is Linux specific, so ...
1415 CONFIG_SYSMOUSE=yes
1416 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1417               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1418               [BSD sysmouse],
1419               [  --disable-sysmouse      disable BSD sysmouse support])
1420
1421 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1422               [  --enable-88-colors      enable 88 color support])
1423
1424 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1425               [  --enable-256-colors     enable 256 color support])
1426
1427 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1428               [  --enable-true-color     enable true color support])
1429
1430 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1431               [  --enable-exmode         enable exmode (CLI) interface])
1432
1433 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1434               [  --disable-leds          disable LEDs support])
1435
1436 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1437               [  --disable-marks         disable document marks support])
1438
1439
1440 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1441               [  --disable-css           disable Cascading Style Sheet support])
1442
1443 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1444               [  --enable-html-highlight HTML highlighting using DOM engine])
1445
1446 # Everything in the tree already uses CONFIG_DOM
1447 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1448 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1449
1450 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1451               [  --disable-backtrace     disable backtrace support])
1452
1453 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1454               [  --enable-no-root        enable prevention of usage by root])
1455
1456
1457 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1458               [  --enable-debug          enable leak debug and internal error checking])
1459
1460 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1461               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1462
1463 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1464               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1465
1466 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1467               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1468
1469 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1470               [  --disable-utf-8         disable UTF-8 support])
1471
1472 EL_ARG_DEPEND(CONFIG_COMBINE, combining, [CONFIG_UTF8:yes HAVE_WCWIDTH:yes], [Combining characters],
1473               [  --enable-combining      support Unicode combining characters (experimental)])
1474
1475
1476 AC_ARG_ENABLE(weehoofooboomookerchoo,
1477               [
1478     Also check out the features.conf file for more information about features!
1479               ],
1480               [AC_MSG_ERROR(Are you strange, or what?)])
1481
1482
1483 # ===================================================================
1484 # Decide whether to use TRE
1485 # ===================================================================
1486 #
1487 # This must be done after the CONFIG_UTF8 check above.
1488 # The first part of the TRE check is separate, to get
1489 # the configure --help output in a sensible order.
1490 #
1491 # After this section, nothing else must be added to the
1492 # beginning of $LIBS.
1493
1494 if test "$tre_log" = "available"; then
1495         if test "$CONFIG_UTF8" = "yes"; then
1496                 # When CONFIG_UTF8 and CONFIG_TRE are both defined,
1497                 # src/viewer/text/search.c makes a string of
1498                 # unicode_val_T and gives it to regwexec(), which
1499                 # expects a string of wchar_t.  If the unicode_val_T
1500                 # and wchar_t types are too different, this won't
1501                 # work, so try to detect that and disable regexp
1502                 # operations entirely in that case.
1503                 #
1504                 # Currently, this code only compares the sizes of the
1505                 # types.  src/intl/charsets.h defines unicode_val_T as
1506                 # uint32_t, so we check whether wchar_t has exactly 32
1507                 # bits.  But don't use AC_CHECK_SIZEOF for this, because
1508                 # there doesn't seem to be a documented way to get the
1509                 # result of that for use in the configure script.
1510                 #
1511                 # C99 says the implementation can define
1512                 # __STDC_ISO_10646__ if wchar_t values match ISO 10646
1513                 # (or Unicode) numbers in all locales.  Do not check
1514                 # that macro here, because it is too restrictive: it
1515                 # should be enough for ELinks if the values match in
1516                 # the locales where ELinks is actually run.
1517                 AC_MSG_CHECKING([[whether wchar_t is exactly 32-bit]])
1518                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1519 #include <limits.h>
1520 #include <stddef.h>
1521 int dummy[(sizeof(wchar_t) * CHAR_BIT == 32) ? 1 : -1];]], [])],
1522                         [AC_MSG_RESULT([[yes]])
1523                          tre_log="TRE"],
1524                         [AC_MSG_RESULT([[no]])
1525                          tre_log="no (unsuitable wchar_t)"])
1526         else
1527                 # If UTF-8 is not used, then wchar_t doesn't matter.
1528                 tre_log="TRE"
1529         fi
1530 fi
1531
1532 if test "$tre_log" = "TRE"; then
1533         AC_DEFINE([CONFIG_TRE], [1],
1534                 [Define as 1 to use the TRE library for regular expression searching.  This requires the <tre/regex.h> header file.  If you define CONFIG_UTF8 too, then wchar_t must be exactly 32-bit so that it matches unicode_val_T.])
1535         # TRE_CFLAGS will be used only where needed.
1536         #
1537         # Bug 1081: If both TRE and libc define the regfree function,
1538         # ELinks needs to use the version defined by TRE because
1539         # that's the one compatible with regex_t initialized by the
1540         # regwcomp function of TRE.  Therefore put $TRE_LIBS at the
1541         # very beginning of $LIBS so that the linker hopefully finds
1542         # regfree there before it examines libc.  In particular,
1543         # $PERL_LIBS appears to often include "-lc".
1544         #
1545         # This scheme still risks a crash if ELinks is linked with
1546         # some static library that uses GNU <regex.h> extensions that
1547         # TRE does not implement.  For example, the library might call
1548         # re_compile_pattern, which is found in GNU libc, and then
1549         # regfree, which is found in TRE and probably crashes with the
1550         # GNU-initialized regex_t.  Ways to avoid such crashes:
1551         #
1552         # - Change TRE so it defines only tre_... functions and does
1553         #   not attempt to override the POSIX names by default.
1554         #
1555         # - Change ELinks to access TRE only via dlopen and dlsym.
1556         #   The problem then is how to find the correct file name.
1557         #   There might be libtre.so.4 and libtre.so.5 with different
1558         #   ABI.  How can this configure script detect which of them
1559         #   matches the <tre/regex.h> in the include path?
1560         #
1561         # - Replace the static library with a shared library.  At
1562         #   least on GNU/Linux, when the shared library is built, the
1563         #   linker should note that e.g. regfree is defined in libc
1564         #   and has the GLIBC_2.0 version there, and write that
1565         #   version string to the shared library as well; because TRE
1566         #   does not provide regfree with that version, any regfree
1567         #   calls at run time should then get resolved to libc.
1568         LIBS="$TRE_LIBS $LIBS"
1569 else
1570         TRE_LIBS=
1571         TRE_CFLAGS=
1572 fi
1573 AC_SUBST(TRE_CFLAGS)
1574 AC_SUBST(TRE_LIBS)
1575 EL_LOG_CONFIG([CONFIG_TRE], [[Regexp searching]], [[$tre_log]])
1576
1577
1578 # ===================================================================
1579 # Further LDFLAGS tweaks
1580 # ===================================================================
1581
1582 # == EMX hack
1583
1584 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1585 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1586
1587
1588 # Check for -rdynamic
1589 #
1590 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1591 # the executable to its dynamic symbol table.  ELinks uses this for
1592 # two purposes:
1593 #
1594 # 1. If ELinks detects a bug, it can try to display a backtrace by
1595 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1596 #    manual states users of GNU ld must pass -rdynamic to make the
1597 #    symbols available to the program.
1598 #
1599 # 2. It would eventually be nice to dynamically load shared
1600 #    libraries as plugins (bug 73).  The plugins must be able to
1601 #    call ELinks functions.  This can be implemented either by
1602 #    registering all callable functions in ELinks-specific data
1603 #    structures, or by letting the dynamic linker handle them.
1604 #    The latter way requires something equivalent to -rdynamic.
1605 #
1606 # Because backtraces are not needed for correct operation, and bug
1607 # 73 is not yet being fixed, the configure script and makefiles
1608 # should not complain to the user if they find that -rdynamic does
1609 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1610 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1611 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1612 # -rdynamic but does something equivalent automatically.  (This was
1613 # tested with "nm -D elinks | grep redraw_from_window".)
1614 #
1615 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1616 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1617 # linker from finding the libraries listed in -l operands.  So this
1618 # -rdynamic check needs to happen after the libraries have already
1619 # been added to $LDFLAGS.
1620 AC_MSG_CHECKING([for -rdynamic])
1621 LDFLAGS_X="$LDFLAGS"
1622 LDFLAGS="-rdynamic $LDFLAGS"
1623 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1624 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1625 AC_MSG_RESULT($have_rdynamic)
1626
1627 # ===================================================================
1628 # Export directory paths
1629 # ===================================================================
1630
1631 # Set up the ``entry points'' if they were not supplied by builder
1632 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1633 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1634
1635 # Create CONFDIR #define for config.h
1636
1637 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1638 # it's autoconf fault to force us to do such hacks ;p.
1639 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1640   # sysconfdir is set to its default value... fine, let's append /elinks/
1641   # XXX: We can't modify listing of the default in ./configure --help :-(
1642   sysconfdir_n=`eval echo "$sysconfdir"`
1643   sysconfdir=$sysconfdir_n
1644   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1645         sysconfdir="$sysconfdir/elinks"
1646 fi
1647
1648 CONFDIR=$sysconfdir
1649 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1650 AC_SUBST(CONFDIR)
1651
1652 # Create LOCALEDIR #define for config.h
1653 LOCALEDIR=`eval echo "$datadir/locale"`
1654 while echo "$LOCALEDIR" | grep "\\$"
1655 do
1656         LOCALEDIR=`eval echo "$LOCALEDIR"`
1657 done > /dev/null 2> /dev/null
1658 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1659 AC_SUBST(LOCALEDIR)
1660
1661 # Create LIBDIR #define for config.h
1662 LIBDIR=`eval echo "$libdir"`
1663 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1664 AC_SUBST(LIBDIR)
1665
1666 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1667 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1668
1669
1670 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1671 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1672         #error not tcc
1673         #endif ]])],[cf_result=yes],[cf_result=no])
1674
1675 if test "$cf_result" = "yes"; then
1676         AC_DEFINE([HAVE_ALLOCA])
1677         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1678                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1679                 override the alloca macro defined in <stddef.h> of TCC.
1680                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1681                 it has already been included, and does not redefine alloca.
1682                 This might not work in future glibc versions though, because
1683                 the names of the #include guard macros are not documented.
1684                 The incompatibility has been reported to the tinycc-devel
1685                 mailing list on 2008-07-14.  If a future version of TCC provides
1686                 an <alloca.h> of its own, this hack won't be needed.])
1687 fi
1688 # ===================================================================
1689 # A little fine tuning of gcc specific options (continued)
1690 # ===================================================================
1691
1692 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1693   if test "$CONFIG_DEBUG" = "yes"; then
1694     # We want to see all warnings and live with none (in debug mode).
1695     CFLAGS="$CFLAGS -Werror"
1696   fi
1697
1698   case "`$CC -dumpversion`" in
1699     3.0|3.1|3.2)
1700       # These should be ok using -Werror
1701       ;;
1702     3.*)
1703       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1704       # "dereferencing type-punned pointer will break strict-aliasing rules"
1705       # warnings. Disable them by not doing any strict-aliasing. The
1706       # alternative is just too ugly. Thanks gcc guys!! ;)
1707       CFLAGS="$CFLAGS -fno-strict-aliasing"
1708       ;;
1709     4.5*)
1710       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign -Wno-enum-compare"
1711       ;;
1712     4.*)
1713       # Do not show warnings related to (char * | unsigned char *) type
1714       # difference.
1715       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1716       ;;
1717     *)
1718       # These should be ok using -Werror
1719       ;;
1720   esac
1721
1722   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1723   # warning: the address of `builtin_modules' will always evaluate as `true'
1724   # This hits the object_lock and foreach_module macros in particular.
1725   # It would be okay to put something in the macros to avoid the warning,
1726   # but currently this seems to require defining parallel macros that skip
1727   # the NULL check, and that's too ugly.  So we instead disable the warning.
1728   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1729   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1730   for warning_flag in -Wno-address -Wno-always-true; do
1731     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1732     EL_SAVE_FLAGS
1733     CFLAGS="$CFLAGS $warning_flag"
1734     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1735       [AC_MSG_RESULT([yes])
1736        break],
1737       [AC_MSG_RESULT([no])])
1738     EL_RESTORE_FLAGS
1739   done
1740
1741   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1742   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1743   # "warning: assuming signed overflow does not occur when assuming
1744   # that (X + c) > X is always true", which may be an incorrect
1745   # optimization (although allowed by the standard), and breaks the
1746   # build with -Werror.
1747   #
1748   # All of the following tests included -S -Wall -Wextra:
1749   #
1750   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1751   # * gcc-4.0 -O0: OK, compares the values
1752   # * gcc-4.0 -O2: assumes no overflow, does not warn
1753   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1754   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1755   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1756   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1757   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1758   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1759   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1760   #
1761   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1762   # * gcc-4.1 -O0: assumes no overflow, does not warn
1763   # * gcc-4.1 -O2: assumes no overflow, does not warn
1764   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1765   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1766   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1767   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1768   # * gcc-4.1 -O2 -ftrapv: compares the values
1769   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1770   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1771   #
1772   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1773   # * gcc-4.2 -O0: OK, compares the values
1774   # * gcc-4.2 -O2: assumes no overflow, warns about it
1775   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1776   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1777   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1778   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1779   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1780   # * gcc-4.2 -O2 -ftrapv: compares the values
1781   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1782   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1783   #
1784   # Apparently, -ftrapv does not work reliably at all.
1785   for overflow_flag in -fno-strict-overflow -fwrapv; do
1786     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1787     EL_SAVE_FLAGS
1788     CFLAGS="$CFLAGS $overflow_flag"
1789     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1790       [AC_MSG_RESULT([yes])
1791        break],
1792       [AC_MSG_RESULT([no])])
1793     EL_RESTORE_FLAGS
1794   done
1795 fi
1796
1797 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1798 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1799 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1800 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1801
1802 # ===================================================================
1803 # Colored make output
1804 # ===================================================================
1805
1806 if test $(`which tput` colors) -ge 4; then
1807         MAKE_COLOR=1
1808         AC_SUBST(MAKE_COLOR)
1809 fi
1810
1811 # ===================================================================
1812 # Generated files
1813 # ===================================================================
1814
1815 AC_CONFIG_FILES([ \
1816  Makefile.config \
1817  contrib/elinks.spec \
1818  contrib/lua/hooks.lua \
1819  contrib/conv/w3m2links.awk \
1820  doc/Doxyfile \
1821  doc/man/man1/elinks.1 \
1822  src/intl/gettext/ref-add.sed \
1823  src/intl/gettext/ref-del.sed
1824 ])
1825 AC_OUTPUT
1826
1827 abs_srcdir="$(cd "$srcdir" && pwd)"
1828 # builddir is always absolute!
1829 if test "$abs_srcdir" != "$builddir"; then
1830         # Bootstrap the Makefile creation
1831         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1832         "$MAKE" "SRC=$abs_srcdir" init
1833
1834         # Make cg-status ignore this build directory
1835         echo "*" > "$builddir/.gitignore"
1836 fi
1837
1838 # ===================================================================
1839 # Configuration summary
1840 # ===================================================================
1841
1842 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1843 cat features.log