configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(src/main/main.c)
   5 AC_CONFIG_AUX_DIR(config)
   6
   7 PACKAGE=elinks
   8 VERSION=0.12.GIT
   9 AC_SUBST(PACKAGE)
  10 AC_SUBST(VERSION)
  11 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  12 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  13 AC_CONFIG_HEADERS(config.h)
  14
  15 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  16 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  17 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  18
  19 MAKE=
  20
  21 for make in gnumake gmake make false; do
  22         if test "x$MAKE" = x; then
  23                 AC_PATH_PROGS(MAKE, "$make")
  24         fi
  25 done
  26
  27 builddir="`pwd`"
  28
  29 # Cleanup if we are configuring with a previous build in the tree
  30 if test -e Makefile.config; then
  31         AC_MSG_CHECKING([for previous build to clean])
  32         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  33         AC_MSG_RESULT(done)
  34 fi
  35
  36 dnl ===================================================================
  37 dnl Load feature configuration file and start logging features.
  38 dnl ===================================================================
  39
  40 features="features.conf"
  41 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  42 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  43 echo "Feature summary:" > features.log
  44
  45 dnl ===================================================================
  46 dnl Checks for programs.
  47 dnl ===================================================================
  48
  49 AC_PROG_CC
  50 AC_PROG_AWK
  51 AC_PATH_PROGS(AWK, "$AWK")
  52 AC_PROG_RANLIB
  53 AC_PROG_INSTALL
  54
  55 AC_PATH_PROGS(CG_COMMIT_ID, "cg-commit-id")
  56 AC_PATH_PROGS(SPARSE, "sparse")
  57
  58 CONFIG_ASCIIDOC="no"
  59 CONFIG_POD2HTML="no"
  60 CONFIG_XMLTO="no"
  61 CONFIG_JW="no"
  62
  63 if test "x$CONFIG_DOC" != xno; then
  64         AC_PATH_PROGS(ASCIIDOC, "asciidoc")
  65         if test "x$ASCIIDOC" != "x"; then
  66                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  67                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  68                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  69
  70                 echo > config.asciidoc-unsafe.txt
  71                 if "$ASCIIDOC" --unsafe config.asciidoc-unsafe.txt >/dev/null 2>/dev/null; then
  72                         ASCIIDOC_FLAGS=--unsafe
  73                 fi
  74                 rm config.asciidoc-unsafe.*
  75         fi
  76
  77         AC_PATH_PROGS(XMLTO, "xmlto")
  78         if test "x$XMLTO" != "x"; then
  79                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  80                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  81                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  82         fi
  83
  84         AC_PATH_PROGS(JW, "jw")
  85         if test "x$JW" != "x"; then
  86                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  87                 EL_CONFIG(MANUAL_JW, [PDF])
  88         fi
  89
  90         AC_PATH_PROGS(POD2HTML, "pod2html")
  91         if test "x$POD2HTML" != "x"; then
  92                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  93         fi
  94 fi
  95
  96 AC_SUBST(ASCIIDOC_FLAGS)
  97 AC_SUBST(CONFIG_ASCIIDOC)
  98 AC_SUBST(CONFIG_POD2HTML)
  99 AC_SUBST(CONFIG_XMLTO)
 100 AC_SUBST(CONFIG_JW)
 101
 102 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 103 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 104 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 105
 106 dnl gcc specific options (to be continued at the bottom of configure)
 107 if test "x$ac_cv_prog_gcc" = "xyes"; then
 108   dnl We want to see all warnings and live with none.
 109   dnl We can't set up -Werror here as there may be some warnings in test
 110   dnl suite of configure, and we don't want to fail them.
 111   CFLAGS="$CFLAGS -Wall"
 112 fi
 113
 114 dnl ===================================================================
 115 dnl Checks for special OSes.
 116 dnl ===================================================================
 117
 118 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 119 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 120 [
 121         AC_MSG_CHECKING([for $2])
 122
 123         for flag in $3; do
 124                 AC_TRY_COMPILE(, [#ifndef $flag
 125 kill me!
 126 #endif ], $1=yes, $1=no)
 127                 if test "[$]$1" = yes; then
 128                         EL_CONFIG([$1], [$2])
 129                         break
 130                 fi
 131         done
 132
 133         AC_MSG_RESULT([$]$1)
 134 ])
 135
 136 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 137 AC_SUBST(CONFIG_OS_BEOS)
 138
 139 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 140 AC_SUBST(CONFIG_OS_RISCOS)
 141
 142 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 143 AC_SUBST(CONFIG_OS_WIN32)
 144
 145 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 146 AC_SUBST(CONFIG_OS_OS2)
 147 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 148
 149 AC_MSG_CHECKING([for UNIX])
 150 dnl FIXME: some depend kind of mechanism
 151 if test "$CONFIG_OS_BEOS" = no && \
 152    test "$CONFIG_OS_RISCOS" = no && \
 153    test "$CONFIG_OS_WIN32" = no && \
 154    test "$CONFIG_OS_OS2" = no; then
 155         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 156 else
 157         CONFIG_OS_UNIX=no
 158 fi
 159 AC_MSG_RESULT($CONFIG_OS_UNIX)
 160 AC_SUBST(CONFIG_OS_UNIX)
 161
 162 dnl ===================================================================
 163 dnl Checks for header files.
 164 dnl ===================================================================
 165
 166 AC_HEADER_DIRENT
 167 AC_HEADER_STDC
 168 AC_HEADER_SYS_WAIT
 169 AC_HEADER_TIME
 170
 171 AC_CHECK_HEADERS(wctype.h)
 172 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 173 AC_CHECK_HEADERS(sigaction.h)
 174 AC_CHECK_HEADERS(arpa/inet.h)
 175 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 176 AC_CHECK_HEADERS(net/if.h netdb.h netinet/in.h netinet/in6_var.h)
 177 AC_CHECK_HEADERS(ifaddrs.h)
 178 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 179 AC_CHECK_HEADERS(sys/fmutex.h)
 180 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 181 AC_CHECK_HEADERS(sys/resource.h)
 182 AC_CHECK_HEADERS(sys/select.h)
 183 AC_CHECK_HEADERS(sys/signal.h)
 184 AC_CHECK_HEADERS(sys/socket.h)
 185 AC_CHECK_HEADERS(sys/time.h)
 186 AC_CHECK_HEADERS(sys/utsname.h)
 187 AC_CHECK_HEADERS(stdint.h inttypes.h)
 188 AC_CHECK_HEADERS(locale.h pwd.h)
 189 AC_CHECK_HEADERS(termios.h)
 190
 191
 192 AC_CHECK_HEADERS(sys/un.h,
 193         [CONFIG_INTERLINK=yes
 194          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 195         [CONFIG_INTERLINK=no])
 196 AC_SUBST(CONFIG_INTERLINK)
 197
 198 dnl ===================================================================
 199 dnl Checks for typedefs, structures, and compiler characteristics.
 200 dnl ===================================================================
 201
 202 AC_STRUCT_TM
 203 AC_C_CONST
 204 AC_C_INLINE
 205 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 206
 207 AC_SYS_LARGEFILE
 208 AC_TYPE_SIZE_T
 209 AC_TYPE_OFF_T
 210 EL_CHECK_TYPE(ssize_t, int)
 211 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 212 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 213 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 214 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 215 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 216
 217 AC_CHECK_SIZEOF(char, 1)
 218 AC_CHECK_SIZEOF(short, 2)
 219 AC_CHECK_SIZEOF(int, 4)
 220 AC_CHECK_SIZEOF(long, 4)
 221 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 222 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 223
 224 dnl Check for variadic macros
 225 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 226                 [#include <stdio.h>
 227                  #define a(b,c...) printf(b,##c)],
 228                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 229
 230 dnl Check for -rdynamic
 231 dnl
 232 dnl gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
 233 dnl the executable to its dynamic symbol table.  ELinks uses this for
 234 dnl two purposes:
 235 dnl
 236 dnl 1. If ELinks detects a bug, it can try to display a backtrace by
 237 dnl    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
 238 dnl    manual states users of GNU ld must pass -rdynamic to make the
 239 dnl    symbols available to the program.
 240 dnl
 241 dnl 2. It would eventually be nice to dynamically load shared
 242 dnl    libraries as plugins (bug 73).  The plugins must be able to
 243 dnl    call ELinks functions.  This can be implemented either by
 244 dnl    registering all callable functions in ELinks-specific data
 245 dnl    structures, or by letting the dynamic linker handle them.
 246 dnl    The latter way requires something equivalent to -rdynamic.
 247 dnl
 248 dnl Because backtraces are not needed for correct operation, and bug
 249 dnl 73 is not yet being fixed, the configure script and makefiles
 250 dnl should not complain to the user if they find that -rdynamic does
 251 dnl not work.  Besides, it was reported at elinks-users on 2006-09-12
 252 dnl that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
 253 dnl Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
 254 dnl -rdynamic but does something equivalent automatically.  (This was
 255 dnl tested with "nm -D elinks | grep redraw_from_window".)
 256 dnl
 257 dnl FIXME: This check doesn't work. Something to do with the compiler
 258 dnl happily ignoring it and stderr not being checked for error messages.
 259 AC_MSG_CHECKING([for -rdynamic])
 260 LDFLAGS_X="$LDFLAGS"
 261 LDFLAGS="$LDFLAGS -rdynamic"
 262 AC_TRY_LINK([], [], have_rdynamic=yes, have_rdynamic=no)
 263 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
 264 AC_MSG_RESULT($have_rdynamic)
 265
 266 dnl ===================================================================
 267 dnl Check for POSIX <regex.h>
 268 dnl ===================================================================
 269
 270 EL_CHECK_SYS_TYPE(regex_t, HAVE_REGEX_H, [#include <regex.h>])
 271
 272 dnl ===================================================================
 273 dnl Checks for library functions.
 274 dnl ===================================================================
 275
 276 AC_PROG_GCC_TRADITIONAL
 277 AC_FUNC_MEMCMP
 278 AC_FUNC_MMAP
 279 AC_FUNC_STRFTIME
 280 AC_CHECK_FUNCS(cfmakeraw gethostbyaddr herror strerror)
 281 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 282 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 283 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 284 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 285 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 286 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 287 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 288
 289 AC_HAVE_FUNCS(cygwin_conv_to_full_win32_path)
 290
 291 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 292 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 293 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 294
 295 dnl These aren't probably needed now, as they are commented in links.h.
 296 dnl I've no idea about their historical background, but I keep them here
 297 dnl just in the case they will help later. --pasky
 298 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 299 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 300 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 301 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 302
 303 if test x"$HAVE_RAISE" = x; then
 304         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 305                 AC_ERROR([Unable to emulate raise()])
 306         fi
 307 fi
 308
 309 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 310 AC_TRY_LINK([#include <stdarg.h>
 311 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 312 el_cv_HAVE_VA_COPY=yes,el_cv_HAVE_VA_COPY=no)])
 313 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 314         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 315 fi
 316
 317 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 318 AC_TRY_LINK([#include <unistd.h>
 319 ], [int page_size = sysconf(_SC_PAGE_SIZE);],
 320 el_cv_HAVE_SC_PAGE_SIZE=yes,el_cv_HAVE_SC_PAGE_SIZE=no)])
 321 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 322         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 323 fi
 324
 325 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 326 AC_TRY_RUN([
 327 #include <stdio.h>
 328 #include <stdarg.h>
 329 #include <stdlib.h>
 330 #include <string.h>
 331
 332 char buf[8];
 333
 334 int bar(char *buf, const char *format, va_list ap)
 335 {
 336        return vsnprintf(buf, 0, format, ap);
 337 }
 338
 339 void foo(const char *format, ...) {
 340        va_list ap;
 341        int len;
 342
 343        va_start(ap, format);
 344        len = bar(buf, format, ap);
 345        va_end(ap);
 346        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 347
 348        va_start(ap, format);
 349        len = bar(buf, format, ap);
 350        va_end(ap);
 351        if ((len != 6) && (len != 7)) exit(1);
 352
 353        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 354
 355        exit(0);
 356 }
 357 main() { foo("hello\n"); }
 358 ],
 359 el_cv_HAVE_C99_VSNPRINTF=yes,el_cv_HAVE_C99_VSNPRINTF=no,el_cv_HAVE_C99_VSNPRINTF=cross)])
 360 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 361         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 362 fi
 363
 364 AC_CHECK_LIB(dl, dlopen) # OpenSSL and Lua frequently needs it
 365
 366 dnl ===================================================================
 367 dnl Checks for libraries.
 368 dnl ===================================================================
 369
 370 dnl Replace `main' with a function in -lsocket:
 371 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 372 if test "$cf_result" = no; then
 373         AC_CHECK_LIB(socket, socket)
 374 fi
 375
 376 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 377 if test "$cf_result" = no; then
 378         AC_CHECK_LIB(socket, setsockopt)
 379 fi
 380
 381 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 382 if test "$cf_result" = no; then
 383         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 384         if test "$cf_result" = no; then
 385                 AC_CHECK_LIB(nsl, gethostbyname)
 386         else
 387                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 388         fi
 389 fi
 390
 391 dnl ===================================================================
 392 dnl Checks for packaging specific options.
 393 dnl ===================================================================
 394
 395 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 396             [ if test "$withval" != no && test "$withval" != yes; then
 397                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 398               fi ])
 399
 400 dnl ===================================================================
 401 dnl Checks for a libraries, optional even if installed.
 402 dnl ===================================================================
 403
 404 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 405 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 406 [
 407         AC_MSG_CHECKING([for $2 support])
 408
 409         if test "[$]$1" != no; then
 410                 AC_MSG_RESULT(yes)
 411                 EL_SAVE_FLAGS
 412                 if test -n "$withval" && test -d "$withval"; then
 413                         # Be a little more careful when setting
 414                         # include and lib directories. This way
 415                         # $withval will work when includes are
 416                         # there but the library is in the common
 417                         # /usr/lib ... Does the right thing when
 418                         # looking for gc on Debian.
 419                         if test -d "$withval/include"; then
 420                                 CFLAGS="$CFLAGS -I$withval/include"
 421                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 422                         else
 423                                 CFLAGS="$CFLAGS -I$withval"
 424                                 CPPFLAGS="$CPPFLAGS -I$withval"
 425                         fi
 426                         if test -d "$withval/lib"; then
 427                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 428                         fi
 429                 fi
 430
 431                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 432                 if test "[$]$1" = yes; then
 433                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 434                 fi
 435
 436                 if test "[$]$1" = yes; then
 437                         EL_CONFIG([$1], [$2])
 438                         LIBS="$LIBS -l$4"
 439                 else
 440                         if test -n "[$]WITHVAL_$1" &&
 441                            test "[$]WITHVAL_$1" != xno; then
 442                                 AC_MSG_ERROR([$2 not found])
 443                         fi
 444                         EL_RESTORE_FLAGS
 445                 fi
 446         else
 447                 AC_MSG_RESULT(disabled)
 448         fi
 449 ])
 450
 451 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 452 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 453 [
 454         $1=yes
 455         WITHVAL_$1=
 456
 457         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 458         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 459
 460         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 461
 462         EL_LOG_CONFIG([$1], [$2], [])
 463 ])
 464
 465 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 466         [  --without-gpm           disable gpm (mouse) support])
 467
 468 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzdopen,
 469         [  --without-zlib          disable zlib support])
 470
 471 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 472         [  --without-bzlib         disable bzlib support])
 473
 474 EL_ARG_DEPEND(CONFIG_BZIP2_ENCODING, bzip2_encoding, [CONFIG_BZIP2:yes],
 475               [Bzip2 content encoding],
 476               [  --enable-bzip2-encoding enable Content-Encoding: bzip2 support (requires patched bzlib)])
 477
 478 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 479         [  --without-idn           disable international domain names support])
 480
 481 if test "x{with_gc}" != xno; then
 482         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 483                 [  --with-gc               enable Boehm's garbage collector])
 484 fi
 485
 486 EL_ARG_ENABLE(CONFIG_LZMA, lzma, [lzma],
 487               [  --enable-lzma           enable lzma encoding support])
 488
 489 dnl ===================================================================
 490 dnl Check for GSSAPI, optional even if installed.
 491 dnl ===================================================================
 492
 493 enable_gssapi="no";
 494
 495 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 496             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 497
 498 AC_MSG_CHECKING([for GSSAPI])
 499
 500 if test "$enable_gssapi" = "yes"; then
 501         AC_MSG_RESULT(yes)
 502         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 503         GSSAPI_LIBS=`krb5-config --libs gssapi`
 504         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 505         LIBS="$GSSAPI_LIBS $LIBS"
 506         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 507 else
 508         AC_MSG_RESULT(no)
 509 fi
 510
 511 AC_SUBST(CONFIG_GSSAPI)
 512
 513 dnl ===================================================================
 514 dnl Bookmark and XBEL support
 515 dnl ===================================================================
 516
 517 EL_SAVE_FLAGS
 518
 519 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 520               [  --disable-bookmarks     disable bookmark support])
 521
 522 # Check whether --enable-xbel or --disable-xbel was given.
 523 if test "x${enable_xbel}" != xno; then
 524         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 525
 526         if test "$HAVE_LIBEXPAT" = yes; then
 527                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 528                 if test "$HAVE_LIBEXPAT" = yes; then
 529                         LIBS="$LIBS -lexpat"
 530                 fi
 531         fi
 532 fi
 533
 534
 535 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 536               [XBEL bookmarks],
 537               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 538
 539 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 540         EL_RESTORE_FLAGS
 541 fi
 542
 543 dnl ===================================================================
 544 dnl Checks for BSD sysmouse
 545 dnl ===================================================================
 546
 547 HAVE_SYSMOUSE_HEADER="no"
 548
 549 # Either of these header files provides the (same) sysmouse interface
 550 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 551
 552 dnl ===================================================================
 553 dnl Checks for OS/2
 554 dnl ===================================================================
 555
 556 if test "$CONFIG_OS_OS2" = yes; then
 557         EL_CONFIG_OS_OS2
 558 fi
 559
 560 dnl ===================================================================
 561 dnl Checks for Win32
 562 dnl ===================================================================
 563
 564 if test "$CONFIG_OS_WIN32" = yes; then
 565         EL_CONFIG_OS_WIN32
 566 fi
 567
 568 dnl ===================================================================
 569 dnl Check for SEE (Simple Ecmascript Engine)
 570 dnl ===================================================================
 571 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 572             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 573
 574 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 575 # SEE_FLAGS but I really don't want to require people to have Guile in order
 576 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 577 # for Guile in $PATH etc. --pasky
 578
 579 AC_MSG_CHECKING([for SEE])
 580
 581 CONFIG_ECMASCRIPT_SEE=no
 582
 583 if test "$enable_see" = "yes"; then
 584         AC_MSG_RESULT(yes);
 585         ## Based on the SEE_FLAGS macro.
 586
 587         if test -d "$withval"; then
 588                 SEE_PATH="$withval:$PATH"
 589         else
 590                 SEE_PATH="$PATH"
 591         fi
 592
 593         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 594
 595         ## First, let's just see if we can find Guile at all.
 596         if test "$SEE_CONFIG" != no; then
 597                 cf_result="yes";
 598
 599                 SEE_LIBS="`$SEE_CONFIG --libs`"
 600                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 601                 LIBS="$SEE_LIBS $LIBS"
 602                 EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 603                 AC_SUBST(SEE_CFLAGS)
 604         else
 605                 if test -n "$withval" && test "x$withval" != xno; then
 606                         AC_MSG_ERROR([SEE not found])
 607                 else
 608                         AC_MSG_WARN([SEE support disabled])
 609                 fi
 610         fi
 611 else
 612         AC_MSG_RESULT(no);
 613 fi
 614
 615
 616 dnl ===================================================================
 617 dnl Check for SpiderMonkey, optional even if installed.
 618 dnl ===================================================================
 619
 620 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 621             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 622 AC_MSG_CHECKING([for SpiderMonkey])
 623
 624 EL_SAVE_FLAGS
 625 cf_result=no
 626
 627 if test -z "$disable_spidermonkey"; then
 628         if test ! -d "$withval"; then
 629                 withval="";
 630         fi
 631         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 632                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 633                         for spidermonkeylib in js smjs mozjs; do
 634                                 if test "$cf_result" = no; then
 635                                         SPIDERMONKEY_LIBS="-l$spidermonkeylib"
 636
 637                                         if test ! -z "$spidermonkeydir"; then
 638                                                 SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib $SPIDERMONKEY_LIBS"
 639                                                 SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 640                                         fi
 641
 642                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 643                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 644                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 645
 646                                         AC_TRY_LINK([#define XP_UNIX
 647                                                      #include <jsapi.h>],
 648                                                      [JS_GetImplementationVersion()],
 649                                                      cf_result=yes, cf_result=no)
 650                                 fi
 651                         done
 652                 done
 653         done
 654 fi
 655
 656 AC_MSG_RESULT($cf_result)
 657 CONFIG_SPIDERMONKEY="$cf_result"
 658 EL_RESTORE_FLAGS
 659
 660 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 661    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 662         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 663 else
 664         CONFIG_ECMASCRIPT_SMJS=no
 665 fi
 666
 667 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 668 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 669 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 670
 671
 672 dnl ===================================================================
 673 dnl Optional Spidermonkey-based ECMAScript browser scripting
 674 dnl ===================================================================
 675
 676 AC_ARG_ENABLE(sm-scripting,
 677               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 678               [if test "$enableval" != no; then enableval="yes"; fi
 679                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 680
 681 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 682    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 683         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 684 else
 685         CONFIG_SCRIPTING_SPIDERMONKEY=no
 686 fi
 687
 688 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 689    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 690         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 691         AC_SUBST(SPIDERMONKEY_LIBS)
 692         AC_SUBST(SPIDERMONKEY_CFLAGS)
 693         AC_SUBST(CONFIG_SPIDERMONKEY)
 694 fi
 695
 696 dnl ===================================================================
 697 dnl Check for Guile, optional even if installed.
 698 dnl ===================================================================
 699
 700 enable_guile="no";
 701
 702 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 703             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 704
 705 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 706 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 707 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 708 # for Guile in $PATH etc. --pasky
 709
 710 AC_MSG_CHECKING([for Guile])
 711
 712 if test "$enable_guile" = "yes"; then
 713         AC_MSG_RESULT(yes);
 714         ## Based on the GUILE_FLAGS macro.
 715
 716         if test -d "$withval"; then
 717                 GUILE_PATH="$withval:$PATH"
 718         else
 719                 GUILE_PATH="$PATH"
 720         fi
 721
 722         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 723
 724         ## First, let's just see if we can find Guile at all.
 725         if test "$GUILE_CONFIG" != no; then
 726                 cf_result="yes";
 727
 728                 GUILE_LIBS="`guile-config link`"
 729                 GUILE_CFLAGS="`guile-config compile`"
 730                 LIBS="$GUILE_LIBS $LIBS"
 731                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 732                 AC_SUBST(GUILE_CFLAGS)
 733                 cat <<EOF
 734 ***********************************************************************
 735 The Guile support is incomplete and not so well integrated to ELinks
 736 yet. That means, e.g., that you have no Guile console and there might
 737 not be all the necessary hooks. Also, the Guile interface is not too
 738 well tested (success stories heartily welcomed!).  See
 739 src/scripting/guile/README for further details and hints.
 740 ***********************************************************************
 741 EOF
 742         else
 743                 if test -n "$withval" && test "x$withval" != xno; then
 744                         AC_MSG_ERROR([Guile not found])
 745                 else
 746                         AC_MSG_WARN([Guile support disabled])
 747                 fi
 748         fi
 749 else
 750         AC_MSG_RESULT(no);
 751 fi
 752
 753 dnl ===================================================================
 754 dnl Check for Perl
 755 dnl ===================================================================
 756 enable_perl="no";
 757
 758 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 759             [
 760 if test "$withval" = yes; then
 761         # FIXME: If withval is a valid directory append it to PATH
 762         # so that you can specify one of several perl installations.
 763         withval="";
 764         enable_perl=yes;
 765 fi
 766             ])
 767
 768 AC_MSG_CHECKING([for Perl])
 769
 770 cf_result=no
 771
 772 EL_SAVE_FLAGS
 773
 774 if test "$enable_perl" = "yes"; then
 775         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 776         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 777         LIBS="$PERL_LIBS $LIBS"
 778         CFLAGS="$PERL_CFLAGS $CFLAGS"
 779         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 780         AC_TRY_LINK([
 781 #include <EXTERN.h>
 782 #include <perl.h>
 783 #include <perlapi.h>
 784 ],
 785                     [PerlInterpreter *my_perl = perl_alloc();],
 786                     cf_result=yes, cf_result=no)
 787 fi
 788
 789 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 790
 791 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 792 AC_TRY_COMPILE([
 793 #include <EXTERN.h>
 794 #include <perl.h>
 795 extern PerlInterpreter *my_perl;
 796 ],
 797         [dSP; (void) POPpx;],
 798         [AC_MSG_RESULT([yes])
 799 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 800                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 801 no longer needs an "n_a" variable like it did in 5.8.7])],
 802         [AC_MSG_RESULT([no])])
 803
 804 if test "$cf_result" != "yes"; then
 805         EL_RESTORE_FLAGS
 806 else
 807         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 808
 809         CFLAGS="$CFLAGS_X"
 810         CPPFLAGS="$CPPFLAGS_X"
 811         AC_SUBST(PERL_LIBS)
 812         AC_SUBST(PERL_CFLAGS)
 813 fi
 814
 815 dnl ===================================================================
 816 dnl Check for Python
 817 dnl ===================================================================
 818 enable_python="no";
 819
 820 AC_ARG_WITH(python, [  --with-python=[DIR]     enable Python support],
 821             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 822
 823 EL_SAVE_FLAGS
 824 cf_result=no
 825
 826 AC_MSG_CHECKING([for Python])
 827
 828 if test "$enable_python" = "yes"; then
 829         AC_MSG_RESULT(yes);
 830
 831         if test -d "$withval"; then
 832                 PYTHON_PATH="$withval:$PATH"
 833         else
 834                 PYTHON_PATH="$PATH"
 835         fi
 836
 837         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 838
 839         if test "$PYTHON" != no; then
 840                 cf_result="yes";
 841
 842                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 843                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 844                 LIBS="$PYTHON_LIBS $LIBS"
 845                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 846                 AC_TRY_LINK([#include <Python.h>],
 847                     [Py_Initialize();],
 848                     cf_result=yes, cf_result=no)
 849
 850                 if test "$cf_result" != "yes"; then
 851                         EL_RESTORE_FLAGS
 852                 else
 853                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 854                         AC_SUBST(PYTHON_LIBS)
 855                         AC_SUBST(PYTHON_CFLAGS)
 856                         CPPFLAGS="$CPPFLAGS_X"
 857                         cat <<EOF
 858 ***********************************************************************
 859 The Python support is incomplete and not so well integrated to ELinks
 860 yet. That means, e.g., that you have no Python console and there might
 861 not be all the necessary hooks. Also, the Python interface is not too
 862 well tested (success stories heartily welcomed!).
 863 ***********************************************************************
 864 EOF
 865                 fi
 866         else
 867                 if test -n "$withval" && test "x$withval" != xno; then
 868                         AC_MSG_ERROR([Python not found])
 869                 else
 870                         AC_MSG_WARN([Python support disabled])
 871                 fi
 872         fi
 873 else
 874         AC_MSG_RESULT(no);
 875 fi
 876
 877
 878 dnl ===================================================================
 879 dnl Check for Lua, optional even if installed.
 880 dnl ===================================================================
 881
 882 dnl Do this the long way, as FreeBSD reportedly needs -L<dir> for
 883 dnl anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 884
 885 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 886             [if test "$withval" = no; then disable_lua=yes; fi])
 887 AC_MSG_CHECKING([for Lua])
 888
 889 EL_SAVE_FLAGS
 890 cf_result=no
 891
 892 if test -z "$disable_lua"; then
 893         if test ! -d "$withval"; then
 894                 withval="";
 895         fi
 896         for luadir in "$withval" "" /usr /usr/local; do
 897                 for suffix in "" 50 51; do
 898                         if test "$cf_result" = no; then
 899                                 LUA_LIBS="-llua$suffix -llualib$suffix -lm"
 900
 901                                 if test ! -z "$luadir"; then
 902                                         LUA_LIBS="-L$luadir/lib $LUA_LIBS"
 903                                         LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 904                                 fi
 905
 906                                 LIBS="$LUA_LIBS $LIBS_X"
 907                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 908                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 909
 910                                 # Check that it is a compatible Lua version
 911                                 AC_TRY_LINK([   #include <lua.h>
 912                                                 #include <lualib.h>],
 913                                             [   lua_State *L = lua_open();
 914                                                 luaopen_base(L);
 915                                                 luaopen_table(L);
 916                                                 luaopen_io(L);
 917                                                 luaopen_string(L);
 918                                                 luaopen_math(L);
 919                                                 lua_pushboolean(L, 1);
 920                                                 lua_close(L);],
 921                                             cf_result=yes, cf_result=no)
 922                         fi
 923                 done
 924         done
 925 fi
 926
 927 AC_MSG_RESULT($cf_result)
 928
 929 if test "$cf_result" != yes; then
 930         EL_RESTORE_FLAGS
 931 else
 932         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 933         AC_CHECK_HEADERS(lauxlib.h)
 934
 935         CFLAGS="$CFLAGS_X"
 936         CPPFLAGS="$CPPFLAGS_X"
 937         AC_SUBST(LUA_LIBS)
 938         AC_SUBST(LUA_CFLAGS)
 939 fi
 940
 941
 942 dnl ===================================================================
 943 dnl Check for Ruby, optional even if installed.
 944 dnl ===================================================================
 945
 946 EL_CONFIG_SCRIPTING_RUBY
 947
 948 dnl ===================================================================
 949 dnl Setup global scripting
 950 dnl ===================================================================
 951
 952 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 953 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 954 AC_SUBST(CONFIG_SCRIPTING_LUA)
 955 AC_SUBST(CONFIG_SCRIPTING_PERL)
 956 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
 957 AC_SUBST(CONFIG_SCRIPTING_RUBY)
 958 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
 959 AC_SUBST(CONFIG_SCRIPTING)
 960
 961
 962 dnl ===================================================================
 963 dnl Check for SSL support.
 964 dnl ===================================================================
 965
 966 dnl We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 967 dnl is enabled, we won't try to use OpenSSL anymore.
 968
 969 dnl For wiping SSL hooks..
 970 #ifdef CONFIG_SSL
 971
 972 disable_openssl=""
 973 disable_gnutls=""
 974 enable_gnutls=""
 975
 976 AC_ARG_WITH(gnutls, [  --without-gnutls        disable GNUTLS SSL support],
 977             [if test "$with_gnutls" = no;  then disable_gnutls=yes; fi])
 978 AC_ARG_WITH(gnutls, [  --with-gnutls[=DIR]     enable GNUTLS SSL support],
 979             [if test "$with_gnutls" != no;  then enable_gnutls=yes; fi])
 980 gnutls_withval="$withval"
 981
 982 if test "$enable_gnutls" = yes; then
 983         disable_openssl=yes;
 984 fi
 985
 986 AC_ARG_WITH(openssl, [  --without-openssl       disable OpenSSL support],
 987             [if test "$with_openssl" = no;  then disable_openssl=yes; fi])
 988 AC_ARG_WITH(openssl, [  --with-openssl[=DIR]    enable OpenSSL support (default)])
 989 openssl_withval="$withval"
 990
 991 dnl ---- OpenSSL
 992
 993 AC_MSG_CHECKING([for OpenSSL])
 994
 995 EL_SAVE_FLAGS
 996 cf_result="no"
 997
 998 if test "$disable_openssl" = yes; then
 999         cf_result="not used"
1000 else
1001         for ssldir in "$openssl_withval" "" /usr /usr/local/openssl \
1002                          /usr/lib/openssl /usr/local/ssl \
1003                          /usr/local/www /usr/lib/ssl /usr/local \
1004                          /usr/pkg /opt /opt/openssl; do
1005                 if test "$cf_result" = no; then
1006                         if test -d "$ssldir"; then
1007                                 OPENSSL_CFLAGS="-I$ssldir/include"
1008                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1009                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1010                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1011 #                               # FIXME: This created serious portability problems. --pasky
1012 #                               if test "$CC" == "gcc"; then
1013 #                                       # I'm not sure about compatibility here. --pasky
1014 #                                       LIBS="$LIBS -R$ssldir/lib"
1015 #                               fi
1016                         else
1017                                 LIBS="-lssl -lcrypto $LIBS_X"
1018                         fi
1019                         AC_TRY_LINK([#include <openssl/ssl.h>],
1020                                     [OpenSSL_add_all_algorithms()],
1021                                     cf_result=yes, cf_result=no)
1022                         if test "$cf_result" != yes; then
1023                                 AC_TRY_LINK([#include <openssl/ssl.h>],
1024                                             [SSLeay_add_ssl_algorithms()],
1025                                             cf_result=yes, cf_result=no)
1026                         fi
1027                 fi
1028         done
1029
1030         if test "$cf_result" != yes; then
1031                 if test -n "$openssl_withval" && test "x$openssl_withval" != xno; then
1032                         AC_MSG_ERROR([OpenSSL not found])
1033                 fi
1034                 EL_RESTORE_FLAGS
1035         else
1036                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1037
1038                 CFLAGS="$CFLAGS_X"
1039                 AC_SUBST(OPENSSL_CFLAGS)
1040         fi
1041 fi
1042
1043 AC_MSG_RESULT($cf_result)
1044
1045 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1046 dnl ---- GNU TLS
1047 dnl We can't have AC_MSG_CHECKING here, because AC_PATH_PROG prints its own and
1048 dnl it looks ugly then.
1049
1050 if test "$cf_result" = yes; then
1051         cf_result="not used"
1052
1053 else
1054         EL_SAVE_FLAGS
1055         cf_result="no"
1056
1057         if test -z "$disable_gnutls"; then
1058                 # Sure, we maybe _could_ use their macro, but how to ensure
1059                 # that the ./configure script won't fail if the macro won't be
1060                 # found..? :( --pasky
1061
1062                 GNUTLS_PATH="$PATH:/usr/local/gnutls:/opt:/opt/gnutls"
1063
1064                 if test -d "$gnutls_withval"; then
1065                         GNUTLS_PATH="$gnutls_withval:$GNUTLS_PATH"
1066                 fi
1067
1068                 AC_PATH_PROG(LIBGNUTLS_CONFIG, libgnutls-config, no, $GNUTLS_PATH)
1069
1070                 if test "$LIBGNUTLS_CONFIG" = "no" ; then
1071                         cf_result=no
1072                 else
1073                         GNUTLS_CFLAGS=`$LIBGNUTLS_CONFIG --cflags`
1074                         GNUTLS_LIBS=`$LIBGNUTLS_CONFIG --libs`
1075
1076                         LIBS="$GNUTLS_LIBS $LIBS_X"
1077                         CFLAGS="$CFLAGS_X $GNUTLS_CFLAGS"
1078                         CPPFLAGS="$CPPFLAGS_X $GNUTLS_CFLAGS"
1079
1080                         # Verify if it's really usable.  gnutls_session was
1081                         # renamed to gnutls_session_t before GNU TLS 1.2.0
1082                         # (on 2004-06-13); ELinks now requires this.
1083                         AC_TRY_LINK([#include <gnutls/gnutls.h>],
1084                                     [gnutls_session_t dummy;
1085                                      gnutls_check_version(NULL)],
1086                                     cf_result=yes, cf_result=no)
1087                 fi
1088
1089                 if test "$cf_result" = yes; then
1090                         EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1091
1092                         CFLAGS="$CFLAGS_X"
1093                         AC_SUBST(GNUTLS_CFLAGS)
1094
1095                         # Verify if the MD5 compatibility layer is usable.
1096                         CONFIG_GNUTLS_OPENSSL_COMPAT=yes
1097                         EL_CHECK_OPTIONAL_LIBRARY(CONFIG_GNUTLS_OPENSSL_COMPAT,
1098                                                   [GNU TLS OpenSSL compatibility],
1099                                                   gnutls/openssl.h, gnutls-openssl,
1100                                                   MD5_Init)
1101                 else
1102                         if test -n "$gnutls_withval" && test "x$gnutls_withval" != xno; then
1103                                 AC_MSG_ERROR([GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.])
1104                         fi
1105                         EL_RESTORE_FLAGS
1106                 fi
1107         fi
1108 fi
1109
1110 AC_MSG_CHECKING([for GNU TLS (1.2 or later)])
1111 AC_MSG_RESULT($cf_result)
1112
1113 dnl Final SSL setup
1114
1115 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS], [SSL])
1116 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1117 AC_SUBST(CONFIG_OPENSSL)
1118 AC_SUBST(CONFIG_GNUTLS)
1119
1120 #endif
1121
1122 AC_MSG_CHECKING([whether to be or not to be])
1123 AC_MSG_RESULT([needs to be determined experimentally])
1124
1125 dnl ===================================================================
1126 dnl Check for IPv6 support and related functions.
1127 dnl ===================================================================
1128
1129 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1130 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1131 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1132
1133 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1134 if test "$HAVE_GETADDRINFO" != yes; then
1135         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1136         if test "$HAVE_GETADDRINFO" = yes; then
1137                 LIBS="$LIBS -linet6"
1138         fi
1139 fi
1140
1141
1142 dnl ===================================================================
1143 dnl Checking for X11 (window title restoring).
1144 dnl ===================================================================
1145
1146 AC_PATH_X
1147 if test x"$no_x" != xyes; then
1148         if test -n "$x_includes"; then
1149                 X_CFLAGS="-I$x_includes"
1150         fi
1151         if test -n "$x_libraries"; then
1152                 LDFLAGS="$LDFLAGS -L$x_libraries"
1153         fi
1154         LIBS="-lX11 $LIBS"
1155         EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1156         AC_SUBST(X_CFLAGS)
1157 fi
1158
1159
1160 dnl ===================================================================
1161 dnl Backtraces displaying support.
1162 dnl ===================================================================
1163
1164 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1165 # possible checks for other system-specific means go here
1166
1167
1168 dnl ===================================================================
1169 dnl SMB protocol support.
1170 dnl ===================================================================
1171
1172 AC_CHECK_PROG(HAVE_SMBCLIENT, smbclient, yes, no)
1173
1174
1175 dnl ===================================================================
1176 dnl Gettext grey zone. Beware.
1177 dnl ===================================================================
1178
1179 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1180
1181 AM_GNU_GETTEXT
1182
1183 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1184 dnl # f33r d4 l33t... I hope it's portable. :)
1185 dnl cf_result=$((48#z - 48#a + 1));
1186 dnl AC_MSG_RESULT($cf_result)
1187
1188
1189 dnl ===================================================================
1190 dnl Compile-time features control
1191 dnl ===================================================================
1192
1193 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1194               [  --disable-cookies       disable cookie support])
1195
1196 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1197               [  --disable-formhist      disable form history support])
1198
1199 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1200               [  --disable-globhist      disable global history support])
1201
1202
1203 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1204               [  --disable-mailcap       disable mailcap support])
1205
1206 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1207               [  --disable-mimetypes     disable mimetypes files support])
1208
1209
1210 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1211               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1212               [IPv6],
1213               [  --disable-ipv6          disable IPv6 support])
1214
1215 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1216               [  --enable-bittorrent     enable BitTorrent protocol support])
1217
1218 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1219               [  --disable-data          disable data protocol support])
1220
1221 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1222               [  --disable-uri-rewrite   disable URI rewrite support])
1223
1224 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1225               [  --enable-cgi            enable local CGI support])
1226
1227 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1228               [  --enable-finger         enable finger protocol support])
1229
1230 dnl ===================================================================
1231 dnl FSP protocol
1232 dnl ===================================================================
1233 EL_SAVE_FLAGS
1234
1235 if test "x${enable_fsp}" != xno; then
1236         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1237
1238         if test "$HAVE_FSPLIB" = yes; then
1239                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1240                 if test "$HAVE_FSPLIB" = yes; then
1241                         LIBS="$LIBS -lfsplib"
1242                 else
1243                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1244                         if test "$HAVE_FSPLIB" = yes; then
1245                                 LIBS="$LIBS -lfsp"
1246                         fi
1247                 fi
1248         fi
1249 fi
1250
1251 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1252               [  --enable-fsp            enable FSP protocol support])
1253
1254 if test "x$CONFIG_FSP" = xno; then
1255         EL_RESTORE_FLAGS
1256 fi
1257
1258 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1259               [  --disable-ftp           disable ftp protocol support])
1260
1261 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1262               [  --enable-gopher         enable gopher protocol support])
1263
1264 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1265               [  --enable-nntp           enable nntp protocol support])
1266
1267 dnl Force disable SMB before EL_ARG_DEPEND so that it logs the correct value.
1268 if test "${enable_smb-no}" != no || test "${CONFIG_SMB-no}" != no; then
1269   AC_MSG_WARN([Forcing --disable-smb because of vulnerability CVE-2006-5925.
1270 If you want to use SMB, please see bug 844.])
1271 fi
1272 enable_smb=no
1273 CONFIG_SMB=no
1274 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [SMB protocol],
1275               [  --enable-smb            not currently allowed])
1276 dnl EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [SMB protocol],
1277 dnl           [  --disable-smb           disable SMB protocol support (requires smbclient)])
1278
1279
1280 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1281               [  --disable-mouse         disable mouse support])
1282
1283 # GPM mouse is Linux specific, so ...
1284 CONFIG_SYSMOUSE=yes
1285 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1286               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1287               [BSD sysmouse],
1288               [  --disable-sysmouse      disable BSD sysmouse support])
1289
1290 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1291               [  --enable-88-colors      enable 88 color support])
1292
1293 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1294               [  --enable-256-colors     enable 256 color support])
1295
1296 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1297               [  --enable-true-color     enable true color support])
1298
1299 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1300               [  --enable-exmode         enable exmode (CLI) interface])
1301
1302 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1303               [  --disable-leds          disable LEDs support])
1304
1305 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1306               [  --disable-marks         disable document marks support])
1307
1308
1309 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1310               [  --disable-css           disable Cascading Style Sheet support])
1311
1312 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1313               [  --enable-html-highlight HTML highlighting using DOM engine])
1314
1315 dnl Everything in the tree already uses CONFIG_DOM
1316 dnl so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1317 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1318
1319 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1320               [  --disable-backtrace     disable backtrace support])
1321
1322 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1323               [  --enable-no-root        enable prevention of usage by root])
1324
1325
1326 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1327               [  --enable-debug          enable leak debug and internal error checking])
1328
1329 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1330               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1331
1332 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1333               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1334
1335 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1336               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1337
1338 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1339               [  --enable-utf-8          enable UTF-8 support])
1340
1341
1342 AC_ARG_ENABLE(weehoofooboomookerchoo,
1343               [
1344     Also check out the features.conf file for more information about features!
1345               ],
1346               [AC_MSG_ERROR(Are you strange, or what?)])
1347
1348
1349 dnl == EMX hack
1350
1351 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1352 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1353
1354
1355 dnl ===================================================================
1356 dnl Export directory paths
1357 dnl ===================================================================
1358
1359 # Set up the ``entry points'' if they were not supplied by builder
1360 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1361 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1362
1363 # Create CONFDIR #define for config.h
1364
1365 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1366 # it's autoconf fault to force us to do such hacks ;p.
1367 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1368   # sysconfdir is set to its default value... fine, let's append /elinks/
1369   # XXX: We can't modify listing of the default in ./configure --help :-(
1370   sysconfdir_n=`eval echo "$sysconfdir"`
1371   sysconfdir=$sysconfdir_n
1372   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1373         sysconfdir="$sysconfdir/elinks"
1374 fi
1375
1376 CONFDIR=$sysconfdir
1377 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1378 AC_SUBST(CONFDIR)
1379
1380 # Create LOCALEDIR #define for config.h
1381 LOCALEDIR=`eval echo "$datadir/locale"`
1382 while echo "$LOCALEDIR" | grep "\\$"
1383 do
1384         LOCALEDIR=`eval echo "$LOCALEDIR"`
1385 done > /dev/null 2> /dev/null
1386 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1387 AC_SUBST(LOCALEDIR)
1388
1389 # Create LIBDIR #define for config.h
1390 LIBDIR=`eval echo "$libdir"`
1391 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1392 AC_SUBST(LIBDIR)
1393
1394 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1395 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1396
1397 dnl ===================================================================
1398 dnl A little fine tuning of gcc specific options (continued)
1399 dnl ===================================================================
1400
1401 if test "x$ac_cv_prog_gcc" = "xyes"; then
1402   if test "$CONFIG_DEBUG" = "yes"; then
1403     dnl We want to see all warnings and live with none (in debug mode).
1404     CFLAGS="$CFLAGS -Werror"
1405   fi
1406
1407   case "`$CC -dumpversion`" in
1408     3.0|3.1|3.2)
1409       # These should be ok using -Werror
1410       ;;
1411     3.*)
1412       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1413       # "dereferencing type-punned pointer will break strict-aliasing rules"
1414       # warnings. Disable them by not doing any strict-aliasing. The
1415       # alternative is just too ugly. Thanks gcc guys!! ;)
1416       CFLAGS="$CFLAGS -fno-strict-aliasing"
1417       ;;
1418     4.*)
1419       # Do not show warnings related to (char * | unsigned char *) type
1420       # difference.
1421       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1422       ;;
1423     *)
1424       # These should be ok using -Werror
1425       ;;
1426   esac
1427
1428   # GCC 4.2 snapshots warn that comparisons like &object != NULL
1429   # always return true.  Some macros in ELinks check whether pointer
1430   # arguments are NULL, and giving them addresses of named objects
1431   # triggers the warning.  These warnings have not revealed any real
1432   # bugs, so shut them up instead of complicating the code.  GCC 4.1
1433   # does not recognize -Wno-always-true and exits with code 1 if it is
1434   # given.
1435   AC_MSG_CHECKING([whether $CC accepts -Wno-always-true])
1436   EL_SAVE_FLAGS
1437   CFLAGS="$CFLAGS -Wno-always-true"
1438   AC_TRY_COMPILE([], [],
1439     [AC_MSG_RESULT([yes])],
1440     [EL_RESTORE_FLAGS
1441      AC_MSG_RESULT([no])])
1442 fi
1443
1444 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1445 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1446 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1447 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1448
1449 dnl ===================================================================
1450 dnl Colored make output
1451 dnl ===================================================================
1452
1453 if test $(`which tput` colors) -ge 4; then
1454         MAKE_COLOR=1
1455         AC_SUBST(MAKE_COLOR)
1456 fi
1457
1458 dnl ===================================================================
1459 dnl Generated files
1460 dnl ===================================================================
1461
1462 AC_OUTPUT([ \
1463  Makefile.config \
1464  contrib/elinks.spec \
1465  contrib/lua/hooks.lua \
1466  contrib/conv/w3m2links.awk \
1467  doc/man/man1/elinks.1 \
1468  src/intl/gettext/ref-add.sed \
1469  src/intl/gettext/ref-del.sed
1470 ])
1471
1472 abs_srcdir="$(cd "$srcdir" && pwd)"
1473 # builddir is always absolute!
1474 if test "$abs_srcdir" != "$builddir"; then
1475         # Bootstrap the Makefile creation
1476         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1477         "$MAKE" "SRC=$abs_srcdir" init
1478
1479         # Make cg-status ignore this build directory
1480         echo "*" > "$builddir/.gitignore"
1481 fi
1482
1483 dnl ===================================================================
1484 dnl Configuration summary
1485 dnl ===================================================================
1486
1487 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1488 cat features.log