CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.0.2)
   2
   3 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake")
   4
   5 include(CheckCCompilerFlag)
   6 include(CheckCSourceCompiles)
   7 include(CheckTypeSize)
   8 include(CheckIncludeFile)
   9
  10 project(DSOAL C)
  11
  12
  13 IF(NOT CMAKE_BUILD_TYPE)
  14     SET(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  15         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  16         FORCE)
  17 ENDIF()
  18
  19 set(DSOAL_DEFS "")
  20 set(DSOAL_INC "")
  21 set(DSOAL_FLAGS "")
  22 set(DSOAL_LIBS "")
  23
  24 set(DSOAL_OBJS buffer.c
  25                capture.c
  26                chorus.c
  27                dsound8.c
  28                dsound_main.c
  29                dsound_private.h
  30                duplex.c
  31                eax.c
  32                eax4.c
  33                eax.h
  34                eax3.h
  35                eax4.h
  36                eax-presets.h
  37                primary.c
  38                propset.c
  39                reverb.c)
  40
  41 set(DSOAL_INC ${DSOAL_INC} ${DSOAL_BINARY_DIR} ${DSOAL_SOURCE_DIR}/include/AL)
  42
  43
  44 check_type_size("long" SIZEOF_LONG)
  45 set(DSOAL_DEFS ${DSOAL_DEFS} "SIZEOF_LONG=${SIZEOF_LONG}")
  46
  47 check_c_source_compiles("#include <intrin.h>
  48 int main()
  49 {
  50     unsigned long idx = 0;
  51     _BitScanForward64(&idx, 1);
  52     return idx;
  53 }" HAVE_BITSCANFORWARD64_INTRINSIC)
  54 if(HAVE_BITSCANFORWARD64_INTRINSIC)
  55     set(DSOAL_DEFS ${DSOAL_DEFS} HAVE_BITSCANFORWARD64_INTRINSIC)
  56 else()
  57     check_c_source_compiles("#include <intrin.h>
  58     int main()
  59     {
  60         unsigned long idx = 0;
  61         _BitScanForward(&idx, 1);
  62         return idx;
  63     }" HAVE_BITSCANFORWARD_INTRINSIC)
  64     if(HAVE_BITSCANFORWARD_INTRINSIC)
  65         set(DSOAL_DEFS ${DSOAL_DEFS} HAVE_BITSCANFORWARD_INTRINSIC)
  66     endif()
  67 endif()
  68
  69
  70 if(NOT MSVC)
  71     set(DSOAL_FLAGS ${DSOAL_FLAGS} -Winline -Wall)
  72     check_c_compiler_flag(-Wextra HAVE_W_EXTRA)
  73     if(HAVE_W_EXTRA)
  74         set(DSOAL_FLAGS ${DSOAL_FLAGS} -Wextra)
  75     endif()
  76     set(DSOAL_LIBS ${DSOAL_LIBS} -static-libgcc)
  77 endif()
  78 if(NOT WIN32)
  79     check_c_compiler_flag(-fvisibility=hidden HAVE_FVISIBILITY_HIDDEN)
  80     if(HAVE_FVISIBILITY_HIDDEN)
  81         set(DSOAL_FLAGS ${DSOAL_FLAGS} -fvisibility=hidden)
  82     endif()
  83 else()
  84     if(MINGW)
  85         set(CMAKE_RC_COMPILER_INIT windres)
  86         set(CMAKE_RC_COMPILE_OBJECT
  87             "<CMAKE_RC_COMPILER> -O coff <DEFINES> -i <SOURCE> -o <OBJECT>")
  88     endif(MINGW)
  89     enable_language(RC)
  90
  91     set(DSOAL_OBJS ${DSOAL_OBJS} debug.c version.rc)
  92
  93     set(DSOAL_DEFS ${DSOAL_DEFS} _WIN32 WINVER=0x0600 DEBUG_INFO)
  94
  95     set(DSOAL_LIBS ${DSOAL_LIBS} winmm ole32)
  96 endif()
  97 set(DSOAL_DEFS ${DSOAL_DEFS} COBJMACROS)
  98
  99 add_library(dsound SHARED ${DSOAL_OBJS} dsound.def)
 100 if(WIN32)
 101     set_target_properties(dsound PROPERTIES PREFIX "")
 102 endif()
 103 target_compile_definitions(dsound PRIVATE ${DSOAL_DEFS})
 104 target_include_directories(dsound PRIVATE ${DSOAL_INC})
 105 target_compile_options(dsound PRIVATE ${DSOAL_FLAGS})
 106 target_link_libraries(dsound PRIVATE ${DSOAL_LIBS})