wmmemload/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.52)
   3
   4 dnl AC_INIT(src/main.c)
   5 AC_INIT(wmmemload, 0.1.8, wmaker-dev@lists.windowmaker.org)
   6 AC_CANONICAL_HOST
   7 AC_CANONICAL_TARGET
   8 AM_INIT_AUTOMAKE
   9
  10 AC_CONFIG_SRCDIR(src/main.c)
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18
  19 dnl
  20 dnl Specify paths to look for libraries and headers
  21 dnl ===============================================
  22 AC_ARG_WITH(libs-from,
  23        [  --with-libs-from        pass compiler flags to look for libraries],
  24        [lib_search_path="$withval $lib_search_path"])
  25
  26 AC_ARG_WITH(incs-from,
  27        [  --with-incs-from        pass compiler flags to look for header files],
  28        [inc_search_path="$withval $inc_search_path"])
  29
  30
  31 dnl ===========================================
  32 dnl             Stuff that uses X
  33 dnl ===========================================
  34
  35 AC_PATH_XTRA
  36
  37 X_LIBRARY_PATH=$x_libraries
  38
  39 XCFLAGS="$X_CFLAGS"
  40
  41 XLFLAGS="$X_LIBS"
  42
  43 XLIBS="-lX11 $X_EXTRA_LIBS"
  44
  45 lib_search_path="$lib_search_path $XLFLAGS -L/usr/local/lib"
  46 inc_search_path="$inc_search_path $XCFLAGS -I/usr/local/include"
  47
  48 AC_SUBST(X_LIBRARY_PATH)
  49
  50 dnl Shape extension
  51 dnl ===============
  52 AC_CHECK_LIB(Xext, XShapeCombineMask, [XLIBS="$XLIBS -lXext"],
  53     [echo "The shape extension stuff could not be found in the X client libraries"
  54      exit 1],
  55     $X_LIBS $X_EXTRA_LIBS -lX11)
  56
  57 dnl XPM library
  58 dnl ===========
  59 AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [XLIBS="$XLIBS -lXpm"],
  60     [echo "The libXpm library was not found, but is necessary to build this library"
  61      exit 1],
  62     $X_LIBS $X_EXTRA_LIBS -lX11)
  63
  64 AC_SUBST(XCFLAGS)
  65 AC_SUBST(XLFLAGS)
  66 AC_SUBST(XLIBS)
  67
  68 AC_SUBST(X_EXTRA_LIBS)
  69
  70 dnl ===============================================
  71 dnl             End of stuff that uses X
  72 dnl ===============================================
  73
  74 dnl =========
  75 dnl Debugging
  76 dnl =========
  77 AC_ARG_ENABLE(debug,
  78              [  --enable-debug          turn on debugging [default=on]],,enable_debug=no)
  79 if test "$enable_debug" = yes; then
  80   DFLAGS="-Wall -g -ansi -pedantic"
  81   AC_DEFINE(DEBUG, 1, [use debug code])
  82 fi
  83 AC_SUBST(DFLAGS)
  84
  85
  86 dnl ============
  87 dnl Check for OS
  88 dnl ============
  89
  90 ignore_buffers=no
  91 ignore_cached=no
  92 ignore_wired=no
  93
  94 case ${host_os} in
  95 linux*)
  96   OS=linux
  97   ignore_buffers=yes
  98   ignore_cached=yes
  99   ;;
 100 *freebsd*)
 101   OS=freebsd
 102   ignore_wired=yes
 103   ignore_cached=yes
 104   ;;
 105 openbsd*)
 106   OS=openbsd
 107   ;;
 108 solaris*)
 109   OS=solaris
 110   ;;
 111 gnu*)
 112   OS=gnu
 113   ignore_buffers=yes
 114   ignore_cached=yes
 115   ;;
 116 *)
 117   echo ""
 118   echo "Sorry, ${host_os} is not supported yet"
 119   echo ""
 120   exit 1
 121   ;;
 122 esac
 123
 124 AC_SUBST(OS)
 125 AC_SUBST(SETGID_FLAGS)
 126 AC_SUBST(LIBS)
 127
 128 if test "$ignore_buffers" = yes; then
 129   AC_DEFINE(IGNORE_BUFFERS, 1, [use '--ignore-buffers' option])
 130 fi
 131 if test "$ignore_cached" = yes; then
 132   AC_DEFINE(IGNORE_CACHED, 1, [use '--ignore-cached' option])
 133 fi
 134 if test "$ignore_wired" = yes; then
 135   AC_DEFINE(IGNORE_WIRED, 1, [use '--ignore-wired' option])
 136 fi
 137
 138
 139 dnl =============================
 140 dnl Checks for library functions.
 141 dnl =============================
 142
 143 LIBRARY_SEARCH_PATH="$lib_search_path"
 144 HEADER_SEARCH_PATH="$inc_search_path"
 145
 146 AC_SUBST(LIBRARY_SEARCH_PATH)
 147 AC_SUBST(HEADER_SEARCH_PATH)
 148
 149 dnl Checks for header files.
 150 AC_HEADER_STDC
 151 AC_CHECK_HEADERS([fcntl.h memory.h stddef.h stdlib.h string.h strings.h sys/param.h sys/time.h unistd.h])
 152
 153 dnl Checks for typedefs, structures, and compiler characteristics.
 154 AC_C_CONST
 155 AC_TYPE_SIZE_T
 156 AC_HEADER_TIME
 157
 158 dnl Checks for library functions.
 159 AC_FUNC_MALLOC
 160 AC_CHECK_FUNCS(select strtoul uname)
 161
 162 AC_CONFIG_FILES(Makefile src/Makefile doc/Makefile)
 163
 164 dnl             icons/Makefile \
 165 dnl             contrib/Makefile \
 166 dnl             contrib/wmmemmon.spec)
 167
 168 AC_OUTPUT