lib/Dist/Zilla/Plugin/Prepender.pm

   1 package Dist::Zilla::Plugin::Prepender;
   2 # ABSTRACT: prepend lines at the top of your perl files
   3
   4 use Moose;
   5 with 'Dist::Zilla::Role::FileMunger';
   6
   7
   8 # -- attributes
   9
  10 # accept some arguments multiple times.
  11 sub multivalue_args { qw{ line } }
  12
  13 has _lines => (
  14   is         => 'ro',
  15   isa        => 'ArrayRef',
  16   lazy       => 1,
  17   auto_deref => 1,
  18   init_arg   => 'line',
  19   default    => sub { [] },
  20 );
  21
  22
  23 # -- public methods
  24
  25 sub munge_file {
  26     my ($self, $file) = @_;
  27
  28     return $self->_munge_perl($file) if $file->name    =~ /\.(?:pm|pl)$/i;
  29     return $self->_munge_perl($file) if $file->content =~ /^#!(?:.*)perl(?:$|\s)/;
  30     return;
  31 }
  32
  33 # -- private methods
  34
  35 #
  36 # $self->_munge_perl($file);
  37 #
  38 # munge content of perl $file: add stuff at the top of the file
  39 #
  40 sub _munge_perl {
  41     my ($self, $file) = @_;
  42     my $stuff = join "\n", $self->_lines;
  43     my @lines = split /\n/, $file->content;
  44
  45     # if there's a shebang line, insert stuff just after it
  46     my $id = ( $lines[0] =~ /^#!(?:.*)perl(?:$|\s)/ ) ? 1 : 0;
  47
  48     splice @lines, $id, 0, $stuff;
  49     $file->content(join "\n", @lines);
  50 }
  51
  52 __PACKAGE__->meta->make_immutable;
  53 no Moose;
  54 1;
  55
  56 __END__
  57
  58 =begin Pod::Coverage
  59
  60 multivalue_args
  61 munge_file
  62
  63 =end Pod::Coverage
  64
  65 =head1 SYNOPSIS
  66
  67 In your F<dist.ini>:
  68
  69     [Prepender]
  70     line = # This file is part of Foo::Bar
  71     line = use strict;
  72     line = use warnings;
  73
  74 =head1 DESCRIPTION
  75
  76 This plugin will prepend the specified lines in each Perl module or
  77 program within the distribution. For scripts having a shebang line,
  78 lines will be inserted just after it.
  79
  80 This is useful to enforce a set of pragmas to your files (since pragmas
  81 are lexical, they will be active for the whole file), or to add some
  82 copyright comments, as the fsf recommends.
  83