lib/Dist/Zilla/Plugin/Prepender.pm

   1 package Dist::Zilla::Plugin::Prepender;
   2 # ABSTRACT: prepend lines at the top of your perl files
   3
   4 use strict;
   5 use warnings;
   6
   7 use Moose;
   8 with 'Dist::Zilla::Role::FileMunger';
   9
  10
  11 # -- attributes
  12
  13 # accept some arguments multiple times.
  14 sub multivalue_args { qw{ line } }
  15
  16 has copyright => (
  17     is => 'ro',
  18     default => 0,
  19 );
  20 has _lines => (
  21     is         => 'ro',
  22     isa        => 'ArrayRef',
  23     lazy       => 1,
  24     auto_deref => 1,
  25     init_arg   => 'line',
  26     default    => sub { [] },
  27 );
  28
  29
  30 # -- public methods
  31
  32 sub munge_file {
  33     my ($self, $file) = @_;
  34
  35     return $self->_munge_perl($file) if $file->name    =~ /\.(?:pm|pl)$/i;
  36     return $self->_munge_perl($file) if $file->content =~ /^#!(?:.*)perl(?:$|\s)/;
  37     return;
  38 }
  39
  40 # -- private methods
  41
  42 #
  43 # $self->_munge_perl($file);
  44 #
  45 # munge content of perl $file: add stuff at the top of the file
  46 #
  47 sub _munge_perl {
  48     my ($self, $file) = @_;
  49     my @prepend;
  50     my @lines = split /\n/, $file->content;
  51
  52     # add copyright information if requested
  53     if ( $self->copyright ) {
  54         my @copyright = (
  55             '',
  56             "This file is part of " . $self->zilla->name,
  57             '',
  58             split(/\n/, $self->zilla->license->notice),
  59             '',
  60         );
  61         push @prepend, map { "# $_" } @copyright;
  62     }
  63
  64     # add hand-written lines to prepend
  65     push @prepend, $self->_lines;
  66
  67     # insertion point depends if there's a shebang line
  68     my $id = ( $lines[0] =~ /^#!(?:.*)perl(?:$|\s)/ ) ? 1 : 0;
  69     splice @lines, $id, 0, @prepend;
  70     $file->content(join "\n", @lines);
  71 }
  72
  73 __PACKAGE__->meta->make_immutable;
  74 no Moose;
  75 1;
  76
  77 __END__
  78
  79 =begin Pod::Coverage
  80
  81 multivalue_args
  82 munge_file
  83
  84 =end Pod::Coverage
  85
  86 =head1 SYNOPSIS
  87
  88 In your F<dist.ini>:
  89
  90     [Prepender]
  91     copyright = 1
  92     line = use strict;
  93     line = use warnings;
  94
  95 =head1 DESCRIPTION
  96
  97 This plugin will prepend the specified lines in each Perl module or
  98 program within the distribution. For scripts having a shebang line,
  99 lines will be inserted just after it.
 100
 101 This is useful to enforce a set of pragmas to your files (since pragmas
 102 are lexical, they will be active for the whole file), or to add some
 103 copyright comments, as the fsf recommends.
 104
 105 The module accepts the following options in its F<dist.ini> section:
 106
 107 =over 4
 108
 109 =item * copyright - whether to insert a boilerplate copyright comment.
 110 defaults to false.
 111
 112 =item * line - anything you want to add. may be specified multiple
 113 times. no default.
 114
 115 =back
 116
 117 =head1 BUGS
 118
 119 Please report any bugs or feature request to
 120 C<< <bug-dist-zilla-plugin-prepender@rt.cpan.org> >>, or through the web interface
 121 at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Dist-Zilla-Plugin-Prepender>.
 122
 123
 124