service/meson.build

   1 service_conf = configuration_data()
   2 service_conf.set('libexecdir', dconf_libexecdir)
   3
   4 service = dconf_namespace + '.service'
   5
   6 configure_file(
   7   input: service + '.in',
   8   output: service,
   9   configuration: service_conf,
  10   install: true,
  11   install_dir: dbus_session_service_dir,
  12 )
  13
  14 sources = [
  15   'dconf-blame.c',
  16   'dconf-gvdb-utils.c',
  17   'dconf-keyfile-writer.c',
  18   'dconf-service.c',
  19   'dconf-shm-writer.c',
  20   'dconf-writer.c',
  21   'main.c',
  22 ]
  23
  24 sources += gnome.gdbus_codegen(
  25   'dconf-generated',
  26   dconf_namespace + '.xml',
  27   interface_prefix: dconf_namespace + '.',
  28   namespace: 'DConfDBus',
  29 )
  30
  31 service_deps = [
  32   gio_unix_dep,
  33   libdconf_common_dep,
  34   libdconf_shm_dep,
  35   libgvdb_dep,
  36 ]
  37
  38 executable(
  39   'dconf-service',
  40   sources,
  41   include_directories: top_inc,
  42   dependencies: service_deps,
  43   install: true,
  44   install_dir: dconf_libexecdir,
  45 )