service/meson.build

   1 service_conf = configuration_data()
   2 service_conf.set('libexecdir', dconf_libexecdir)
   3
   4 service = dconf_namespace + '.service'
   5
   6 configure_file(
   7   input: service + '.in',
   8   output: service,
   9   configuration: service_conf,
  10   install: true,
  11   install_dir: dbus_session_service_dir,
  12 )
  13
  14 lib_sources = [
  15   'dconf-blame.c',
  16   'dconf-gvdb-utils.c',
  17   'dconf-keyfile-writer.c',
  18   'dconf-service.c',
  19   'dconf-shm-writer.c',
  20   'dconf-writer.c',
  21 ]
  22 sources = [
  23   'main.c',
  24 ]
  25
  26 dconf_generated = gnome.gdbus_codegen(
  27   'dconf-generated',
  28   dconf_namespace + '.xml',
  29   interface_prefix: dconf_namespace + '.',
  30   namespace: 'DConfDBus',
  31 )
  32
  33 lib_sources += dconf_generated
  34
  35 libdconf_service = static_library(
  36   'dconf-service',
  37   sources: lib_sources,
  38   include_directories: top_inc,
  39   c_args: dconf_c_args,
  40   dependencies: gio_unix_dep,
  41   link_with: [
  42     libdconf_common,
  43     libdconf_shm,
  44     libgvdb,
  45   ],
  46 )
  47
  48 libdconf_service_dep = declare_dependency(
  49   link_with: libdconf_service,
  50   dependencies: gio_unix_dep,
  51   sources: dconf_generated,
  52 )
  53
  54 executable(
  55   'dconf-service',
  56   sources,
  57   include_directories: top_inc,
  58   c_args: dconf_c_args,
  59   dependencies: gio_unix_dep,
  60   link_with: libdconf_service,
  61   install: true,
  62   install_dir: dconf_libexecdir,
  63 )