db-sqlite/sqlite-sql.lisp

   1 ;;;; -*- Mode: LISP; Syntax: ANSI-Common-Lisp; Base: 10 -*-
   2 ;;;; *************************************************************************
   3 ;;;; FILE IDENTIFICATION
   4 ;;;;
   5 ;;;; Name:     sqlite-sql.lisp
   6 ;;;; Purpose:  High-level SQLite interface
   7 ;;;; Authors:  Aurelio Bignoli, Kevin Rosenberg, Marcus Pearce
   8 ;;;; Created:  Aug 2003
   9 ;;;;
  10 ;;;; $Id$
  11 ;;;;
  12 ;;;; This file, part of CLSQL, is Copyright (c) 2003 by Aurelio Bignoli and
  13 ;;;; Copyright (c) 2003-2004 by Kevin Rosenberg and Marcus Pearce.
  14 ;;;;
  15 ;;;; CLSQL users are granted the rights to distribute and use this software
  16 ;;;; as governed by the terms of the Lisp Lesser GNU Public License
  17 ;;;; (http://opensource.franz.com/preamble.html), also known as the LLGPL.
  18 ;;;; *************************************************************************
  19
  20 (in-package #:clsql-sqlite)
  21
  22 (defclass sqlite-database (database)
  23   ((sqlite-db :initarg :sqlite-db :accessor sqlite-db)))
  24
  25 (defmethod database-type ((database sqlite-database))
  26   :sqlite)
  27
  28 (defmethod database-initialize-database-type ((database-type (eql :sqlite)))
  29   t)
  30
  31 (defun check-sqlite-connection-spec (connection-spec)
  32   (check-connection-spec connection-spec :sqlite (name)))
  33
  34 (defmethod database-name-from-spec (connection-spec
  35                                     (database-type (eql :sqlite)))
  36   (check-sqlite-connection-spec connection-spec)
  37   (first connection-spec))
  38
  39 (defmethod database-connect (connection-spec (database-type (eql :sqlite)))
  40   (check-sqlite-connection-spec connection-spec)
  41   (handler-case
  42       (make-instance 'sqlite-database
  43                      :name (database-name-from-spec connection-spec :sqlite)
  44                      :database-type :sqlite
  45                      :connection-spec connection-spec
  46                      :sqlite-db (sqlite:sqlite-open (first connection-spec)))
  47     (sqlite:sqlite-error (err)
  48       (error 'sql-connection-error
  49              :database-type database-type
  50              :connection-spec connection-spec
  51              :error-id (sqlite:sqlite-error-code err)
  52              :message (sqlite:sqlite-error-message err)))))
  53
  54 (defmethod database-disconnect ((database sqlite-database))
  55   (sqlite:sqlite-close (sqlite-db database))
  56   (setf (sqlite-db database) nil)
  57   t)
  58
  59 (defmethod database-execute-command (sql-expression (database sqlite-database))
  60   (handler-case
  61       (multiple-value-bind (data row-n col-n)
  62           (sqlite:sqlite-get-table (sqlite-db database) sql-expression)
  63         (sqlite:sqlite-free-table data)
  64         (unless (= row-n 0)
  65           (error 'sql-warning
  66                  :format-control
  67                  "Result set not empty: ~@(~A~) row~:P, ~@(~A~) column~:P "
  68                  :format-arguments (list row-n col-n))))
  69     (sqlite:sqlite-error (err)
  70       (error 'sql-database-data-error
  71              :database database
  72              :expression sql-expression
  73              :error-id (sqlite:sqlite-error-code err)
  74              :message (sqlite:sqlite-error-message err))))
  75   t)
  76
  77 (defstruct sqlite-result-set
  78   (vm (sqlite:make-null-vm)
  79       :type sqlite:sqlite-vm-pointer)
  80   (first-row (sqlite:make-null-row)
  81              :type sqlite:sqlite-row-pointer-type)
  82   (col-names (sqlite:make-null-row)
  83              :type sqlite:sqlite-row-pointer-type)
  84   (result-types nil)
  85   (n-col 0 :type fixnum))
  86
  87 (defmethod database-query (query-expression (database sqlite-database) result-types field-names)
  88   (declare (optimize (speed 3) (safety 0) (debug 0) (space 0)))
  89   (handler-case
  90       (let ((vm (sqlite:sqlite-compile (sqlite-db database)
  91                                        query-expression))
  92             (rows '())
  93             (col-names '()))
  94         (unwind-protect
  95              ;; Read the first row to get column number and names.
  96              (multiple-value-bind (n-col new-row sqlite-col-names)
  97                  (sqlite:sqlite-step vm)
  98                (declare (type sqlite:sqlite-row-pointer-type new-row))
  99                (when (> n-col 0)
 100                  (when field-names
 101                    (setf col-names (loop for i from 0 below n-col
 102                                          collect (sqlite:sqlite-aref sqlite-col-names i))))
 103                  (let ((canonicalized-result-types
 104                         (canonicalize-result-types result-types n-col sqlite-col-names)))
 105                    (flet ((extract-row-data (row)
 106                             (declare (type sqlite:sqlite-row-pointer-type row))
 107                             (loop for i from 0 below n-col
 108                                   collect (clsql-uffi:convert-raw-field
 109                                            (sqlite:sqlite-raw-aref row i)
 110                                            canonicalized-result-types i))))
 111                      (push (extract-row-data new-row) rows)
 112
 113                      ;; Read subsequent rows.
 114                      (do () (nil)
 115                        (multiple-value-bind (n-col new-row)
 116                            (sqlite:sqlite-step vm)
 117                          (declare (type sqlite:sqlite-row-pointer-type new-row))
 118                          (if (> n-col 0)
 119                              (push (extract-row-data new-row) rows)
 120                              (return))))))))
 121           (sqlite:sqlite-finalize vm))
 122         (values (nreverse rows) col-names))
 123     (sqlite:sqlite-error (err)
 124       (error 'sql-database-data-error
 125              :database database
 126              :expression query-expression
 127              :error-id (sqlite:sqlite-error-code err)
 128              :message (sqlite:sqlite-error-message err)))))
 129
 130 (defmethod database-query-result-set ((query-expression string)
 131                                       (database sqlite-database)
 132                                       &key result-types full-set)
 133   (let ((vm nil))
 134     (handler-case
 135         (progn
 136           (setf vm (sqlite:sqlite-compile (sqlite-db database)
 137                                           query-expression))
 138           ;;; To obtain column number/datatypes we have to read the first row.
 139           (multiple-value-bind (n-col cols col-names)
 140               (sqlite:sqlite-step vm)
 141             (declare (type sqlite:sqlite-row-pointer-type cols))
 142             (let ((result-set (make-sqlite-result-set
 143                                :vm vm
 144                                :first-row cols
 145                                :n-col n-col
 146                                :col-names col-names
 147                                :result-types
 148                                (canonicalize-result-types
 149                                 result-types
 150                                 n-col
 151                                 col-names))))
 152               (if full-set
 153                   (values result-set n-col nil)
 154                   (values result-set n-col)))))
 155       (sqlite:sqlite-error (err)
 156         (progn
 157           (when vm
 158             ;; The condition was thrown by sqlite-step, vm must be
 159             ;; deallocated.
 160             (ignore-errors
 161               (sqlite:sqlite-finalize vm)))
 162           (error 'sql-database-data-error
 163                  :database database
 164                  :expression query-expression
 165                  :error-id (sqlite:sqlite-error-code err)
 166                  :message (sqlite:sqlite-error-message err))11)))))
 167
 168 (defun canonicalize-result-types (result-types n-col col-names)
 169   (when result-types
 170     (let ((raw-types (if (eq :auto result-types)
 171                          (loop for j from n-col below (* 2 n-col)
 172                                collect (ensure-keyword (sqlite:sqlite-aref col-names j)))
 173                        result-types)))
 174       (loop for type in raw-types
 175             collect
 176             (case type
 177               ((:int :integer :tinyint)
 178                :int32)
 179               (:long #+(or x86-64 64bit) :int64 #-(or x86-64 64bit) :int32)
 180               (:bigint
 181                :int64)
 182               ((:float :double)
 183                :double)
 184               ((:numeric)
 185                :number)
 186               (otherwise
 187                :string))))))
 188
 189 (defmethod database-dump-result-set (result-set (database sqlite-database))
 190   (handler-case
 191       (sqlite:sqlite-finalize (sqlite-result-set-vm result-set))
 192     (sqlite:sqlite-error (err)
 193       (error 'sql-database-error
 194              :message
 195              (format nil "Error finalizing SQLite VM: ~A"
 196                      (sqlite:sqlite-error-message err))))))
 197
 198 (defmethod database-store-next-row (result-set (database sqlite-database) list)
 199   (let ((n-col (sqlite-result-set-n-col result-set))
 200         (result-types (sqlite-result-set-result-types result-set)))
 201     (if (= n-col 0)
 202         ;; empty result set
 203         nil
 204         (let ((row (sqlite-result-set-first-row result-set)))
 205           (if (sqlite:null-row-p row)
 206               ;; First row already used. fetch another row from DB.
 207               (handler-case
 208                   (multiple-value-bind (n new-row col-names)
 209                       (sqlite:sqlite-step (sqlite-result-set-vm result-set))
 210                     (declare (ignore n col-names)
 211                              (type sqlite:sqlite-row-pointer-type new-row))
 212                     (if (sqlite:null-row-p new-row)
 213                         (return-from database-store-next-row nil)
 214                         (setf row new-row)))
 215                 (sqlite:sqlite-error (err)
 216                   (error 'sql-database-error
 217                          :message
 218                          (format nil "Error in sqlite-step: ~A"
 219                                  (sqlite:sqlite-error-message err)))))
 220
 221             ;; Use the row previously read by database-query-result-set.
 222               (setf (sqlite-result-set-first-row result-set)
 223                     (sqlite:make-null-row)))
 224           (loop for i = 0 then (1+ i)
 225                 for rest on list
 226                 do (setf (car rest)
 227                          (clsql-uffi:convert-raw-field
 228                           (sqlite:sqlite-raw-aref row i)
 229                           result-types
 230                           i)))
 231           (sqlite:sqlite-free-row row)
 232           t))))
 233
 234 ;;; Object listing
 235
 236 (defmethod database-list-tables-and-sequences ((database sqlite-database) &key owner)
 237   (declare (ignore owner))
 238   ;; Query is copied from .table command of sqlite comamnd line utility.
 239   (mapcar #'car (database-query
 240                  "SELECT name FROM sqlite_master WHERE type='table' UNION ALL SELECT name FROM sqlite_temp_master WHERE type='table' ORDER BY name"
 241                  database nil nil)))
 242
 243 (defmethod database-list-tables ((database sqlite-database) &key owner)
 244   (remove-if #'(lambda (s)
 245                  (and (>= (length s) 11)
 246                       (string-equal (subseq s 0 11) "_CLSQL_SEQ_")))
 247              (database-list-tables-and-sequences database :owner owner)))
 248
 249 (defmethod database-list-views ((database sqlite-database)
 250                                 &key (owner nil))
 251   (declare (ignore owner))
 252   (mapcar #'car (database-query
 253                  "SELECT name FROM sqlite_master WHERE type='view' UNION ALL SELECT name FROM sqlite_temp_master WHERE type='view' ORDER BY name"
 254                  database nil nil)))
 255
 256 (defmethod database-list-indexes ((database sqlite-database)
 257                                   &key (owner nil))
 258   (declare (ignore owner))
 259   (mapcar #'car (database-query
 260                  "SELECT name FROM sqlite_master WHERE type='index' UNION ALL SELECT name FROM sqlite_temp_master WHERE type='index' ORDER BY name"
 261                  database nil nil)))
 262
 263 (defmethod database-list-table-indexes (table (database sqlite-database)
 264                                         &key (owner nil))
 265   (declare (ignore owner))
 266   (let ((*print-circle* nil))
 267     (mapcar #'car
 268             (database-query
 269              (format
 270               nil
 271               "SELECT name FROM sqlite_master WHERE type='index' AND tbl_name='~A' UNION ALL SELECT name FROM sqlite_temp_master WHERE type='index' AND tbl_name='~A' ORDER BY name"
 272               table table)
 273              database nil nil))))
 274
 275 (declaim (inline sqlite-table-info))
 276 (defun sqlite-table-info (table database)
 277   (database-query (format nil "PRAGMA table_info('~A')" table)
 278                   database nil nil))
 279
 280 (defmethod database-list-attributes (table (database sqlite-database)
 281                                            &key (owner nil))
 282   (declare (ignore owner))
 283   (mapcar #'(lambda (table-info) (second table-info))
 284           (sqlite-table-info table database)))
 285
 286 (defmethod database-attribute-type (attribute table
 287                                     (database sqlite-database)
 288                                     &key (owner nil))
 289   (declare (ignore owner))
 290   (loop for field-info in (sqlite-table-info table database)
 291       when (string= attribute (second field-info))
 292       return
 293         (let* ((raw-type (third field-info))
 294                (start-length (position #\( raw-type))
 295                (type (if start-length
 296                          (subseq raw-type 0 start-length)
 297                        raw-type))
 298                (length (if start-length
 299                            (parse-integer (subseq raw-type (1+ start-length))
 300                                           :junk-allowed t)
 301                          nil)))
 302           (values (when type (ensure-keyword type))
 303                   length
 304                   nil
 305                   (if (string-equal (fourth field-info) "0")
 306                       1 0)))))
 307
 308 (defmethod database-create (connection-spec (type (eql :sqlite)))
 309   (declare (ignore connection-spec))
 310   ;; databases are created automatically by SQLite
 311   t)
 312
 313 (defmethod database-destroy (connection-spec (type (eql :sqlite)))
 314   (destructuring-bind (name) connection-spec
 315     (if (probe-file name)
 316         (delete-file name)
 317         nil)))
 318
 319 (defmethod database-probe (connection-spec (type (eql :sqlite)))
 320   (destructuring-bind (name) connection-spec
 321     ;; TODO: Add a test that this file is a real sqlite database
 322     (or (string-equal ":memory:" name)
 323         (and (probe-file name) t))))
 324
 325 ;;; Database capabilities
 326
 327 (defmethod db-type-has-boolean-where? ((db-type (eql :sqlite)))
 328   nil)
 329
 330
 331