src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2010 Philippe Brochard <hocwp@free.fr>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  47   (labels ((has-x (mask) (= 1 (logand mask 1)))
  48            (has-y (mask) (= 2 (logand mask 2)))
  49            (has-w (mask) (= 4 (logand mask 4)))
  50            (has-h (mask) (= 8 (logand mask 8)))
  51            (has-bw (mask) (= 16 (logand mask 16)))
  52            (has-stackmode (mask) (= 64 (logand mask 64)))
  53            (adjust-from-request ()
  54              (when (has-x value-mask) (setf (xlib:drawable-x window) x))
  55              (when (has-y value-mask) (setf (xlib:drawable-y window) y))
  56              (when (has-h value-mask) (setf (xlib:drawable-height window) height))
  57              (when (has-w value-mask) (setf (xlib:drawable-width window) width))))
  58     (xlib:with-state (window)
  59       (when (has-bw value-mask)
  60         (setf (xlib:drawable-border-width window) border-width))
  61       (if (find-child window *current-root*)
  62           (let ((parent (find-parent-frame window *current-root*)))
  63             (if (and parent (managed-window-p window parent))
  64                 (adapt-child-to-parent window parent)
  65                 (adjust-from-request)))
  66           (adjust-from-request))
  67       (send-configuration-notify window (xlib:drawable-x window) (xlib:drawable-y window)
  68                                  (xlib:drawable-width window) (xlib:drawable-height window)
  69                                  (xlib:drawable-border-width window))
  70       (when (has-stackmode value-mask)
  71         (case stack-mode
  72           (:above
  73            (unless (null-size-window-p window)
  74              (when (or (child-equal-p window *current-child*)
  75                        (is-in-current-child-p window))
  76                (raise-window window)
  77                (focus-window window)
  78                (focus-all-children window (find-parent-frame window *current-root*))))))))))
  79
  80
  81 (define-handler main-mode :map-request (window send-event-p)
  82   (unless send-event-p
  83     (unhide-window window)
  84     (process-new-window window)
  85     (map-window window)
  86     (unless (null-size-window-p window)
  87       (show-all-children))))
  88
  89 (define-handler main-mode :unmap-notify (send-event-p event-window window)
  90   (unless (and (not send-event-p)
  91                (not (xlib:window-equal window event-window)))
  92     (when (find-child window *root-frame*)
  93       (delete-child-in-all-frames window)
  94       (show-all-children))))
  95
  96
  97 (define-handler main-mode :destroy-notify (send-event-p event-window window)
  98   (unless (or send-event-p
  99               (xlib:window-equal window event-window))
 100     (when (find-child window *root-frame*)
 101       (delete-child-in-all-frames window)
 102       (show-all-children))))
 103
 104 (define-handler main-mode :enter-notify  (window root-x root-y)
 105   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 106                (> root-y (- (xlib:screen-height *screen*) 3)))
 107     (case (if (frame-p *current-child*)
 108               (frame-focus-policy *current-child*)
 109               *default-focus-policy*)
 110       (:sloppy (focus-window window))
 111       (:sloppy-strict (when (and (frame-p *current-child*)
 112                                  (child-member window (frame-child *current-child*)))
 113                         (focus-window window)))
 114       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 115                              (parent (find-parent-frame child)))
 116                         (unless (or (child-equal-p child *current-root*)
 117                                     (equal (typecase child
 118                                              (xlib:window parent)
 119                                              (t child))
 120                                            *current-child*))
 121                             (focus-all-children child parent)
 122                             (show-all-children)))))))
 123
 124 (define-handler main-mode :exposure (window)
 125   (awhen (find-frame-window window *current-root*)
 126     (display-frame-info it)))
 127
 128
 129 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 130   "Handle X errors"
 131   (cond
 132     ;; ignore asynchronous window errors
 133     ((and asynchronous
 134           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 135      (format t "Ignoring XLib asynchronous error: ~s~%" error-key))
 136     ((eq error-key 'xlib:access-error)
 137      (write-line "Another window manager is running.")
 138      (throw 'exit-clfswm nil))
 139      ;; all other asynchronous errors are printed.
 140      (asynchronous
 141       (format t "Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 142      (t
 143       (apply 'error error-key :display display :error-key error-key key-vals))))
 144
 145
 146 (defun main-loop ()
 147   (loop
 148      (call-hook *loop-hook*)
 149      (process-timers)
 150      (with-xlib-protect
 151        (when (xlib:event-listen *display* *loop-timeout*)
 152          (xlib:process-event *display* :handler #'handle-event))
 153        (xlib:display-finish-output *display*))))
 154
 155
 156
 157 (defun open-display (display-str protocol)
 158   (multiple-value-bind (host display-num) (parse-display-string display-str)
 159     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 160           (xlib:display-error-handler *display*) 'error-handler
 161           (getenv "DISPLAY") display-str)))
 162
 163
 164
 165 (defun default-init-hook ()
 166   (let ((frame (add-frame (create-frame :name "Default"
 167                                         :layout nil :x 0.05 :y 0.05
 168                                         :w 0.9 :h 0.9) *root-frame*)))
 169     (setf *current-child* frame)))
 170
 171
 172 (defun init-display ()
 173   (fill-handle-event-fun-symbols)
 174   (assoc-keyword-handle-event 'main-mode)
 175   (setf *screen* (first (xlib:display-roots *display*))
 176         *root* (xlib:screen-root *screen*)
 177         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 178         *default-font* (xlib:open-font *display* *default-font-string*)
 179         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 180                                             :height (xlib:screen-height *screen*)
 181                                             :depth (xlib:screen-root-depth *screen*)
 182                                             :drawable *root*)
 183         *in-second-mode* nil)
 184   (init-modifier-list)
 185   (xgrab-init-pointer)
 186   (xgrab-init-keyboard)
 187   (init-last-child)
 188   (call-hook *binding-hook*)
 189   (clear-timers)
 190   (map-window *no-focus-window*)
 191   (dbg *display*)
 192   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 193                                                               :substructure-notify
 194                                                               :property-change
 195                                                               :exposure
 196                                                               :button-press
 197                                                               :button-release
 198                                                               :pointer-motion))
 199   ;;(intern-atoms *display*)
 200   (netwm-set-properties)
 201   (xlib:display-force-output *display*)
 202   (setf *child-selection* nil)
 203   (setf *root-frame* (create-frame :name "Root" :number 0) ;; :layout #'tile-space-layout)
 204         *current-root* *root-frame*
 205         *current-child* *current-root*)
 206   (call-hook *init-hook*)
 207   (process-existing-windows *screen*)
 208   (show-all-children *current-root*)
 209   (grab-main-keys)
 210   (xlib:display-finish-output *display*))
 211
 212
 213
 214
 215 (defun read-conf-file ()
 216   (let* ((conf (conf-file-name)))
 217     (if conf
 218         (handler-case (load conf)
 219           (error (c)
 220             (format t "~2%*** Error loading configurtion file: ~A ***~&~A~%" conf c)
 221             (values nil (format nil "~s" c) conf))
 222           (:no-error (&rest args)
 223             (declare (ignore args))
 224             (values t nil conf)))
 225         (values t nil nil))))
 226
 227
 228
 229
 230
 231
 232 (defun exit-clfswm ()
 233   "Exit clfswm"
 234   (throw 'exit-clfswm nil))
 235
 236 (defun reset-clfswm ()
 237   "Reset clfswm"
 238   (throw 'exit-main-loop nil))
 239
 240
 241
 242
 243 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 244                          (base-dir (directory-namestring (or *load-truename* "")))
 245                          (read-conf-file-p t) (alternate-conf nil)
 246                          error-msg)
 247   (setf *contrib-dir* base-dir)
 248   (conf-file-name alternate-conf)
 249   (when read-conf-file-p
 250     (read-conf-file))
 251   (call-hook *main-entrance-hook*)
 252   (handler-case
 253       (open-display display protocol)
 254     (xlib:access-error (c)
 255       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 256       (force-output)
 257       (exit-clfswm)))
 258   (handler-case
 259       (init-display)
 260     (xlib:access-error (c)
 261       (ungrab-main-keys)
 262       (xlib:destroy-window *no-focus-window*)
 263       (xlib:close-display *display*)
 264       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 265       (force-output)
 266       (exit-clfswm)))
 267   (when error-msg
 268     (info-mode error-msg))
 269   (catch 'exit-main-loop
 270       (unwind-protect
 271            (main-loop)
 272         (ungrab-main-keys)
 273         (xlib:destroy-window *no-focus-window*)
 274         (xlib:free-pixmap *pixmap-buffer*)
 275         (xlib:close-display *display*)
 276         #+:event-debug
 277         (format t "~2&Unhandled events: ~A~%" *unhandled-events*))))
 278
 279
 280
 281 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 282              (base-dir (directory-namestring (or *load-truename* "")))
 283              (read-conf-file-p t)
 284              (alternate-conf nil))
 285   (let (error-msg)
 286     (catch 'exit-clfswm
 287       (loop
 288          (handler-case
 289              (if *other-window-manager*
 290                  (run-other-window-manager)
 291                  (main-unprotected :display display :protocol protocol :base-dir base-dir
 292                                    :read-conf-file-p read-conf-file-p
 293                                    :alternate-conf alternate-conf
 294                                    :error-msg error-msg))
 295            (error (c)
 296              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 297                (format t "~&~A~%Reinitializing...~%" msg)
 298                (setf error-msg (list (list msg *info-color-title*)
 299                                      "Reinitializing...")))))))))
 300
 301
 302