src/clfswm.lisp

   1 ;;; --------------------------------------------------------------------------
   2 ;;; CLFSWM - FullScreen Window Manager
   3 ;;;
   4 ;;; --------------------------------------------------------------------------
   5 ;;; Documentation: Main functions
   6 ;;; --------------------------------------------------------------------------
   7 ;;;
   8 ;;; (C) 2011 Philippe Brochard <hocwp@free.fr>
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software
  22 ;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23 ;;;
  24 ;;; --------------------------------------------------------------------------
  25
  26 (in-package :clfswm)
  27
  28
  29 (define-handler main-mode :key-press (code state)
  30   (funcall-key-from-code *main-keys* code state))
  31
  32 (define-handler main-mode :button-press (code state window root-x root-y)
  33   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-press*)
  34     (replay-button-event)))
  35
  36 (define-handler main-mode :button-release (code state window root-x root-y)
  37   (unless (funcall-button-from-code *main-mouse* code state window root-x root-y *fun-release*)
  38     (replay-button-event)))
  39
  40 (define-handler main-mode :motion-notify (window root-x root-y)
  41   (unless (compress-motion-notify)
  42     (funcall-button-from-code *main-mouse* 'motion
  43                               (modifiers->state *default-modifiers*)
  44                               window root-x root-y *fun-press*)))
  45
  46 (define-handler main-mode :configure-request (stack-mode window x y width height border-width value-mask)
  47   (labels ((has-x (mask) (= 1 (logand mask 1)))
  48            (has-y (mask) (= 2 (logand mask 2)))
  49            (has-w (mask) (= 4 (logand mask 4)))
  50            (has-h (mask) (= 8 (logand mask 8)))
  51            (has-bw (mask) (= 16 (logand mask 16)))
  52            (has-stackmode (mask) (= 64 (logand mask 64)))
  53            (adjust-from-request ()
  54              (when (has-x value-mask) (setf (xlib:drawable-x window) x))
  55              (when (has-y value-mask) (setf (xlib:drawable-y window) y))
  56              (when (has-h value-mask) (setf (xlib:drawable-height window) height))
  57              (when (has-w value-mask) (setf (xlib:drawable-width window) width))))
  58     (xlib:with-state (window)
  59       (when (has-bw value-mask)
  60         (setf (xlib:drawable-border-width window) border-width))
  61       (if (find-child window *current-root*)
  62           (let ((parent (find-parent-frame window *current-root*)))
  63             (if (and parent (managed-window-p window parent))
  64                 (adapt-child-to-parent window parent)
  65                 (adjust-from-request)))
  66           (adjust-from-request))
  67       (send-configuration-notify window (xlib:drawable-x window) (xlib:drawable-y window)
  68                                  (xlib:drawable-width window) (xlib:drawable-height window)
  69                                  (xlib:drawable-border-width window))
  70       (when (has-stackmode value-mask)
  71         (case stack-mode
  72           (:above
  73            (unless (null-size-window-p window)
  74              (when (or (child-equal-p window *current-child*)
  75                        (is-in-current-child-p window))
  76                (raise-window window)
  77                (focus-window window)
  78                (focus-all-children window (find-parent-frame window *current-root*))))))))))
  79
  80
  81 (define-handler main-mode :map-request (window send-event-p)
  82   (unless send-event-p
  83     (unhide-window window)
  84     (process-new-window window)
  85     (map-window window)
  86     (unless (null-size-window-p window)
  87       (multiple-value-bind (never-managed raise)
  88           (never-managed-window-p window)
  89         (unless (and never-managed raise)
  90           (show-all-children))))))
  91
  92
  93 (define-handler main-mode :unmap-notify (send-event-p event-window window)
  94   (unless (and (not send-event-p)
  95                (not (xlib:window-equal window event-window)))
  96     (when (find-child window *root-frame*)
  97       (delete-child-in-all-frames window)
  98       (show-all-children))))
  99
 100
 101 (define-handler main-mode :destroy-notify (send-event-p event-window window)
 102   (unless (or send-event-p
 103               (xlib:window-equal window event-window))
 104     (when (find-child window *root-frame*)
 105       (delete-child-in-all-frames window)
 106       (show-all-children))))
 107
 108 (define-handler main-mode :enter-notify  (window root-x root-y)
 109   (unless (and (> root-x (- (xlib:screen-width *screen*) 3))
 110                (> root-y (- (xlib:screen-height *screen*) 3)))
 111     (case (if (frame-p *current-child*)
 112               (frame-focus-policy *current-child*)
 113               *default-focus-policy*)
 114       (:sloppy (focus-window window))
 115       (:sloppy-strict (when (and (frame-p *current-child*)
 116                                  (child-member window (frame-child *current-child*)))
 117                         (focus-window window)))
 118       (:sloppy-select (let* ((child (find-child-under-mouse root-x root-y))
 119                              (parent (find-parent-frame child)))
 120                         (unless (or (child-equal-p child *current-root*)
 121                                     (equal (typecase child
 122                                              (xlib:window parent)
 123                                              (t child))
 124                                            *current-child*))
 125                             (focus-all-children child parent)
 126                             (show-all-children)))))))
 127
 128 (define-handler main-mode :exposure (window)
 129   (awhen (find-frame-window window *current-root*)
 130     (display-frame-info it)))
 131
 132
 133 (defun error-handler (display error-key &rest key-vals &key asynchronous &allow-other-keys)
 134   "Handle X errors"
 135   (cond
 136     ;; ignore asynchronous window errors
 137     ((and asynchronous
 138           (find error-key '(xlib:window-error xlib:drawable-error xlib:match-error)))
 139      (format t "Ignoring XLib asynchronous error: ~s~%" error-key))
 140     ((eq error-key 'xlib:access-error)
 141      (write-line "Another window manager is running.")
 142      (throw 'exit-clfswm nil))
 143      ;; all other asynchronous errors are printed.
 144      (asynchronous
 145       (format t "Caught Asynchronous X Error: ~s ~s" error-key key-vals))
 146      (t
 147       (apply 'error error-key :display display :error-key error-key key-vals))))
 148
 149
 150 (defun main-loop ()
 151   (loop
 152      (call-hook *loop-hook*)
 153      (process-timers)
 154      (with-xlib-protect
 155        (when (xlib:event-listen *display* *loop-timeout*)
 156          (xlib:process-event *display* :handler #'handle-event))
 157        (xlib:display-finish-output *display*))))
 158
 159
 160
 161 (defun open-display (display-str protocol)
 162   (multiple-value-bind (host display-num) (parse-display-string display-str)
 163     (setf *display* (xlib:open-display host :display display-num :protocol protocol)
 164           (xlib:display-error-handler *display*) 'error-handler
 165           (getenv "DISPLAY") display-str)))
 166
 167
 168
 169 (defun default-init-hook ()
 170   (let ((frame (add-frame (create-frame :name "Default"
 171                                         :layout nil :x 0.05 :y 0.05
 172                                         :w 0.9 :h 0.9)
 173                           *root-frame*)))
 174     (setf *current-child* frame)))
 175
 176
 177 (defun init-display ()
 178   (fill-handle-event-fun-symbols)
 179   (assoc-keyword-handle-event 'main-mode)
 180   (setf *screen* (first (xlib:display-roots *display*))
 181         *root* (xlib:screen-root *screen*)
 182         *no-focus-window* (xlib:create-window :parent *root* :x 0 :y 0 :width 1 :height 1)
 183         *default-font* (xlib:open-font *display* *default-font-string*)
 184         *pixmap-buffer* (xlib:create-pixmap :width (xlib:screen-width *screen*)
 185                                             :height (xlib:screen-height *screen*)
 186                                             :depth (xlib:screen-root-depth *screen*)
 187                                             :drawable *root*)
 188         *in-second-mode* nil)
 189   (init-modifier-list)
 190   (xgrab-init-pointer)
 191   (xgrab-init-keyboard)
 192   (init-last-child)
 193   (call-hook *binding-hook*)
 194   (clear-timers)
 195   (map-window *no-focus-window*)
 196   (dbg *display*)
 197   (setf (xlib:window-event-mask *root*) (xlib:make-event-mask :substructure-redirect
 198                                                               :substructure-notify
 199                                                               :property-change
 200                                                               :exposure
 201                                                               :button-press
 202                                                               :button-release
 203                                                               :pointer-motion))
 204   ;;(intern-atoms *display*)
 205   (netwm-set-properties)
 206   (xlib:display-force-output *display*)
 207   (setf *child-selection* nil)
 208   (setf *root-frame* (create-frame :name "Root" :number 0)
 209         *current-root* *root-frame*
 210         *current-child* *current-root*)
 211   (call-hook *init-hook*)
 212   (process-existing-windows *screen*)
 213   (show-all-children)
 214   (grab-main-keys)
 215   (xlib:display-finish-output *display*))
 216
 217
 218
 219
 220 (defun read-conf-file ()
 221   (let* ((conf (conf-file-name)))
 222     (if conf
 223         (handler-case (load conf)
 224           (error (c)
 225             (format t "~2%*** Error loading configuration file: ~A ***~&~A~%" conf c)
 226             (values nil (format nil "~s" c) conf))
 227           (:no-error (&rest args)
 228             (declare (ignore args))
 229             (values t nil conf)))
 230         (values t nil nil))))
 231
 232
 233
 234
 235
 236
 237 (defun exit-clfswm ()
 238   "Exit clfswm"
 239   (throw 'exit-clfswm nil))
 240
 241 (defun reset-clfswm ()
 242   "Reset clfswm"
 243   (throw 'exit-main-loop nil))
 244
 245
 246
 247
 248 (defun main-unprotected (&key (display (or (getenv "DISPLAY") ":0")) protocol
 249                          (base-dir (asdf:system-source-directory :clfswm))
 250                          (read-conf-file-p t) (alternate-conf nil)
 251                          error-msg)
 252   (setf *contrib-dir* (merge-pathnames "contrib/" base-dir))
 253   (conf-file-name alternate-conf)
 254   (when read-conf-file-p
 255     (read-conf-file))
 256   (create-configuration-menu :clear t)
 257   (call-hook *main-entrance-hook*)
 258   (handler-case
 259       (open-display display protocol)
 260     (xlib:access-error (c)
 261       (format t "~&~A~&Maybe another window manager is running. [1]~%" c)
 262       (force-output)
 263       (exit-clfswm)))
 264   (handler-case
 265       (init-display)
 266     (xlib:access-error (c)
 267       (ungrab-main-keys)
 268       (xlib:destroy-window *no-focus-window*)
 269       (xlib:close-display *display*)
 270       (format t "~&~A~&Maybe another window manager is running. [2]~%" c)
 271       (force-output)
 272       (exit-clfswm)))
 273   (when error-msg
 274     (info-mode error-msg))
 275   (catch 'exit-main-loop
 276       (unwind-protect
 277            (main-loop)
 278         (ungrab-main-keys)
 279         (xlib:destroy-window *no-focus-window*)
 280         (xlib:free-pixmap *pixmap-buffer*)
 281         (destroy-all-frames-window)
 282         (call-hook *close-hook*)
 283         (xlib:close-display *display*)
 284         #+:event-debug
 285         (format t "~2&Unhandled events: ~A~%" *unhandled-events*))))
 286
 287
 288
 289 (defun main (&key (display (or (getenv "DISPLAY") ":0")) protocol
 290              (base-dir (asdf:system-source-directory :clfswm))
 291              (read-conf-file-p t)
 292              (alternate-conf nil))
 293   (let (error-msg)
 294     (catch 'exit-clfswm
 295       (loop
 296          (handler-case
 297              (if *other-window-manager*
 298                  (run-other-window-manager)
 299                  (main-unprotected :display display :protocol protocol :base-dir base-dir
 300                                    :read-conf-file-p read-conf-file-p
 301                                    :alternate-conf alternate-conf
 302                                    :error-msg error-msg))
 303            (error (c)
 304              (let ((msg (format nil "CLFSWM Error: ~A." c)))
 305                (format t "~&~A~%Reinitializing...~%" msg)
 306                (setf error-msg (list (list msg *info-color-title*)
 307                                      "Reinitializing...")))))))))
 308
 309
 310