lib/Blog/Controller/Post.pm

   1 package Blog::Controller::Post;
   2
   3 use strict;
   4 use warnings;
   5 use base 'Catalyst::Controller';
   6
   7 use Blog::Form::Post;
   8 use Blog::Validator::Post;
   9
  10 use HTTP::Date;
  11
  12 sub list : Path('') Args(0) { }
  13
  14 sub archive
  15     : Route('archive/:year|(19|20)\d\d|=/:month|(0|1)?\d|=/:day|[0-3]?\d|=')
  16 #sub archive_list : LocalRegex('archive/((?:19|20)?\d\d)/(?:((?:0|1)?\d)/())?')
  17 {
  18     my ( $self, $c ) = @_;
  19
  20     foreach ( qw/ year month day / ) {
  21         $c->stash->{ $_ } = $c->req->param( $_ );
  22     }
  23 }
  24
  25 sub view : Local Args(1) {
  26     my ( $self, $c, $id ) = @_;
  27
  28     my $post = $c->model( 'Post' )->create( key => $id );
  29     $post->load( i18n => $c->language,
  30         speculative => 1
  31     );
  32
  33     $self->throw_not_found( $c ) if $post->not_found;
  34
  35     $c->stash->{ post } = {
  36         $post->column_value_pairs,
  37         available_translations => $post->available_translations,
  38         tags => [ $post->tags ]
  39     };
  40 }
  41
  42 sub add : Local Args(0) {
  43     my ( $self, $c ) = @_;
  44
  45     my $form      = Blog::Form::Post->new( $c );
  46     my $validator = Blog::Validator::Post->new( $c->req->params );
  47
  48     if ( $form->was_submitted && $validator->is_valid ) {
  49         my $post = $form->create_from_form( $c->model( 'Post' )->name->new(),
  50             $validator->params );
  51         $post->save();
  52
  53         $c->flash->{ msg } = $c->loc( 'Post was added successfully' );
  54
  55         $c->res->redirect( $c->uri_for( '/post/view', $post->key ) );
  56     }
  57
  58     $c->stash->{ validator } = $validator;
  59 }
  60
  61 sub edit : LocalRegex('^edit/(\d+)$') {
  62     my ( $self, $c ) = @_;
  63
  64     my $id = $c->req->captures->[ 0 ];
  65
  66     my $post = $c->model( 'Post' )->create( id => $id );
  67     $post->load( i18n => $c->language,
  68         speculative => 1
  69     );
  70     $self->throw_not_found( $c ) if $post->not_found;
  71
  72     my $form      = Blog::Form::Post->new( $c );
  73     my $validator = Blog::Validator::Post->new( $c->req->params );
  74
  75     if (   $form->was_submitted
  76         && $validator->is_valid( unique_except => $post->key ) )
  77     {
  78         $post = $form->update_from_form( $post, $validator->params );
  79         $post->save( cascade => 1);
  80
  81         $c->flash->{ msg } = $c->loc( 'Post was saved successfully' );
  82
  83         $c->res->redirect( $c->uri_for( '/post/view', $post->key ) );
  84     }
  85
  86     $c->stash->{ validator } = $validator;
  87
  88     $c->stash->{ post } = {
  89         $post->column_value_pairs,
  90         tags => [ $post->tags ]
  91     };
  92 }
  93
  94 sub delete : LocalRegex('^delete/(\d+)$') {
  95     my ( $self, $c ) = @_;
  96
  97     my $object = $c->model( 'Post' )->create( id => $c->req->captures->[ 0 ] );
  98     $object->load( speculative => 1, select => [ 'id' ] );
  99     $self->throw_not_found( $c ) if $object->not_found;
 100
 101     $object->delete( cascade => 1 );
 102
 103     $c->flash->{ msg } = $c->loc( 'Post was deleted successfully' );
 104
 105     $c->res->redirect( $c->uri_for( '/post' ) );
 106 }
 107
 108 sub feed : Local Args(0) {
 109     my ( $self, $c ) = @_;
 110
 111     my $items = $c->model( 'Post' )->manager->feed();
 112
 113     $c->stash->{ feed } = {
 114         description => $c->loc( 'Recent posts' ),
 115         items       => []
 116     };
 117
 118     return unless @$items;
 119
 120     my $feed_items = [
 121         map {
 122             {
 123                 title       => $_->i18n->title,
 124                 description => $c->helper('BBCode')->render( $_->i18n->annot ),
 125                 category    => [ map { { name => $_->name } } @{ $_->tags } ],
 126                 pubDate     => $_->addtime->epoch,
 127                 link     => $c->uri_for( '/post/view', $_->key ),
 128                 comments => $c->uri_for( '/post/view', $_->key ) . '#comments',
 129                 author   => $c->config->{ author }
 130             }
 131           } @$items
 132     ];
 133
 134     $c->res->headers->header(
 135         'Last-Modified' => time2str( $feed_items->[ 0 ]->{ pubDate } ) );
 136
 137     $c->stash->{ feed }->{ items } = $feed_items;
 138 }
 139
 140 sub throw_not_found {
 141     my ( $self, $c ) = @_;
 142
 143     $c->detach( '/default' );
 144 }
 145
 146 =head1 AUTHOR
 147
 148 vti
 149
 150 =head1 LICENSE
 151
 152 This library is free software, you can redistribute it and/or modify
 153 it under the same terms as Perl itself.
 154
 155 =cut
 156
 157 1;