configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/gcc-plugin.m4)
  27 m4_include(config/ax_cxx_compile_stdcxx.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT(move-if-change)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty build-libcpp"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #f
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 145
 146 # these libraries are built for the target environment, and are built after
 147 # the host libraries and the host tools (which may be a cross compiler)
 148 # Note that libiberty is not a target library.
 149 target_libraries="target-libgcc \
 150                 target-libbacktrace \
 151                 target-libgloss \
 152                 target-newlib \
 153                 target-libgomp \
 154                 target-liboffloadmic \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 252 # is provided.
 253 if test x$with_system_readline = xyes ; then
 254   noconfigdirs="$noconfigdirs readline"
 255 fi
 256
 257 AC_ARG_WITH(zstd,
 258 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 259
 260 # some tools are so dependent upon X11 that if we're not building with X,
 261 # it's not even worth trying to configure, much less build, that tool.
 262
 263 case ${with_x} in
 264   yes | "") ;; # the default value for this tree is that X11 is available
 265   no)
 266     skipdirs="${skipdirs} tk itcl libgui"
 267     # We won't be able to build gdbtk without X.
 268     enable_gdbtk=no
 269     ;;
 270   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 271 esac
 272
 273 # Some are only suitable for cross toolchains.
 274 # Remove these if host=target.
 275 cross_only="target-libgloss target-newlib target-opcodes"
 276
 277 case $is_cross_compiler in
 278   no) skipdirs="${skipdirs} ${cross_only}" ;;
 279 esac
 280
 281 # If both --with-headers and --with-libs are specified, default to
 282 # --without-newlib.
 283 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 284    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 285   if test x"${with_newlib}" = x ; then
 286     with_newlib=no
 287   fi
 288 fi
 289
 290 # Recognize --with-newlib/--without-newlib.
 291 case ${with_newlib} in
 292   no) skipdirs="${skipdirs} target-newlib" ;;
 293   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 294 esac
 295
 296 AC_ARG_ENABLE(as-accelerator-for,
 297 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 298                 [build as offload target compiler.
 299                 Specify offload host triple by ARG])])
 300
 301 AC_ARG_ENABLE(offload-targets,
 302 [AS_HELP_STRING([--enable-offload-targets=LIST],
 303                 [enable offloading to devices from comma-separated LIST of
 304                 TARGET[=DIR]. Use optional path to find offload target compiler
 305                 during the build])],
 306 [
 307   if test x"$enable_offload_targets" = x; then
 308     AC_MSG_ERROR([no offload targets specified])
 309   fi
 310 ], [enable_offload_targets=])
 311
 312 AC_ARG_ENABLE(offload-defaulted,
 313 [AS_HELP_STRING([--enable-offload-defaulted]
 314                 [If enabled, configured but not installed offload compilers and
 315                 libgomp plugins are silently ignored.  Useful for distribution
 316                 compilers where those are in separate optional packages.])],
 317 [enable_offload_defaulted=$enableval],
 318 [enable_offload_defaulted=])
 319
 320 # Handle --enable-gold, --enable-ld.
 321 # --disable-gold [--enable-ld]
 322 #     Build only ld.  Default option.
 323 # --enable-gold [--enable-ld]
 324 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 325 #     as "ld.bfd" and "ld".
 326 # --enable-gold=default [--enable-ld]
 327 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 328 #     install ld as "ld.bfd".
 329 # --enable-gold[=default] --disable-ld
 330 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 331 # --enable-gold --enable-ld=default
 332 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 333 #     and ld.bfd).
 334 #     In other words, ld is default
 335 # --enable-gold=default --enable-ld=default
 336 #     Error.
 337
 338 default_ld=
 339 AC_ARG_ENABLE(gold,
 340 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 341                 [build gold @<:@ARG={default,yes,no}@:>@])],
 342 ENABLE_GOLD=$enableval,
 343 ENABLE_GOLD=no)
 344 case "${ENABLE_GOLD}" in
 345   yes|default)
 346     # Check for ELF target.
 347     is_elf=no
 348     case "${target}" in
 349       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 350       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 351       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 352       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 353         case "${target}" in
 354           *-*-linux*aout* | *-*-linux*oldld*)
 355             ;;
 356           *)
 357             is_elf=yes
 358             ;;
 359         esac
 360     esac
 361
 362     if test "$is_elf" = "yes"; then
 363       # Check for target supported by gold.
 364       case "${target}" in
 365         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 366         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 367           configdirs="$configdirs gold"
 368           if test x${ENABLE_GOLD} = xdefault; then
 369             default_ld=gold
 370           fi
 371           ENABLE_GOLD=yes
 372           ;;
 373       esac
 374     fi
 375     ;;
 376   no)
 377     ;;
 378   *)
 379     AC_MSG_ERROR([invalid --enable-gold argument])
 380     ;;
 381 esac
 382
 383 AC_ARG_ENABLE(ld,
 384 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 385                 [build ld @<:@ARG={default,yes,no}@:>@])],
 386 ENABLE_LD=$enableval,
 387 ENABLE_LD=yes)
 388
 389 case "${ENABLE_LD}" in
 390   default)
 391     if test x${default_ld} != x; then
 392       AC_MSG_ERROR([either gold or ld can be the default ld])
 393     fi
 394     ;;
 395   yes)
 396     ;;
 397   no)
 398     if test x${ENABLE_GOLD} != xyes; then
 399       AC_MSG_WARN([neither ld nor gold are enabled])
 400     fi
 401     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 402     ;;
 403   *)
 404     AC_MSG_ERROR([invalid --enable-ld argument])
 405     ;;
 406 esac
 407
 408 AC_ARG_ENABLE(gprofng,
 409 [AS_HELP_STRING([[--enable-gprofng[=ARG]]],
 410                 [build gprofng @<:@ARG={yes,no}@:>@])],
 411 enable_gprofng=$enableval,
 412 enable_gprofng=yes)
 413 if test "$enable_gprofng" = "yes"; then
 414   case "${target}" in
 415     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux*)
 416     configdirs="$configdirs gprofng"
 417     ;;
 418   esac
 419 fi
 420
 421
 422 # PR gas/19109
 423 # Decide the default method for compressing debug sections.
 424 # Provide a configure time option to override our default.
 425 AC_ARG_ENABLE(compressed_debug_sections,
 426 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 427                 [Enable compressed debug sections for gas, gold or ld by
 428                  default])],
 429 [
 430   if test x"$enable_compressed_debug_sections" = xyes; then
 431     AC_MSG_ERROR([no program with compressed debug sections specified])
 432   fi
 433 ], [enable_compressed_debug_sections=])
 434
 435 # Select default compression algorithm.
 436 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 437 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 438                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 439 [], [default_compressed_debug_sections_algorithm=])
 440
 441 # Configure extra directories which are host specific
 442
 443 case "${host}" in
 444   *-cygwin*)
 445     configdirs="$configdirs libtermcap" ;;
 446 esac
 447
 448 # A target can indicate whether a language isn't supported for some reason.
 449 # Only spaces may be used in this macro; not newlines or tabs.
 450 unsupported_languages=
 451
 452 # Remove more programs from consideration, based on the host or
 453 # target this usually means that a port of the program doesn't
 454 # exist yet.
 455
 456 case "${host}" in
 457   i[[3456789]]86-*-msdosdjgpp*)
 458     noconfigdirs="$noconfigdirs tcl tk itcl"
 459     ;;
 460 esac
 461
 462 # Default to --disable-year2038 until we can handle differences between
 463 # projects that use gnulib (which understands year 2038) and projects that
 464 # do not (like BFD).
 465 AC_ARG_ENABLE(year2038,
 466 AS_HELP_STRING([--enable-year2038],
 467   [enable support for timestamps past the year 2038]),
 468 ENABLE_YEAR2038=$enableval,
 469 ENABLE_YEAR2038=no)
 470 enable_year2038=
 471 if test "${ENABLE_YEAR2038}" = "no" ; then
 472   enable_year2038=no
 473 fi
 474
 475 AC_ARG_ENABLE(libquadmath,
 476 AS_HELP_STRING([--disable-libquadmath],
 477   [do not build libquadmath directory]),
 478 ENABLE_LIBQUADMATH=$enableval,
 479 ENABLE_LIBQUADMATH=yes)
 480 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 481   noconfigdirs="$noconfigdirs target-libquadmath"
 482 fi
 483
 484
 485 AC_ARG_ENABLE(libquadmath-support,
 486 AS_HELP_STRING([--disable-libquadmath-support],
 487   [disable libquadmath support for Fortran]),
 488 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 489 ENABLE_LIBQUADMATH_SUPPORT=yes)
 490 enable_libquadmath_support=
 491 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 492   enable_libquadmath_support=no
 493 fi
 494
 495
 496 AC_ARG_ENABLE(libada,
 497 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 498 ENABLE_LIBADA=$enableval,
 499 ENABLE_LIBADA=yes)
 500 if test "${ENABLE_LIBADA}" != "yes" ; then
 501   noconfigdirs="$noconfigdirs gnattools"
 502 fi
 503
 504 AC_ARG_ENABLE(libssp,
 505 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 506 ENABLE_LIBSSP=$enableval,
 507 ENABLE_LIBSSP=yes)
 508
 509 AC_ARG_ENABLE(libstdcxx,
 510 AS_HELP_STRING([--disable-libstdcxx],
 511   [do not build libstdc++-v3 directory]),
 512 ENABLE_LIBSTDCXX=$enableval,
 513 ENABLE_LIBSTDCXX=default)
 514 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 515   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 516 fi]
 517
 518 # If this is accelerator compiler and its target is intelmic we enable
 519 # target liboffloadmic by default.  If this is compiler with offloading
 520 # for intelmic we enable host liboffloadmic by default.  Otherwise
 521 # liboffloadmic is disabled by default.
 522 AC_ARG_ENABLE([liboffloadmic],
 523 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 524                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 525 [case "$enableval" in
 526   no | host | target)
 527     enable_liboffloadmic=$enableval ;;
 528   *)
 529     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 530 esac],
 531 [if test x"$enable_as_accelerator_for" != x; then
 532   case "${target}" in
 533     *-intelmic-* | *-intelmicemul-*)
 534       enable_liboffloadmic=target
 535       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 536       ;;
 537     *)
 538       enable_liboffloadmic=no
 539       ;;
 540   esac
 541 else
 542   case "${enable_offload_targets}" in
 543     *-intelmic-* | *-intelmicemul-*)
 544       enable_liboffloadmic=host
 545       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 546       ;;
 547     *)
 548       enable_liboffloadmic=no
 549       ;;
 550     esac
 551 fi])
 552 AC_SUBST(extra_liboffloadmic_configure_flags)
 553
 554 # Enable libgomp by default on hosted POSIX systems, and a few others.
 555 if test x$enable_libgomp = x ; then
 556     case "${target}" in
 557     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 558         ;;
 559     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 560         ;;
 561     *-*-solaris2* | *-*-hpux11*)
 562         ;;
 563     *-*-darwin* | *-*-aix*)
 564         ;;
 565     nvptx*-*-* | amdgcn*-*-*)
 566         ;;
 567     *)
 568         noconfigdirs="$noconfigdirs target-libgomp"
 569         ;;
 570     esac
 571 fi
 572
 573 # Disable libatomic on unsupported systems.
 574 if test -d ${srcdir}/libatomic; then
 575     if test x$enable_libatomic = x; then
 576         AC_MSG_CHECKING([for libatomic support])
 577         if (srcdir=${srcdir}/libatomic; \
 578                 . ${srcdir}/configure.tgt; \
 579                 test -n "$UNSUPPORTED")
 580         then
 581             AC_MSG_RESULT([no])
 582             noconfigdirs="$noconfigdirs target-libatomic"
 583         else
 584             AC_MSG_RESULT([yes])
 585         fi
 586     fi
 587 fi
 588
 589 # Disable liboffloadmic on unsupported systems.
 590 if test -d ${srcdir}/liboffloadmic; then
 591     if test x$enable_liboffloadmic != xno; then
 592         AC_MSG_CHECKING([for liboffloadmic support])
 593         if (srcdir=${srcdir}/liboffloadmic; \
 594                 . ${srcdir}/configure.tgt; \
 595                 test -n "$UNSUPPORTED")
 596         then
 597             AC_MSG_RESULT([no])
 598             noconfigdirs="$noconfigdirs target-liboffloadmic"
 599         else
 600             AC_MSG_RESULT([yes])
 601         fi
 602     fi
 603 fi
 604
 605 # Disable libitm on unsupported systems.
 606 if test -d ${srcdir}/libitm; then
 607     if test x$enable_libitm = x; then
 608         AC_MSG_CHECKING([for libitm support])
 609         if (srcdir=${srcdir}/libitm; \
 610                 . ${srcdir}/configure.tgt; \
 611                 test -n "$UNSUPPORTED")
 612         then
 613             AC_MSG_RESULT([no])
 614             noconfigdirs="$noconfigdirs target-libitm"
 615         else
 616             AC_MSG_RESULT([yes])
 617         fi
 618     fi
 619 fi
 620
 621 # Disable libsanitizer on unsupported systems.
 622 if test -d ${srcdir}/libsanitizer; then
 623     if test x$enable_libsanitizer = x; then
 624         AC_MSG_CHECKING([for libsanitizer support])
 625         if (srcdir=${srcdir}/libsanitizer; \
 626                 . ${srcdir}/configure.tgt; \
 627                 test -n "$UNSUPPORTED")
 628         then
 629             AC_MSG_RESULT([no])
 630             noconfigdirs="$noconfigdirs target-libsanitizer"
 631         else
 632             AC_MSG_RESULT([yes])
 633         fi
 634     fi
 635 fi
 636
 637 # Disable libvtv on unsupported systems.
 638 if test -d ${srcdir}/libvtv; then
 639     if test x$enable_libvtv = x; then
 640         AC_MSG_CHECKING([for libvtv support])
 641         if (srcdir=${srcdir}/libvtv; \
 642                 . ${srcdir}/configure.tgt; \
 643                 test "$VTV_SUPPORTED" != "yes")
 644         then
 645             AC_MSG_RESULT([no])
 646             noconfigdirs="$noconfigdirs target-libvtv"
 647         else
 648             AC_MSG_RESULT([yes])
 649         fi
 650     fi
 651 fi
 652
 653 # Disable libquadmath for some systems.
 654 case "${target}" in
 655   avr-*-*)
 656     noconfigdirs="$noconfigdirs target-libquadmath"
 657     ;;
 658   # libquadmath is unused on AIX and libquadmath build process use of
 659   # LD_LIBRARY_PATH can break AIX bootstrap.
 660   powerpc-*-aix* | rs6000-*-aix*)
 661     noconfigdirs="$noconfigdirs target-libquadmath"
 662     ;;
 663 esac
 664
 665 # Disable libssp for some systems.
 666 case "${target}" in
 667   avr-*-*)
 668     # No hosted I/O support.
 669     noconfigdirs="$noconfigdirs target-libssp"
 670     ;;
 671   bpf-*-*)
 672     noconfigdirs="$noconfigdirs target-libssp"
 673     ;;
 674   powerpc-*-aix* | rs6000-*-aix*)
 675     noconfigdirs="$noconfigdirs target-libssp"
 676     ;;
 677   pru-*-*)
 678     # No hosted I/O support.
 679     noconfigdirs="$noconfigdirs target-libssp"
 680     ;;
 681   rl78-*-*)
 682     # libssp uses a misaligned load to trigger a fault, but the RL78
 683     # doesn't fault for those - instead, it gives a build-time error
 684     # for explicit misaligned loads.
 685     noconfigdirs="$noconfigdirs target-libssp"
 686     ;;
 687   visium-*-*)
 688     # No hosted I/O support.
 689     noconfigdirs="$noconfigdirs target-libssp"
 690     ;;
 691 esac
 692
 693 # Disable libstdc++-v3 for some systems.
 694 # Allow user to override this if they pass --enable-libstdcxx
 695 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 696   case "${target}" in
 697     *-*-vxworks*)
 698       # VxWorks uses the Dinkumware C++ library.
 699       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 700       ;;
 701     amdgcn*-*-*)
 702       # Not ported/fails to build when using newlib.
 703       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 704       ;;
 705     arm*-wince-pe*)
 706       # the C++ libraries don't build on top of CE's C libraries
 707       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 708       ;;
 709     avr-*-*)
 710       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 711       ;;
 712     bpf-*-*)
 713       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 714       ;;
 715     ft32-*-*)
 716       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 717       ;;
 718   esac
 719 fi
 720
 721 # Disable C++ on systems where it is known to not work.
 722 # For testing, you can override this with --enable-languages=c++.
 723 case ,${enable_languages}, in
 724   *,c++,*)
 725     ;;
 726   *)
 727       case "${target}" in
 728         bpf-*-*)
 729           unsupported_languages="$unsupported_languages c++"
 730           ;;
 731       esac
 732       ;;
 733 esac
 734
 735 # Disable Objc on systems where it is known to not work.
 736 # For testing, you can override this with --enable-languages=objc.
 737 case ,${enable_languages}, in
 738   *,objc,*)
 739     ;;
 740   *)
 741       case "${target}" in
 742         bpf-*-*)
 743           unsupported_languages="$unsupported_languages objc"
 744           ;;
 745       esac
 746       ;;
 747 esac
 748
 749 # Disable D on systems where it is known to not work.
 750 # For testing, you can override this with --enable-languages=d.
 751 case ,${enable_languages}, in
 752   *,d,*)
 753     ;;
 754   *)
 755     case "${target}" in
 756       bpf-*-*)
 757         unsupported_languages="$unsupported_languages d"
 758         ;;
 759     esac
 760     ;;
 761 esac
 762
 763 # Disable libphobos on unsupported systems.
 764 # For testing, you can override this with --enable-libphobos.
 765 if test -d ${srcdir}/libphobos; then
 766     if test x$enable_libphobos = x; then
 767         AC_MSG_CHECKING([for libphobos support])
 768         if (srcdir=${srcdir}/libphobos; \
 769                 . ${srcdir}/configure.tgt; \
 770                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 771         then
 772             AC_MSG_RESULT([no])
 773             noconfigdirs="$noconfigdirs target-libphobos"
 774         else
 775             AC_MSG_RESULT([yes])
 776         fi
 777     fi
 778 fi
 779
 780 # Disable Fortran for some systems.
 781 case "${target}" in
 782   mmix-*-*)
 783     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 784     unsupported_languages="$unsupported_languages fortran"
 785     ;;
 786   bpf-*-*)
 787     unsupported_languages="$unsupported_languages fortran"
 788     ;;
 789 esac
 790
 791 # Disable libffi for some systems.
 792 case "${target}" in
 793   powerpc-*-darwin*)
 794     ;;
 795   i[[3456789]]86-*-darwin*)
 796     ;;
 797   x86_64-*-darwin[[912]]*)
 798     ;;
 799   *-*-darwin*)
 800     noconfigdirs="$noconfigdirs target-libffi"
 801     ;;
 802   *-*-netware*)
 803     noconfigdirs="$noconfigdirs target-libffi"
 804     ;;
 805   *-*-phoenix*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   *-*-rtems*)
 809     noconfigdirs="$noconfigdirs target-libffi"
 810     ;;
 811   *-*-tpf*)
 812     noconfigdirs="$noconfigdirs target-libffi"
 813     ;;
 814   *-*-uclinux*)
 815     noconfigdirs="$noconfigdirs target-libffi"
 816     ;;
 817   *-*-vxworks*)
 818     noconfigdirs="$noconfigdirs target-libffi"
 819     ;;
 820   aarch64*-*-freebsd*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   alpha*-*-*vms*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826   arm*-*-freebsd*)
 827     noconfigdirs="$noconfigdirs target-libffi"
 828     ;;
 829   arm-wince-pe)
 830     noconfigdirs="$noconfigdirs target-libffi"
 831     ;;
 832   arm*-*-symbianelf*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   bpf-*-*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838   cris-*-* | crisv32-*-*)
 839     case "${target}" in
 840       *-*-linux*)
 841         ;;
 842       *) # See PR46792 regarding target-libffi.
 843         noconfigdirs="$noconfigdirs target-libffi";;
 844     esac
 845     ;;
 846   hppa*64*-*-hpux*)
 847     noconfigdirs="$noconfigdirs target-libffi"
 848     ;;
 849   hppa*-hp-hpux11*)
 850     ;;
 851   hppa*-*-hpux*)
 852     noconfigdirs="$noconfigdirs target-libffi"
 853     ;;
 854   ia64*-*-*vms*)
 855     noconfigdirs="$noconfigdirs target-libffi"
 856     ;;
 857   i[[3456789]]86-w64-mingw*)
 858     noconfigdirs="$noconfigdirs target-libffi"
 859     ;;
 860   i[[3456789]]86-*-mingw*)
 861     noconfigdirs="$noconfigdirs target-libffi"
 862     ;;
 863   x86_64-*-mingw*)
 864     noconfigdirs="$noconfigdirs target-libffi"
 865     ;;
 866   mmix-*-*)
 867     noconfigdirs="$noconfigdirs target-libffi"
 868     ;;
 869   powerpc-*-aix*)
 870     ;;
 871   rs6000-*-aix*)
 872     ;;
 873   ft32-*-*)
 874     noconfigdirs="$noconfigdirs target-libffi"
 875     ;;
 876   *-*-lynxos*)
 877     noconfigdirs="$noconfigdirs target-libffi"
 878     ;;
 879 esac
 880
 881 # Disable the go frontend on systems where it is known to not work. Please keep
 882 # this in sync with contrib/config-list.mk.
 883 case "${target}" in
 884 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 885     unsupported_languages="$unsupported_languages go"
 886     ;;
 887 esac
 888
 889 # Only allow gdbserver on some systems.
 890 if test -d ${srcdir}/gdbserver; then
 891     if test x$enable_gdbserver = x; then
 892         AC_MSG_CHECKING([for gdbserver support])
 893         if (srcdir=${srcdir}/gdbserver; \
 894                 . ${srcdir}/configure.srv; \
 895                 test -n "$UNSUPPORTED")
 896         then
 897             AC_MSG_RESULT([no])
 898             noconfigdirs="$noconfigdirs gdbserver"
 899         else
 900             AC_MSG_RESULT([yes])
 901         fi
 902     fi
 903 fi
 904
 905 # Disable libgo for some systems where it is known to not work.
 906 # For testing, you can easily override this with --enable-libgo.
 907 if test x$enable_libgo = x; then
 908     case "${target}" in
 909     *-*-darwin*)
 910         # PR 46986
 911         noconfigdirs="$noconfigdirs target-libgo"
 912         ;;
 913     *-*-cygwin* | *-*-mingw*)
 914         noconfigdirs="$noconfigdirs target-libgo"
 915         ;;
 916     bpf-*-*)
 917         noconfigdirs="$noconfigdirs target-libgo"
 918         ;;
 919     esac
 920 fi
 921
 922 # Default libgloss CPU subdirectory.
 923 libgloss_dir="$target_cpu"
 924
 925 case "${target}" in
 926   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 927     libgloss_dir=wince
 928     ;;
 929   aarch64*-*-* )
 930     libgloss_dir=aarch64
 931     ;;
 932   arm*-*-*)
 933     libgloss_dir=arm
 934     ;;
 935   cris-*-* | crisv32-*-*)
 936     libgloss_dir=cris
 937     ;;
 938   hppa*-*-*)
 939     libgloss_dir=pa
 940     ;;
 941   i[[3456789]]86-*-*)
 942     libgloss_dir=i386
 943     ;;
 944   loongarch*-*-*)
 945     libgloss_dir=loongarch
 946     ;;
 947   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 948     libgloss_dir=m68hc11
 949     ;;
 950   m68*-*-* | fido-*-*)
 951     libgloss_dir=m68k
 952     ;;
 953   mips*-*-*)
 954     libgloss_dir=mips
 955     ;;
 956   powerpc*-*-*)
 957     libgloss_dir=rs6000
 958     ;;
 959   pru-*-*)
 960     libgloss_dir=pru
 961     ;;
 962   sparc*-*-*)
 963     libgloss_dir=sparc
 964     ;;
 965 esac
 966
 967 # Disable newlib and libgloss for various target OSes.
 968 case "${target}" in
 969   alpha*-dec-osf*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   i[[3456789]]86-*-linux*)
 973     # This section makes it possible to build newlib natively on linux.
 974     # If we are using a cross compiler then don't configure newlib.
 975     if test x${is_cross_compiler} != xno ; then
 976       noconfigdirs="$noconfigdirs target-newlib"
 977     fi
 978     noconfigdirs="$noconfigdirs target-libgloss"
 979     # If we are not using a cross compiler, do configure newlib.
 980     # Note however, that newlib will only be configured in this situation
 981     # if the --with-newlib option has been given, because otherwise
 982     # 'target-newlib' will appear in skipdirs.
 983     ;;
 984   i[[3456789]]86-*-rdos*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990   sparc-*-sunos4*)
 991     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 992     ;;
 993   bpf-*-*)
 994     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 995     ;;
 996   *-*-aix*)
 997     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 998     ;;
 999   *-*-beos*)
1000     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     ;;
1002   *-*-chorusos)
1003     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1004     ;;
1005   *-*-dragonfly*)
1006     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1007     ;;
1008   *-*-freebsd*)
1009     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1010     ;;
1011   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1012     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1013     ;;
1014   *-*-lynxos*)
1015     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1016     ;;
1017   *-*-mingw*)
1018     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1019     ;;
1020   *-*-netbsd*)
1021     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1022     ;;
1023   *-*-netware*)
1024     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1025     ;;
1026   *-*-tpf*)
1027     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1028     ;;
1029   *-*-uclinux*)
1030     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1031     ;;
1032   *-*-vxworks*)
1033     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1034     ;;
1035 esac
1036
1037 case "${target}" in
1038   *-*-chorusos)
1039     ;;
1040   aarch64-*-darwin*)
1041     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1042     noconfigdirs="$noconfigdirs sim target-rda"
1043     ;;
1044   amdgcn*-*-*)
1045     ;;
1046   arm-*-darwin*)
1047     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1048     noconfigdirs="$noconfigdirs sim target-rda"
1049     ;;
1050   powerpc-*-darwin*)
1051     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1052     noconfigdirs="$noconfigdirs sim target-rda"
1053     ;;
1054   i[[3456789]]86-*-darwin*)
1055     noconfigdirs="$noconfigdirs ld gprof"
1056     noconfigdirs="$noconfigdirs sim target-rda"
1057     ;;
1058   x86_64-*-darwin[[912]]*)
1059     noconfigdirs="$noconfigdirs ld gas gprof"
1060     noconfigdirs="$noconfigdirs sim target-rda"
1061     ;;
1062   *-*-darwin*)
1063     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1064     noconfigdirs="$noconfigdirs sim target-rda"
1065     ;;
1066   *-*-dragonfly*)
1067     ;;
1068   *-*-freebsd*)
1069     if test "x$with_gmp" = x \
1070         && ! test -d ${srcdir}/gmp \
1071         && test -f /usr/local/include/gmp.h; then
1072       with_gmp=/usr/local
1073     fi
1074     ;;
1075   *-*-kaos*)
1076     # Remove unsupported stuff on all kaOS configurations.
1077     noconfigdirs="$noconfigdirs target-libgloss"
1078     ;;
1079   *-*-netbsd*)
1080     ;;
1081   *-*-netware*)
1082     ;;
1083   *-*-phoenix*)
1084     noconfigdirs="$noconfigdirs target-libgloss"
1085     ;;
1086   *-*-rtems*)
1087     noconfigdirs="$noconfigdirs target-libgloss"
1088     ;;
1089     # The tpf target doesn't support gdb yet.
1090   *-*-tpf*)
1091     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1092     ;;
1093   *-*-uclinux*)
1094     noconfigdirs="$noconfigdirs target-rda"
1095     ;;
1096   *-*-vxworks*)
1097     ;;
1098   alpha*-dec-osf*)
1099     # ld works, but does not support shared libraries.
1100     # gas doesn't generate exception information.
1101     noconfigdirs="$noconfigdirs gas ld"
1102     ;;
1103   alpha*-*-*vms*)
1104     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1105     ;;
1106   alpha*-*-*)
1107     # newlib is not 64 bit ready
1108     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1109     ;;
1110   bpf-*-*)
1111     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1112     ;;
1113   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1114     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1115     ;;
1116   arc*-*-*)
1117     noconfigdirs="$noconfigdirs sim"
1118     ;;
1119   arm-*-pe*)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   arm-*-riscix*)
1123     noconfigdirs="$noconfigdirs ld target-libgloss"
1124     ;;
1125   avr-*-*)
1126     if test x${with_avrlibc} != xno; then
1127       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1128     fi
1129     ;;
1130   c4x-*-* | tic4x-*-*)
1131     noconfigdirs="$noconfigdirs target-libgloss"
1132     ;;
1133   tic54x-*-*)
1134     noconfigdirs="$noconfigdirs target-libgloss gdb"
1135     ;;
1136   d10v-*-*)
1137     noconfigdirs="$noconfigdirs target-libgloss"
1138     ;;
1139   d30v-*-*)
1140     noconfigdirs="$noconfigdirs gdb"
1141     ;;
1142   fr30-*-elf*)
1143     noconfigdirs="$noconfigdirs gdb"
1144     ;;
1145   ft32-*-*)
1146     noconfigdirs="$noconfigdirs target-rda gprof"
1147     ;;
1148   moxie-*-*)
1149     noconfigdirs="$noconfigdirs"
1150     ;;
1151   h8300*-*-*)
1152     noconfigdirs="$noconfigdirs target-libgloss"
1153     ;;
1154   h8500-*-*)
1155     noconfigdirs="$noconfigdirs target-libgloss"
1156     ;;
1157   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1158     ;;
1159   hppa*64*-*-hpux*)
1160     noconfigdirs="$noconfigdirs gdb"
1161     ;;
1162   hppa*-*-hpux11*)
1163     noconfigdirs="$noconfigdirs gdb ld"
1164     ;;
1165   hppa*64*-*-linux*)
1166     ;;
1167   hppa*-*-linux*)
1168     ;;
1169   hppa*-*-*elf* | \
1170   hppa*-*-lites* | \
1171   hppa*-*-openbsd* | \
1172   hppa*64*-*-*)
1173     ;;
1174   hppa*-*-pro*)
1175     ;;
1176   hppa*-*-*)
1177     noconfigdirs="$noconfigdirs ld"
1178     ;;
1179   i960-*-*)
1180     noconfigdirs="$noconfigdirs gdb"
1181     ;;
1182   ia64*-*-elf*)
1183     # No gdb support yet.
1184     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1185     ;;
1186   ia64*-**-hpux*)
1187     # No ld support yet.
1188     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1189     ;;
1190   ia64*-*-*vms*)
1191     # No ld support yet.
1192     noconfigdirs="$noconfigdirs libgui itcl ld"
1193     ;;
1194   i[[3456789]]86-w64-mingw*)
1195     ;;
1196   i[[3456789]]86-*-mingw*)
1197     target_configdirs="$target_configdirs target-winsup"
1198     ;;
1199   *-*-cygwin*)
1200     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1201     noconfigdirs="$noconfigdirs target-libgloss"
1202     # always build newlib if winsup directory is present.
1203     if test -d "$srcdir/winsup/cygwin"; then
1204       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1205     elif test -d "$srcdir/newlib"; then
1206       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1207     fi
1208     ;;
1209   i[[3456789]]86-*-pe)
1210     noconfigdirs="$noconfigdirs target-libgloss"
1211     ;;
1212   i[[3456789]]86-*-sco3.2v5*)
1213     # The linker does not yet know about weak symbols in COFF,
1214     # and is not configured to handle mixed ELF and COFF.
1215     noconfigdirs="$noconfigdirs ld target-libgloss"
1216     ;;
1217   i[[3456789]]86-*-sco*)
1218     noconfigdirs="$noconfigdirs gprof target-libgloss"
1219     ;;
1220   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1221     noconfigdirs="$noconfigdirs target-libgloss"
1222     ;;
1223   i[[3456789]]86-*-sysv4*)
1224     noconfigdirs="$noconfigdirs target-libgloss"
1225     ;;
1226   i[[3456789]]86-*-beos*)
1227     noconfigdirs="$noconfigdirs gdb"
1228     ;;
1229   i[[3456789]]86-*-rdos*)
1230     noconfigdirs="$noconfigdirs gdb"
1231     ;;
1232   mmix-*-*)
1233     noconfigdirs="$noconfigdirs gdb"
1234     ;;
1235   mt-*-*)
1236     noconfigdirs="$noconfigdirs sim"
1237     ;;
1238   nfp-*-*)
1239     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1240     noconfigdirs="$noconfigdirs $target_libraries"
1241     ;;
1242   pdp11-*-*)
1243     noconfigdirs="$noconfigdirs gdb gprof"
1244     ;;
1245   powerpc-*-aix*)
1246     # copied from rs6000-*-* entry
1247     noconfigdirs="$noconfigdirs gprof"
1248     ;;
1249   powerpc*-*-winnt* | powerpc*-*-pe*)
1250     target_configdirs="$target_configdirs target-winsup"
1251     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1252     # always build newlib.
1253     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1254     ;;
1255     # This is temporary until we can link against shared libraries
1256   powerpcle-*-solaris*)
1257     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1258     ;;
1259   powerpc-*-beos*)
1260     noconfigdirs="$noconfigdirs gdb"
1261     ;;
1262   rs6000-*-lynxos*)
1263     noconfigdirs="$noconfigdirs gprof"
1264     ;;
1265   rs6000-*-aix*)
1266     noconfigdirs="$noconfigdirs gprof"
1267     ;;
1268   rs6000-*-*)
1269     noconfigdirs="$noconfigdirs gprof"
1270     ;;
1271   m68k-apollo-*)
1272     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1273     ;;
1274   microblaze*)
1275     noconfigdirs="$noconfigdirs gprof"
1276     ;;
1277   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1278     if test x$with_newlib = xyes; then
1279       noconfigdirs="$noconfigdirs gprof"
1280     fi
1281     ;;
1282   mips*-*-irix5*)
1283     noconfigdirs="$noconfigdirs gprof target-libgloss"
1284     ;;
1285   mips*-*-irix6*)
1286     noconfigdirs="$noconfigdirs gprof target-libgloss"
1287     ;;
1288   mips*-*-bsd*)
1289     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1290     ;;
1291   mips*-*-linux*)
1292     ;;
1293   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1294   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1295     noconfigdirs="$noconfigdirs ld gas gprof"
1296     ;;
1297   mips*-*-*)
1298     noconfigdirs="$noconfigdirs gprof"
1299     ;;
1300   nvptx*-*-*)
1301     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1302     ;;
1303   sh-*-*)
1304     case "${target}" in
1305       sh*-*-elf)
1306          ;;
1307       *)
1308          noconfigdirs="$noconfigdirs target-libgloss" ;;
1309     esac
1310     ;;
1311   sparc-*-sunos4*)
1312     if test x${is_cross_compiler} = xno ; then
1313            use_gnu_ld=no
1314     fi
1315     ;;
1316   tic6x-*-*)
1317     noconfigdirs="$noconfigdirs sim"
1318     ;;
1319   tilepro*-*-* | tilegx*-*-*)
1320     noconfigdirs="$noconfigdirs sim"
1321     ;;
1322   v810-*-*)
1323     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1324     ;;
1325   vax-*-*)
1326     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1327     ;;
1328   wasm32-*-*)
1329     noconfigdirs="$noconfigdirs ld"
1330     ;;
1331   loongarch*-*-linux*)
1332     ;;
1333   loongarch*-*-*)
1334     noconfigdirs="$noconfigdirs gprof"
1335     ;;
1336 esac
1337
1338 # If we aren't building newlib, then don't build libgloss, since libgloss
1339 # depends upon some newlib header files.
1340 case "${noconfigdirs}" in
1341   *target-libgloss*) ;;
1342   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1343 esac
1344
1345 # Work in distributions that contain no compiler tools, like Autoconf.
1346 host_makefile_frag=/dev/null
1347 if test -d ${srcdir}/config ; then
1348 case "${host}" in
1349   i[[3456789]]86-*-msdosdjgpp*)
1350     host_makefile_frag="config/mh-djgpp"
1351     ;;
1352   *-cygwin*)
1353     ACX_CHECK_CYGWIN_CAT_WORKS
1354     host_makefile_frag="config/mh-cygwin"
1355     ;;
1356   *-mingw*)
1357     host_makefile_frag="config/mh-mingw"
1358     ;;
1359   alpha*-linux*)
1360     host_makefile_frag="config/mh-alpha-linux"
1361     ;;
1362   hppa*-hp-hpux10*)
1363     host_makefile_frag="config/mh-pa-hpux10"
1364     ;;
1365   hppa*-hp-hpux*)
1366     host_makefile_frag="config/mh-pa"
1367     ;;
1368   hppa*-*)
1369     host_makefile_frag="config/mh-pa"
1370     ;;
1371   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1372     host_makefile_frag="config/mh-darwin"
1373     ;;
1374   powerpc-*-aix*)
1375     host_makefile_frag="config/mh-ppc-aix"
1376     ;;
1377   rs6000-*-aix*)
1378     host_makefile_frag="config/mh-ppc-aix"
1379     ;;
1380 esac
1381 fi
1382
1383 if test "${build}" != "${host}" ; then
1384   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1385   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1386   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1387   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1388   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1389   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1390   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1391   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1392   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1393   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1394   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1395   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1396   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1397   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1398   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1399 else
1400   AR_FOR_BUILD="\$(AR)"
1401   AS_FOR_BUILD="\$(AS)"
1402   CC_FOR_BUILD="\$(CC)"
1403   CXX_FOR_BUILD="\$(CXX)"
1404   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1405   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1406   GOC_FOR_BUILD="\$(GOC)"
1407   GDC_FOR_BUILD="\$(GDC)"
1408   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1409   LD_FOR_BUILD="\$(LD)"
1410   NM_FOR_BUILD="\$(NM)"
1411   RANLIB_FOR_BUILD="\$(RANLIB)"
1412   WINDRES_FOR_BUILD="\$(WINDRES)"
1413   WINDMC_FOR_BUILD="\$(WINDMC)"
1414 fi
1415
1416 AC_PROG_CC_C99
1417 AC_PROG_CXX
1418
1419 # We must set the default linker to the linker used by gcc for the correct
1420 # operation of libtool.  If LD is not defined and we are using gcc, try to
1421 # set the LD default to the ld used by gcc.
1422 if test -z "$LD"; then
1423   if test "$GCC" = yes; then
1424     case $build in
1425     *-*-mingw*)
1426       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1427     *)
1428       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1429     esac
1430     case $gcc_prog_ld in
1431     # Accept absolute paths.
1432     [[\\/]* | [A-Za-z]:[\\/]*)]
1433       LD="$gcc_prog_ld" ;;
1434     esac
1435   fi
1436 fi
1437
1438 # Check whether -static-libstdc++ -static-libgcc is supported.
1439 have_static_libs=no
1440 if test "$GCC" = yes; then
1441   saved_LDFLAGS="$LDFLAGS"
1442
1443   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1444   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1445   AC_LANG_PUSH(C++)
1446   AC_LINK_IFELSE([AC_LANG_SOURCE([
1447 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1448 #error -static-libstdc++ not implemented
1449 #endif
1450 int main() {}])],
1451     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1452     [AC_MSG_RESULT([no])])
1453   AC_LANG_POP(C++)
1454
1455   LDFLAGS="$saved_LDFLAGS"
1456 fi
1457
1458 ACX_PROG_GNAT
1459 ACX_PROG_GDC
1460 ACX_PROG_CMP_IGNORE_INITIAL
1461
1462 AC_ARG_ENABLE([bootstrap],
1463 [AS_HELP_STRING([--enable-bootstrap],
1464                 [enable bootstrapping @<:@yes if native build@:>@])],,
1465 enable_bootstrap=default)
1466
1467 # Issue errors and warnings for invalid/strange bootstrap combinations.
1468 if test -r $srcdir/gcc/configure; then
1469   have_compiler=yes
1470 else
1471   have_compiler=no
1472 fi
1473
1474 case "$have_compiler:$host:$target:$enable_bootstrap" in
1475   *:*:*:no) ;;
1476
1477   # Default behavior.  Enable bootstrap if we have a compiler
1478   # and we are in a native configuration.
1479   yes:$build:$build:default)
1480     enable_bootstrap=yes ;;
1481
1482   *:*:*:default)
1483     enable_bootstrap=no ;;
1484
1485   # We have a compiler and we are in a native configuration, bootstrap is ok
1486   yes:$build:$build:yes)
1487     ;;
1488
1489   # Other configurations, but we have a compiler.  Assume the user knows
1490   # what he's doing.
1491   yes:*:*:yes)
1492     AC_MSG_WARN([trying to bootstrap a cross compiler])
1493     ;;
1494
1495   # No compiler: if they passed --enable-bootstrap explicitly, fail
1496   no:*:*:yes)
1497     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1498
1499   # Fail if wrong command line
1500   *)
1501     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1502     ;;
1503 esac
1504
1505 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1506 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1507 # require C++11 (or higher).
1508 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1509   CXX="$CXX -std=c++11"
1510 elif test "$have_compiler" = yes; then
1511   AX_CXX_COMPILE_STDCXX(11)
1512
1513   if test "${build}" != "${host}"; then
1514     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1515   fi
1516 fi
1517
1518 AC_ARG_ENABLE([pgo-build],
1519 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1520                 [enable the PGO build])],
1521 [enable_pgo_build=$enableval],
1522 [enable_pgo_build=no])
1523
1524 # Issue errors and warnings for invalid/strange PGO build combinations.
1525 case "$have_compiler:$host:$target:$enable_pgo_build" in
1526   *:*:*:no) ;;
1527
1528   # Allow the PGO build only if we aren't building a compiler and
1529   # we are in a native configuration.
1530   no:$build:$build:yes | no:$build:$build:lto) ;;
1531
1532   # Disallow the PGO bootstrap if we are building a compiler.
1533   yes:*:*:yes | yes:*:*:lto)
1534     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1535
1536   *)
1537     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1538     ;;
1539 esac
1540
1541 if test "$enable_pgo_build" != "no"; then
1542   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1543   old_CFLAGS="$CFLAGS"
1544   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1545   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1546   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1547                     [PGO_BUILD_GEN_CFLAGS=])
1548   CFLAGS="$old_CFLAGS"
1549   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1550     AC_MSG_RESULT([yes])
1551     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1552   else
1553     AC_MSG_RESULT([no])
1554     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1555   fi
1556
1557   if test "$enable_pgo_build" = "lto"; then
1558     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1559     old_CFLAGS="$CFLAGS"
1560     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1561     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1562     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1563                       [PGO_BUILD_LTO_CFLAGS=])
1564     CFLAGS="$old_CFLAGS"
1565     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1566       AC_MSG_RESULT([yes])
1567     else
1568       AC_MSG_RESULT([no])
1569       AC_MSG_WARN([LTO is disabled for the PGO build])
1570     fi
1571   fi
1572 fi
1573 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1574 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1575 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1576
1577 # Used for setting $lt_cv_objdir
1578 _LT_CHECK_OBJDIR
1579
1580 # Check for GMP, MPFR and MPC
1581 gmplibs="-lmpc -lmpfr -lgmp"
1582 gmpinc=
1583 have_gmp=no
1584
1585 # Specify a location for mpc
1586 # check for this first so it ends up on the link line before mpfr.
1587 AC_ARG_WITH(mpc,
1588 [AS_HELP_STRING([--with-mpc=PATH],
1589                 [specify prefix directory for installed MPC package.
1590                  Equivalent to --with-mpc-include=PATH/include
1591                  plus --with-mpc-lib=PATH/lib])])
1592 AC_ARG_WITH(mpc-include,
1593 [AS_HELP_STRING([--with-mpc-include=PATH],
1594                 [specify directory for installed MPC include files])])
1595 AC_ARG_WITH(mpc-lib,
1596 [AS_HELP_STRING([--with-mpc-lib=PATH],
1597                 [specify directory for the installed MPC library])])
1598
1599 if test "x$with_mpc" != x; then
1600   gmplibs="-L$with_mpc/lib $gmplibs"
1601   gmpinc="-I$with_mpc/include $gmpinc"
1602 fi
1603 if test "x$with_mpc_include" != x; then
1604   gmpinc="-I$with_mpc_include $gmpinc"
1605 fi
1606 if test "x$with_mpc_lib" != x; then
1607   gmplibs="-L$with_mpc_lib $gmplibs"
1608 fi
1609 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1610   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1611   gmpinc='-I$$s/mpc/src '"$gmpinc"
1612   # Do not test the mpc version.  Assume that it is sufficient, since
1613   # it is in the source tree, and the library has not been built yet
1614   # but it would be included on the link line in the version check below
1615   # hence making the test fail.
1616   have_gmp=yes
1617 fi
1618
1619 # Specify a location for mpfr
1620 # check for this first so it ends up on the link line before gmp.
1621 AC_ARG_WITH(mpfr,
1622 [AS_HELP_STRING([--with-mpfr=PATH],
1623                 [specify prefix directory for installed MPFR package.
1624                  Equivalent to --with-mpfr-include=PATH/include
1625                  plus --with-mpfr-lib=PATH/lib])])
1626 AC_ARG_WITH(mpfr-include,
1627 [AS_HELP_STRING([--with-mpfr-include=PATH],
1628                 [specify directory for installed MPFR include files])])
1629 AC_ARG_WITH(mpfr-lib,
1630 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1631                 [specify directory for the installed MPFR library])])
1632
1633 if test "x$with_mpfr" != x; then
1634   gmplibs="-L$with_mpfr/lib $gmplibs"
1635   gmpinc="-I$with_mpfr/include $gmpinc"
1636 fi
1637 if test "x$with_mpfr_include" != x; then
1638   gmpinc="-I$with_mpfr_include $gmpinc"
1639 fi
1640 if test "x$with_mpfr_lib" != x; then
1641   gmplibs="-L$with_mpfr_lib $gmplibs"
1642 fi
1643 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1644   # MPFR v3.1.0 moved the sources into a src sub-directory.
1645   if ! test -d ${srcdir}/mpfr/src; then
1646     AC_MSG_ERROR([dnl
1647 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1648   fi
1649   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1650   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1651   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1652   # Do not test the mpfr version.  Assume that it is sufficient, since
1653   # it is in the source tree, and the library has not been built yet
1654   # but it would be included on the link line in the version check below
1655   # hence making the test fail.
1656   have_gmp=yes
1657 fi
1658
1659 # Specify a location for gmp
1660 AC_ARG_WITH(gmp,
1661 [AS_HELP_STRING([--with-gmp=PATH],
1662                 [specify prefix directory for the installed GMP package.
1663                  Equivalent to --with-gmp-include=PATH/include
1664                  plus --with-gmp-lib=PATH/lib])])
1665 AC_ARG_WITH(gmp-include,
1666 [AS_HELP_STRING([--with-gmp-include=PATH],
1667                 [specify directory for installed GMP include files])])
1668 AC_ARG_WITH(gmp-lib,
1669 [AS_HELP_STRING([--with-gmp-lib=PATH],
1670                 [specify directory for the installed GMP library])])
1671
1672
1673 if test "x$with_gmp" != x; then
1674   gmplibs="-L$with_gmp/lib $gmplibs"
1675   gmpinc="-I$with_gmp/include $gmpinc"
1676 fi
1677 if test "x$with_gmp_include" != x; then
1678   gmpinc="-I$with_gmp_include $gmpinc"
1679 fi
1680 if test "x$with_gmp_lib" != x; then
1681   gmplibs="-L$with_gmp_lib $gmplibs"
1682 fi
1683 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1684   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1685   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1686   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1687   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1688   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1689   # Do not test the gmp version.  Assume that it is sufficient, since
1690   # it is in the source tree, and the library has not been built yet
1691   # but it would be included on the link line in the version check below
1692   # hence making the test fail.
1693   have_gmp=yes
1694 fi
1695
1696 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1697   have_gmp=yes
1698   saved_CFLAGS="$CFLAGS"
1699   CFLAGS="$CFLAGS $gmpinc"
1700   # Check for the recommended and required versions of GMP.
1701   AC_MSG_CHECKING([for the correct version of gmp.h])
1702   AC_TRY_COMPILE([#include "gmp.h"],[
1703   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1704   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1705   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1706   choke me
1707   #endif
1708   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1709   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1710   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1711   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1712   choke me
1713   #endif
1714   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1715    [AC_MSG_RESULT([no]); have_gmp=no])
1716
1717   # If we have GMP, check the MPFR version.
1718   if test x"$have_gmp" = xyes; then
1719     # Check for the recommended and required versions of MPFR.
1720     AC_MSG_CHECKING([for the correct version of mpfr.h])
1721     AC_TRY_COMPILE([#include <gmp.h>
1722     #include <mpfr.h>],[
1723     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1724     choke me
1725     #endif
1726     ], [AC_TRY_COMPILE([#include <gmp.h>
1727     #include <mpfr.h>],[
1728     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1729     choke me
1730     #endif
1731     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1732      [AC_MSG_RESULT([no]); have_gmp=no])
1733   fi
1734
1735   # Check for the MPC header version.
1736   if test x"$have_gmp" = xyes ; then
1737     # Check for the recommended and required versions of MPC.
1738     AC_MSG_CHECKING([for the correct version of mpc.h])
1739     AC_TRY_COMPILE([#include <mpc.h>],[
1740     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1741     choke me
1742     #endif
1743     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1744     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1745     choke me
1746     #endif
1747     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1748      [AC_MSG_RESULT([no]); have_gmp=no])
1749   fi
1750
1751   # Now check the MPFR library.
1752   if test x"$have_gmp" = xyes; then
1753     saved_LIBS="$LIBS"
1754     LIBS="$LIBS $gmplibs"
1755     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1756     AC_TRY_LINK([#include <mpc.h>],[
1757     mpfr_t n;
1758     mpfr_t x;
1759     mpc_t c;
1760     int t;
1761     mpfr_init (n);
1762     mpfr_init (x);
1763     mpfr_atan2 (n, n, x, MPFR_RNDN);
1764     mpfr_erfc (n, x, MPFR_RNDN);
1765     mpfr_subnormalize (x, t, MPFR_RNDN);
1766     mpfr_clear(n);
1767     mpfr_clear(x);
1768     mpc_init2 (c, 53);
1769     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1770     mpc_cosh (c, c, MPC_RNDNN);
1771     mpc_pow (c, c, c, MPC_RNDNN);
1772     mpc_acosh (c, c, MPC_RNDNN);
1773     mpc_clear (c);
1774     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1775     LIBS="$saved_LIBS"
1776   fi
1777
1778   CFLAGS="$saved_CFLAGS"
1779
1780 # The library versions listed in the error message below should match
1781 # the HARD-minimums enforced above.
1782   if test x$have_gmp != xyes; then
1783     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1784 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1785 their locations.  Source code for these libraries can be found at
1786 their respective hosting sites as well as at
1787 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1788 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1789 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1790 make sure that you have installed both the libraries and the header
1791 files.  They may be located in separate packages.])
1792   fi
1793 fi
1794
1795 # Flags needed for both GMP, MPFR and/or MPC.
1796 AC_SUBST(gmplibs)
1797 AC_SUBST(gmpinc)
1798 AC_SUBST(extra_mpfr_configure_flags)
1799 AC_SUBST(extra_mpc_gmp_configure_flags)
1800 AC_SUBST(extra_mpc_mpfr_configure_flags)
1801 AC_SUBST(extra_isl_gmp_configure_flags)
1802
1803 # Libraries to use for stage1 or when not bootstrapping.
1804 AC_ARG_WITH(stage1-libs,
1805 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1806 [if test "$withval" = "no" -o "$withval" = "yes"; then
1807    stage1_libs=
1808  else
1809    stage1_libs=$withval
1810  fi],
1811 [stage1_libs=])
1812 AC_SUBST(stage1_libs)
1813
1814 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1815 # default is yes if gcc is being built; no otherwise.  The reason for
1816 # this default is that gdb is sometimes linked against GNU Source
1817 # Highlight, which is a shared library that uses C++ exceptions.  In
1818 # this case, -static-libstdc++ will cause crashes.
1819 AC_ARG_WITH(static-standard-libraries,
1820 [AS_HELP_STRING([--with-static-standard-libraries],
1821                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1822 [], [with_static_standard_libraries=auto])
1823 if test "$with_static_standard_libraries" = auto; then
1824   with_static_standard_libraries=$have_compiler
1825 fi
1826
1827 # Linker flags to use for stage1 or when not bootstrapping.
1828 AC_ARG_WITH(stage1-ldflags,
1829 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1830 [if test "$withval" = "no" -o "$withval" = "yes"; then
1831    stage1_ldflags=
1832  else
1833    stage1_ldflags=$withval
1834  fi],
1835 [stage1_ldflags=
1836  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1837  # if supported.  But if the user explicitly specified the libraries to use,
1838  # trust that they are doing what they want.
1839  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1840      -a "$have_static_libs" = yes; then
1841    stage1_ldflags="-static-libstdc++ -static-libgcc"
1842  fi])
1843 AC_SUBST(stage1_ldflags)
1844
1845 # Libraries to use for stage2 and later builds.
1846 AC_ARG_WITH(boot-libs,
1847 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1848 [if test "$withval" = "no" -o "$withval" = "yes"; then
1849    poststage1_libs=
1850  else
1851    poststage1_libs=$withval
1852  fi],
1853 [poststage1_libs=])
1854 AC_SUBST(poststage1_libs)
1855
1856 # Linker flags to use for stage2 and later builds.
1857 AC_ARG_WITH(boot-ldflags,
1858 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1859                 [linker flags for stage2 and later])],
1860 [if test "$withval" = "no" -o "$withval" = "yes"; then
1861    poststage1_ldflags=
1862  else
1863    poststage1_ldflags=$withval
1864  fi],
1865 [poststage1_ldflags=
1866  # In stages 2 and 3, default to linking libstdc++ and libgcc
1867  # statically.  But if the user explicitly specified the libraries to
1868  # use, trust that they are doing what they want.
1869  if test "$poststage1_libs" = ""; then
1870    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1871  fi])
1872 AC_SUBST(poststage1_ldflags)
1873
1874 # GCC GRAPHITE dependency isl.
1875 # Basic setup is inlined here, actual checks are in config/isl.m4
1876
1877 AC_ARG_WITH(isl,
1878   [AS_HELP_STRING(
1879    [--with-isl=PATH],
1880    [Specify prefix directory for the installed isl package.
1881     Equivalent to --with-isl-include=PATH/include
1882     plus --with-isl-lib=PATH/lib])])
1883
1884 # Treat --without-isl as a request to disable
1885 # GRAPHITE support and skip all following checks.
1886 if test "x$with_isl" != "xno"; then
1887   # Check for isl
1888   dnl Provide configure switches and initialize islinc & isllibs
1889   dnl with user input.
1890   ISL_INIT_FLAGS
1891   dnl The versions of isl that work for Graphite
1892   ISL_CHECK_VERSION()
1893   dnl Only execute fail-action, if isl has been requested.
1894   ISL_IF_FAILED([
1895     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1896 fi
1897
1898 # If the isl check failed, disable builds of in-tree variant of isl
1899 if test "x$with_isl" = xno ||
1900    test "x$gcc_cv_isl" = xno; then
1901   noconfigdirs="$noconfigdirs isl"
1902   islinc=
1903 fi
1904
1905 AC_SUBST(isllibs)
1906 AC_SUBST(islinc)
1907
1908 # Check for LTO support.
1909 AC_ARG_ENABLE(lto,
1910 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1911 enable_lto=$enableval,
1912 enable_lto=yes; default_enable_lto=yes)
1913
1914 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1915   build_lto_plugin=yes
1916 ],[if test x"$default_enable_lto" = x"yes" ; then
1917     case $target in
1918       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1919       # On other non-ELF platforms, LTO has yet to be validated.
1920       *) enable_lto=no ;;
1921     esac
1922   else
1923   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1924   # It would also be nice to check the binutils support, but we don't
1925   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1926   # warn during gcc/ subconfigure; unless you're bootstrapping with
1927   # -flto it won't be needed until after installation anyway.
1928     case $target in
1929       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1930       *) if test x"$enable_lto" = x"yes"; then
1931         AC_MSG_ERROR([LTO support is not enabled for this target.])
1932         fi
1933       ;;
1934     esac
1935   fi
1936   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1937   # Build it unless LTO was explicitly disabled.
1938   case $target in
1939     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1940     *) ;;
1941   esac
1942 ])
1943
1944 AC_ARG_ENABLE(linker-plugin-configure-flags,
1945   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1946     [additional flags for configuring linker plugins @<:@none@:>@])],
1947   extra_linker_plugin_configure_flags=$enableval,
1948   extra_linker_plugin_configure_flags=)
1949 AC_SUBST(extra_linker_plugin_configure_flags)
1950 AC_ARG_ENABLE(linker-plugin-flags,
1951   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1952     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1953   extra_linker_plugin_flags=$enableval,
1954   extra_linker_plugin_flags=)
1955 AC_SUBST(extra_linker_plugin_flags)
1956
1957 # Enable --enable-host-shared.
1958 # Checked early to determine whether jit is an 'all' language
1959 AC_ARG_ENABLE(host-shared,
1960 [AS_HELP_STRING([--enable-host-shared],
1961                 [build host code as shared libraries])],
1962 [host_shared=$enableval
1963  case $host in
1964    x86_64-*-darwin* | aarch64-*-darwin*)
1965      if test x$host_shared != xyes ; then
1966        # PIC is the default, and actually cannot be switched off.
1967        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1968        host_shared=yes
1969      fi ;;
1970   *) ;;
1971  esac],
1972 [case $host in
1973   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1974   *) host_shared=no ;;
1975  esac])
1976 AC_SUBST(host_shared)
1977
1978 # By default, C and C++ are the only stage 1 languages.
1979 stage1_languages=,c,
1980
1981 # Target libraries that we bootstrap.
1982 bootstrap_target_libs=,target-libgcc,
1983
1984 # Figure out what language subdirectories are present.
1985 # Look if the user specified --enable-languages="..."; if not, use
1986 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1987 # go away some day.
1988 # NB:  embedded tabs in this IF block -- do not untabify
1989 if test -d ${srcdir}/gcc; then
1990   if test x"${enable_languages+set}" != xset; then
1991     if test x"${LANGUAGES+set}" = xset; then
1992       enable_languages="${LANGUAGES}"
1993         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1994     else
1995       enable_languages=default
1996     fi
1997   else
1998     if test x"${enable_languages}" = x ||
1999        test x"${enable_languages}" = xyes;
2000        then
2001       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2002       exit 1
2003     fi
2004   fi
2005   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2006
2007   # 'f95' is the old name for the 'fortran' language. We issue a warning
2008   # and make the substitution.
2009   case ,${enable_languages}, in
2010     *,f95,*)
2011       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2012       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2013       ;;
2014   esac
2015
2016   # If bootstrapping, C++ must be enabled.
2017   case ",$enable_languages,:$enable_bootstrap" in
2018     *,c++,*:*) ;;
2019     *:yes)
2020       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2021         enable_languages="${enable_languages},c++"
2022       else
2023         AC_MSG_ERROR([bootstrapping requires c++ sources])
2024       fi
2025       ;;
2026   esac
2027
2028   # First scan to see if an enabled language requires some other language.
2029   # We assume that a given config-lang.in will list all the language
2030   # front ends it requires, even if some are required indirectly.
2031   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2032     case ${lang_frag} in
2033       ..) ;;
2034       # The odd quoting in the next line works around
2035       # an apparent bug in bash 1.12 on linux.
2036       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2037       *)
2038         # From the config-lang.in, get $language, $lang_requires, and
2039         # $lang_requires_boot_languages.
2040         language=
2041         lang_requires=
2042         lang_requires_boot_languages=
2043         # set srcdir during sourcing lang_frag to the gcc dir.
2044         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2045         # polutes this shell
2046         saved_srcdir=${srcdir}
2047         srcdir=${srcdir}/gcc . ${lang_frag}
2048         srcdir=${saved_srcdir}
2049         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2050           case ,${enable_languages}, in
2051             *,$other,*) ;;
2052             *,default,*) ;;
2053             *,all,*) ;;
2054             *,$language,*)
2055               echo " \`$other' language required by \`$language'; enabling" 1>&2
2056               enable_languages="${enable_languages},${other}"
2057               ;;
2058           esac
2059         done
2060         for other in ${lang_requires_boot_languages} ; do
2061           if test "$other" != "c"; then
2062             case ,${enable_stage1_languages}, in
2063               *,$other,*) ;;
2064               *,default,*) ;;
2065               *,all,*) ;;
2066               *)
2067                 case ,${enable_languages}, in
2068                   *,$language,*)
2069                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2070                     enable_stage1_languages="$enable_stage1_languages,${other}"
2071                     ;;
2072                 esac
2073                 ;;
2074             esac
2075           fi
2076         done
2077         ;;
2078     esac
2079   done
2080
2081   new_enable_languages=,c,
2082
2083   # If LTO is enabled, add the LTO front end.
2084   if test "$enable_lto" = "yes" ; then
2085     case ,${enable_languages}, in
2086       *,lto,*) ;;
2087       *) enable_languages="${enable_languages},lto" ;;
2088     esac
2089     if test "${build_lto_plugin}" = "yes" ; then
2090       configdirs="$configdirs lto-plugin"
2091     fi
2092   fi
2093
2094   # If we're building an offloading compiler, add the LTO front end.
2095   if test x"$enable_as_accelerator_for" != x ; then
2096     case ,${enable_languages}, in
2097       *,lto,*) ;;
2098       *) enable_languages="${enable_languages},lto" ;;
2099     esac
2100   fi
2101
2102   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2103   potential_languages=,c,
2104
2105   enabled_target_libs=
2106   disabled_target_libs=
2107
2108   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2109     case ${lang_frag} in
2110       ..) ;;
2111       # The odd quoting in the next line works around
2112       # an apparent bug in bash 1.12 on linux.
2113       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2114       *)
2115         # From the config-lang.in, get $language, $target_libs,
2116         # $lang_dirs, $boot_language, and $build_by_default
2117         language=
2118         target_libs=
2119         lang_dirs=
2120         subdir_requires=
2121         boot_language=no
2122         build_by_default=yes
2123         # set srcdir during sourcing.  See above about save & restore
2124         saved_srcdir=${srcdir}
2125         srcdir=${srcdir}/gcc . ${lang_frag}
2126         srcdir=${saved_srcdir}
2127         if test x${language} = x; then
2128           echo "${lang_frag} doesn't set \$language." 1>&2
2129           exit 1
2130         fi
2131
2132         if test "$language" = "c++"; then
2133           boot_language=yes
2134         fi
2135
2136         add_this_lang=no
2137         # C is always enabled, so no need to add it again
2138         if test "$language" != "c"; then
2139           case ,${enable_languages}, in
2140             *,${language},*)
2141               # Language was explicitly selected; include it
2142               add_this_lang=yes
2143               ;;
2144             *,all,*)
2145               # All languages are enabled
2146               add_this_lang=all
2147               ;;
2148             *,default,*)
2149               # 'default' was selected, select it if it is a default language
2150               add_this_lang=${build_by_default}
2151               ;;
2152           esac
2153         fi
2154
2155         # Disable languages that need other directories if these aren't available.
2156         for i in $subdir_requires; do
2157           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2158           case ${add_this_lang} in
2159             yes)
2160               # Specifically requested language; tell them.
2161               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2162               ;;
2163             all)
2164               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2165               add_this_lang=unsupported
2166               ;;
2167             *)
2168               # Silently disable.
2169               add_this_lang=unsupported
2170               ;;
2171           esac
2172         done
2173
2174         # Disable Ada if no preexisting GNAT is available.
2175         case ${add_this_lang}:${language}:${have_gnat} in
2176           yes:ada:no)
2177             # Specifically requested language; tell them.
2178             AC_MSG_ERROR([GNAT is required to build $language])
2179             ;;
2180           all:ada:no)
2181             AC_MSG_WARN([GNAT is required to build $language])
2182             add_this_lang=unsupported
2183             ;;
2184           *:ada:no)
2185             # Silently disable.
2186             add_this_lang=unsupported
2187             ;;
2188         esac
2189
2190         # Disable D if no preexisting GDC is available.
2191         case ${add_this_lang}:${language}:${have_gdc} in
2192           yes:d:no)
2193             # Specifically requested language; tell them.
2194             AC_MSG_ERROR([GDC is required to build $language])
2195            ;;
2196           all:d:no)
2197             AC_MSG_WARN([GDC is required to build $language])
2198             add_this_lang=unsupported
2199             ;;
2200           *:d:no)
2201             # Silently disable.
2202             add_this_lang=unsupported
2203             ;;
2204         esac
2205
2206         # Disable jit if -enable-host-shared not specified
2207         # but not if building for Mingw. All code in Windows
2208         # is position independent code (PIC).
2209         case $target in
2210           *mingw*) ;;
2211           *)
2212           case ${add_this_lang}:${language}:${host_shared} in
2213             yes:jit:no)
2214                    # PR jit/64780: explicitly specify --enable-host-shared
2215             AC_MSG_ERROR([
2216 Enabling language "jit" requires --enable-host-shared.
2217
2218 --enable-host-shared typically slows the rest of the compiler down by
2219 a few %, so you must explicitly enable it.
2220
2221 If you want to build both the jit and the regular compiler, it is often
2222 best to do this via two separate configure/builds, in separate
2223 directories, to avoid imposing the performance cost of
2224 --enable-host-shared on the regular compiler.])
2225                     ;;
2226             all:jit:no)
2227               AC_MSG_WARN([--enable-host-shared required to build $language])
2228               add_this_lang=unsupported
2229               ;;
2230             *:jit:no)
2231               # Silently disable.
2232               add_this_lang=unsupported
2233               ;;
2234                 esac
2235           ;;
2236         esac
2237
2238         # Disable a language that is unsupported by the target.
2239         case "${add_this_lang}: $unsupported_languages " in
2240           no:*) ;;
2241           unsupported:*) ;;
2242           *:*" $language "*)
2243             AC_MSG_WARN([${language} not supported for this target])
2244             add_this_lang=unsupported
2245             ;;
2246         esac
2247
2248         case $add_this_lang in
2249           unsupported)
2250             # Remove language-dependent dirs.
2251             disabled_target_libs="$disabled_target_libs $target_libs"
2252             noconfigdirs="$noconfigdirs $lang_dirs"
2253             ;;
2254           no)
2255             # Remove language-dependent dirs; still show language as supported.
2256             disabled_target_libs="$disabled_target_libs $target_libs"
2257             noconfigdirs="$noconfigdirs $lang_dirs"
2258             potential_languages="${potential_languages}${language},"
2259             ;;
2260           all|yes)
2261             new_enable_languages="${new_enable_languages}${language},"
2262             potential_languages="${potential_languages}${language},"
2263             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2264             enabled_target_libs="$enabled_target_libs $target_libs"
2265             case "${boot_language}:,$enable_stage1_languages," in
2266               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2267                 # Add to (comma-separated) list of stage 1 languages.
2268                 case ",$stage1_languages," in
2269                   *,$language,* | ,yes, | ,all,) ;;
2270                   *) stage1_languages="${stage1_languages}${language}," ;;
2271                 esac
2272                 # We need to bootstrap any supporting libraries.
2273                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2274                 ;;
2275             esac
2276             ;;
2277         esac
2278         ;;
2279     esac
2280   done
2281
2282   # Add target libraries which are only needed for disabled languages
2283   # to noconfigdirs.
2284   if test -n "$disabled_target_libs"; then
2285     for dir in $disabled_target_libs; do
2286       case " $enabled_target_libs " in
2287       *" ${dir} "*) ;;
2288       *) noconfigdirs="$noconfigdirs $dir" ;;
2289       esac
2290     done
2291   fi
2292
2293   AC_ARG_ENABLE(stage1-languages,
2294   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2295                   [choose additional languages to build during
2296                   stage1.  Mostly useful for compiler development])],
2297   [case ,${enable_stage1_languages}, in
2298     ,no,|,,)
2299       # Set it to something that will have no effect in the loop below
2300       enable_stage1_languages=c ;;
2301     ,yes,)
2302       enable_stage1_languages=`echo $new_enable_languages | \
2303         sed -e "s/^,//" -e "s/,$//" ` ;;
2304     *,all,*)
2305       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2306         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2307   esac
2308
2309   # Add "good" languages from enable_stage1_languages to stage1_languages,
2310   # while "bad" languages go in missing_languages.  Leave no duplicates.
2311   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2312     case $potential_languages in
2313       *,$i,*)
2314         case $stage1_languages in
2315           *,$i,*) ;;
2316           *) stage1_languages="$stage1_languages$i," ;;
2317         esac ;;
2318       *)
2319         case $missing_languages in
2320           *,$i,*) ;;
2321           *) missing_languages="$missing_languages$i," ;;
2322         esac ;;
2323      esac
2324   done])
2325
2326   # Remove leading/trailing commas that were added for simplicity
2327   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2328   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2329   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2330   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2331
2332   if test "x$missing_languages" != x; then
2333     AC_MSG_ERROR([
2334 The following requested languages could not be built: ${missing_languages}
2335 Supported languages are: ${potential_languages}])
2336   fi
2337   if test "x$new_enable_languages" != "x$enable_languages"; then
2338     echo The following languages will be built: ${new_enable_languages}
2339     enable_languages="$new_enable_languages"
2340   fi
2341
2342   AC_SUBST(stage1_languages)
2343   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2344 fi
2345
2346 # Handle --disable-<component> generically.
2347 for dir in $configdirs $build_configdirs $target_configdirs ; do
2348   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2349   varname=`echo $dirname | sed -e s/+/_/g`
2350   if eval test x\${enable_${varname}} "=" xno ; then
2351     noconfigdirs="$noconfigdirs $dir"
2352   fi
2353 done
2354
2355 # Check for Boehm's garbage collector
2356 AC_ARG_ENABLE(objc-gc,
2357 [AS_HELP_STRING([--enable-objc-gc],
2358                 [enable use of Boehm's garbage collector with the
2359                  GNU Objective-C runtime])])
2360 AC_ARG_WITH([target-bdw-gc],
2361 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2362                 [specify prefix directory for installed bdw-gc package.
2363                  Equivalent to --with-target-bdw-gc-include=PATH/include
2364                  plus --with-target-bdw-gc-lib=PATH/lib])])
2365 AC_ARG_WITH([target-bdw-gc-include],
2366 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2367                 [specify directories for installed bdw-gc include files])])
2368 AC_ARG_WITH([target-bdw-gc-lib],
2369 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2370                 [specify directories for installed bdw-gc library])])
2371
2372 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2373   AC_MSG_CHECKING([for bdw garbage collector])
2374   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2375     dnl no bdw-gw options, assume default locations
2376     AC_MSG_RESULT([using bdw-gc in default locations])
2377   else
2378     dnl bdw-gw options, first error checking, complete checking in libobjc
2379     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2380       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2381     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2382       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2383     else
2384       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2385     fi
2386   fi
2387 esac
2388
2389 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2390 case ,${enable_languages}, in
2391   *,c++,*)
2392     # Disable libitm, libsanitizer if we're not building libstdc++
2393     case "${noconfigdirs}" in
2394       *target-libstdc++-v3*)
2395         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2396         ;;
2397       *) ;;
2398     esac
2399     ;;
2400   *)
2401     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2402     ;;
2403 esac
2404
2405 # If gcc/ is not in the source tree then we'll not be building a
2406 # target compiler, assume in that case we don't want to build any
2407 # target libraries or tools.
2408 #
2409 # This was added primarily for the benefit for binutils-gdb who reuse
2410 # this configure script, but don't always have target tools available.
2411 if test ! -d ${srcdir}/gcc; then
2412    skipdirs="${skipdirs} ${target_configdirs}"
2413 fi
2414
2415 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2416 # $build_configdirs and $target_configdirs.
2417 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2418
2419 notsupp=""
2420 for dir in . $skipdirs $noconfigdirs ; do
2421   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2422   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2423     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2424     if test -r $srcdir/$dirname/configure ; then
2425       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2426         true
2427       else
2428         notsupp="$notsupp $dir"
2429       fi
2430     fi
2431   fi
2432   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2433     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2434     if test -r $srcdir/$dirname/configure ; then
2435       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2436         true
2437       else
2438         notsupp="$notsupp $dir"
2439       fi
2440     fi
2441   fi
2442   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2443     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2444     if test -r $srcdir/$dirname/configure ; then
2445       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2446         true
2447       else
2448         notsupp="$notsupp $dir"
2449       fi
2450     fi
2451   fi
2452 done
2453
2454 # Quietly strip out all directories which aren't configurable in this tree.
2455 # This relies on all configurable subdirectories being autoconfiscated, which
2456 # is now the case.
2457 build_configdirs_all="$build_configdirs"
2458 build_configdirs=
2459 for i in ${build_configdirs_all} ; do
2460   j=`echo $i | sed -e s/build-//g`
2461   if test -f ${srcdir}/$j/configure ; then
2462     build_configdirs="${build_configdirs} $i"
2463   fi
2464 done
2465
2466 configdirs_all="$configdirs"
2467 configdirs=
2468 for i in ${configdirs_all} ; do
2469   if test -f ${srcdir}/$i/configure ; then
2470     configdirs="${configdirs} $i"
2471   fi
2472 done
2473
2474 target_configdirs_all="$target_configdirs"
2475 target_configdirs=
2476 for i in ${target_configdirs_all} ; do
2477   j=`echo $i | sed -e s/target-//g`
2478   if test -f ${srcdir}/$j/configure ; then
2479     target_configdirs="${target_configdirs} $i"
2480   fi
2481 done
2482
2483 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2484 # so we have to add it after the preceding checks.
2485 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2486 then
2487   case " $configdirs " in
2488     *" libiberty "*)
2489       # If we can build libiberty, we can also build libiberty-linker-plugin.
2490       configdirs="$configdirs libiberty-linker-plugin"
2491       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2492         --with-libiberty=../libiberty-linker-plugin";;
2493     *)
2494       AC_MSG_ERROR([libiberty missing]);;
2495   esac
2496 fi
2497
2498 # Sometimes we have special requirements for the host libiberty.
2499 extra_host_libiberty_configure_flags=
2500 case " $configdirs " in
2501   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2502     # When these are to be built as shared libraries, the same applies to
2503     # libiberty.
2504     extra_host_libiberty_configure_flags=--enable-shared
2505     ;;
2506 esac
2507 AC_SUBST(extra_host_libiberty_configure_flags)
2508
2509 # Sometimes we have special requirements for the host zlib.
2510 extra_host_zlib_configure_flags=
2511 case " $configdirs " in
2512   *" bfd "*)
2513     # When bfd is to be built as a shared library, the same applies to
2514     # zlib.
2515     if test "$enable_shared" = "yes"; then
2516       extra_host_zlib_configure_flags=--enable-host-shared
2517     fi
2518     ;;
2519 esac
2520 AC_SUBST(extra_host_zlib_configure_flags)
2521
2522 # Produce a warning message for the subdirs we can't configure.
2523 # This isn't especially interesting in the Cygnus tree, but in the individual
2524 # FSF releases, it's important to let people know when their machine isn't
2525 # supported by the one or two programs in a package.
2526
2527 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2528   # If $appdirs is non-empty, at least one of those directories must still
2529   # be configured, or we error out.  (E.g., if the gas release supports a
2530   # specified target in some subdirs but not the gas subdir, we shouldn't
2531   # pretend that all is well.)
2532   if test -n "$appdirs" ; then
2533     for dir in $appdirs ; do
2534       if test -r $dir/Makefile.in ; then
2535         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2536           appdirs=""
2537           break
2538         fi
2539         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2540           appdirs=""
2541           break
2542         fi
2543       fi
2544     done
2545     if test -n "$appdirs" ; then
2546       echo "*** This configuration is not supported by this package." 1>&2
2547       exit 1
2548     fi
2549   fi
2550   # Okay, some application will build, or we don't care to check.  Still
2551   # notify of subdirs not getting built.
2552   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2553   echo "    ${notsupp}" 1>&2
2554   echo "    (Any other directories should still work fine.)" 1>&2
2555 fi
2556
2557 case "$host" in
2558   *msdosdjgpp*)
2559     enable_gdbtk=no ;;
2560 esac
2561
2562 # To find our prefix, in gcc_cv_tool_prefix.
2563 ACX_TOOL_DIRS
2564
2565 copy_dirs=
2566
2567 AC_ARG_WITH([build-sysroot],
2568   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2569                   [use sysroot as the system root during the build])],
2570   [if test x"$withval" != x ; then
2571      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2572    fi],
2573   [SYSROOT_CFLAGS_FOR_TARGET=])
2574 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2575
2576 AC_ARG_WITH([debug-prefix-map],
2577   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2578                   [map A to B, C to D ... in debug information])],
2579   [if test x"$withval" != x; then
2580      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2581      for debug_map in $withval; do
2582        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2583      done
2584    fi],
2585   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2586 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2587
2588 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2589 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2590 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2591 # We want to ensure that TARGET libraries (which we know are built with
2592 # gcc) are built with "-O2 -g", so include those options when setting
2593 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2594 if test "x$CFLAGS_FOR_TARGET" = x; then
2595   if test "x${is_cross_compiler}" = xyes; then
2596     CFLAGS_FOR_TARGET="-g -O2"
2597   else
2598     CFLAGS_FOR_TARGET=$CFLAGS
2599     case " $CFLAGS " in
2600       *" -O2 "*) ;;
2601       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2602     esac
2603     case " $CFLAGS " in
2604       *" -g "* | *" -g3 "*) ;;
2605       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2606     esac
2607   fi
2608 fi
2609 AC_SUBST(CFLAGS_FOR_TARGET)
2610
2611 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2612   if test "x${is_cross_compiler}" = xyes; then
2613     CXXFLAGS_FOR_TARGET="-g -O2"
2614   else
2615     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2616     case " $CXXFLAGS " in
2617       *" -O2 "*) ;;
2618       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2619     esac
2620     case " $CXXFLAGS " in
2621       *" -g "* | *" -g3 "*) ;;
2622       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2623     esac
2624   fi
2625 fi
2626 AC_SUBST(CXXFLAGS_FOR_TARGET)
2627
2628 AC_SUBST(LDFLAGS_FOR_TARGET)
2629
2630 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2631 # the named directory are copied to $(tooldir)/sys-include.
2632 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2633   if test x${is_cross_compiler} = xno ; then
2634     echo 1>&2 '***' --with-headers is only supported when cross compiling
2635     exit 1
2636   fi
2637   if test x"${with_headers}" != xyes ; then
2638     x=${gcc_cv_tool_prefix}
2639     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2640   fi
2641 fi
2642
2643 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2644 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2645 # are permitted.
2646 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2647   if test x${is_cross_compiler} = xno ; then
2648     echo 1>&2 '***' --with-libs is only supported when cross compiling
2649     exit 1
2650   fi
2651   if test x"${with_libs}" != xyes ; then
2652     # Copy the libraries in reverse order, so that files in the first named
2653     # library override files in subsequent libraries.
2654     x=${gcc_cv_tool_prefix}
2655     for l in ${with_libs}; do
2656       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2657     done
2658   fi
2659 fi
2660
2661 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2662 #
2663 # This is done by determining whether or not the appropriate directory
2664 # is available, and by checking whether or not specific configurations
2665 # have requested that this magic not happen.
2666 #
2667 # The command line options always override the explicit settings in
2668 # configure.ac, and the settings in configure.ac override this magic.
2669 #
2670 # If the default for a toolchain is to use GNU as and ld, and you don't
2671 # want to do that, then you should use the --without-gnu-as and
2672 # --without-gnu-ld options for the configure script.  Similarly, if
2673 # the default is to use the included zlib and you don't want to do that,
2674 # you should use the --with-system-zlib option for the configure script.
2675
2676 if test x${use_gnu_as} = x &&
2677    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2678   with_gnu_as=yes
2679   extra_host_args="$extra_host_args --with-gnu-as"
2680 fi
2681
2682 if test x${use_gnu_ld} = x &&
2683    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2684   with_gnu_ld=yes
2685   extra_host_args="$extra_host_args --with-gnu-ld"
2686 fi
2687
2688 if test x${use_included_zlib} = x &&
2689    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2690   :
2691 else
2692   with_system_zlib=yes
2693   extra_host_args="$extra_host_args --with-system-zlib"
2694 fi
2695
2696 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2697 # can detect this case.
2698
2699 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2700   with_newlib=yes
2701   extra_host_args="$extra_host_args --with-newlib"
2702 fi
2703
2704 # Handle ${copy_dirs}
2705 set fnord ${copy_dirs}
2706 shift
2707 while test $# != 0 ; do
2708   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2709     :
2710   else
2711     echo Copying $1 to $2
2712
2713     # Use the install script to create the directory and all required
2714     # parent directories.
2715     if test -d $2 ; then
2716       :
2717     else
2718       echo >config.temp
2719       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2720     fi
2721
2722     # Copy the directory, assuming we have tar.
2723     # FIXME: Should we use B in the second tar?  Not all systems support it.
2724     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2725
2726     # It is the responsibility of the user to correctly adjust all
2727     # symlinks.  If somebody can figure out how to handle them correctly
2728     # here, feel free to add the code.
2729
2730     echo $1 > $2/COPIED
2731   fi
2732   shift; shift
2733 done
2734
2735 # Determine a target-dependent exec_prefix that the installed
2736 # gcc will search in.  Keep this list sorted by triplet, with
2737 # the *-*-osname triplets last.
2738 md_exec_prefix=
2739 case "${target}" in
2740   i[[34567]]86-pc-msdosdjgpp*)
2741     md_exec_prefix=/dev/env/DJDIR/bin
2742     ;;
2743   *-*-hpux* | \
2744   *-*-nto-qnx* | \
2745   *-*-solaris2*)
2746     md_exec_prefix=/usr/ccs/bin
2747     ;;
2748 esac
2749
2750 extra_arflags_for_target=
2751 extra_nmflags_for_target=
2752 extra_ranlibflags_for_target=
2753 target_makefile_frag=/dev/null
2754 case "${target}" in
2755   spu-*-*)
2756     target_makefile_frag="config/mt-spu"
2757     ;;
2758   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2759     target_makefile_frag="config/mt-sde"
2760     ;;
2761   mipsisa*-*-elfoabi*)
2762     target_makefile_frag="config/mt-mips-elfoabi"
2763     ;;
2764   mips*-*-*linux* | mips*-*-gnu*)
2765     target_makefile_frag="config/mt-mips-gnu"
2766     ;;
2767   nios2-*-elf*)
2768     target_makefile_frag="config/mt-nios2-elf"
2769     ;;
2770   *-*-linux-android*)
2771     target_makefile_frag="config/mt-android"
2772     ;;
2773   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2774     target_makefile_frag="config/mt-gnu"
2775     ;;
2776   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2777     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2778     # commands to handle both 32-bit and 64-bit objects.  These flags are
2779     # harmless if we're using GNU nm or ar.
2780     extra_arflags_for_target=" -X32_64"
2781     extra_nmflags_for_target=" -B -X32_64"
2782     ;;
2783 esac
2784
2785 alphaieee_frag=/dev/null
2786 case $target in
2787   alpha*-*-*)
2788     # This just makes sure to use the -mieee option to build target libs.
2789     # This should probably be set individually by each library.
2790     alphaieee_frag="config/mt-alphaieee"
2791     ;;
2792 esac
2793
2794 # If --enable-target-optspace always use -Os instead of -O2 to build
2795 # the target libraries, similarly if it is not specified, use -Os
2796 # on selected platforms.
2797 ospace_frag=/dev/null
2798 case "${enable_target_optspace}:${target}" in
2799   yes:*)
2800     ospace_frag="config/mt-ospace"
2801     ;;
2802   :d30v-*)
2803     ospace_frag="config/mt-d30v"
2804     ;;
2805   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2806     ospace_frag="config/mt-ospace"
2807     ;;
2808   no:* | :*)
2809     ;;
2810   *)
2811     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2812     ;;
2813 esac
2814
2815 # Some systems (e.g., one of the i386-aix systems the gas testers are
2816 # using) don't handle "\$" correctly, so don't use it here.
2817 tooldir='${exec_prefix}'/${target_noncanonical}
2818 build_tooldir=${tooldir}
2819
2820 # Create a .gdbinit file which runs the one in srcdir
2821 # and tells GDB to look there for source files.
2822
2823 if test -r ${srcdir}/.gdbinit ; then
2824   case ${srcdir} in
2825     .) ;;
2826     *) cat > ./.gdbinit <<EOF
2827 # ${NO_EDIT}
2828 dir ${srcdir}
2829 dir .
2830 source ${srcdir}/.gdbinit
2831 EOF
2832     ;;
2833   esac
2834 fi
2835
2836 # Make sure that the compiler is able to generate an executable.  If it
2837 # can't, we are probably in trouble.  We don't care whether we can run the
2838 # executable--we might be using a cross compiler--we only care whether it
2839 # can be created.  At this point the main configure script has set CC.
2840 we_are_ok=no
2841 echo "int main () { return 0; }" > conftest.c
2842 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2843 if test $? = 0 ; then
2844   if test -s conftest || test -s conftest.exe ; then
2845     we_are_ok=yes
2846   fi
2847 fi
2848 case $we_are_ok in
2849   no)
2850     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2851     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2852     rm -f conftest*
2853     exit 1
2854     ;;
2855 esac
2856 rm -f conftest*
2857
2858 # Decide which environment variable is used to find dynamic libraries.
2859 case "${host}" in
2860   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2861   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2862   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2863   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2864 esac
2865
2866 # On systems where the dynamic library environment variable is PATH,
2867 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2868 # built executables to PATH.
2869 if test "$RPATH_ENVVAR" = PATH; then
2870   GCC_SHLIB_SUBDIR=/shlib
2871 else
2872   GCC_SHLIB_SUBDIR=
2873 fi
2874
2875 # Adjust the toplevel makefile according to whether bootstrap was selected.
2876 case $enable_bootstrap in
2877   yes)
2878     bootstrap_suffix=bootstrap
2879     BUILD_CONFIG=bootstrap-debug
2880     ;;
2881   no)
2882     bootstrap_suffix=no-bootstrap
2883     BUILD_CONFIG=
2884     ;;
2885 esac
2886
2887 AC_MSG_CHECKING(for default BUILD_CONFIG)
2888
2889 AC_ARG_WITH([build-config],
2890   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2891                   [use config/NAME.mk build configuration])],
2892   [case $with_build_config in
2893    yes) with_build_config= ;;
2894    no) with_build_config= BUILD_CONFIG= ;;
2895    esac])
2896
2897 if test "x${with_build_config}" != x; then
2898   BUILD_CONFIG=$with_build_config
2899 else
2900   case $BUILD_CONFIG in
2901   bootstrap-debug)
2902     if echo "int f (void) { return 0; }" > conftest.c &&
2903        ${CC} -c conftest.c &&
2904        mv conftest.o conftest.o.g0 &&
2905        ${CC} -c -g conftest.c &&
2906        mv conftest.o conftest.o.g &&
2907        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2908       :
2909     else
2910       BUILD_CONFIG=
2911     fi
2912     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2913     ;;
2914   esac
2915 fi
2916 AC_MSG_RESULT($BUILD_CONFIG)
2917 AC_SUBST(BUILD_CONFIG)
2918
2919 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2920 AC_MSG_CHECKING([for --enable-vtable-verify])
2921 AC_ARG_ENABLE(vtable-verify,
2922 [AS_HELP_STRING([--enable-vtable-verify],
2923                 [Enable vtable verification feature])],
2924 [case "$enableval" in
2925  yes) enable_vtable_verify=yes ;;
2926  no)  enable_vtable_verify=no ;;
2927  *)   enable_vtable_verify=no;;
2928  esac],
2929 [enable_vtable_verify=no])
2930 AC_MSG_RESULT($enable_vtable_verify)
2931
2932 # Record target_configdirs and the configure arguments for target and
2933 # build configuration in Makefile.
2934 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2935 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2936 bootstrap_fixincludes=no
2937
2938 # If we are building libgomp, bootstrap it.
2939 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2940   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2941 fi
2942
2943 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2944 # or bootstrap-ubsan, bootstrap it.
2945 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2946   case "$BUILD_CONFIG" in
2947     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2948       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2949       bootstrap_fixincludes=yes
2950       ;;
2951   esac
2952 fi
2953
2954 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2955 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2956    test "$enable_vtable_verify" != no; then
2957   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2958 fi
2959
2960 # If we are building libatomic and the list of enabled languages includes the
2961 # D frontend, bootstrap it.
2962 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2963   case ,${enable_languages}, in
2964     *,d,*)
2965       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2966       ;;
2967   esac
2968 fi
2969
2970 # Determine whether gdb needs tk/tcl or not.
2971 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2972 # and in that case we want gdb to be built without tk.  Ugh!
2973 # In fact I believe gdb is the *only* package directly dependent on tk,
2974 # so we should be able to put the 'maybe's in unconditionally and
2975 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2976 # 100% sure that that's safe though.
2977
2978 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2979 case "$enable_gdbtk" in
2980   no)
2981     GDB_TK="" ;;
2982   yes)
2983     GDB_TK="${gdb_tk}" ;;
2984   *)
2985     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2986     # distro.  Eventually someone will fix this and move Insight, nee
2987     # gdbtk to a separate directory.
2988     if test -d ${srcdir}/gdb/gdbtk ; then
2989       GDB_TK="${gdb_tk}"
2990     else
2991       GDB_TK=""
2992     fi
2993     ;;
2994 esac
2995 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2996 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2997
2998 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2999 # else does, only include them if one of these is built.  The Makefile
3000 # provides the ordering, so it's enough here to add to the list.
3001 case " ${configdirs} " in
3002   *\ gdb\ *)
3003     configdirs="${configdirs} gnulib gdbsupport"
3004     ;;
3005   *\ gdbserver\ *)
3006     configdirs="${configdirs} gnulib gdbsupport"
3007     ;;
3008   *\ sim\ *)
3009     configdirs="${configdirs} gnulib"
3010     ;;
3011 esac
3012
3013 # Strip out unwanted targets.
3014
3015 # While at that, we remove Makefiles if we were started for recursive
3016 # configuration, so that the top-level Makefile reconfigures them,
3017 # like we used to do when configure itself was recursive.
3018
3019 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3020 # but now we're fixing up the Makefile ourselves with the additional
3021 # commands passed to AC_CONFIG_FILES.  Use separate variables
3022 # extrasub-{build,host,target} not because there is any reason to split
3023 # the substitutions up that way, but only to remain below the limit of
3024 # 99 commands in a script, for HP-UX sed.
3025
3026 # Do not nest @if/@endif or @unless/@endunless pairs, because
3027 # configure will not warn you at all.
3028
3029 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3030   yes:yes:*\ gold\ *:*,c++,*) ;;
3031   yes:yes:*\ gold\ *:*)
3032     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3033     ;;
3034 esac
3035
3036 extrasub_build=
3037 for module in ${build_configdirs} ; do
3038   if test -z "${no_recursion}" \
3039      && test -f ${build_subdir}/${module}/Makefile; then
3040     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3041     rm -f ${build_subdir}/${module}/Makefile
3042   fi
3043   extrasub_build="$extrasub_build
3044 /^@if build-$module\$/d
3045 /^@endif build-$module\$/d
3046 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3047 /^@if build-$module-$bootstrap_suffix\$/d
3048 /^@endif build-$module-$bootstrap_suffix\$/d
3049 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3050 done
3051 extrasub_host=
3052 for module in ${configdirs} ; do
3053   if test -z "${no_recursion}"; then
3054     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3055       if test -f ${file}; then
3056         echo 1>&2 "*** removing ${file} to force reconfigure"
3057         rm -f ${file}
3058       fi
3059     done
3060   fi
3061   case ${module},${bootstrap_fixincludes} in
3062     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3063     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3064   esac
3065   extrasub_host="$extrasub_host
3066 /^@if $module\$/d
3067 /^@endif $module\$/d
3068 /^@unless $module\$/,/^@endunless $module\$/d
3069 /^@if $module-$host_bootstrap_suffix\$/d
3070 /^@endif $module-$host_bootstrap_suffix\$/d
3071 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3072 done
3073 extrasub_target=
3074 for module in ${target_configdirs} ; do
3075   if test -z "${no_recursion}" \
3076      && test -f ${target_subdir}/${module}/Makefile; then
3077     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3078     rm -f ${target_subdir}/${module}/Makefile
3079   fi
3080
3081   # We only bootstrap target libraries listed in bootstrap_target_libs.
3082   case $bootstrap_target_libs in
3083     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3084     *) target_bootstrap_suffix=no-bootstrap ;;
3085   esac
3086
3087   extrasub_target="$extrasub_target
3088 /^@if target-$module\$/d
3089 /^@endif target-$module\$/d
3090 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3091 /^@if target-$module-$target_bootstrap_suffix\$/d
3092 /^@endif target-$module-$target_bootstrap_suffix\$/d
3093 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3094 done
3095
3096 # Do the final fixup along with target modules.
3097 extrasub_target="$extrasub_target
3098 /^@if /,/^@endif /d
3099 /^@unless /d
3100 /^@endunless /d"
3101
3102 if test "$enable_pgo_build" != "no"; then
3103   extrasub_build="$extrasub_build
3104 /^@if pgo-build\$/d
3105 /^@endif pgo-build\$/d"
3106 fi
3107
3108 # Create the serialization dependencies.  This uses a temporary file.
3109
3110 AC_ARG_ENABLE([serial-configure],
3111 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3112                 [force sequential configuration of
3113                  sub-packages for the host, target or build
3114                  machine, or all sub-packages])])
3115
3116 case ${enable_serial_configure} in
3117   yes)
3118     enable_serial_build_configure=yes
3119     enable_serial_host_configure=yes
3120     enable_serial_target_configure=yes
3121     ;;
3122 esac
3123
3124 # These force 'configure's to be done one at a time, to avoid problems
3125 # with contention over a shared config.cache.
3126 rm -f serdep.tmp
3127 echo '# serdep.tmp' > serdep.tmp
3128 olditem=
3129 test "x${enable_serial_build_configure}" = xyes &&
3130 for item in ${build_configdirs} ; do
3131   case ${olditem} in
3132     "") ;;
3133     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3134   esac
3135   olditem=${item}
3136 done
3137 olditem=
3138 test "x${enable_serial_host_configure}" = xyes &&
3139 for item in ${configdirs} ; do
3140   case ${olditem} in
3141     "") ;;
3142     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3143   esac
3144   olditem=${item}
3145 done
3146 olditem=
3147 test "x${enable_serial_target_configure}" = xyes &&
3148 for item in ${target_configdirs} ; do
3149   case ${olditem} in
3150     "") ;;
3151     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3152   esac
3153   olditem=${item}
3154 done
3155 serialization_dependencies=serdep.tmp
3156 AC_SUBST_FILE(serialization_dependencies)
3157
3158 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3159 # target, nonopt, and variable assignments.  These are the ones we
3160 # might not want to pass down to subconfigures.  The exception being
3161 # --cache-file=/dev/null, which is used to turn off the use of cache
3162 # files altogether, and which should be passed on to subconfigures.
3163 # Also strip program-prefix, program-suffix, and program-transform-name,
3164 # so that we can pass down a consistent program-transform-name.
3165 baseargs=
3166 tbaseargs=
3167 keep_next=no
3168 skip_next=no
3169 eval "set -- $ac_configure_args"
3170 for ac_arg
3171 do
3172   if test X"$skip_next" = X"yes"; then
3173     skip_next=no
3174     continue
3175   fi
3176   if test X"$keep_next" = X"yes"; then
3177     case $ac_arg in
3178       *\'*)
3179         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3180     esac
3181     baseargs="$baseargs '$ac_arg'"
3182     tbaseargs="$tbaseargs '$ac_arg'"
3183     keep_next=no
3184     continue
3185   fi
3186
3187   # Handle separated arguments.  Based on the logic generated by
3188   # autoconf 2.59.
3189   case $ac_arg in
3190     *=* | --config-cache | -C | -disable-* | --disable-* \
3191       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3192       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3193       | -with-* | --with-* | -without-* | --without-* | --x)
3194       separate_arg=no
3195       ;;
3196     -*)
3197       separate_arg=yes
3198       ;;
3199     *)
3200       separate_arg=no
3201       ;;
3202   esac
3203
3204   skip_targ=no
3205   case $ac_arg in
3206 changequote(,)
3207   --with-* | --without-*)
3208     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3209
3210     case $libopt in
3211     *[-_]include)
3212       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3213       ;;
3214     *[-_]lib)
3215       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3216       ;;
3217     *)
3218       lib=$libopt
3219       ;;
3220     esac
3221 changequote([,])
3222
3223     case $lib in
3224     mpc | mpfr | gmp | isl)
3225       # If we're processing --with-$lib, --with-$lib-include or
3226       # --with-$lib-lib, for one of the libs above, and target is
3227       # different from host, don't pass the current argument to any
3228       # target library's configure.
3229       if test x$is_cross_compiler = xyes; then
3230         skip_targ=yes
3231       fi
3232       ;;
3233     esac
3234     ;;
3235   esac
3236
3237   case "$ac_arg" in
3238     --cache-file=/dev/null | \
3239     -cache-file=/dev/null )
3240       # Handled here to avoid the test to skip args below.
3241       baseargs="$baseargs '$ac_arg'"
3242       tbaseargs="$tbaseargs '$ac_arg'"
3243       # Assert: $separate_arg should always be no.
3244       keep_next=$separate_arg
3245       ;;
3246     --no*)
3247       continue
3248       ;;
3249     --c* | \
3250     --sr* | \
3251     --ho* | \
3252     --bu* | \
3253     --t* | \
3254     --program-* | \
3255     -cache_file* | \
3256     -srcdir* | \
3257     -host* | \
3258     -build* | \
3259     -target* | \
3260     -program-prefix* | \
3261     -program-suffix* | \
3262     -program-transform-name* )
3263       skip_next=$separate_arg
3264       continue
3265       ;;
3266     -*)
3267       # An option.  Add it.
3268       case $ac_arg in
3269         *\'*)
3270           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3271       esac
3272       baseargs="$baseargs '$ac_arg'"
3273       if test X"$skip_targ" = Xno; then
3274         tbaseargs="$tbaseargs '$ac_arg'"
3275       fi
3276       keep_next=$separate_arg
3277       ;;
3278     *)
3279       # Either a variable assignment, or a nonopt (triplet).  Don't
3280       # pass it down; let the Makefile handle this.
3281       continue
3282       ;;
3283   esac
3284 done
3285 # Remove the initial space we just introduced and, as these will be
3286 # expanded by make, quote '$'.
3287 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3288
3289 # Add in --program-transform-name, after --program-prefix and
3290 # --program-suffix have been applied to it.  Autoconf has already
3291 # doubled dollar signs and backslashes in program_transform_name; we want
3292 # the backslashes un-doubled, and then the entire thing wrapped in single
3293 # quotes, because this will be expanded first by make and then by the shell.
3294 # Also, because we want to override the logic in subdir configure scripts to
3295 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3296 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3297 ${program_transform_name}
3298 EOF_SED
3299 gcc_transform_name=`cat conftestsed.out`
3300 rm -f conftestsed.out
3301 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3302 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3303 if test "$silent" = yes; then
3304   baseargs="$baseargs --silent"
3305   tbaseargs="$tbaseargs --silent"
3306 fi
3307
3308 baseargs="$baseargs --disable-option-checking"
3309 tbaseargs="$tbaseargs --disable-option-checking"
3310
3311 if test "$enable_year2038" = no; then
3312   baseargs="$baseargs --disable-year2038"
3313   tbaseargs="$tbaseargs --disable-year2038"
3314 fi
3315
3316 # Record and document user additions to sub configure arguments.
3317 AC_ARG_VAR([build_configargs],
3318            [additional configure arguments for build directories])
3319 AC_ARG_VAR([host_configargs],
3320            [additional configure arguments for host directories])
3321 AC_ARG_VAR([target_configargs],
3322            [additional configure arguments for target directories])
3323
3324 # For the build-side libraries, we just need to pretend we're native,
3325 # and not use the same cache file.  Multilibs are neither needed nor
3326 # desired.  We can't even use the same cache file for all build-side
3327 # libraries, as they're compiled differently; some with C, some with
3328 # C++ or with different feature-enabling options.
3329 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3330
3331 # For host modules, accept cache file option, or specification as blank.
3332 case "${cache_file}" in
3333 "") # empty
3334   cache_file_option="" ;;
3335 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3336   cache_file_option="--cache-file=${cache_file}" ;;
3337 *) # relative path
3338   cache_file_option="--cache-file=../${cache_file}" ;;
3339 esac
3340
3341 # Host dirs don't like to share a cache file either, horribly enough.
3342 # This seems to be due to autoconf 2.5x stupidity.
3343 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3344
3345 target_configargs="$target_configargs ${tbaseargs}"
3346
3347 # Passing a --with-cross-host argument lets the target libraries know
3348 # whether they are being built with a cross-compiler or being built
3349 # native.  However, it would be better to use other mechanisms to make the
3350 # sorts of decisions they want to make on this basis.  Please consider
3351 # this option to be deprecated.  FIXME.
3352 if test x${is_cross_compiler} = xyes ; then
3353   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3354 fi
3355
3356 # Special user-friendly check for native x86_64-linux build, if
3357 # multilib is not explicitly enabled.
3358 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3359   x86_64-*linux*:yes:$build:$build:)
3360     # Make sure we have a development environment that handles 32-bit
3361     dev64=no
3362     echo "int main () { return 0; }" > conftest.c
3363     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3364     if test $? = 0 ; then
3365       if test -s conftest || test -s conftest.exe ; then
3366         dev64=yes
3367       fi
3368     fi
3369     rm -f conftest*
3370     if test x${dev64} != xyes ; then
3371       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3372     fi
3373     ;;
3374 esac
3375
3376 # Default to --enable-multilib.
3377 if test x${enable_multilib} = x ; then
3378   target_configargs="--enable-multilib ${target_configargs}"
3379 fi
3380
3381 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3382 # changed from the earlier setting of with_newlib.
3383 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3384   target_configargs="--with-newlib ${target_configargs}"
3385 fi
3386
3387 # Different target subdirs use different values of certain variables
3388 # (notably CXX).  Worse, multilibs use *lots* of different values.
3389 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3390 # it doesn't automatically accept command-line overrides of them.
3391 # This means it's not safe for target subdirs to share a cache file,
3392 # which is disgusting, but there you have it.  Hopefully this can be
3393 # fixed in future.  It's still worthwhile to use a cache file for each
3394 # directory.  I think.
3395
3396 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3397 # We need to pass --target, as newer autoconf's requires consistency
3398 # for target_alias and gcc doesn't manage it consistently.
3399 target_configargs="--cache-file=./config.cache ${target_configargs}"
3400
3401 FLAGS_FOR_TARGET=
3402 case " $target_configdirs " in
3403  *" newlib "*)
3404   case " $target_configargs " in
3405   *" --with-newlib "*)
3406    case "$target" in
3407     *-cygwin*)
3408       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3409       ;;
3410    esac
3411
3412    # If we're not building GCC, don't discard standard headers.
3413    if test -d ${srcdir}/gcc; then
3414      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3415
3416      if test "${build}" != "${host}"; then
3417        # On Canadian crosses, CC_FOR_TARGET will have already been set
3418        # by `configure', so we won't have an opportunity to add -Bgcc/
3419        # to it.  This is right: we don't want to search that directory
3420        # for binaries, but we want the header files in there, so add
3421        # them explicitly.
3422        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3423
3424        # Someone might think of using the pre-installed headers on
3425        # Canadian crosses, in case the installed compiler is not fully
3426        # compatible with the compiler being built.  In this case, it
3427        # would be better to flag an error than risking having
3428        # incompatible object files being constructed.  We can't
3429        # guarantee that an error will be flagged, but let's hope the
3430        # compiler will do it, when presented with incompatible header
3431        # files.
3432      fi
3433    fi
3434
3435    case "${target}-${is_cross_compiler}" in
3436    i[[3456789]]86-*-linux*-no)
3437       # Here host == target, so we don't need to build gcc,
3438       # so we don't want to discard standard headers.
3439       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3440       ;;
3441    *)
3442       # If we're building newlib, use its generic headers last, but search
3443       # for any libc-related directories first (so make it the last -B
3444       # switch).
3445       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3446
3447       # If we're building libgloss, find the startup file, simulator library
3448       # and linker script.
3449       case " $target_configdirs " in
3450         *" libgloss "*)
3451         # Look for startup file, simulator library and maybe linker script.
3452         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3453         # Look for libnosys.a in case the target needs it.
3454         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3455         # Most targets have the linker script in the source directory.
3456         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3457         ;;
3458       esac
3459       ;;
3460    esac
3461    ;;
3462   esac
3463   ;;
3464 esac
3465
3466 case "$target" in
3467   x86_64-*mingw* | *-w64-mingw*)
3468   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3469   # however, use a symlink named 'mingw' in ${prefix} .
3470     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3471     ;;
3472   *-mingw*)
3473   # MinGW can't be handled as Cygwin above since it does not use newlib.
3474     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3475     ;;
3476 esac
3477
3478 # Allow the user to override the flags for
3479 # our build compiler if desired.
3480 if test x"${build}" = x"${host}" ; then
3481   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3482   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3483   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3484   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3485 fi
3486
3487 # On Canadian crosses, we'll be searching the right directories for
3488 # the previously-installed cross compiler, so don't bother to add
3489 # flags for directories within the install tree of the compiler
3490 # being built; programs in there won't even run.
3491 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3492   # Search for pre-installed headers if nothing else fits.
3493   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3494 fi
3495
3496 if test "x${use_gnu_ld}" = x &&
3497    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3498   # Arrange for us to find uninstalled linker scripts.
3499   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3500 fi
3501
3502 # Search for other target-specific linker scripts and such.
3503 case "${target}" in
3504   mep*)
3505     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3506     ;;
3507   # The VxWorks support for shared libraries is getting in
3508   # incrementally.  Make sure it doesn't get activated implicitly:
3509   *vxworks*)
3510     if test "${enable_shared-unset}" = unset ; then
3511       enable_shared=no
3512       # So the build of libraries knows ...
3513       target_configargs="${target_configargs} --disable-shared"
3514       # So gcc knows ...
3515       host_configargs="${host_configargs} --disable-shared"
3516     fi
3517     ;;
3518 esac
3519
3520 # Makefile fragments.
3521 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3522 do
3523   eval fragval=\$$frag
3524   if test $fragval != /dev/null; then
3525     eval $frag=${srcdir}/$fragval
3526   fi
3527 done
3528 AC_SUBST_FILE(host_makefile_frag)
3529 AC_SUBST_FILE(target_makefile_frag)
3530 AC_SUBST_FILE(alphaieee_frag)
3531 AC_SUBST_FILE(ospace_frag)
3532
3533 # Miscellanea: directories, flags, etc.
3534 AC_SUBST(RPATH_ENVVAR)
3535 AC_SUBST(GCC_SHLIB_SUBDIR)
3536 AC_SUBST(tooldir)
3537 AC_SUBST(build_tooldir)
3538 AC_SUBST(CONFIGURE_GDB_TK)
3539 AC_SUBST(GDB_TK)
3540 AC_SUBST(INSTALL_GDB_TK)
3541
3542 # Build module lists & subconfigure args.
3543 AC_SUBST(build_configargs)
3544 AC_SUBST(build_configdirs)
3545
3546 # Host module lists & subconfigure args.
3547 AC_SUBST(host_configargs)
3548 AC_SUBST(configdirs)
3549 AC_SUBST(target_configdirs)
3550
3551 # Target module lists & subconfigure args.
3552 AC_SUBST(target_configargs)
3553
3554
3555 # Build tools.
3556 AC_SUBST(AR_FOR_BUILD)
3557 AC_SUBST(AS_FOR_BUILD)
3558 AC_SUBST(CC_FOR_BUILD)
3559 AC_SUBST(CFLAGS_FOR_BUILD)
3560 AC_SUBST(CPP_FOR_BUILD)
3561 AC_SUBST(CPPFLAGS_FOR_BUILD)
3562 AC_SUBST(CXXFLAGS_FOR_BUILD)
3563 AC_SUBST(CXX_FOR_BUILD)
3564 AC_SUBST(DLLTOOL_FOR_BUILD)
3565 AC_SUBST(DSYMUTIL_FOR_BUILD)
3566 AC_SUBST(GFORTRAN_FOR_BUILD)
3567 AC_SUBST(GOC_FOR_BUILD)
3568 AC_SUBST(GDC_FOR_BUILD)
3569 AC_SUBST(LDFLAGS_FOR_BUILD)
3570 AC_SUBST(LD_FOR_BUILD)
3571 AC_SUBST(NM_FOR_BUILD)
3572 AC_SUBST(RANLIB_FOR_BUILD)
3573 AC_SUBST(WINDMC_FOR_BUILD)
3574 AC_SUBST(WINDRES_FOR_BUILD)
3575
3576 # Generate default definitions for YACC, M4, LEX and other programs that run
3577 # on the build machine.  These are used if the Makefile can't locate these
3578 # programs in objdir.
3579 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3580
3581 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3582 case " $build_configdirs " in
3583   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3584 esac
3585
3586 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3587 case " $build_configdirs " in
3588   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3589 esac
3590
3591 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3592 case " $build_configdirs " in
3593   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3594 esac
3595
3596 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3597 case " $build_configdirs " in
3598   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3599   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3600 esac
3601
3602 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3603 case " $build_configdirs " in
3604   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3605 esac
3606
3607 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3608 case " $build_configdirs " in
3609   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3610   *)
3611 changequote(,)
3612     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3613     # higher, else we use the "missing" dummy.
3614     if ${MAKEINFO} --version \
3615        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3616       :
3617     else
3618       MAKEINFO="$MISSING makeinfo"
3619     fi
3620     ;;
3621 changequote([,])
3622 esac
3623
3624 # FIXME: expect and dejagnu may become build tools?
3625
3626 AC_CHECK_PROGS(EXPECT, expect, expect)
3627 case " $configdirs " in
3628   *" expect "*)
3629     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3630     ;;
3631 esac
3632
3633 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3634 case " $configdirs " in
3635   *" dejagnu "*)
3636     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3637     ;;
3638 esac
3639
3640
3641 # Host tools.
3642 NCN_STRICT_CHECK_TOOLS(AR, ar)
3643 NCN_STRICT_CHECK_TOOLS(AS, as)
3644 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3645 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3646 NCN_STRICT_CHECK_TOOLS(LD, ld)
3647 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3648 NCN_STRICT_CHECK_TOOLS(NM, nm)
3649 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3650 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3651 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3652 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3653 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3654 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3655 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3656 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3657 AC_SUBST(CC)
3658 AC_SUBST(CXX)
3659 AC_SUBST(CFLAGS)
3660 AC_SUBST(CXXFLAGS)
3661 AC_SUBST(GDC)
3662 AC_SUBST(GDCFLAGS)
3663 AC_SUBST(PKG_CONFIG_PATH)
3664
3665 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3666 AR_PLUGIN_OPTION=
3667 RANLIB_PLUGIN_OPTION=
3668 if test -n "$PLUGIN_OPTION"; then
3669   if $AR --help 2>&1 | grep -q "\--plugin"; then
3670     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3671   fi
3672   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3673     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3674   fi
3675 fi
3676 AC_SUBST(AR_PLUGIN_OPTION)
3677 AC_SUBST(RANLIB_PLUGIN_OPTION)
3678
3679 # Target tools.
3680 AC_ARG_WITH([build-time-tools],
3681   [AS_HELP_STRING([--with-build-time-tools=PATH],
3682                   [use given path to find target tools during the build])],
3683   [case x"$withval" in
3684      x/*) ;;
3685      *)
3686        with_build_time_tools=
3687        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3688        ;;
3689    esac],
3690   [with_build_time_tools=])
3691
3692 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3693 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3694 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3695 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3696 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3697 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3698
3699 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3700 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3701 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3702 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3703 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3704 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3705 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3706 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3707 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3708 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3709 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3710 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3711 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3712 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3713 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3714
3715 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3716
3717 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3718 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3719 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3720 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3721 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3722                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3723                 c++)
3724 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3725                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3726                 c++)
3727 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3728 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3729 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3730 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3731                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3732 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3733                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3734 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3735                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3736 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3737 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3738 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3739 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3740 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3741 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3742 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3743 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3744 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3745 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3746 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3747
3748 AC_SUBST(FLAGS_FOR_TARGET)
3749 AC_SUBST(RAW_CXX_FOR_TARGET)
3750
3751 # Certain tools may need extra flags.
3752 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3753 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3754 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3755
3756 # When building target libraries, except in a Canadian cross, we use
3757 # the same toolchain as the compiler we just built.
3758 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3759 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3760 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3761 if test $host = $build; then
3762   case " $configdirs " in
3763     *" gcc "*)
3764       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3765       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3766       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3767       ;;
3768   esac
3769 fi
3770
3771 AC_SUBST(COMPILER_AS_FOR_TARGET)
3772 AC_SUBST(COMPILER_LD_FOR_TARGET)
3773 AC_SUBST(COMPILER_NM_FOR_TARGET)
3774
3775 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3776 AC_ARG_ENABLE(maintainer-mode,
3777 [AS_HELP_STRING([--enable-maintainer-mode],
3778                 [enable make rules and dependencies not useful
3779                  (and sometimes confusing) to the casual installer])],
3780       USE_MAINTAINER_MODE=$enableval,
3781       USE_MAINTAINER_MODE=no)
3782 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3783 AC_SUBST(MAINTAINER_MODE_TRUE)
3784 AC_SUBST(MAINTAINER_MODE_FALSE)
3785 if test "$USE_MAINTAINER_MODE" = yes; then
3786   MAINTAINER_MODE_TRUE=
3787   MAINTAINER_MODE_FALSE='#'
3788 else
3789   MAINTAINER_MODE_TRUE='#'
3790   MAINTAINER_MODE_FALSE=
3791 fi
3792 MAINT=$MAINTAINER_MODE_TRUE
3793 AC_SUBST(MAINT)dnl
3794
3795 # ---------------------
3796 # GCC bootstrap support
3797 # ---------------------
3798
3799 # Stage specific cflags for build.
3800 stage1_cflags="-g"
3801 case $build in
3802   vax-*-*)
3803     case ${GCC} in
3804       yes) stage1_cflags="-g -Wa,-J" ;;
3805       *) stage1_cflags="-g -J" ;;
3806     esac ;;
3807 esac
3808
3809 AC_SUBST(stage1_cflags)
3810
3811 # Enable --enable-checking in stage1 of the compiler.
3812 AC_ARG_ENABLE(stage1-checking,
3813 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3814                 [choose additional checking for stage1 of the compiler])],
3815 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3816 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3817   # For --disable-checking or implicit --enable-checking=release, avoid
3818   # setting --enable-checking=gc in the default stage1 checking for LTO
3819   # bootstraps.  See PR62077.
3820   case $BUILD_CONFIG in
3821     *lto*)
3822       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3823     *)
3824       stage1_checking=--enable-checking=yes,types;;
3825   esac
3826   if test "x$enable_checking" = x && \
3827      test -d ${srcdir}/gcc && \
3828      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3829     stage1_checking=--enable-checking=yes,types,extra
3830   fi
3831 else
3832   stage1_checking=--enable-checking=$enable_checking,types
3833 fi])
3834 AC_SUBST(stage1_checking)
3835
3836 # Enable -Werror in bootstrap stage2 and later.
3837 AC_ARG_ENABLE(werror,
3838 [AS_HELP_STRING([--enable-werror],
3839                 [enable -Werror in bootstrap stage2 and later])],
3840 [
3841 case ${enable_werror} in
3842   yes) stage2_werror_flag="--enable-werror-always" ;;
3843   *) stage2_werror_flag="" ;;
3844 esac
3845 ],
3846 [
3847 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3848   case $BUILD_CONFIG in
3849   bootstrap-debug)
3850       stage2_werror_flag="--enable-werror-always" ;;
3851   "")
3852       stage2_werror_flag="--enable-werror-always" ;;
3853   esac
3854 fi
3855 ])
3856
3857 AC_SUBST(stage2_werror_flag)
3858
3859 # Specify what files to not compare during bootstrap.
3860
3861 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3862 case "$target" in
3863   hppa*64*-*-hpux*) ;;
3864   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3865   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3866 esac
3867 AC_SUBST(compare_exclusions)
3868
3869 AC_CONFIG_FILES([Makefile],
3870   [sed "$extrasub_build" Makefile |
3871    sed "$extrasub_host" |
3872    sed "$extrasub_target" > mf$$
3873    mv -f mf$$ Makefile],
3874   [extrasub_build="$extrasub_build"
3875    extrasub_host="$extrasub_host"
3876    extrasub_target="$extrasub_target"])
3877 AC_OUTPUT