configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include(config/gcc-plugin.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT
  36 AC_CONFIG_SRCDIR([move-if-change])
  37 AC_DISABLE_OPTION_CHECKING
  38
  39 progname=$0
  40 # if PWD already has a value, it is probably wrong.
  41 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  42
  43 # Export original configure arguments for use by sub-configures.
  44 # Quote arguments with shell meta charatcers.
  45 TOPLEVEL_CONFIGURE_ARGUMENTS=
  46 set -- "$progname" "$@"
  47 for ac_arg
  48 do
  49   case "$ac_arg" in
  50   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  51     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  52     # if the argument is of the form -foo=baz, quote the baz part only
  53     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  54   *) ;;
  55   esac
  56   # Add the quoted argument to the list.
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  58 done
  59 if test "$silent" = yes; then
  60   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  61 fi
  62 # Remove the initial space we just introduced and, as these will be
  63 # expanded by make, quote '$'.
  64 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  65 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  66
  67 # Find the build, host, and target systems.
  68 ACX_NONCANONICAL_BUILD
  69 ACX_NONCANONICAL_HOST
  70 ACX_NONCANONICAL_TARGET
  71
  72 dnl Autoconf 2.5x and later will set a default program prefix if
  73 dnl --target was used, even if it was the same as --host.  Disable
  74 dnl that behavior.  This must be done before AC_CANONICAL_TARGET
  75 dnl to take effect.
  76 test "$host_noncanonical" = "$target_noncanonical" &&
  77   test "$program_prefix$program_suffix$program_transform_name" = \
  78     NONENONEs,x,x, &&
  79   program_transform_name=s,y,y,
  80
  81 AC_CANONICAL_TARGET
  82 AC_ARG_PROGRAM
  83
  84 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  85 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  86
  87 # Get 'install' or 'install-sh' and its variants.
  88 AC_PROG_INSTALL
  89 ACX_PROG_LN
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_AWK
  93
  94 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  95
  96 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  97 # a relative path.
  98 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  99   INSTALL="${srcpwd}/install-sh -c"
 100 fi
 101
 102 # Set srcdir to "." if that's what it is.
 103 # This is important for multilib support.
 104 pwd=`${PWDCMD-pwd}`
 105 if test "${pwd}" = "${srcpwd}" ; then
 106   srcdir=.
 107 fi
 108
 109 topsrcdir=$srcpwd
 110
 111 extra_host_args=
 112
 113 ### To add a new directory to the tree, first choose whether it is a target
 114 ### or a host dependent tool.  Then put it into the appropriate list
 115 ### (library or tools, host or target), doing a dependency sort.
 116
 117 # Subdirs will be configured in the order listed in build_configdirs,
 118 # configdirs, or target_configdirs; see the serialization section below.
 119
 120 # Dependency sorting is only needed when *configuration* must be done in
 121 # a particular order.  In all cases a dependency should be specified in
 122 # the Makefile, whether or not it's implicitly specified here.
 123
 124 # Double entries in build_configdirs, configdirs, or target_configdirs may
 125 # cause circular dependencies and break everything horribly.
 126
 127 # these library is used by various programs built for the build
 128 # environment
 129 #
 130 build_libs="build-libiberty build-libcpp"
 131
 132 # these tools are built for the build environment
 133 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 134
 135 # these libraries are used by various programs built for the host environment
 136 #f
 137 host_libs="gettext libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe libgrust "
 138
 139 # these tools are built for the host environment
 140 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 141 # know that we are building the simulator.
 142 # binutils, gas and ld appear in that order because it makes sense to run
 143 # "make check" in that particular order.
 144 # If --enable-gold is used, "gold" may replace "ld".
 145 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 146
 147 # these libraries are built for the target environment, and are built after
 148 # the host libraries and the host tools (which may be a cross compiler)
 149 # Note that libiberty is not a target library.
 150 target_libraries="target-libgcc \
 151                 target-libbacktrace \
 152                 target-libgloss \
 153                 target-newlib \
 154                 target-libgomp \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgm2 \
 167                 target-libgo \
 168                 target-libgrust \
 169                 target-libphobos \
 170                 target-zlib"
 171
 172 # these tools are built using the target libraries, and are intended to
 173 # run only in the target environment
 174 #
 175 # note: any program that *uses* libraries that are in the "target_libraries"
 176 # list belongs in this list.
 177 #
 178 target_tools="target-rda"
 179
 180 ################################################################################
 181
 182 ## All tools belong in one of the four categories, and are assigned above
 183 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 184 ## is important because configure will choke if they ever get through.
 185 ## ${configdirs} is directories we build using the host tools.
 186 ## ${target_configdirs} is directories we build using the target tools.
 187 configdirs=`echo ${host_libs} ${host_tools}`
 188 target_configdirs=`echo ${target_libraries} ${target_tools}`
 189 build_configdirs=`echo ${build_libs} ${build_tools}`
 190
 191 m4_divert_text([PARSE_ARGS],
 192 [case $srcdir in
 193   *" "*)
 194 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 195     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 196 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 197     ;;
 198 esac
 199 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 200 ])
 201
 202 ################################################################################
 203
 204 srcname="gnu development package"
 205
 206 # This gets set non-empty for some net releases of packages.
 207 appdirs=""
 208
 209 # Define is_cross_compiler to save on calls to 'test'.
 210 is_cross_compiler=
 211 if test x"${host}" = x"${target}" ; then
 212   is_cross_compiler=no
 213 else
 214   is_cross_compiler=yes
 215 fi
 216
 217 # Find the build and target subdir names.
 218 GCC_TOPLEV_SUBDIRS
 219 # Be sure to cover against remnants of an in-tree build.
 220 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 221   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 222 Use a pristine source tree when building in a separate tree])
 223 fi
 224
 225 # Skipdirs are removed silently.
 226 skipdirs=
 227 # Noconfigdirs are removed loudly.
 228 noconfigdirs=""
 229
 230 use_gnu_ld=
 231 # Make sure we don't let GNU ld be added if we didn't want it.
 232 if test x$with_gnu_ld = xno ; then
 233   use_gnu_ld=no
 234   noconfigdirs="$noconfigdirs ld gold"
 235 fi
 236
 237 use_gnu_as=
 238 # Make sure we don't let GNU as be added if we didn't want it.
 239 if test x$with_gnu_as = xno ; then
 240   use_gnu_as=no
 241   noconfigdirs="$noconfigdirs gas"
 242 fi
 243
 244 use_included_zlib=
 245 AC_ARG_WITH(system-zlib,
 246 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 247 # Make sure we don't let ZLIB be added if we didn't want it.
 248 if test x$with_system_zlib = xyes ; then
 249   use_included_zlib=no
 250   noconfigdirs="$noconfigdirs zlib"
 251 fi
 252
 253 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 254 # is provided.
 255 if test x$with_system_readline = xyes ; then
 256   noconfigdirs="$noconfigdirs readline"
 257 fi
 258
 259 AC_ARG_WITH(zstd,
 260 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 261
 262 # some tools are so dependent upon X11 that if we're not building with X,
 263 # it's not even worth trying to configure, much less build, that tool.
 264
 265 case ${with_x} in
 266   yes | "") ;; # the default value for this tree is that X11 is available
 267   no)
 268     skipdirs="${skipdirs} tk itcl libgui"
 269     # We won't be able to build gdbtk without X.
 270     enable_gdbtk=no
 271     ;;
 272   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 273 esac
 274
 275 # Some are only suitable for cross toolchains.
 276 # Remove these if host=target.
 277 cross_only="target-libgloss target-newlib target-opcodes"
 278
 279 case $is_cross_compiler in
 280   no) skipdirs="${skipdirs} ${cross_only}" ;;
 281 esac
 282
 283 # If both --with-headers and --with-libs are specified, default to
 284 # --without-newlib.
 285 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 286    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 287   if test x"${with_newlib}" = x ; then
 288     with_newlib=no
 289   fi
 290 fi
 291
 292 # Recognize --with-newlib/--without-newlib.
 293 case ${with_newlib} in
 294   no) skipdirs="${skipdirs} target-newlib" ;;
 295   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 296 esac
 297
 298 AC_ARG_ENABLE(as-accelerator-for,
 299 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 300                 [build as offload target compiler.
 301                 Specify offload host triple by ARG])])
 302
 303 AC_ARG_ENABLE(offload-targets,
 304 [AS_HELP_STRING([--enable-offload-targets=LIST],
 305                 [enable offloading to devices from comma-separated LIST of
 306                 TARGET[=DIR]. Use optional path to find offload target compiler
 307                 during the build])],
 308 [
 309   if test x"$enable_offload_targets" = x; then
 310     AC_MSG_ERROR([no offload targets specified])
 311   fi
 312 ], [enable_offload_targets=])
 313
 314 AC_ARG_ENABLE(offload-defaulted,
 315 [AS_HELP_STRING([--enable-offload-defaulted]
 316                 [If enabled, configured but not installed offload compilers and
 317                 libgomp plugins are silently ignored.  Useful for distribution
 318                 compilers where those are in separate optional packages.])],
 319 [enable_offload_defaulted=$enableval],
 320 [enable_offload_defaulted=])
 321
 322 # Handle --enable-gold, --enable-ld.
 323 # --disable-gold [--enable-ld]
 324 #     Build only ld.  Default option.
 325 # --enable-gold [--enable-ld]
 326 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 327 #     as "ld.bfd" and "ld".
 328 # --enable-gold=default [--enable-ld]
 329 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 330 #     install ld as "ld.bfd".
 331 # --enable-gold[=default] --disable-ld
 332 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 333 # --enable-gold --enable-ld=default
 334 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 335 #     and ld.bfd).
 336 #     In other words, ld is default
 337 # --enable-gold=default --enable-ld=default
 338 #     Error.
 339
 340 default_ld=
 341 AC_ARG_ENABLE(gold,
 342 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 343                 [build gold @<:@ARG={default,yes,no}@:>@])],
 344 ENABLE_GOLD=$enableval,
 345 ENABLE_GOLD=no)
 346 case "${ENABLE_GOLD}" in
 347   yes|default)
 348     # Check for ELF target.
 349     is_elf=no
 350     case "${target}" in
 351       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 352       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 353       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 354       | *-*-solaris2* | *-*-nto* | *-*-nacl* | *-*-haiku*)
 355         case "${target}" in
 356           *-*-linux*aout* | *-*-linux*oldld*)
 357             ;;
 358           *)
 359             is_elf=yes
 360             ;;
 361         esac
 362     esac
 363
 364     if test "$is_elf" = "yes"; then
 365       # Check for target supported by gold.
 366       case "${target}" in
 367         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 368         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 369           configdirs="$configdirs gold"
 370           if test x${ENABLE_GOLD} = xdefault; then
 371             default_ld=gold
 372           fi
 373           ENABLE_GOLD=yes
 374           ;;
 375       esac
 376     fi
 377     ;;
 378   no)
 379     ;;
 380   *)
 381     AC_MSG_ERROR([invalid --enable-gold argument])
 382     ;;
 383 esac
 384
 385 AC_ARG_ENABLE(ld,
 386 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 387                 [build ld @<:@ARG={default,yes,no}@:>@])],
 388 ENABLE_LD=$enableval,
 389 ENABLE_LD=yes)
 390
 391 case "${ENABLE_LD}" in
 392   default)
 393     if test x${default_ld} != x; then
 394       AC_MSG_ERROR([either gold or ld can be the default ld])
 395     fi
 396     ;;
 397   yes)
 398     ;;
 399   no)
 400     if test x${ENABLE_GOLD} != xyes; then
 401       AC_MSG_WARN([neither ld nor gold are enabled])
 402     fi
 403     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 404     ;;
 405   *)
 406     AC_MSG_ERROR([invalid --enable-ld argument])
 407     ;;
 408 esac
 409
 410 AC_ARG_ENABLE(gprofng,
 411 [AS_HELP_STRING([[--disable-gprofng]], [do not build gprofng])],
 412 enable_gprofng=$enableval,
 413 enable_gprofng=yes)
 414 if test "$enable_gprofng" = "yes"; then
 415   case "${target}" in
 416     *-musl*)
 417       ;;
 418     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux* | riscv64-*-linux*)
 419     configdirs="$configdirs gprofng"
 420     ;;
 421   esac
 422 fi
 423
 424
 425 # PR gas/19109
 426 # Decide the default method for compressing debug sections.
 427 # Provide a configure time option to override our default.
 428 AC_ARG_ENABLE(compressed_debug_sections,
 429 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 430                 [Enable compressed debug sections for gas, gold or ld by
 431                  default])],
 432 [
 433   if test x"$enable_compressed_debug_sections" = xyes; then
 434     AC_MSG_ERROR([no program with compressed debug sections specified])
 435   fi
 436 ], [enable_compressed_debug_sections=])
 437
 438 # Select default compression algorithm.
 439 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 440 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 441                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 442 [], [default_compressed_debug_sections_algorithm=])
 443
 444 # Configure extra directories which are host specific
 445
 446 case "${host}" in
 447   *-cygwin*)
 448     configdirs="$configdirs libtermcap" ;;
 449 esac
 450
 451 # A target can indicate whether a language isn't supported for some reason.
 452 # Only spaces may be used in this macro; not newlines or tabs.
 453 unsupported_languages=
 454
 455 # Remove more programs from consideration, based on the host or
 456 # target this usually means that a port of the program doesn't
 457 # exist yet.
 458
 459 case "${host}" in
 460   i[[3456789]]86-*-msdosdjgpp*)
 461     noconfigdirs="$noconfigdirs tcl tk itcl"
 462     ;;
 463 esac
 464
 465 # Default to --disable-year2038 until we can handle differences between
 466 # projects that use gnulib (which understands year 2038) and projects that
 467 # do not (like BFD).
 468 AC_ARG_ENABLE(year2038,
 469 AS_HELP_STRING([--enable-year2038],
 470   [enable support for timestamps past the year 2038]),
 471 ENABLE_YEAR2038=$enableval,
 472 ENABLE_YEAR2038=no)
 473 enable_year2038=
 474 if test "${ENABLE_YEAR2038}" = "no" ; then
 475   enable_year2038=no
 476 fi
 477
 478 AC_ARG_ENABLE(libquadmath,
 479 AS_HELP_STRING([--disable-libquadmath],
 480   [do not build libquadmath directory]),
 481 ENABLE_LIBQUADMATH=$enableval,
 482 ENABLE_LIBQUADMATH=yes)
 483 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 484   noconfigdirs="$noconfigdirs target-libquadmath"
 485 fi
 486
 487
 488 AC_ARG_ENABLE(libquadmath-support,
 489 AS_HELP_STRING([--disable-libquadmath-support],
 490   [disable libquadmath support for Fortran]),
 491 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 492 ENABLE_LIBQUADMATH_SUPPORT=yes)
 493 enable_libquadmath_support=
 494 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 495   enable_libquadmath_support=no
 496 fi
 497
 498
 499 AC_ARG_ENABLE(libada,
 500 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 501 ENABLE_LIBADA=$enableval,
 502 ENABLE_LIBADA=yes)
 503 if test "${ENABLE_LIBADA}" != "yes" ; then
 504   noconfigdirs="$noconfigdirs gnattools"
 505 fi
 506
 507 AC_ARG_ENABLE(libgm2,
 508 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 509 ENABLE_LIBGM2=$enableval,
 510 ENABLE_LIBGM2=no)
 511 if test "${ENABLE_LIBGM2}" != "yes" ; then
 512   noconfigdirs="$noconfigdirs gm2tools"
 513 fi
 514
 515 AC_ARG_ENABLE(libssp,
 516 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 517 ENABLE_LIBSSP=$enableval,
 518 ENABLE_LIBSSP=yes)
 519
 520 AC_ARG_ENABLE(libstdcxx,
 521 AS_HELP_STRING([--disable-libstdcxx],
 522   [do not build libstdc++-v3 directory]),
 523 ENABLE_LIBSTDCXX=$enableval,
 524 ENABLE_LIBSTDCXX=default)
 525 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 526   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 527 fi]
 528
 529 # Enable libgomp by default on hosted POSIX systems, and a few others.
 530 if test x$enable_libgomp = x ; then
 531     case "${target}" in
 532     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 533         ;;
 534     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 535         ;;
 536     *-*-solaris2* | *-*-hpux11*)
 537         ;;
 538     *-*-darwin* | *-*-aix*)
 539         ;;
 540     nvptx*-*-* | amdgcn*-*-*)
 541         ;;
 542     *)
 543         noconfigdirs="$noconfigdirs target-libgomp"
 544         ;;
 545     esac
 546 fi
 547
 548 # Disable libatomic on unsupported systems.
 549 if test -d ${srcdir}/libatomic; then
 550     if test x$enable_libatomic = x; then
 551         AC_MSG_CHECKING([for libatomic support])
 552         if (srcdir=${srcdir}/libatomic; \
 553                 . ${srcdir}/configure.tgt; \
 554                 test -n "$UNSUPPORTED")
 555         then
 556             AC_MSG_RESULT([no])
 557             noconfigdirs="$noconfigdirs target-libatomic"
 558         else
 559             AC_MSG_RESULT([yes])
 560         fi
 561     fi
 562 fi
 563
 564 # Disable libitm on unsupported systems.
 565 if test -d ${srcdir}/libitm; then
 566     if test x$enable_libitm = x; then
 567         AC_MSG_CHECKING([for libitm support])
 568         if (srcdir=${srcdir}/libitm; \
 569                 . ${srcdir}/configure.tgt; \
 570                 test -n "$UNSUPPORTED")
 571         then
 572             AC_MSG_RESULT([no])
 573             noconfigdirs="$noconfigdirs target-libitm"
 574         else
 575             AC_MSG_RESULT([yes])
 576         fi
 577     fi
 578 fi
 579
 580 # Disable libsanitizer on unsupported systems.
 581 if test -d ${srcdir}/libsanitizer; then
 582     if test x$enable_libsanitizer = x; then
 583         AC_MSG_CHECKING([for libsanitizer support])
 584         if (srcdir=${srcdir}/libsanitizer; \
 585                 . ${srcdir}/configure.tgt; \
 586                 test -n "$UNSUPPORTED")
 587         then
 588             AC_MSG_RESULT([no])
 589             noconfigdirs="$noconfigdirs target-libsanitizer"
 590         else
 591             AC_MSG_RESULT([yes])
 592         fi
 593     fi
 594 fi
 595
 596 # Disable libvtv on unsupported systems.
 597 if test -d ${srcdir}/libvtv; then
 598     if test x$enable_libvtv = x; then
 599         AC_MSG_CHECKING([for libvtv support])
 600         if (srcdir=${srcdir}/libvtv; \
 601                 . ${srcdir}/configure.tgt; \
 602                 test "$VTV_SUPPORTED" != "yes")
 603         then
 604             AC_MSG_RESULT([no])
 605             noconfigdirs="$noconfigdirs target-libvtv"
 606         else
 607             AC_MSG_RESULT([yes])
 608         fi
 609     fi
 610 fi
 611
 612 # Disable libquadmath for some systems.
 613 case "${target}" in
 614   avr-*-*)
 615     noconfigdirs="$noconfigdirs target-libquadmath"
 616     ;;
 617   # libquadmath is unused on AIX and libquadmath build process use of
 618   # LD_LIBRARY_PATH can break AIX bootstrap.
 619   powerpc-*-aix* | rs6000-*-aix*)
 620     noconfigdirs="$noconfigdirs target-libquadmath"
 621     ;;
 622 esac
 623
 624 # Disable libssp for some systems.
 625 case "${target}" in
 626   avr-*-*)
 627     # No hosted I/O support.
 628     noconfigdirs="$noconfigdirs target-libssp"
 629     ;;
 630   bpf-*-*)
 631     noconfigdirs="$noconfigdirs target-libssp"
 632     ;;
 633   powerpc-*-aix* | rs6000-*-aix*)
 634     noconfigdirs="$noconfigdirs target-libssp"
 635     ;;
 636   pru-*-*)
 637     # No hosted I/O support.
 638     noconfigdirs="$noconfigdirs target-libssp"
 639     ;;
 640   rl78-*-*)
 641     # libssp uses a misaligned load to trigger a fault, but the RL78
 642     # doesn't fault for those - instead, it gives a build-time error
 643     # for explicit misaligned loads.
 644     noconfigdirs="$noconfigdirs target-libssp"
 645     ;;
 646   visium-*-*)
 647     # No hosted I/O support.
 648     noconfigdirs="$noconfigdirs target-libssp"
 649     ;;
 650 esac
 651
 652 # Disable libstdc++-v3 for some systems.
 653 # Allow user to override this if they pass --enable-libstdcxx
 654 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 655   case "${target}" in
 656     *-*-vxworks*)
 657       # VxWorks uses the Dinkumware C++ library.
 658       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 659       ;;
 660     amdgcn*-*-*)
 661       # Not ported/fails to build when using newlib.
 662       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 663       ;;
 664     arm*-wince-pe*)
 665       # the C++ libraries don't build on top of CE's C libraries
 666       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 667       ;;
 668     avr-*-*)
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     bpf-*-*)
 672       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 673       ;;
 674     ft32-*-*)
 675       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 676       ;;
 677   esac
 678 fi
 679
 680 # Disable C++ on systems where it is known to not work.
 681 # For testing, you can override this with --enable-languages=c++.
 682 case ,${enable_languages}, in
 683   *,c++,*)
 684     ;;
 685   *)
 686       case "${target}" in
 687         bpf-*-*)
 688           unsupported_languages="$unsupported_languages c++"
 689           ;;
 690       esac
 691       ;;
 692 esac
 693
 694 # Disable Objc on systems where it is known to not work.
 695 # For testing, you can override this with --enable-languages=objc.
 696 case ,${enable_languages}, in
 697   *,objc,*)
 698     ;;
 699   *)
 700       case "${target}" in
 701         bpf-*-*)
 702           unsupported_languages="$unsupported_languages objc"
 703           ;;
 704       esac
 705       ;;
 706 esac
 707
 708 # Disable D on systems where it is known to not work.
 709 # For testing, you can override this with --enable-languages=d.
 710 case ,${enable_languages}, in
 711   *,d,*)
 712     ;;
 713   *)
 714     case "${target}" in
 715       bpf-*-*)
 716         unsupported_languages="$unsupported_languages d"
 717         ;;
 718     esac
 719     ;;
 720 esac
 721
 722 # Disable libphobos on unsupported systems.
 723 # For testing, you can override this with --enable-libphobos.
 724 if test -d ${srcdir}/libphobos; then
 725     if test x$enable_libphobos = x; then
 726         AC_MSG_CHECKING([for libphobos support])
 727         if (srcdir=${srcdir}/libphobos; \
 728                 . ${srcdir}/configure.tgt; \
 729                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 730         then
 731             AC_MSG_RESULT([no])
 732             noconfigdirs="$noconfigdirs target-libphobos"
 733         else
 734             AC_MSG_RESULT([yes])
 735         fi
 736     fi
 737 fi
 738
 739 # Disable Fortran for some systems.
 740 case "${target}" in
 741   mmix-*-*)
 742     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 743     unsupported_languages="$unsupported_languages fortran"
 744     ;;
 745   bpf-*-*)
 746     unsupported_languages="$unsupported_languages fortran"
 747     ;;
 748 esac
 749
 750 # Disable libffi for some systems.
 751 case "${target}" in
 752   powerpc-*-darwin*)
 753     ;;
 754   i[[3456789]]86-*-darwin*)
 755     ;;
 756   x86_64-*-darwin[[912]]*)
 757     ;;
 758   *-*-darwin*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   *-*-netware*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   *-*-phoenix*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   *-*-rtems*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   *-*-tpf*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   *-*-uclinux*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   *-*-vxworks*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   aarch64*-*-freebsd*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   alpha*-*-*vms*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   arm*-*-freebsd*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   arm-wince-pe)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   arm*-*-symbianelf*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   bpf-*-*)
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   cris-*-* | crisv32-*-*)
 798     case "${target}" in
 799       *-*-linux*)
 800         ;;
 801       *) # See PR46792 regarding target-libffi.
 802         noconfigdirs="$noconfigdirs target-libffi";;
 803     esac
 804     ;;
 805   hppa*64*-*-hpux*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   hppa*-hp-hpux11*)
 809     ;;
 810   hppa*-*-hpux*)
 811     noconfigdirs="$noconfigdirs target-libffi"
 812     ;;
 813   ia64*-*-*vms*)
 814     noconfigdirs="$noconfigdirs target-libffi"
 815     ;;
 816   i[[3456789]]86-w64-mingw*)
 817     noconfigdirs="$noconfigdirs target-libffi"
 818     ;;
 819   i[[3456789]]86-*-mingw*)
 820     noconfigdirs="$noconfigdirs target-libffi"
 821     ;;
 822   x86_64-*-mingw*)
 823     noconfigdirs="$noconfigdirs target-libffi"
 824     ;;
 825   mmix-*-*)
 826     noconfigdirs="$noconfigdirs target-libffi"
 827     ;;
 828   powerpc-*-aix*)
 829     ;;
 830   rs6000-*-aix*)
 831     ;;
 832   ft32-*-*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   *-*-lynxos*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838 esac
 839
 840 # Disable the go frontend on systems where it is known to not work. Please keep
 841 # this in sync with contrib/config-list.mk.
 842 case "${target}" in
 843 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 844     unsupported_languages="$unsupported_languages go"
 845     ;;
 846 esac
 847
 848 # Only allow gdbserver on some systems.
 849 if test -d ${srcdir}/gdbserver; then
 850     if test x$enable_gdbserver = x; then
 851         AC_MSG_CHECKING([for gdbserver support])
 852         if (srcdir=${srcdir}/gdbserver; \
 853                 . ${srcdir}/configure.srv; \
 854                 test -n "$UNSUPPORTED")
 855         then
 856             AC_MSG_RESULT([no])
 857             noconfigdirs="$noconfigdirs gdbserver"
 858         else
 859             AC_MSG_RESULT([yes])
 860         fi
 861     fi
 862 fi
 863
 864 # Disable libgo for some systems where it is known to not work.
 865 # For testing, you can easily override this with --enable-libgo.
 866 if test x$enable_libgo = x; then
 867     case "${target}" in
 868     *-*-darwin*)
 869         # PR 46986
 870         noconfigdirs="$noconfigdirs target-libgo"
 871         ;;
 872     *-*-cygwin* | *-*-mingw*)
 873         noconfigdirs="$noconfigdirs target-libgo"
 874         ;;
 875     bpf-*-*)
 876         noconfigdirs="$noconfigdirs target-libgo"
 877         ;;
 878     esac
 879 fi
 880
 881 # Default libgloss CPU subdirectory.
 882 libgloss_dir="$target_cpu"
 883
 884 case "${target}" in
 885   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 886     libgloss_dir=wince
 887     ;;
 888   aarch64*-*-* )
 889     libgloss_dir=aarch64
 890     ;;
 891   arm*-*-*)
 892     libgloss_dir=arm
 893     ;;
 894   cris-*-* | crisv32-*-*)
 895     libgloss_dir=cris
 896     ;;
 897   kvx-*-elf)
 898     libgloss_dir=kvx-elf
 899     ;;
 900   kvx-*-mbr)
 901     libgloss_dir=kvx-mbr
 902     ;;
 903   kvx-*-cos)
 904     libgloss_dir=kvx-cos
 905     ;;
 906   hppa*-*-*)
 907     libgloss_dir=pa
 908     ;;
 909   i[[3456789]]86-*-*)
 910     libgloss_dir=i386
 911     ;;
 912   loongarch*-*-*)
 913     libgloss_dir=loongarch
 914     ;;
 915   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 916     libgloss_dir=m68hc11
 917     ;;
 918   m68*-*-* | fido-*-*)
 919     libgloss_dir=m68k
 920     ;;
 921   mips*-*-*)
 922     libgloss_dir=mips
 923     ;;
 924   powerpc*-*-*)
 925     libgloss_dir=rs6000
 926     ;;
 927   pru-*-*)
 928     libgloss_dir=pru
 929     ;;
 930   sparc*-*-*)
 931     libgloss_dir=sparc
 932     ;;
 933 esac
 934
 935 # Disable newlib and libgloss for various target OSes.
 936 case "${target}" in
 937   alpha*-dec-osf*)
 938     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 939     ;;
 940   i[[3456789]]86-*-linux*)
 941     # This section makes it possible to build newlib natively on linux.
 942     # If we are using a cross compiler then don't configure newlib.
 943     if test x${is_cross_compiler} != xno ; then
 944       noconfigdirs="$noconfigdirs target-newlib"
 945     fi
 946     noconfigdirs="$noconfigdirs target-libgloss"
 947     # If we are not using a cross compiler, do configure newlib.
 948     # Note however, that newlib will only be configured in this situation
 949     # if the --with-newlib option has been given, because otherwise
 950     # 'target-newlib' will appear in skipdirs.
 951     ;;
 952   i[[3456789]]86-*-rdos*)
 953     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 954     ;;
 955   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   sparc-*-sunos4*)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   bpf-*-*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   *-*-aix*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-beos*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-chorusos)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-dragonfly*)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-freebsd*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-lynxos*)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985   *-*-mingw*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   *-*-netbsd*)
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   *-*-netware*)
 992     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 993     ;;
 994   *-*-tpf*)
 995     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 996     ;;
 997   *-*-uclinux*)
 998     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 999     ;;
1000   *-*-vxworks*)
1001     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1002     ;;
1003 esac
1004
1005 case "${target}" in
1006   *-*-chorusos)
1007     ;;
1008   aarch64-*-darwin*)
1009     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1010     noconfigdirs="$noconfigdirs sim target-rda"
1011     ;;
1012   amdgcn*-*-*)
1013     ;;
1014   arm-*-darwin*)
1015     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1016     noconfigdirs="$noconfigdirs sim target-rda"
1017     ;;
1018   powerpc-*-darwin*)
1019     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1020     noconfigdirs="$noconfigdirs sim target-rda"
1021     ;;
1022   i[[3456789]]86-*-darwin*)
1023     noconfigdirs="$noconfigdirs ld gprof"
1024     noconfigdirs="$noconfigdirs sim target-rda"
1025     ;;
1026   x86_64-*-darwin[[912]]*)
1027     noconfigdirs="$noconfigdirs ld gas gprof"
1028     noconfigdirs="$noconfigdirs sim target-rda"
1029     ;;
1030   *-*-darwin*)
1031     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1032     noconfigdirs="$noconfigdirs sim target-rda"
1033     ;;
1034   *-*-dragonfly*)
1035     ;;
1036   *-*-freebsd*)
1037     if test "x$with_gmp" = x \
1038         && ! test -d ${srcdir}/gmp \
1039         && test -f /usr/local/include/gmp.h; then
1040       with_gmp=/usr/local
1041     fi
1042     ;;
1043   *-*-kaos*)
1044     # Remove unsupported stuff on all kaOS configurations.
1045     noconfigdirs="$noconfigdirs target-libgloss"
1046     ;;
1047   *-*-netbsd*)
1048     ;;
1049   *-*-netware*)
1050     ;;
1051   *-*-phoenix*)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   *-*-rtems*)
1055     noconfigdirs="$noconfigdirs target-libgloss"
1056     ;;
1057     # The tpf target doesn't support gdb yet.
1058   *-*-tpf*)
1059     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1060     ;;
1061   *-*-uclinux*)
1062     noconfigdirs="$noconfigdirs target-rda"
1063     ;;
1064   *-*-vxworks*)
1065     ;;
1066   alpha*-dec-osf*)
1067     # ld works, but does not support shared libraries.
1068     # gas doesn't generate exception information.
1069     noconfigdirs="$noconfigdirs gas ld"
1070     ;;
1071   alpha*-*-*vms*)
1072     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1073     ;;
1074   alpha*-*-*)
1075     # newlib is not 64 bit ready
1076     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1077     ;;
1078   bpf-*-*)
1079     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1080     ;;
1081   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1082     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1083     ;;
1084   arc*-*-*)
1085     noconfigdirs="$noconfigdirs sim"
1086     ;;
1087   arm-*-pe*)
1088     noconfigdirs="$noconfigdirs target-libgloss"
1089     ;;
1090   arm-*-riscix*)
1091     noconfigdirs="$noconfigdirs ld target-libgloss"
1092     ;;
1093   avr-*-*)
1094     if test x${with_avrlibc} != xno; then
1095       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1096     fi
1097     ;;
1098   c4x-*-* | tic4x-*-*)
1099     noconfigdirs="$noconfigdirs target-libgloss"
1100     ;;
1101   tic54x-*-*)
1102     noconfigdirs="$noconfigdirs target-libgloss gdb"
1103     ;;
1104   d10v-*-*)
1105     noconfigdirs="$noconfigdirs target-libgloss"
1106     ;;
1107   d30v-*-*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   fr30-*-elf*)
1111     noconfigdirs="$noconfigdirs gdb"
1112     ;;
1113   ft32-*-*)
1114     noconfigdirs="$noconfigdirs target-rda gprof"
1115     ;;
1116   moxie-*-*)
1117     noconfigdirs="$noconfigdirs"
1118     ;;
1119   h8300*-*-*)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   h8500-*-*)
1123     noconfigdirs="$noconfigdirs target-libgloss"
1124     ;;
1125   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1126     ;;
1127   hppa*64*-*-hpux*)
1128     noconfigdirs="$noconfigdirs gdb"
1129     ;;
1130   hppa*-*-hpux11*)
1131     noconfigdirs="$noconfigdirs gdb ld"
1132     ;;
1133   hppa*64*-*-linux*)
1134     ;;
1135   hppa*-*-linux*)
1136     ;;
1137   hppa*-*-*elf* | \
1138   hppa*-*-lites* | \
1139   hppa*-*-openbsd* | \
1140   hppa*64*-*-*)
1141     ;;
1142   hppa*-*-pro*)
1143     ;;
1144   hppa*-*-*)
1145     noconfigdirs="$noconfigdirs ld"
1146     ;;
1147   i960-*-*)
1148     noconfigdirs="$noconfigdirs gdb"
1149     ;;
1150   ia64*-*-elf*)
1151     # No gdb support yet.
1152     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1153     ;;
1154   ia64*-**-hpux*)
1155     # No ld support yet.
1156     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1157     ;;
1158   ia64*-*-*vms*)
1159     # No ld support yet.
1160     noconfigdirs="$noconfigdirs libgui itcl ld"
1161     ;;
1162   i[[3456789]]86-w64-mingw*)
1163     ;;
1164   i[[3456789]]86-*-mingw*)
1165     target_configdirs="$target_configdirs target-winsup"
1166     ;;
1167   *-*-cygwin*)
1168     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1169     noconfigdirs="$noconfigdirs target-libgloss"
1170     # always build newlib if winsup directory is present.
1171     if test -d "$srcdir/winsup/cygwin"; then
1172       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1173     elif test -d "$srcdir/newlib"; then
1174       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1175     fi
1176     ;;
1177   i[[3456789]]86-*-pe)
1178     noconfigdirs="$noconfigdirs target-libgloss"
1179     ;;
1180   i[[3456789]]86-*-sco3.2v5*)
1181     # The linker does not yet know about weak symbols in COFF,
1182     # and is not configured to handle mixed ELF and COFF.
1183     noconfigdirs="$noconfigdirs ld target-libgloss"
1184     ;;
1185   i[[3456789]]86-*-sco*)
1186     noconfigdirs="$noconfigdirs gprof target-libgloss"
1187     ;;
1188   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1189     noconfigdirs="$noconfigdirs target-libgloss"
1190     ;;
1191   i[[3456789]]86-*-sysv4*)
1192     noconfigdirs="$noconfigdirs target-libgloss"
1193     ;;
1194   i[[3456789]]86-*-beos*)
1195     noconfigdirs="$noconfigdirs gdb"
1196     ;;
1197   i[[3456789]]86-*-rdos*)
1198     noconfigdirs="$noconfigdirs gdb"
1199     ;;
1200   kvx-*-*)
1201     noconfigdirs="$noconfigdirs gdb gdbserver sim"
1202     ;;
1203   mmix-*-*)
1204     noconfigdirs="$noconfigdirs gdb"
1205     ;;
1206   mt-*-*)
1207     noconfigdirs="$noconfigdirs sim"
1208     ;;
1209   nfp-*-*)
1210     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1211     noconfigdirs="$noconfigdirs $target_libraries"
1212     ;;
1213   pdp11-*-*)
1214     noconfigdirs="$noconfigdirs gdb gprof"
1215     ;;
1216   powerpc-*-aix*)
1217     # copied from rs6000-*-* entry
1218     noconfigdirs="$noconfigdirs gprof"
1219     ;;
1220   powerpc*-*-winnt* | powerpc*-*-pe*)
1221     target_configdirs="$target_configdirs target-winsup"
1222     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1223     # always build newlib.
1224     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1225     ;;
1226     # This is temporary until we can link against shared libraries
1227   powerpcle-*-solaris*)
1228     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1229     ;;
1230   powerpc-*-beos*)
1231     noconfigdirs="$noconfigdirs gdb"
1232     ;;
1233   rs6000-*-lynxos*)
1234     noconfigdirs="$noconfigdirs gprof"
1235     ;;
1236   rs6000-*-aix*)
1237     noconfigdirs="$noconfigdirs gprof"
1238     ;;
1239   rs6000-*-*)
1240     noconfigdirs="$noconfigdirs gprof"
1241     ;;
1242   m68k-apollo-*)
1243     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1244     ;;
1245   microblaze*)
1246     noconfigdirs="$noconfigdirs gprof"
1247     ;;
1248   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1249     if test x$with_newlib = xyes; then
1250       noconfigdirs="$noconfigdirs gprof"
1251     fi
1252     ;;
1253   mips*-*-irix5*)
1254     noconfigdirs="$noconfigdirs gprof target-libgloss"
1255     ;;
1256   mips*-*-irix6*)
1257     noconfigdirs="$noconfigdirs gprof target-libgloss"
1258     ;;
1259   mips*-*-bsd*)
1260     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1261     ;;
1262   mips*-*-linux*)
1263     ;;
1264   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1265   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1266     noconfigdirs="$noconfigdirs ld gas gprof"
1267     ;;
1268   mips*-*-*)
1269     noconfigdirs="$noconfigdirs gprof"
1270     ;;
1271   nvptx*-*-*)
1272     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1273     ;;
1274   sh-*-*)
1275     case "${target}" in
1276       sh*-*-elf)
1277          ;;
1278       *)
1279          noconfigdirs="$noconfigdirs target-libgloss" ;;
1280     esac
1281     ;;
1282   sparc-*-sunos4*)
1283     if test x${is_cross_compiler} = xno ; then
1284            use_gnu_ld=no
1285     fi
1286     ;;
1287   tic6x-*-*)
1288     noconfigdirs="$noconfigdirs sim"
1289     ;;
1290   tilepro*-*-* | tilegx*-*-*)
1291     noconfigdirs="$noconfigdirs sim"
1292     ;;
1293   v810-*-*)
1294     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1295     ;;
1296   vax-*-*)
1297     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1298     ;;
1299   wasm32-*-*)
1300     noconfigdirs="$noconfigdirs ld"
1301     ;;
1302   loongarch*-*-linux*)
1303     ;;
1304   loongarch*-*-*)
1305     noconfigdirs="$noconfigdirs gprof"
1306     ;;
1307 esac
1308
1309 # If we aren't building newlib, then don't build libgloss, since libgloss
1310 # depends upon some newlib header files.
1311 case "${noconfigdirs}" in
1312   *target-libgloss*) ;;
1313   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1314 esac
1315
1316 # Work in distributions that contain no compiler tools, like Autoconf.
1317 host_makefile_frag=/dev/null
1318 if test -d ${srcdir}/config ; then
1319 case "${host}" in
1320   i[[3456789]]86-*-msdosdjgpp*)
1321     host_makefile_frag="config/mh-djgpp"
1322     ;;
1323   *-cygwin*)
1324     ACX_CHECK_CYGWIN_CAT_WORKS
1325     host_makefile_frag="config/mh-cygwin"
1326     ;;
1327   *-mingw*)
1328     host_makefile_frag="config/mh-mingw"
1329     ;;
1330   alpha*-linux*)
1331     host_makefile_frag="config/mh-alpha-linux"
1332     ;;
1333   hppa*-hp-hpux*)
1334     host_makefile_frag="config/mh-pa"
1335     ;;
1336   hppa*-*)
1337     host_makefile_frag="config/mh-pa"
1338     ;;
1339   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1340     host_makefile_frag="config/mh-darwin"
1341     ;;
1342   powerpc-*-aix*)
1343     host_makefile_frag="config/mh-ppc-aix"
1344     ;;
1345   rs6000-*-aix*)
1346     host_makefile_frag="config/mh-ppc-aix"
1347     ;;
1348 esac
1349 fi
1350
1351 if test "${build}" != "${host}" ; then
1352   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1353   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1354   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1355   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1356   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1357   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1358   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1359   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1360   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1361   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1362   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1363   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1364   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1365   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1366   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1367 else
1368   AR_FOR_BUILD="\$(AR)"
1369   AS_FOR_BUILD="\$(AS)"
1370   CC_FOR_BUILD="\$(CC)"
1371   CXX_FOR_BUILD="\$(CXX)"
1372   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1373   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1374   GOC_FOR_BUILD="\$(GOC)"
1375   GDC_FOR_BUILD="\$(GDC)"
1376   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1377   LD_FOR_BUILD="\$(LD)"
1378   NM_FOR_BUILD="\$(NM)"
1379   RANLIB_FOR_BUILD="\$(RANLIB)"
1380   WINDRES_FOR_BUILD="\$(WINDRES)"
1381   WINDMC_FOR_BUILD="\$(WINDMC)"
1382 fi
1383
1384 AC_PROG_CC_C99
1385 AC_PROG_CXX
1386
1387 # We must set the default linker to the linker used by gcc for the correct
1388 # operation of libtool.  If LD is not defined and we are using gcc, try to
1389 # set the LD default to the ld used by gcc.
1390 if test -z "$LD"; then
1391   if test "$GCC" = yes; then
1392     case $build in
1393     *-*-mingw*)
1394       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1395     *)
1396       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1397     esac
1398     case $gcc_prog_ld in
1399     # Accept absolute paths.
1400     [[\\/]* | [A-Za-z]:[\\/]*)]
1401       LD="$gcc_prog_ld" ;;
1402     esac
1403   fi
1404 fi
1405
1406 # Check whether -static-libstdc++ -static-libgcc is supported.
1407 have_static_libs=no
1408 if test "$GCC" = yes; then
1409   saved_LDFLAGS="$LDFLAGS"
1410
1411   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1412   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1413   AC_LANG_PUSH(C++)
1414   AC_LINK_IFELSE([AC_LANG_SOURCE([
1415 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1416 #error -static-libstdc++ not implemented
1417 #endif
1418 int main() {}])],
1419     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1420     [AC_MSG_RESULT([no])])
1421   AC_LANG_POP(C++)
1422
1423   LDFLAGS="$saved_LDFLAGS"
1424 fi
1425
1426 ACX_PROG_GNAT
1427 ACX_PROG_GDC
1428 ACX_PROG_CMP_IGNORE_INITIAL
1429
1430 AC_ARG_ENABLE([bootstrap],
1431 [AS_HELP_STRING([--enable-bootstrap],
1432                 [enable bootstrapping @<:@yes if native build@:>@])],,
1433 enable_bootstrap=default)
1434
1435 # Issue errors and warnings for invalid/strange bootstrap combinations.
1436 if test -r $srcdir/gcc/configure; then
1437   have_compiler=yes
1438 else
1439   have_compiler=no
1440 fi
1441
1442 case "$have_compiler:$host:$target:$enable_bootstrap" in
1443   *:*:*:no) ;;
1444
1445   # Default behavior.  Enable bootstrap if we have a compiler
1446   # and we are in a native configuration.
1447   yes:$build:$build:default)
1448     enable_bootstrap=yes ;;
1449
1450   *:*:*:default)
1451     enable_bootstrap=no ;;
1452
1453   # We have a compiler and we are in a native configuration, bootstrap is ok
1454   yes:$build:$build:yes)
1455     ;;
1456
1457   # Other configurations, but we have a compiler.  Assume the user knows
1458   # what he's doing.
1459   yes:*:*:yes)
1460     AC_MSG_WARN([trying to bootstrap a cross compiler])
1461     ;;
1462
1463   # No compiler: if they passed --enable-bootstrap explicitly, fail
1464   no:*:*:yes)
1465     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1466
1467   # Fail if wrong command line
1468   *)
1469     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1470     ;;
1471 esac
1472
1473 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1474 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1475 # require C++11 (or higher).
1476 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1477   CXX="$CXX -std=c++11"
1478 elif test "$have_compiler" = yes; then
1479   AX_CXX_COMPILE_STDCXX(11)
1480
1481   if test "${build}" != "${host}"; then
1482     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1483   fi
1484 fi
1485
1486 AC_ARG_ENABLE([pgo-build],
1487 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1488                 [enable the PGO build])],
1489 [enable_pgo_build=$enableval],
1490 [enable_pgo_build=no])
1491
1492 # Issue errors and warnings for invalid/strange PGO build combinations.
1493 case "$have_compiler:$host:$target:$enable_pgo_build" in
1494   *:*:*:no) ;;
1495
1496   # Allow the PGO build only if we aren't building a compiler and
1497   # we are in a native configuration.
1498   no:$build:$build:yes | no:$build:$build:lto) ;;
1499
1500   # Disallow the PGO bootstrap if we are building a compiler.
1501   yes:*:*:yes | yes:*:*:lto)
1502     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1503
1504   *)
1505     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1506     ;;
1507 esac
1508
1509 if test "$enable_pgo_build" != "no"; then
1510   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1511   old_CFLAGS="$CFLAGS"
1512   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1513   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1514   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1515                     [PGO_BUILD_GEN_CFLAGS=])
1516   CFLAGS="$old_CFLAGS"
1517   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1518     AC_MSG_RESULT([yes])
1519     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1520   else
1521     AC_MSG_RESULT([no])
1522     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1523   fi
1524
1525   if test "$enable_pgo_build" = "lto"; then
1526     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1527     old_CFLAGS="$CFLAGS"
1528     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1529     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1530     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1531                       [PGO_BUILD_LTO_CFLAGS=])
1532     CFLAGS="$old_CFLAGS"
1533     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1534       AC_MSG_RESULT([yes])
1535     else
1536       AC_MSG_RESULT([no])
1537       AC_MSG_WARN([LTO is disabled for the PGO build])
1538     fi
1539   fi
1540 fi
1541 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1542 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1543 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1544
1545 # Used for setting $lt_cv_objdir
1546 _LT_CHECK_OBJDIR
1547
1548 # Check for GMP, MPFR and MPC
1549 require_gmp=no
1550 require_mpc=no
1551 if test -d ${srcdir}/gcc ; then
1552   require_gmp=yes
1553   require_mpc=yes
1554 fi
1555 if test -d ${srcdir}/gdb ; then
1556   if test "x$enable_gdb" != xno; then
1557    require_gmp=yes
1558   fi
1559 fi
1560
1561 gmplibs="-lmpfr -lgmp"
1562 if test x"$require_mpc" = "xyes" ; then
1563   gmplibs="-lmpc $gmplibs"
1564 fi
1565 gmpinc=
1566 have_gmp=no
1567
1568 # Specify a location for mpc
1569 # check for this first so it ends up on the link line before mpfr.
1570 AC_ARG_WITH(mpc,
1571 [AS_HELP_STRING([--with-mpc=PATH],
1572                 [specify prefix directory for installed MPC package.
1573                  Equivalent to --with-mpc-include=PATH/include
1574                  plus --with-mpc-lib=PATH/lib])])
1575 AC_ARG_WITH(mpc-include,
1576 [AS_HELP_STRING([--with-mpc-include=PATH],
1577                 [specify directory for installed MPC include files])])
1578 AC_ARG_WITH(mpc-lib,
1579 [AS_HELP_STRING([--with-mpc-lib=PATH],
1580                 [specify directory for the installed MPC library])])
1581
1582 if test "x$with_mpc" != x; then
1583   gmplibs="-L$with_mpc/lib $gmplibs"
1584   gmpinc="-I$with_mpc/include $gmpinc"
1585 fi
1586 if test "x$with_mpc_include" != x; then
1587   gmpinc="-I$with_mpc_include $gmpinc"
1588 fi
1589 if test "x$with_mpc_lib" != x; then
1590   gmplibs="-L$with_mpc_lib $gmplibs"
1591 fi
1592 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1593   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1594   gmpinc='-I$$s/mpc/src '"$gmpinc"
1595   # Do not test the mpc version.  Assume that it is sufficient, since
1596   # it is in the source tree, and the library has not been built yet
1597   # but it would be included on the link line in the version check below
1598   # hence making the test fail.
1599   have_gmp=yes
1600 fi
1601
1602 # Specify a location for mpfr
1603 # check for this first so it ends up on the link line before gmp.
1604 AC_ARG_WITH(mpfr,
1605 [AS_HELP_STRING([--with-mpfr=PATH],
1606                 [specify prefix directory for installed MPFR package.
1607                  Equivalent to --with-mpfr-include=PATH/include
1608                  plus --with-mpfr-lib=PATH/lib])])
1609 AC_ARG_WITH(mpfr-include,
1610 [AS_HELP_STRING([--with-mpfr-include=PATH],
1611                 [specify directory for installed MPFR include files])])
1612 AC_ARG_WITH(mpfr-lib,
1613 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1614                 [specify directory for the installed MPFR library])])
1615
1616 if test "x$with_mpfr" != x; then
1617   gmplibs="-L$with_mpfr/lib $gmplibs"
1618   gmpinc="-I$with_mpfr/include $gmpinc"
1619 fi
1620 if test "x$with_mpfr_include" != x; then
1621   gmpinc="-I$with_mpfr_include $gmpinc"
1622 fi
1623 if test "x$with_mpfr_lib" != x; then
1624   gmplibs="-L$with_mpfr_lib $gmplibs"
1625 fi
1626 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1627   # MPFR v3.1.0 moved the sources into a src sub-directory.
1628   if ! test -d ${srcdir}/mpfr/src; then
1629     AC_MSG_ERROR([dnl
1630 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1631   fi
1632   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1633   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1634   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1635   # Do not test the mpfr version.  Assume that it is sufficient, since
1636   # it is in the source tree, and the library has not been built yet
1637   # but it would be included on the link line in the version check below
1638   # hence making the test fail.
1639   have_gmp=yes
1640 fi
1641
1642 # Specify a location for gmp
1643 AC_ARG_WITH(gmp,
1644 [AS_HELP_STRING([--with-gmp=PATH],
1645                 [specify prefix directory for the installed GMP package.
1646                  Equivalent to --with-gmp-include=PATH/include
1647                  plus --with-gmp-lib=PATH/lib])])
1648 AC_ARG_WITH(gmp-include,
1649 [AS_HELP_STRING([--with-gmp-include=PATH],
1650                 [specify directory for installed GMP include files])])
1651 AC_ARG_WITH(gmp-lib,
1652 [AS_HELP_STRING([--with-gmp-lib=PATH],
1653                 [specify directory for the installed GMP library])])
1654
1655
1656 if test "x$with_gmp" != x; then
1657   gmplibs="-L$with_gmp/lib $gmplibs"
1658   gmpinc="-I$with_gmp/include $gmpinc"
1659 fi
1660 if test "x$with_gmp_include" != x; then
1661   gmpinc="-I$with_gmp_include $gmpinc"
1662 fi
1663 if test "x$with_gmp_lib" != x; then
1664   gmplibs="-L$with_gmp_lib $gmplibs"
1665 fi
1666 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1667   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1668   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1669   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1670   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1671   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1672   # Do not test the gmp version.  Assume that it is sufficient, since
1673   # it is in the source tree, and the library has not been built yet
1674   # but it would be included on the link line in the version check below
1675   # hence making the test fail.
1676   have_gmp=yes
1677 fi
1678
1679 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1680   have_gmp=yes
1681   saved_CFLAGS="$CFLAGS"
1682   CFLAGS="$CFLAGS $gmpinc"
1683   # Check for the recommended and required versions of GMP.
1684   AC_MSG_CHECKING([for the correct version of gmp.h])
1685   AC_TRY_COMPILE([#include "gmp.h"],[
1686   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1687   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1688   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1689   choke me
1690   #endif
1691   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1692   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1693   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1694   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1695   choke me
1696   #endif
1697   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1698    [AC_MSG_RESULT([no]); have_gmp=no])
1699
1700   # If we have GMP, check the MPFR version.
1701   if test x"$have_gmp" = xyes; then
1702     # Check for the recommended and required versions of MPFR.
1703     AC_MSG_CHECKING([for the correct version of mpfr.h])
1704     AC_TRY_COMPILE([#include <gmp.h>
1705     #include <mpfr.h>],[
1706     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1707     choke me
1708     #endif
1709     ], [AC_TRY_COMPILE([#include <gmp.h>
1710     #include <mpfr.h>],[
1711     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1712     choke me
1713     #endif
1714     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1715      [AC_MSG_RESULT([no]); have_gmp=no])
1716   fi
1717
1718   # Check for the MPC header version.
1719   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1720     # Check for the recommended and required versions of MPC.
1721     AC_MSG_CHECKING([for the correct version of mpc.h])
1722     AC_TRY_COMPILE([#include <mpc.h>],[
1723     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1724     choke me
1725     #endif
1726     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1727     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1728     choke me
1729     #endif
1730     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1731      [AC_MSG_RESULT([no]); have_gmp=no])
1732   fi
1733
1734   # Now check the MPFR library.
1735   if test x"$have_gmp" = xyes; then
1736     saved_LIBS="$LIBS"
1737     LIBS="$LIBS $gmplibs"
1738     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1739     AC_TRY_LINK([#include <mpfr.h>],[
1740     mpfr_t n;
1741     mpfr_t x;
1742     int t;
1743     mpfr_init (n);
1744     mpfr_init (x);
1745     mpfr_atan2 (n, n, x, MPFR_RNDN);
1746     mpfr_erfc (n, x, MPFR_RNDN);
1747     mpfr_subnormalize (x, t, MPFR_RNDN);
1748     mpfr_clear(n);
1749     mpfr_clear(x);
1750     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1751     LIBS="$saved_LIBS"
1752   fi
1753
1754   # Now check the MPC library
1755   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1756     saved_LIBS="$LIBS"
1757     LIBS="$LIBS $gmplibs"
1758     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1759     AC_TRY_LINK([#include <mpc.h>],[
1760     mpc_t c;
1761     mpc_init2 (c, 53);
1762     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1763     mpc_cosh (c, c, MPC_RNDNN);
1764     mpc_pow (c, c, c, MPC_RNDNN);
1765     mpc_acosh (c, c, MPC_RNDNN);
1766     mpc_clear (c);
1767     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1768     LIBS="$saved_LIBS"
1769   fi
1770
1771   CFLAGS="$saved_CFLAGS"
1772
1773 # The library versions listed in the error message below should match
1774 # the HARD-minimums enforced above.
1775   if test x$have_gmp != xyes; then
1776     if test -d ${srcdir}/gcc ; then
1777       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1778 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1779 their locations.  Source code for these libraries can be found at
1780 their respective hosting sites as well as at
1781 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1782 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1783 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1784 make sure that you have installed both the libraries and the header
1785 files.  They may be located in separate packages.])
1786     else
1787       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1788 Try the --with-gmp and/or --with-mpfr options to specify
1789 their locations.  If you obtained GMP and/or MPFR from a vendor
1790 distribution package, make sure that you have installed both the libraries
1791 and the header files.  They may be located in separate packages.])
1792     fi
1793   fi
1794 fi
1795
1796 # Flags needed for both GMP, MPFR and/or MPC.
1797 AC_SUBST(gmplibs)
1798 AC_SUBST(gmpinc)
1799 AC_SUBST(extra_mpfr_configure_flags)
1800 AC_SUBST(extra_mpc_gmp_configure_flags)
1801 AC_SUBST(extra_mpc_mpfr_configure_flags)
1802 AC_SUBST(extra_isl_gmp_configure_flags)
1803
1804 # Libraries to use for stage1 or when not bootstrapping.
1805 AC_ARG_WITH(stage1-libs,
1806 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1807 [if test "$withval" = "no" -o "$withval" = "yes"; then
1808    stage1_libs=
1809  else
1810    stage1_libs=$withval
1811  fi],
1812 [stage1_libs=])
1813 AC_SUBST(stage1_libs)
1814
1815 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1816 # default is yes if gcc is being built; no otherwise.  The reason for
1817 # this default is that gdb is sometimes linked against GNU Source
1818 # Highlight, which is a shared library that uses C++ exceptions.  In
1819 # this case, -static-libstdc++ will cause crashes.
1820 AC_ARG_WITH(static-standard-libraries,
1821 [AS_HELP_STRING([--with-static-standard-libraries],
1822                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1823 [], [with_static_standard_libraries=auto])
1824 if test "$with_static_standard_libraries" = auto; then
1825   with_static_standard_libraries=$have_compiler
1826 fi
1827
1828 # Linker flags to use for stage1 or when not bootstrapping.
1829 AC_ARG_WITH(stage1-ldflags,
1830 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1831 [if test "$withval" = "no" -o "$withval" = "yes"; then
1832    stage1_ldflags=
1833  else
1834    stage1_ldflags=$withval
1835  fi],
1836 [stage1_ldflags=
1837  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1838  # if supported.  But if the user explicitly specified the libraries to use,
1839  # trust that they are doing what they want.
1840  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1841      -a "$have_static_libs" = yes; then
1842    stage1_ldflags="-static-libstdc++ -static-libgcc"
1843  fi])
1844 AC_SUBST(stage1_ldflags)
1845
1846 # Libraries to use for stage2 and later builds.
1847 AC_ARG_WITH(boot-libs,
1848 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1849 [if test "$withval" = "no" -o "$withval" = "yes"; then
1850    poststage1_libs=
1851  else
1852    poststage1_libs=$withval
1853  fi],
1854 [poststage1_libs=])
1855 AC_SUBST(poststage1_libs)
1856
1857 # Linker flags to use for stage2 and later builds.
1858 AC_ARG_WITH(boot-ldflags,
1859 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1860                 [linker flags for stage2 and later])],
1861 [if test "$withval" = "no" -o "$withval" = "yes"; then
1862    poststage1_ldflags=
1863  else
1864    poststage1_ldflags=$withval
1865  fi],
1866 [poststage1_ldflags=
1867  # In stages 2 and 3, default to linking libstdc++ and libgcc
1868  # statically.  But if the user explicitly specified the libraries to
1869  # use, trust that they are doing what they want.
1870  if test "$poststage1_libs" = ""; then
1871    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1872  fi])
1873 case $target in
1874   *-darwin2* | *-darwin1[[56789]]*)
1875     # For these versions, we default to using embedded rpaths.
1876     if test "x$enable_darwin_at_rpath" != "xno"; then
1877       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1878     fi
1879   ;;
1880   *-darwin*)
1881     # For these versions, we only use embedded rpaths on demand.
1882     if test "x$enable_darwin_at_rpath" = "xyes"; then
1883       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1884     fi
1885   ;;
1886 esac
1887 AC_SUBST(poststage1_ldflags)
1888
1889 # GCC GRAPHITE dependency isl.
1890 # Basic setup is inlined here, actual checks are in config/isl.m4
1891
1892 AC_ARG_WITH(isl,
1893   [AS_HELP_STRING(
1894    [--with-isl=PATH],
1895    [Specify prefix directory for the installed isl package.
1896     Equivalent to --with-isl-include=PATH/include
1897     plus --with-isl-lib=PATH/lib])])
1898
1899 # Treat --without-isl as a request to disable
1900 # GRAPHITE support and skip all following checks.
1901 if test "x$with_isl" != "xno"; then
1902   # Check for isl
1903   dnl Provide configure switches and initialize islinc & isllibs
1904   dnl with user input.
1905   ISL_INIT_FLAGS
1906   dnl The versions of isl that work for Graphite
1907   ISL_CHECK_VERSION()
1908   dnl Only execute fail-action, if isl has been requested.
1909   ISL_IF_FAILED([
1910     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1911 fi
1912
1913 # If the isl check failed, disable builds of in-tree variant of isl
1914 if test "x$with_isl" = xno ||
1915    test "x$gcc_cv_isl" = xno; then
1916   noconfigdirs="$noconfigdirs isl"
1917   islinc=
1918 fi
1919
1920 AC_SUBST(isllibs)
1921 AC_SUBST(islinc)
1922
1923 # Check for LTO support.
1924 AC_ARG_ENABLE(lto,
1925 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1926 enable_lto=$enableval,
1927 enable_lto=yes; default_enable_lto=yes)
1928
1929 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1930   build_lto_plugin=yes
1931 ],[if test x"$default_enable_lto" = x"yes" ; then
1932     case $target in
1933       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1934       # On other non-ELF platforms, LTO has yet to be validated.
1935       *) enable_lto=no ;;
1936     esac
1937   else
1938   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1939   # It would also be nice to check the binutils support, but we don't
1940   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1941   # warn during gcc/ subconfigure; unless you're bootstrapping with
1942   # -flto it won't be needed until after installation anyway.
1943     case $target in
1944       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1945       *) if test x"$enable_lto" = x"yes"; then
1946         AC_MSG_ERROR([LTO support is not enabled for this target.])
1947         fi
1948       ;;
1949     esac
1950   fi
1951   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1952   # Build it unless LTO was explicitly disabled.
1953   case $target in
1954     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1955     *) ;;
1956   esac
1957 ])
1958
1959 AC_ARG_ENABLE(linker-plugin-configure-flags,
1960   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1961     [additional flags for configuring linker plugins @<:@none@:>@])],
1962   extra_linker_plugin_configure_flags=$enableval,
1963   extra_linker_plugin_configure_flags=)
1964 AC_SUBST(extra_linker_plugin_configure_flags)
1965 AC_ARG_ENABLE(linker-plugin-flags,
1966   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1967     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1968   extra_linker_plugin_flags=$enableval,
1969   extra_linker_plugin_flags=)
1970 AC_SUBST(extra_linker_plugin_flags)
1971
1972 # Handle --enable-host-pie
1973 # If host PIE executables are the default (or must be forced on) for some host,
1974 # we must pass that configuration to the gcc directory.
1975 gcc_host_pie=
1976 AC_ARG_ENABLE(host-pie,
1977 [AS_HELP_STRING([--enable-host-pie],
1978                 [build position independent host executables])],
1979 [host_pie=$enableval
1980  case $host in
1981    *-*-darwin2*)
1982      if test x$host_pie != xyes ; then
1983        # for Darwin20+ this is required.
1984        AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
1985        host_pie=yes
1986        gcc_host_pie=--enable-host-pie
1987      fi ;;
1988   *) ;;
1989  esac],
1990 [case $host in
1991   *-*-darwin2*)
1992     # Default to PIE (mandatory for aarch64).
1993     host_pie=yes
1994     gcc_host_pie=--enable-host-pie
1995     ;;
1996   *) host_pie=no ;;
1997  esac])
1998
1999 AC_SUBST(host_pie)
2000 AC_SUBST(gcc_host_pie)
2001
2002 # Enable --enable-host-shared.
2003 # Checked early to determine whether jit is an 'all' language
2004 AC_ARG_ENABLE(host-shared,
2005 [AS_HELP_STRING([--enable-host-shared],
2006                 [build host code as shared libraries])],
2007 [host_shared=$enableval
2008  case $host in
2009    x86_64-*-darwin* | aarch64-*-darwin*)
2010      if test x$host_shared != xyes ; then
2011        # PIC is the default, and actually cannot be switched off.
2012        AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
2013        host_shared=yes
2014      fi ;;
2015    *-*-darwin*)
2016      if test x$host_pie = xyes -a x$host_shared != xyes ; then
2017        AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
2018        host_shared=yes
2019      fi ;;
2020   *) ;;
2021  esac],
2022 [case $host in
2023   # 64B x86_64 and Aarch64 Darwin default to PIC.
2024   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2025   # 32B and powerpc64 Darwin must use PIC to link PIE exes.
2026   *-*-darwin*) host_shared=$host_pie ;;
2027   *) host_shared=no;;
2028  esac])
2029
2030 AC_SUBST(host_shared)
2031
2032 if test x$host_shared = xyes; then
2033   case $host in
2034     *-*-darwin*)
2035       # Since host shared is the default for 64b Darwin, and also enabled for
2036       # host_pie, ensure that we present the PIE flag when host_pie is active.
2037       if test x$host_pie = xyes; then
2038         PICFLAG=-fPIE
2039       fi
2040       ;;
2041     *)
2042       PICFLAG=-fPIC
2043       ;;
2044   esac
2045 elif test x$host_pie = xyes; then
2046   PICFLAG=-fPIE
2047 else
2048   PICFLAG=
2049 fi
2050
2051 AC_SUBST(PICFLAG)
2052
2053 # If we are building PIC/PIE host executables, and we are building dependent
2054 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2055 # code.
2056 host_libs_picflag=
2057 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2058 host_libs_picflag='--with-pic'
2059 fi
2060 AC_SUBST(host_libs_picflag)
2061
2062 # By default, C and C++ are the only stage 1 languages.
2063 stage1_languages=,c,
2064
2065 # Target libraries that we bootstrap.
2066 bootstrap_target_libs=,target-libgcc,
2067
2068 # Figure out what language subdirectories are present.
2069 # Look if the user specified --enable-languages="..."; if not, use
2070 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2071 # go away some day.
2072 # NB:  embedded tabs in this IF block -- do not untabify
2073 if test -d ${srcdir}/gcc; then
2074   if test x"${enable_languages+set}" != xset; then
2075     if test x"${LANGUAGES+set}" = xset; then
2076       enable_languages="${LANGUAGES}"
2077         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2078     else
2079       enable_languages=default
2080     fi
2081   else
2082     if test x"${enable_languages}" = x ||
2083        test x"${enable_languages}" = xyes;
2084        then
2085       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2086       exit 1
2087     fi
2088   fi
2089   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2090
2091   # 'f95' is the old name for the 'fortran' language. We issue a warning
2092   # and make the substitution.
2093   case ,${enable_languages}, in
2094     *,f95,*)
2095       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2096       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2097       ;;
2098   esac
2099
2100   # If bootstrapping, C++ must be enabled.
2101   case ",$enable_languages,:$enable_bootstrap" in
2102     *,c++,*:*) ;;
2103     *:yes)
2104       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2105         enable_languages="${enable_languages},c++"
2106       else
2107         AC_MSG_ERROR([bootstrapping requires c++ sources])
2108       fi
2109       ;;
2110   esac
2111
2112   # First scan to see if an enabled language requires some other language.
2113   # We assume that a given config-lang.in will list all the language
2114   # front ends it requires, even if some are required indirectly.
2115   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2116     case ${lang_frag} in
2117       ..) ;;
2118       # The odd quoting in the next line works around
2119       # an apparent bug in bash 1.12 on linux.
2120       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2121       *)
2122         # From the config-lang.in, get $language, $lang_requires, and
2123         # $lang_requires_boot_languages.
2124         language=
2125         lang_requires=
2126         lang_requires_boot_languages=
2127         # set srcdir during sourcing lang_frag to the gcc dir.
2128         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2129         # polutes this shell
2130         saved_srcdir=${srcdir}
2131         srcdir=${srcdir}/gcc . ${lang_frag}
2132         srcdir=${saved_srcdir}
2133         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2134           case ,${enable_languages}, in
2135             *,$other,*) ;;
2136             *,default,*) ;;
2137             *,all,*) ;;
2138             *,$language,*)
2139               echo " \`$other' language required by \`$language'; enabling" 1>&2
2140               enable_languages="${enable_languages},${other}"
2141               ;;
2142           esac
2143         done
2144         for other in ${lang_requires_boot_languages} ; do
2145           if test "$other" != "c"; then
2146             case ,${enable_stage1_languages}, in
2147               *,$other,*) ;;
2148               *,default,*) ;;
2149               *,all,*) ;;
2150               *)
2151                 case ,${enable_languages}, in
2152                   *,$language,*)
2153                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2154                     enable_stage1_languages="$enable_stage1_languages,${other}"
2155                     ;;
2156                 esac
2157                 ;;
2158             esac
2159           fi
2160         done
2161         ;;
2162     esac
2163   done
2164
2165   new_enable_languages=,c,
2166
2167   # If LTO is enabled, add the LTO front end.
2168   if test "$enable_lto" = "yes" ; then
2169     case ,${enable_languages}, in
2170       *,lto,*) ;;
2171       *) enable_languages="${enable_languages},lto" ;;
2172     esac
2173     if test "${build_lto_plugin}" = "yes" ; then
2174       configdirs="$configdirs lto-plugin"
2175     fi
2176   fi
2177
2178   # If we're building an offloading compiler, add the LTO front end.
2179   if test x"$enable_as_accelerator_for" != x ; then
2180     case ,${enable_languages}, in
2181       *,lto,*) ;;
2182       *) enable_languages="${enable_languages},lto" ;;
2183     esac
2184   fi
2185
2186   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2187   potential_languages=,c,
2188
2189   enabled_target_libs=
2190   disabled_target_libs=
2191
2192   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2193     case ${lang_frag} in
2194       ..) ;;
2195       # The odd quoting in the next line works around
2196       # an apparent bug in bash 1.12 on linux.
2197       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2198       *)
2199         # From the config-lang.in, get $language, $target_libs,
2200         # $lang_dirs, $boot_language, and $build_by_default
2201         language=
2202         target_libs=
2203         lang_dirs=
2204         subdir_requires=
2205         boot_language=no
2206         build_by_default=yes
2207         # set srcdir during sourcing.  See above about save & restore
2208         saved_srcdir=${srcdir}
2209         srcdir=${srcdir}/gcc . ${lang_frag}
2210         srcdir=${saved_srcdir}
2211         if test x${language} = x; then
2212           echo "${lang_frag} doesn't set \$language." 1>&2
2213           exit 1
2214         fi
2215
2216         if test "$language" = "c++"; then
2217           boot_language=yes
2218         fi
2219
2220         add_this_lang=no
2221         # C is always enabled, so no need to add it again
2222         if test "$language" != "c"; then
2223           case ,${enable_languages}, in
2224             *,${language},*)
2225               # Language was explicitly selected; include it
2226               add_this_lang=yes
2227               ;;
2228             *,all,*)
2229               # All languages are enabled
2230               add_this_lang=all
2231               ;;
2232             *,default,*)
2233               # 'default' was selected, select it if it is a default language
2234               add_this_lang=${build_by_default}
2235               ;;
2236           esac
2237         fi
2238
2239         # Disable languages that need other directories if these aren't available.
2240         for i in $subdir_requires; do
2241           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2242           case ${add_this_lang} in
2243             yes)
2244               # Specifically requested language; tell them.
2245               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2246               ;;
2247             all)
2248               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2249               add_this_lang=unsupported
2250               ;;
2251             *)
2252               # Silently disable.
2253               add_this_lang=unsupported
2254               ;;
2255           esac
2256         done
2257
2258         # Disable Ada if no preexisting GNAT is available.
2259         case ${add_this_lang}:${language}:${have_gnat} in
2260           yes:ada:no)
2261             # Specifically requested language; tell them.
2262             AC_MSG_ERROR([GNAT is required to build $language])
2263             ;;
2264           all:ada:no)
2265             AC_MSG_WARN([GNAT is required to build $language])
2266             add_this_lang=unsupported
2267             ;;
2268           *:ada:no)
2269             # Silently disable.
2270             add_this_lang=unsupported
2271             ;;
2272         esac
2273
2274         # Disable D if no preexisting GDC is available.
2275         case ${add_this_lang}:${language}:${have_gdc} in
2276           yes:d:no)
2277             # Specifically requested language; tell them.
2278             AC_MSG_ERROR([GDC is required to build $language])
2279            ;;
2280           all:d:no)
2281             AC_MSG_WARN([GDC is required to build $language])
2282             add_this_lang=unsupported
2283             ;;
2284           *:d:no)
2285             # Silently disable.
2286             add_this_lang=unsupported
2287             ;;
2288         esac
2289
2290         # Disable jit if -enable-host-shared not specified
2291         # but not if building for Mingw. All code in Windows
2292         # is position independent code (PIC).
2293         case $target in
2294           *mingw*) ;;
2295           *)
2296           case ${add_this_lang}:${language}:${host_shared} in
2297             yes:jit:no)
2298                    # PR jit/64780: explicitly specify --enable-host-shared
2299             AC_MSG_ERROR([
2300 Enabling language "jit" requires --enable-host-shared.
2301
2302 --enable-host-shared typically slows the rest of the compiler down by
2303 a few %, so you must explicitly enable it.
2304
2305 If you want to build both the jit and the regular compiler, it is often
2306 best to do this via two separate configure/builds, in separate
2307 directories, to avoid imposing the performance cost of
2308 --enable-host-shared on the regular compiler.])
2309                     ;;
2310             all:jit:no)
2311               AC_MSG_WARN([--enable-host-shared required to build $language])
2312               add_this_lang=unsupported
2313               ;;
2314             *:jit:no)
2315               # Silently disable.
2316               add_this_lang=unsupported
2317               ;;
2318                 esac
2319           ;;
2320         esac
2321
2322         # Disable a language that is unsupported by the target.
2323         case "${add_this_lang}: $unsupported_languages " in
2324           no:*) ;;
2325           unsupported:*) ;;
2326           *:*" $language "*)
2327             AC_MSG_WARN([${language} not supported for this target])
2328             add_this_lang=unsupported
2329             ;;
2330         esac
2331
2332         case $add_this_lang in
2333           unsupported)
2334             # Remove language-dependent dirs.
2335             disabled_target_libs="$disabled_target_libs $target_libs"
2336             noconfigdirs="$noconfigdirs $lang_dirs"
2337             ;;
2338           no)
2339             # Remove language-dependent dirs; still show language as supported.
2340             disabled_target_libs="$disabled_target_libs $target_libs"
2341             noconfigdirs="$noconfigdirs $lang_dirs"
2342             potential_languages="${potential_languages}${language},"
2343             ;;
2344           all|yes)
2345             new_enable_languages="${new_enable_languages}${language},"
2346             potential_languages="${potential_languages}${language},"
2347             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2348             enabled_target_libs="$enabled_target_libs $target_libs"
2349             case "${boot_language}:,$enable_stage1_languages," in
2350               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2351                 # Add to (comma-separated) list of stage 1 languages.
2352                 case ",$stage1_languages," in
2353                   *,$language,* | ,yes, | ,all,) ;;
2354                   *) stage1_languages="${stage1_languages}${language}," ;;
2355                 esac
2356                 # We need to bootstrap any supporting libraries.
2357                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2358                 ;;
2359             esac
2360             ;;
2361         esac
2362         ;;
2363     esac
2364   done
2365
2366   # Add target libraries which are only needed for disabled languages
2367   # to noconfigdirs.
2368   if test -n "$disabled_target_libs"; then
2369     for dir in $disabled_target_libs; do
2370       case " $enabled_target_libs " in
2371       *" ${dir} "*) ;;
2372       *) noconfigdirs="$noconfigdirs $dir" ;;
2373       esac
2374     done
2375   fi
2376
2377   AC_ARG_ENABLE(stage1-languages,
2378   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2379                   [choose additional languages to build during
2380                   stage1.  Mostly useful for compiler development])],
2381   [case ,${enable_stage1_languages}, in
2382     ,no,|,,)
2383       # Set it to something that will have no effect in the loop below
2384       enable_stage1_languages=c ;;
2385     ,yes,)
2386       enable_stage1_languages=`echo $new_enable_languages | \
2387         sed -e "s/^,//" -e "s/,$//" ` ;;
2388     *,all,*)
2389       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2390         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2391   esac
2392
2393   # Add "good" languages from enable_stage1_languages to stage1_languages,
2394   # while "bad" languages go in missing_languages.  Leave no duplicates.
2395   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2396     case $potential_languages in
2397       *,$i,*)
2398         case $stage1_languages in
2399           *,$i,*) ;;
2400           *) stage1_languages="$stage1_languages$i," ;;
2401         esac ;;
2402       *)
2403         case $missing_languages in
2404           *,$i,*) ;;
2405           *) missing_languages="$missing_languages$i," ;;
2406         esac ;;
2407      esac
2408   done])
2409
2410   # Remove leading/trailing commas that were added for simplicity
2411   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2412   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2413   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2414   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2415
2416   if test "x$missing_languages" != x; then
2417     AC_MSG_ERROR([
2418 The following requested languages could not be built: ${missing_languages}
2419 Supported languages are: ${potential_languages}])
2420   fi
2421   if test "x$new_enable_languages" != "x$enable_languages"; then
2422     echo The following languages will be built: ${new_enable_languages}
2423     enable_languages="$new_enable_languages"
2424   fi
2425
2426   AC_SUBST(stage1_languages)
2427   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2428 fi
2429
2430 # Handle --disable-<component> generically.
2431 for dir in $configdirs $build_configdirs $target_configdirs ; do
2432   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2433   varname=`echo $dirname | sed -e s/+/_/g`
2434   if eval test x\${enable_${varname}} "=" xno ; then
2435     noconfigdirs="$noconfigdirs $dir"
2436   fi
2437 done
2438
2439 # Check for Boehm's garbage collector
2440 AC_ARG_ENABLE(objc-gc,
2441 [AS_HELP_STRING([--enable-objc-gc],
2442                 [enable use of Boehm's garbage collector with the
2443                  GNU Objective-C runtime])])
2444 AC_ARG_WITH([target-bdw-gc],
2445 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2446                 [specify prefix directory for installed bdw-gc package.
2447                  Equivalent to --with-target-bdw-gc-include=PATH/include
2448                  plus --with-target-bdw-gc-lib=PATH/lib])])
2449 AC_ARG_WITH([target-bdw-gc-include],
2450 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2451                 [specify directories for installed bdw-gc include files])])
2452 AC_ARG_WITH([target-bdw-gc-lib],
2453 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2454                 [specify directories for installed bdw-gc library])])
2455
2456 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2457   AC_MSG_CHECKING([for bdw garbage collector])
2458   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2459     dnl no bdw-gw options, assume default locations
2460     AC_MSG_RESULT([using bdw-gc in default locations])
2461   else
2462     dnl bdw-gw options, first error checking, complete checking in libobjc
2463     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2464       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2465     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2466       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2467     else
2468       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2469     fi
2470   fi
2471 esac
2472
2473 # Disable libitm, libsanitizer, libvtv if we're not building C++
2474 case ,${enable_languages}, in
2475   *,c++,*)
2476     # Disable libitm, libsanitizer if we're not building libstdc++
2477     case "${noconfigdirs}" in
2478       *target-libstdc++-v3*)
2479         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2480         ;;
2481       *) ;;
2482     esac
2483     ;;
2484   *)
2485     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2486     ;;
2487 esac
2488
2489 case ,${enable_languages}, in
2490   *,rust,*)
2491     case " ${noconfigdirs} " in
2492       *\ target-libstdc++-v3\ *)
2493         # Disable target libgrust if we're not building target libstdc++.
2494         noconfigdirs="$noconfigdirs target-libgrust"
2495         ;;
2496     esac
2497     ;;
2498 esac
2499
2500 # If gcc/ is not in the source tree then we'll not be building a
2501 # target compiler, assume in that case we don't want to build any
2502 # target libraries or tools.
2503 #
2504 # This was added primarily for the benefit for binutils-gdb who reuse
2505 # this configure script, but don't always have target tools available.
2506 if test ! -d ${srcdir}/gcc; then
2507    skipdirs="${skipdirs} ${target_configdirs}"
2508 fi
2509
2510 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2511 # $build_configdirs and $target_configdirs.
2512 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2513
2514 notsupp=""
2515 for dir in . $skipdirs $noconfigdirs ; do
2516   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2517   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2518     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2519     if test -r $srcdir/$dirname/configure ; then
2520       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2521         true
2522       else
2523         notsupp="$notsupp $dir"
2524       fi
2525     fi
2526   fi
2527   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2528     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2529     if test -r $srcdir/$dirname/configure ; then
2530       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2531         true
2532       else
2533         notsupp="$notsupp $dir"
2534       fi
2535     fi
2536   fi
2537   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2538     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2539     if test -r $srcdir/$dirname/configure ; then
2540       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2541         true
2542       else
2543         notsupp="$notsupp $dir"
2544       fi
2545     fi
2546   fi
2547 done
2548
2549 # Quietly strip out all directories which aren't configurable in this tree.
2550 # This relies on all configurable subdirectories being autoconfiscated, which
2551 # is now the case.
2552 build_configdirs_all="$build_configdirs"
2553 build_configdirs=
2554 for i in ${build_configdirs_all} ; do
2555   j=`echo $i | sed -e s/build-//g`
2556   if test -f ${srcdir}/$j/configure ; then
2557     build_configdirs="${build_configdirs} $i"
2558   fi
2559 done
2560
2561 configdirs_all="$configdirs"
2562 configdirs=
2563 for i in ${configdirs_all} ; do
2564   if test -f ${srcdir}/$i/configure ; then
2565     configdirs="${configdirs} $i"
2566   fi
2567 done
2568
2569 target_configdirs_all="$target_configdirs"
2570 target_configdirs=
2571 for i in ${target_configdirs_all} ; do
2572   j=`echo $i | sed -e s/target-//g`
2573   if test -f ${srcdir}/$j/configure ; then
2574     target_configdirs="${target_configdirs} $i"
2575   fi
2576 done
2577
2578 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2579 # so we have to add it after the preceding checks.
2580 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2581 then
2582   case " $configdirs " in
2583     *" libiberty "*)
2584       # If we can build libiberty, we can also build libiberty-linker-plugin.
2585       configdirs="$configdirs libiberty-linker-plugin"
2586       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2587         --with-libiberty=../libiberty-linker-plugin";;
2588     *)
2589       AC_MSG_ERROR([libiberty missing]);;
2590   esac
2591 fi
2592
2593 # Sometimes we have special requirements for the host libiberty.
2594 extra_host_libiberty_configure_flags=
2595 case " $configdirs " in
2596   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2597     # When these are to be built as shared libraries, the same applies to
2598     # libiberty.
2599     extra_host_libiberty_configure_flags=--enable-shared
2600     ;;
2601 esac
2602 AC_SUBST(extra_host_libiberty_configure_flags)
2603
2604 # Sometimes we have special requirements for the host zlib.
2605 extra_host_zlib_configure_flags=
2606 case " $configdirs " in
2607   *" bfd "*)
2608     # When bfd is to be built as a shared library, the same applies to
2609     # zlib.
2610     if test "$enable_shared" = "yes"; then
2611       extra_host_zlib_configure_flags=--enable-host-shared
2612     fi
2613     ;;
2614 esac
2615 AC_SUBST(extra_host_zlib_configure_flags)
2616
2617 # Produce a warning message for the subdirs we can't configure.
2618 # This isn't especially interesting in the Cygnus tree, but in the individual
2619 # FSF releases, it's important to let people know when their machine isn't
2620 # supported by the one or two programs in a package.
2621
2622 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2623   # If $appdirs is non-empty, at least one of those directories must still
2624   # be configured, or we error out.  (E.g., if the gas release supports a
2625   # specified target in some subdirs but not the gas subdir, we shouldn't
2626   # pretend that all is well.)
2627   if test -n "$appdirs" ; then
2628     for dir in $appdirs ; do
2629       if test -r $dir/Makefile.in ; then
2630         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2631           appdirs=""
2632           break
2633         fi
2634         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2635           appdirs=""
2636           break
2637         fi
2638       fi
2639     done
2640     if test -n "$appdirs" ; then
2641       echo "*** This configuration is not supported by this package." 1>&2
2642       exit 1
2643     fi
2644   fi
2645   # Okay, some application will build, or we don't care to check.  Still
2646   # notify of subdirs not getting built.
2647   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2648   echo "    ${notsupp}" 1>&2
2649   echo "    (Any other directories should still work fine.)" 1>&2
2650 fi
2651
2652 case "$host" in
2653   *msdosdjgpp*)
2654     enable_gdbtk=no ;;
2655 esac
2656
2657 # To find our prefix, in gcc_cv_tool_prefix.
2658 ACX_TOOL_DIRS
2659
2660 copy_dirs=
2661
2662 AC_ARG_WITH([build-sysroot],
2663   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2664                   [use sysroot as the system root during the build])],
2665   [if test x"$withval" != x ; then
2666      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2667    fi],
2668   [SYSROOT_CFLAGS_FOR_TARGET=])
2669 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2670
2671 AC_ARG_WITH([debug-prefix-map],
2672   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2673                   [map A to B, C to D ... in debug information])],
2674   [if test x"$withval" != x; then
2675      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2676      for debug_map in $withval; do
2677        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2678      done
2679    fi],
2680   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2681 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2682
2683 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2684 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2685 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2686 # We want to ensure that TARGET libraries (which we know are built with
2687 # gcc) are built with "-O2 -g", so include those options when setting
2688 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2689 if test "x$CFLAGS_FOR_TARGET" = x; then
2690   if test "x${is_cross_compiler}" = xyes; then
2691     CFLAGS_FOR_TARGET="-g -O2"
2692   else
2693     CFLAGS_FOR_TARGET=$CFLAGS
2694     case " $CFLAGS " in
2695       *" -O2 "*) ;;
2696       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2697     esac
2698     case " $CFLAGS " in
2699       *" -g "* | *" -g3 "*) ;;
2700       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2701     esac
2702   fi
2703 fi
2704 AC_SUBST(CFLAGS_FOR_TARGET)
2705
2706 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2707   if test "x${is_cross_compiler}" = xyes; then
2708     CXXFLAGS_FOR_TARGET="-g -O2"
2709   else
2710     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2711     case " $CXXFLAGS " in
2712       *" -O2 "*) ;;
2713       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2714     esac
2715     case " $CXXFLAGS " in
2716       *" -g "* | *" -g3 "*) ;;
2717       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2718     esac
2719   fi
2720 fi
2721 AC_SUBST(CXXFLAGS_FOR_TARGET)
2722
2723 AC_SUBST(LDFLAGS_FOR_TARGET)
2724
2725 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2726 # the named directory are copied to $(tooldir)/sys-include.
2727 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2728   if test x${is_cross_compiler} = xno ; then
2729     echo 1>&2 '***' --with-headers is only supported when cross compiling
2730     exit 1
2731   fi
2732   if test x"${with_headers}" != xyes ; then
2733     x=${gcc_cv_tool_prefix}
2734     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2735   fi
2736 fi
2737
2738 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2739 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2740 # are permitted.
2741 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2742   if test x${is_cross_compiler} = xno ; then
2743     echo 1>&2 '***' --with-libs is only supported when cross compiling
2744     exit 1
2745   fi
2746   if test x"${with_libs}" != xyes ; then
2747     # Copy the libraries in reverse order, so that files in the first named
2748     # library override files in subsequent libraries.
2749     x=${gcc_cv_tool_prefix}
2750     for l in ${with_libs}; do
2751       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2752     done
2753   fi
2754 fi
2755
2756 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2757 #
2758 # This is done by determining whether or not the appropriate directory
2759 # is available, and by checking whether or not specific configurations
2760 # have requested that this magic not happen.
2761 #
2762 # The command line options always override the explicit settings in
2763 # configure.ac, and the settings in configure.ac override this magic.
2764 #
2765 # If the default for a toolchain is to use GNU as and ld, and you don't
2766 # want to do that, then you should use the --without-gnu-as and
2767 # --without-gnu-ld options for the configure script.  Similarly, if
2768 # the default is to use the included zlib and you don't want to do that,
2769 # you should use the --with-system-zlib option for the configure script.
2770
2771 if test x${use_gnu_as} = x &&
2772    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2773   with_gnu_as=yes
2774   extra_host_args="$extra_host_args --with-gnu-as"
2775 fi
2776
2777 if test x${use_gnu_ld} = x &&
2778    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2779   with_gnu_ld=yes
2780   extra_host_args="$extra_host_args --with-gnu-ld"
2781 fi
2782
2783 if test x${use_included_zlib} = x &&
2784    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2785   :
2786 else
2787   with_system_zlib=yes
2788   extra_host_args="$extra_host_args --with-system-zlib"
2789 fi
2790
2791 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2792 # can detect this case.
2793
2794 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2795   with_newlib=yes
2796   extra_host_args="$extra_host_args --with-newlib"
2797 fi
2798
2799 # Handle ${copy_dirs}
2800 set fnord ${copy_dirs}
2801 shift
2802 while test $# != 0 ; do
2803   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2804     :
2805   else
2806     echo Copying $1 to $2
2807
2808     # Use the install script to create the directory and all required
2809     # parent directories.
2810     if test -d $2 ; then
2811       :
2812     else
2813       echo >config.temp
2814       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2815     fi
2816
2817     # Copy the directory, assuming we have tar.
2818     # FIXME: Should we use B in the second tar?  Not all systems support it.
2819     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2820
2821     # It is the responsibility of the user to correctly adjust all
2822     # symlinks.  If somebody can figure out how to handle them correctly
2823     # here, feel free to add the code.
2824
2825     echo $1 > $2/COPIED
2826   fi
2827   shift; shift
2828 done
2829
2830 # Determine a target-dependent exec_prefix that the installed
2831 # gcc will search in.  Keep this list sorted by triplet, with
2832 # the *-*-osname triplets last.
2833 md_exec_prefix=
2834 case "${target}" in
2835   i[[34567]]86-pc-msdosdjgpp*)
2836     md_exec_prefix=/dev/env/DJDIR/bin
2837     ;;
2838   *-*-hpux* | \
2839   *-*-nto-qnx* | \
2840   *-*-solaris2*)
2841     md_exec_prefix=/usr/ccs/bin
2842     ;;
2843 esac
2844
2845 extra_arflags_for_target=
2846 extra_nmflags_for_target=
2847 extra_ranlibflags_for_target=
2848 target_makefile_frag=/dev/null
2849 case "${target}" in
2850   spu-*-*)
2851     target_makefile_frag="config/mt-spu"
2852     ;;
2853   loongarch*-*linux* | loongarch*-*gnu*)
2854     target_makefile_frag="config/mt-loongarch-gnu"
2855     ;;
2856   loongarch*-*elf*)
2857     target_makefile_frag="config/mt-loongarch-elf"
2858     ;;
2859   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2860     target_makefile_frag="config/mt-sde"
2861     ;;
2862   mipsisa*-*-elfoabi*)
2863     target_makefile_frag="config/mt-mips-elfoabi"
2864     ;;
2865   mips*-*-*linux* | mips*-*-gnu*)
2866     target_makefile_frag="config/mt-mips-gnu"
2867     ;;
2868   nios2-*-elf*)
2869     target_makefile_frag="config/mt-nios2-elf"
2870     ;;
2871   *-*-linux-android*)
2872     target_makefile_frag="config/mt-android"
2873     ;;
2874   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2875     target_makefile_frag="config/mt-gnu"
2876     ;;
2877   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2878     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2879     # commands to handle both 32-bit and 64-bit objects.  These flags are
2880     # harmless if we're using GNU nm or ar.
2881     extra_arflags_for_target=" -X32_64"
2882     extra_nmflags_for_target=" -B -X32_64"
2883     ;;
2884 esac
2885
2886 alphaieee_frag=/dev/null
2887 case $target in
2888   alpha*-*-*)
2889     # This just makes sure to use the -mieee option to build target libs.
2890     # This should probably be set individually by each library.
2891     alphaieee_frag="config/mt-alphaieee"
2892     ;;
2893 esac
2894
2895 # If --enable-target-optspace always use -Os instead of -O2 to build
2896 # the target libraries, similarly if it is not specified, use -Os
2897 # on selected platforms.
2898 ospace_frag=/dev/null
2899 case "${enable_target_optspace}:${target}" in
2900   yes:*)
2901     ospace_frag="config/mt-ospace"
2902     ;;
2903   :d30v-*)
2904     ospace_frag="config/mt-d30v"
2905     ;;
2906   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2907     ospace_frag="config/mt-ospace"
2908     ;;
2909   no:* | :*)
2910     ;;
2911   *)
2912     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2913     ;;
2914 esac
2915
2916 # Some systems (e.g., one of the i386-aix systems the gas testers are
2917 # using) don't handle "\$" correctly, so don't use it here.
2918 tooldir='${exec_prefix}'/${target_noncanonical}
2919 build_tooldir=${tooldir}
2920
2921 # Create a .gdbinit file which runs the one in srcdir
2922 # and tells GDB to look there for source files.
2923
2924 if test -r ${srcdir}/.gdbinit ; then
2925   case ${srcdir} in
2926     .) ;;
2927     *) cat > ./.gdbinit <<EOF
2928 # ${NO_EDIT}
2929 dir ${srcdir}
2930 dir .
2931 source ${srcdir}/.gdbinit
2932 EOF
2933     ;;
2934   esac
2935 fi
2936
2937 # Make sure that the compiler is able to generate an executable.  If it
2938 # can't, we are probably in trouble.  We don't care whether we can run the
2939 # executable--we might be using a cross compiler--we only care whether it
2940 # can be created.  At this point the main configure script has set CC.
2941 we_are_ok=no
2942 echo "int main () { return 0; }" > conftest.c
2943 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2944 if test $? = 0 ; then
2945   if test -s conftest || test -s conftest.exe ; then
2946     we_are_ok=yes
2947   fi
2948 fi
2949 case $we_are_ok in
2950   no)
2951     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2952     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2953     rm -f conftest*
2954     exit 1
2955     ;;
2956 esac
2957 rm -f conftest*
2958
2959 # Decide which environment variable is used to find dynamic libraries.
2960 case "${host}" in
2961   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2962   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2963   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2964   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2965 esac
2966
2967 # On systems where the dynamic library environment variable is PATH,
2968 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2969 # built executables to PATH.
2970 if test "$RPATH_ENVVAR" = PATH; then
2971   GCC_SHLIB_SUBDIR=/shlib
2972 else
2973   GCC_SHLIB_SUBDIR=
2974 fi
2975
2976 # Adjust the toplevel makefile according to whether bootstrap was selected.
2977 case $enable_bootstrap in
2978   yes)
2979     bootstrap_suffix=bootstrap
2980     BUILD_CONFIG=bootstrap-debug
2981     ;;
2982   no)
2983     bootstrap_suffix=no-bootstrap
2984     BUILD_CONFIG=
2985     ;;
2986 esac
2987
2988 AC_MSG_CHECKING(for default BUILD_CONFIG)
2989
2990 AC_ARG_WITH([build-config],
2991   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2992                   [use config/NAME.mk build configuration])],
2993   [case $with_build_config in
2994    yes) with_build_config= ;;
2995    no) with_build_config= BUILD_CONFIG= ;;
2996    esac])
2997
2998 if test "x${with_build_config}" != x; then
2999   BUILD_CONFIG=$with_build_config
3000 else
3001   case $BUILD_CONFIG in
3002   bootstrap-debug)
3003     if echo "int f (void) { return 0; }" > conftest.c &&
3004        ${CC} -c conftest.c &&
3005        mv conftest.o conftest.o.g0 &&
3006        ${CC} -c -g conftest.c &&
3007        mv conftest.o conftest.o.g &&
3008        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
3009       :
3010     else
3011       BUILD_CONFIG=
3012     fi
3013     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
3014     ;;
3015   esac
3016 fi
3017 AC_MSG_RESULT($BUILD_CONFIG)
3018 AC_SUBST(BUILD_CONFIG)
3019
3020 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
3021 AC_MSG_CHECKING([for --enable-vtable-verify])
3022 AC_ARG_ENABLE(vtable-verify,
3023 [AS_HELP_STRING([--enable-vtable-verify],
3024                 [Enable vtable verification feature])],
3025 [case "$enableval" in
3026  yes) enable_vtable_verify=yes ;;
3027  no)  enable_vtable_verify=no ;;
3028  *)   enable_vtable_verify=no;;
3029  esac],
3030 [enable_vtable_verify=no])
3031 AC_MSG_RESULT($enable_vtable_verify)
3032
3033 # Record target_configdirs and the configure arguments for target and
3034 # build configuration in Makefile.
3035 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
3036 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
3037 bootstrap_fixincludes=no
3038
3039 # If we are building libgomp, bootstrap it.
3040 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
3041   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
3042 fi
3043
3044 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
3045 # or bootstrap-ubsan, bootstrap it.
3046 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
3047   case "$BUILD_CONFIG" in
3048     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
3049       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
3050       bootstrap_fixincludes=yes
3051       ;;
3052   esac
3053 fi
3054
3055 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3056 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3057    test "$enable_vtable_verify" != no; then
3058   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3059 fi
3060
3061 # If we are building libatomic and the list of enabled languages includes the
3062 # D frontend, bootstrap it.
3063 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3064   case ,${enable_languages}, in
3065     *,d,*)
3066       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3067       ;;
3068   esac
3069 fi
3070
3071 # Determine whether gdb needs tk/tcl or not.
3072 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3073 # and in that case we want gdb to be built without tk.  Ugh!
3074 # In fact I believe gdb is the *only* package directly dependent on tk,
3075 # so we should be able to put the 'maybe's in unconditionally and
3076 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3077 # 100% sure that that's safe though.
3078
3079 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3080 case "$enable_gdbtk" in
3081   no)
3082     GDB_TK="" ;;
3083   yes)
3084     GDB_TK="${gdb_tk}" ;;
3085   *)
3086     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3087     # distro.  Eventually someone will fix this and move Insight, nee
3088     # gdbtk to a separate directory.
3089     if test -d ${srcdir}/gdb/gdbtk ; then
3090       GDB_TK="${gdb_tk}"
3091     else
3092       GDB_TK=""
3093     fi
3094     ;;
3095 esac
3096 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3097 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3098
3099 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3100 # else does, only include them if one of these is built.  The Makefile
3101 # provides the ordering, so it's enough here to add to the list.
3102 case " ${configdirs} " in
3103   *\ gdb\ *)
3104     configdirs="${configdirs} gnulib gdbsupport"
3105     ;;
3106   *\ gdbserver\ *)
3107     configdirs="${configdirs} gnulib gdbsupport"
3108     ;;
3109   *\ sim\ *)
3110     configdirs="${configdirs} gnulib"
3111     ;;
3112 esac
3113
3114 # Strip out unwanted targets.
3115
3116 # While at that, we remove Makefiles if we were started for recursive
3117 # configuration, so that the top-level Makefile reconfigures them,
3118 # like we used to do when configure itself was recursive.
3119
3120 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3121 # but now we're fixing up the Makefile ourselves with the additional
3122 # commands passed to AC_CONFIG_FILES.  Use separate variables
3123 # extrasub-{build,host,target} not because there is any reason to split
3124 # the substitutions up that way, but only to remain below the limit of
3125 # 99 commands in a script, for HP-UX sed.
3126
3127 # Do not nest @if/@endif or @unless/@endunless pairs, because
3128 # configure will not warn you at all.
3129
3130 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3131   yes:yes:*\ gold\ *:*,c++,*) ;;
3132   yes:yes:*\ gold\ *:*)
3133     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3134     ;;
3135 esac
3136
3137 extrasub_build=
3138 for module in ${build_configdirs} ; do
3139   if test -z "${no_recursion}" \
3140      && test -f ${build_subdir}/${module}/Makefile; then
3141     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3142     rm -f ${build_subdir}/${module}/Makefile
3143   fi
3144   extrasub_build="$extrasub_build
3145 /^@if build-$module\$/d
3146 /^@endif build-$module\$/d
3147 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3148 /^@if build-$module-$bootstrap_suffix\$/d
3149 /^@endif build-$module-$bootstrap_suffix\$/d
3150 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3151 done
3152 extrasub_host=
3153 for module in ${configdirs} ; do
3154   if test -z "${no_recursion}"; then
3155     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3156       if test -f ${file}; then
3157         echo 1>&2 "*** removing ${file} to force reconfigure"
3158         rm -f ${file}
3159       fi
3160     done
3161   fi
3162   case ${module},${bootstrap_fixincludes} in
3163     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3164     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3165   esac
3166   extrasub_host="$extrasub_host
3167 /^@if $module\$/d
3168 /^@endif $module\$/d
3169 /^@unless $module\$/,/^@endunless $module\$/d
3170 /^@if $module-$host_bootstrap_suffix\$/d
3171 /^@endif $module-$host_bootstrap_suffix\$/d
3172 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3173 done
3174 extrasub_target=
3175 for module in ${target_configdirs} ; do
3176   if test -z "${no_recursion}" \
3177      && test -f ${target_subdir}/${module}/Makefile; then
3178     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3179     rm -f ${target_subdir}/${module}/Makefile
3180   fi
3181
3182   # We only bootstrap target libraries listed in bootstrap_target_libs.
3183   case $bootstrap_target_libs in
3184     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3185     *) target_bootstrap_suffix=no-bootstrap ;;
3186   esac
3187
3188   extrasub_target="$extrasub_target
3189 /^@if target-$module\$/d
3190 /^@endif target-$module\$/d
3191 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3192 /^@if target-$module-$target_bootstrap_suffix\$/d
3193 /^@endif target-$module-$target_bootstrap_suffix\$/d
3194 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3195 done
3196
3197 # Do the final fixup along with target modules.
3198 extrasub_target="$extrasub_target
3199 /^@if /,/^@endif /d
3200 /^@unless /d
3201 /^@endunless /d"
3202
3203 if test "$enable_pgo_build" != "no"; then
3204   extrasub_build="$extrasub_build
3205 /^@if pgo-build\$/d
3206 /^@endif pgo-build\$/d"
3207 fi
3208
3209 # Create the serialization dependencies.  This uses a temporary file.
3210
3211 AC_ARG_ENABLE([serial-configure],
3212 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3213                 [force sequential configuration of
3214                  sub-packages for the host, target or build
3215                  machine, or all sub-packages])])
3216
3217 case ${enable_serial_configure} in
3218   yes)
3219     enable_serial_build_configure=yes
3220     enable_serial_host_configure=yes
3221     enable_serial_target_configure=yes
3222     ;;
3223 esac
3224
3225 # These force 'configure's to be done one at a time, to avoid problems
3226 # with contention over a shared config.cache.
3227 rm -f serdep.tmp
3228 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3229 echo '# serdep.tmp' > serdep.tmp
3230 fi
3231 olditem=
3232 test "x${enable_serial_build_configure}" = xyes &&
3233 for item in ${build_configdirs} ; do
3234   case ${olditem} in
3235     "") ;;
3236     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3237   esac
3238   olditem=${item}
3239 done
3240 olditem=
3241 test "x${enable_serial_host_configure}" = xyes &&
3242 for item in ${configdirs} ; do
3243   case ${olditem} in
3244     "") ;;
3245     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3246   esac
3247   olditem=${item}
3248 done
3249 olditem=
3250 test "x${enable_serial_target_configure}" = xyes &&
3251 for item in ${target_configdirs} ; do
3252   case ${olditem} in
3253     "") ;;
3254     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3255   esac
3256   olditem=${item}
3257 done
3258 serialization_dependencies=serdep.tmp
3259 AC_SUBST_FILE(serialization_dependencies)
3260
3261 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3262 # target, nonopt, and variable assignments.  These are the ones we
3263 # might not want to pass down to subconfigures.  The exception being
3264 # --cache-file=/dev/null, which is used to turn off the use of cache
3265 # files altogether, and which should be passed on to subconfigures.
3266 # Also strip program-prefix, program-suffix, and program-transform-name,
3267 # so that we can pass down a consistent program-transform-name.
3268 hbaseargs=
3269 bbaseargs=
3270 tbaseargs=
3271 keep_next=no
3272 skip_next=no
3273 eval "set -- $ac_configure_args"
3274 for ac_arg
3275 do
3276   if test X"$skip_next" = X"yes"; then
3277     skip_next=no
3278     continue
3279   fi
3280   if test X"$keep_next" = X"yes"; then
3281     case $ac_arg in
3282       *\'*)
3283         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3284     esac
3285     hbaseargs="$hbaseargs '$ac_arg'"
3286     bbaseargs="$bbaseargs '$ac_arg'"
3287     tbaseargs="$tbaseargs '$ac_arg'"
3288     keep_next=no
3289     continue
3290   fi
3291
3292   # Handle separated arguments.  Based on the logic generated by
3293   # autoconf 2.59.
3294   case $ac_arg in
3295     *=* | --config-cache | -C | -disable-* | --disable-* \
3296       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3297       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3298       | -with-* | --with-* | -without-* | --without-* | --x)
3299       separate_arg=no
3300       ;;
3301     -*)
3302       separate_arg=yes
3303       ;;
3304     *)
3305       separate_arg=no
3306       ;;
3307   esac
3308
3309   skip_targ=no
3310   skip_barg=no
3311   case $ac_arg in
3312 changequote(,)
3313   --with-* | --without-*)
3314     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3315
3316     case $libopt in
3317     *[-_]include)
3318       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3319       ;;
3320     *[-_]lib)
3321       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3322       ;;
3323     *[-_]prefix)
3324       lib=`echo "$libopt" | sed 's,[-_]prefix$,,'`
3325       ;;
3326     *[-_]type)
3327       lib=`echo "$libopt" | sed 's,[-_]type$,,'`
3328       ;;
3329     *)
3330       lib=$libopt
3331       ;;
3332     esac
3333 changequote([,])
3334
3335     case $lib in
3336     mpc | mpfr | gmp | isl)
3337       # If we're processing --with-$lib, --with-$lib-include or
3338       # --with-$lib-lib, for one of the libs above, and target is
3339       # different from host, don't pass the current argument to any
3340       # target library's configure.
3341       if test x$is_cross_compiler = xyes; then
3342         skip_targ=yes
3343       fi
3344       ;;
3345     libintl | libiconv)
3346       # We don't want libintl (and co.) in anything but the host arguments.
3347       skip_targ=yes
3348       skip_barg=yes
3349       ;;
3350     esac
3351     ;;
3352   esac
3353
3354   case "$ac_arg" in
3355     --cache-file=/dev/null | \
3356     -cache-file=/dev/null )
3357       # Handled here to avoid the test to skip args below.
3358       hbaseargs="$hbaseargs '$ac_arg'"
3359       bbaseargs="$bbaseargs '$ac_arg'"
3360       tbaseargs="$tbaseargs '$ac_arg'"
3361       # Assert: $separate_arg should always be no.
3362       keep_next=$separate_arg
3363       ;;
3364     --no*)
3365       continue
3366       ;;
3367     --c* | \
3368     --sr* | \
3369     --ho* | \
3370     --bu* | \
3371     --t* | \
3372     --program-* | \
3373     -cache_file* | \
3374     -srcdir* | \
3375     -host* | \
3376     -build* | \
3377     -target* | \
3378     -program-prefix* | \
3379     -program-suffix* | \
3380     -program-transform-name* )
3381       skip_next=$separate_arg
3382       continue
3383       ;;
3384     -*)
3385       # An option.  Add it.
3386       case $ac_arg in
3387         *\'*)
3388           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3389       esac
3390       hbaseargs="$hbaseargs '$ac_arg'"
3391       if test X"$skip_barg" = Xno; then
3392         bbaseargs="$bbaseargs '$ac_arg'"
3393       fi
3394       if test X"$skip_targ" = Xno; then
3395         tbaseargs="$tbaseargs '$ac_arg'"
3396       fi
3397       keep_next=$separate_arg
3398       ;;
3399     *)
3400       # Either a variable assignment, or a nonopt (triplet).  Don't
3401       # pass it down; let the Makefile handle this.
3402       continue
3403       ;;
3404   esac
3405 done
3406 # Remove the initial space we just introduced and, as these will be
3407 # expanded by make, quote '$'.
3408 hbaseargs=`echo "x$hbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3409 bbaseargs=`echo "x$bbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3410
3411 # Add in --program-transform-name, after --program-prefix and
3412 # --program-suffix have been applied to it.  Autoconf has already
3413 # doubled dollar signs and backslashes in program_transform_name; we want
3414 # the backslashes un-doubled, and then the entire thing wrapped in single
3415 # quotes, because this will be expanded first by make and then by the shell.
3416 # Also, because we want to override the logic in subdir configure scripts to
3417 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3418 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3419 ${program_transform_name}
3420 EOF_SED
3421 gcc_transform_name=`cat conftestsed.out`
3422 rm -f conftestsed.out
3423 hbaseargs="$hbaseargs --program-transform-name='${gcc_transform_name}'"
3424 bbaseargs="$bbaseargs --program-transform-name='${gcc_transform_name}'"
3425 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3426 if test "$silent" = yes; then
3427   bbaseargs="$bbaseargs --silent"
3428   hbaseargs="$hbaseargs --silent"
3429   tbaseargs="$tbaseargs --silent"
3430 fi
3431
3432 bbaseargs="$bbaseargs --disable-option-checking"
3433 hbaseargs="$hbaseargs --disable-option-checking"
3434 tbaseargs="$tbaseargs --disable-option-checking"
3435
3436 if test "$enable_year2038" = no; then
3437   bbaseargs="$bbaseargs --disable-year2038"
3438   hbaseargs="$hbaseargs --disable-year2038"
3439   tbaseargs="$tbaseargs --disable-year2038"
3440 fi
3441
3442 # Record and document user additions to sub configure arguments.
3443 AC_ARG_VAR([build_configargs],
3444            [additional configure arguments for build directories])
3445 AC_ARG_VAR([host_configargs],
3446            [additional configure arguments for host directories])
3447 AC_ARG_VAR([target_configargs],
3448            [additional configure arguments for target directories])
3449
3450 # For the build-side libraries, we just need to pretend we're native,
3451 # and not use the same cache file.  Multilibs are neither needed nor
3452 # desired.  We can't even use the same cache file for all build-side
3453 # libraries, as they're compiled differently; some with C, some with
3454 # C++ or with different feature-enabling options.
3455 build_configargs="$build_configargs --cache-file=./config.cache ${bbaseargs}"
3456
3457 # For host modules, accept cache file option, or specification as blank.
3458 case "${cache_file}" in
3459 "") # empty
3460   cache_file_option="" ;;
3461 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3462   cache_file_option="--cache-file=${cache_file}" ;;
3463 *) # relative path
3464   cache_file_option="--cache-file=../${cache_file}" ;;
3465 esac
3466
3467 # Host dirs don't like to share a cache file either, horribly enough.
3468 # This seems to be due to autoconf 2.5x stupidity.
3469 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${hbaseargs}"
3470
3471 target_configargs="$target_configargs ${tbaseargs}"
3472
3473 # Passing a --with-cross-host argument lets the target libraries know
3474 # whether they are being built with a cross-compiler or being built
3475 # native.  However, it would be better to use other mechanisms to make the
3476 # sorts of decisions they want to make on this basis.  Please consider
3477 # this option to be deprecated.  FIXME.
3478 if test x${is_cross_compiler} = xyes ; then
3479   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3480 fi
3481
3482 # Special user-friendly check for native x86_64-linux build, if
3483 # multilib is not explicitly enabled.
3484 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3485   x86_64-*linux*:yes:$build:$build:)
3486     # Make sure we have a development environment that handles 32-bit
3487     dev64=no
3488     echo "int main () { return 0; }" > conftest.c
3489     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3490     if test $? = 0 ; then
3491       if test -s conftest || test -s conftest.exe ; then
3492         dev64=yes
3493       fi
3494     fi
3495     rm -f conftest*
3496     if test x${dev64} != xyes ; then
3497       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3498     fi
3499     ;;
3500 esac
3501
3502 # Default to --enable-multilib.
3503 if test x${enable_multilib} = x ; then
3504   target_configargs="--enable-multilib ${target_configargs}"
3505 fi
3506
3507 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3508 # changed from the earlier setting of with_newlib.
3509 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3510   target_configargs="--with-newlib ${target_configargs}"
3511 fi
3512
3513 # Different target subdirs use different values of certain variables
3514 # (notably CXX).  Worse, multilibs use *lots* of different values.
3515 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3516 # it doesn't automatically accept command-line overrides of them.
3517 # This means it's not safe for target subdirs to share a cache file,
3518 # which is disgusting, but there you have it.  Hopefully this can be
3519 # fixed in future.  It's still worthwhile to use a cache file for each
3520 # directory.  I think.
3521
3522 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3523 # We need to pass --target, as newer autoconf's requires consistency
3524 # for target_alias and gcc doesn't manage it consistently.
3525 target_configargs="--cache-file=./config.cache ${target_configargs}"
3526
3527 FLAGS_FOR_TARGET=
3528 case " $target_configdirs " in
3529  *" newlib "*)
3530   case " $target_configargs " in
3531   *" --with-newlib "*)
3532    case "$target" in
3533     *-cygwin*)
3534       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3535       ;;
3536    esac
3537
3538    # If we're not building GCC, don't discard standard headers.
3539    if test -d ${srcdir}/gcc; then
3540      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3541
3542      if test "${build}" != "${host}"; then
3543        # On Canadian crosses, CC_FOR_TARGET will have already been set
3544        # by `configure', so we won't have an opportunity to add -Bgcc/
3545        # to it.  This is right: we don't want to search that directory
3546        # for binaries, but we want the header files in there, so add
3547        # them explicitly.
3548        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3549
3550        # Someone might think of using the pre-installed headers on
3551        # Canadian crosses, in case the installed compiler is not fully
3552        # compatible with the compiler being built.  In this case, it
3553        # would be better to flag an error than risking having
3554        # incompatible object files being constructed.  We can't
3555        # guarantee that an error will be flagged, but let's hope the
3556        # compiler will do it, when presented with incompatible header
3557        # files.
3558      fi
3559    fi
3560
3561    case "${target}-${is_cross_compiler}" in
3562    i[[3456789]]86-*-linux*-no)
3563       # Here host == target, so we don't need to build gcc,
3564       # so we don't want to discard standard headers.
3565       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3566       ;;
3567    *)
3568       # If we're building newlib, use its generic headers last, but search
3569       # for any libc-related directories first (so make it the last -B
3570       # switch).
3571       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3572
3573       # If we're building libgloss, find the startup file, simulator library
3574       # and linker script.
3575       case " $target_configdirs " in
3576         *" libgloss "*)
3577         # Look for startup file, simulator library and maybe linker script.
3578         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3579         # Look for libnosys.a in case the target needs it.
3580         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3581         # Most targets have the linker script in the source directory.
3582         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3583         ;;
3584       esac
3585       ;;
3586    esac
3587    ;;
3588   esac
3589   ;;
3590 esac
3591
3592 case "$target" in
3593   x86_64-*mingw* | *-w64-mingw*)
3594   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3595   # however, use a symlink named 'mingw' in ${prefix} .
3596     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3597     ;;
3598   *-mingw*)
3599   # MinGW can't be handled as Cygwin above since it does not use newlib.
3600     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3601     ;;
3602 esac
3603
3604 # Allow the user to override the flags for
3605 # our build compiler if desired.
3606 if test x"${build}" = x"${host}" ; then
3607   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3608   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3609   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3610   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3611 fi
3612
3613 # On Canadian crosses, we'll be searching the right directories for
3614 # the previously-installed cross compiler, so don't bother to add
3615 # flags for directories within the install tree of the compiler
3616 # being built; programs in there won't even run.
3617 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3618   # Search for pre-installed headers if nothing else fits.
3619   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3620 fi
3621
3622 if test "x${use_gnu_ld}" = x &&
3623    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3624   # Arrange for us to find uninstalled linker scripts.
3625   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3626 fi
3627
3628 # Search for other target-specific linker scripts and such.
3629 case "${target}" in
3630   mep*)
3631     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3632     ;;
3633   # The VxWorks support for shared libraries is getting in
3634   # incrementally.  Make sure it doesn't get activated implicitly:
3635   *vxworks*)
3636     if test "${enable_shared-unset}" = unset ; then
3637       enable_shared=no
3638       # So the build of libraries knows ...
3639       target_configargs="${target_configargs} --disable-shared"
3640       # So gcc knows ...
3641       host_configargs="${host_configargs} --disable-shared"
3642     fi
3643     ;;
3644 esac
3645
3646 # Makefile fragments.
3647 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3648 do
3649   eval fragval=\$$frag
3650   if test $fragval != /dev/null; then
3651     eval $frag=${srcdir}/$fragval
3652   fi
3653 done
3654 AC_SUBST_FILE(host_makefile_frag)
3655 AC_SUBST_FILE(target_makefile_frag)
3656 AC_SUBST_FILE(alphaieee_frag)
3657 AC_SUBST_FILE(ospace_frag)
3658
3659 # Miscellanea: directories, flags, etc.
3660 AC_SUBST(RPATH_ENVVAR)
3661 AC_SUBST(GCC_SHLIB_SUBDIR)
3662 AC_SUBST(tooldir)
3663 AC_SUBST(build_tooldir)
3664 AC_SUBST(CONFIGURE_GDB_TK)
3665 AC_SUBST(GDB_TK)
3666 AC_SUBST(INSTALL_GDB_TK)
3667
3668 # Build module lists & subconfigure args.
3669 AC_SUBST(build_configargs)
3670 AC_SUBST(build_configdirs)
3671
3672 # Host module lists & subconfigure args.
3673 AC_SUBST(host_configargs)
3674 AC_SUBST(configdirs)
3675 AC_SUBST(target_configdirs)
3676
3677 # Target module lists & subconfigure args.
3678 AC_SUBST(target_configargs)
3679
3680
3681 # Build tools.
3682 AC_SUBST(AR_FOR_BUILD)
3683 AC_SUBST(AS_FOR_BUILD)
3684 AC_SUBST(CC_FOR_BUILD)
3685 AC_SUBST(CFLAGS_FOR_BUILD)
3686 AC_SUBST(CPP_FOR_BUILD)
3687 AC_SUBST(CPPFLAGS_FOR_BUILD)
3688 AC_SUBST(CXXFLAGS_FOR_BUILD)
3689 AC_SUBST(CXX_FOR_BUILD)
3690 AC_SUBST(DLLTOOL_FOR_BUILD)
3691 AC_SUBST(DSYMUTIL_FOR_BUILD)
3692 AC_SUBST(GFORTRAN_FOR_BUILD)
3693 AC_SUBST(GOC_FOR_BUILD)
3694 AC_SUBST(GDC_FOR_BUILD)
3695 AC_SUBST(LDFLAGS_FOR_BUILD)
3696 AC_SUBST(LD_FOR_BUILD)
3697 AC_SUBST(NM_FOR_BUILD)
3698 AC_SUBST(RANLIB_FOR_BUILD)
3699 AC_SUBST(WINDMC_FOR_BUILD)
3700 AC_SUBST(WINDRES_FOR_BUILD)
3701
3702 # Generate default definitions for YACC, M4, LEX and other programs that run
3703 # on the build machine.  These are used if the Makefile can't locate these
3704 # programs in objdir.
3705 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3706
3707 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3708 case " $build_configdirs " in
3709   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3710 esac
3711
3712 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3713 case " $build_configdirs " in
3714   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3715 esac
3716
3717 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3718 case " $build_configdirs " in
3719   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3720 esac
3721
3722 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3723 case " $build_configdirs " in
3724   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3725   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3726 esac
3727
3728 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3729 case " $build_configdirs " in
3730   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3731 esac
3732
3733 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3734 case " $build_configdirs " in
3735   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3736   *)
3737 changequote(,)
3738     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3739     # higher, else we use the "missing" dummy.
3740     if ${MAKEINFO} --version \
3741        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3742       :
3743     else
3744       MAKEINFO="$MISSING makeinfo"
3745     fi
3746     ;;
3747 changequote([,])
3748 esac
3749
3750 # FIXME: expect and dejagnu may become build tools?
3751
3752 AC_CHECK_PROGS(EXPECT, expect, expect)
3753 case " $configdirs " in
3754   *" expect "*)
3755     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3756     ;;
3757 esac
3758
3759 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3760 case " $configdirs " in
3761   *" dejagnu "*)
3762     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3763     ;;
3764 esac
3765
3766
3767 # Host tools.
3768 NCN_STRICT_CHECK_TOOLS(AR, ar)
3769 NCN_STRICT_CHECK_TOOLS(AS, as)
3770 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3771 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3772 NCN_STRICT_CHECK_TOOLS(LD, ld)
3773 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3774 NCN_STRICT_CHECK_TOOLS(NM, nm)
3775 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3776 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3777 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3778 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3779 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3780 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3781 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3782 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3783 AC_SUBST(CC)
3784 AC_SUBST(CXX)
3785 AC_SUBST(CFLAGS)
3786 AC_SUBST(CXXFLAGS)
3787 AC_SUBST(GDC)
3788 AC_SUBST(GDCFLAGS)
3789 GDCFLAGS=${GDCFLAGS-${CFLAGS}}
3790 AC_SUBST(PKG_CONFIG_PATH)
3791
3792 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3793 AR_PLUGIN_OPTION=
3794 RANLIB_PLUGIN_OPTION=
3795 if test -n "$PLUGIN_OPTION"; then
3796   if $AR --help 2>&1 | grep -q "\--plugin"; then
3797     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3798   fi
3799   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3800     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3801   fi
3802 fi
3803 AC_SUBST(AR_PLUGIN_OPTION)
3804 AC_SUBST(RANLIB_PLUGIN_OPTION)
3805
3806 # Target tools.
3807 AC_ARG_WITH([build-time-tools],
3808   [AS_HELP_STRING([--with-build-time-tools=PATH],
3809                   [use given path to find target tools during the build])],
3810   [case x"$withval" in
3811      x/*) ;;
3812      *)
3813        with_build_time_tools=
3814        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3815        ;;
3816    esac],
3817   [with_build_time_tools=])
3818
3819 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3820 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3821 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3822 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3823 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3824 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3825 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3826
3827 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3828 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3829 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3830 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3831 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3832 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3833 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3834 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3835 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3836 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3837 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3838 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3839 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3840 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3841 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3842
3843 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3844
3845 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3846 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3847 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3848 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3849 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3850                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3851                 c++)
3852 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3853                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3854                 c++)
3855 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3856 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3857 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3858 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3859                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3860 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3861                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3862 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3863                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3864 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3865                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3866 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3867 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3868 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3869 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3870 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3871 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3872 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3873 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3874 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3875 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3876 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3877
3878 AC_SUBST(FLAGS_FOR_TARGET)
3879 AC_SUBST(RAW_CXX_FOR_TARGET)
3880
3881 # Certain tools may need extra flags.
3882 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3883 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3884 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3885
3886 # When building target libraries, except in a Canadian cross, we use
3887 # the same toolchain as the compiler we just built.
3888 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3889 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3890 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3891 if test $host = $build; then
3892   case " $configdirs " in
3893     *" gcc "*)
3894       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3895       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3896       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3897       ;;
3898   esac
3899 fi
3900
3901 AC_SUBST(COMPILER_AS_FOR_TARGET)
3902 AC_SUBST(COMPILER_LD_FOR_TARGET)
3903 AC_SUBST(COMPILER_NM_FOR_TARGET)
3904
3905 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3906 AC_ARG_ENABLE(maintainer-mode,
3907 [AS_HELP_STRING([--enable-maintainer-mode],
3908                 [enable make rules and dependencies not useful
3909                  (and sometimes confusing) to the casual installer])],
3910       USE_MAINTAINER_MODE=$enableval,
3911       USE_MAINTAINER_MODE=no)
3912 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3913 AC_SUBST(MAINTAINER_MODE_TRUE)
3914 AC_SUBST(MAINTAINER_MODE_FALSE)
3915 if test "$USE_MAINTAINER_MODE" = yes; then
3916   MAINTAINER_MODE_TRUE=
3917   MAINTAINER_MODE_FALSE='#'
3918 else
3919   MAINTAINER_MODE_TRUE='#'
3920   MAINTAINER_MODE_FALSE=
3921 fi
3922 MAINT=$MAINTAINER_MODE_TRUE
3923 AC_SUBST(MAINT)dnl
3924
3925 # ---------------------
3926 # GCC bootstrap support
3927 # ---------------------
3928
3929 # Stage specific cflags for build.
3930 stage1_cflags="-g"
3931 case $build in
3932   vax-*-*)
3933     case ${GCC} in
3934       yes) stage1_cflags="-g -Wa,-J" ;;
3935       *) stage1_cflags="-g -J" ;;
3936     esac ;;
3937 esac
3938
3939 AC_SUBST(stage1_cflags)
3940
3941 # Enable --enable-checking in stage1 of the compiler.
3942 AC_ARG_ENABLE(stage1-checking,
3943 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3944                 [choose additional checking for stage1 of the compiler])],
3945 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3946 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3947   # For --disable-checking or implicit --enable-checking=release, avoid
3948   # setting --enable-checking=gc in the default stage1 checking for LTO
3949   # bootstraps.  See PR62077.
3950   case $BUILD_CONFIG in
3951     *lto*)
3952       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3953     *)
3954       stage1_checking=--enable-checking=yes,types;;
3955   esac
3956   if test "x$enable_checking" = x && \
3957      test -d ${srcdir}/gcc && \
3958      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3959     stage1_checking=--enable-checking=yes,types,extra
3960   fi
3961 else
3962   stage1_checking=--enable-checking=$enable_checking,types
3963 fi])
3964 AC_SUBST(stage1_checking)
3965
3966 # Enable -Werror in bootstrap stage2 and later.
3967 AC_ARG_ENABLE(werror,
3968 [AS_HELP_STRING([--enable-werror],
3969                 [enable -Werror in bootstrap stage2 and later])],
3970 [
3971 case ${enable_werror} in
3972   yes) stage2_werror_flag="--enable-werror-always" ;;
3973   *) stage2_werror_flag="" ;;
3974 esac
3975 ],
3976 [
3977 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3978   case $BUILD_CONFIG in
3979   bootstrap-debug)
3980       stage2_werror_flag="--enable-werror-always" ;;
3981   "")
3982       stage2_werror_flag="--enable-werror-always" ;;
3983   esac
3984 fi
3985 ])
3986
3987 AC_SUBST(stage2_werror_flag)
3988
3989 # Specify what files to not compare during bootstrap.
3990
3991 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3992 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
3993 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
3994 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
3995 case "$target" in
3996   hppa*64*-*-hpux*) ;;
3997   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3998 esac
3999 AC_SUBST(compare_exclusions)
4000
4001 AC_CONFIG_FILES([Makefile],
4002   [sed "$extrasub_build" Makefile |
4003    sed "$extrasub_host" |
4004    sed "$extrasub_target" > mf$$
4005    mv -f mf$$ Makefile],
4006   [extrasub_build="$extrasub_build"
4007    extrasub_host="$extrasub_host"
4008    extrasub_target="$extrasub_target"])
4009 AC_OUTPUT