configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/gcc-plugin.m4)
  27 m4_include(config/ax_cxx_compile_stdcxx.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT(move-if-change)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty build-libcpp"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #f
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 145
 146 # these libraries are built for the target environment, and are built after
 147 # the host libraries and the host tools (which may be a cross compiler)
 148 # Note that libiberty is not a target library.
 149 target_libraries="target-libgcc \
 150                 target-libbacktrace \
 151                 target-libgloss \
 152                 target-newlib \
 153                 target-libgomp \
 154                 target-liboffloadmic \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 252 # is provided.
 253 if test x$with_system_readline = xyes ; then
 254   noconfigdirs="$noconfigdirs readline"
 255 fi
 256
 257 AC_ARG_WITH(zstd,
 258 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 259
 260 # some tools are so dependent upon X11 that if we're not building with X,
 261 # it's not even worth trying to configure, much less build, that tool.
 262
 263 case ${with_x} in
 264   yes | "") ;; # the default value for this tree is that X11 is available
 265   no)
 266     skipdirs="${skipdirs} tk itcl libgui"
 267     # We won't be able to build gdbtk without X.
 268     enable_gdbtk=no
 269     ;;
 270   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 271 esac
 272
 273 # Some are only suitable for cross toolchains.
 274 # Remove these if host=target.
 275 cross_only="target-libgloss target-newlib target-opcodes"
 276
 277 case $is_cross_compiler in
 278   no) skipdirs="${skipdirs} ${cross_only}" ;;
 279 esac
 280
 281 # If both --with-headers and --with-libs are specified, default to
 282 # --without-newlib.
 283 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 284    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 285   if test x"${with_newlib}" = x ; then
 286     with_newlib=no
 287   fi
 288 fi
 289
 290 # Recognize --with-newlib/--without-newlib.
 291 case ${with_newlib} in
 292   no) skipdirs="${skipdirs} target-newlib" ;;
 293   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 294 esac
 295
 296 AC_ARG_ENABLE(as-accelerator-for,
 297 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 298                 [build as offload target compiler.
 299                 Specify offload host triple by ARG])])
 300
 301 AC_ARG_ENABLE(offload-targets,
 302 [AS_HELP_STRING([--enable-offload-targets=LIST],
 303                 [enable offloading to devices from comma-separated LIST of
 304                 TARGET[=DIR]. Use optional path to find offload target compiler
 305                 during the build])],
 306 [
 307   if test x"$enable_offload_targets" = x; then
 308     AC_MSG_ERROR([no offload targets specified])
 309   fi
 310 ], [enable_offload_targets=])
 311
 312 AC_ARG_ENABLE(offload-defaulted,
 313 [AS_HELP_STRING([--enable-offload-defaulted]
 314                 [If enabled, configured but not installed offload compilers and
 315                 libgomp plugins are silently ignored.  Useful for distribution
 316                 compilers where those are in separate optional packages.])],
 317 [enable_offload_defaulted=$enableval],
 318 [enable_offload_defaulted=])
 319
 320 # Handle --enable-gold, --enable-ld.
 321 # --disable-gold [--enable-ld]
 322 #     Build only ld.  Default option.
 323 # --enable-gold [--enable-ld]
 324 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 325 #     as "ld.bfd" and "ld".
 326 # --enable-gold=default [--enable-ld]
 327 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 328 #     install ld as "ld.bfd".
 329 # --enable-gold[=default] --disable-ld
 330 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 331 # --enable-gold --enable-ld=default
 332 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 333 #     and ld.bfd).
 334 #     In other words, ld is default
 335 # --enable-gold=default --enable-ld=default
 336 #     Error.
 337
 338 default_ld=
 339 AC_ARG_ENABLE(gold,
 340 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 341                 [build gold @<:@ARG={default,yes,no}@:>@])],
 342 ENABLE_GOLD=$enableval,
 343 ENABLE_GOLD=no)
 344 case "${ENABLE_GOLD}" in
 345   yes|default)
 346     # Check for ELF target.
 347     is_elf=no
 348     case "${target}" in
 349       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 350       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 351       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 352       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 353         case "${target}" in
 354           *-*-linux*aout* | *-*-linux*oldld*)
 355             ;;
 356           *)
 357             is_elf=yes
 358             ;;
 359         esac
 360     esac
 361
 362     if test "$is_elf" = "yes"; then
 363       # Check for target supported by gold.
 364       case "${target}" in
 365         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 366         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 367           configdirs="$configdirs gold"
 368           if test x${ENABLE_GOLD} = xdefault; then
 369             default_ld=gold
 370           fi
 371           ENABLE_GOLD=yes
 372           ;;
 373       esac
 374     fi
 375     ;;
 376   no)
 377     ;;
 378   *)
 379     AC_MSG_ERROR([invalid --enable-gold argument])
 380     ;;
 381 esac
 382
 383 AC_ARG_ENABLE(ld,
 384 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 385                 [build ld @<:@ARG={default,yes,no}@:>@])],
 386 ENABLE_LD=$enableval,
 387 ENABLE_LD=yes)
 388
 389 case "${ENABLE_LD}" in
 390   default)
 391     if test x${default_ld} != x; then
 392       AC_MSG_ERROR([either gold or ld can be the default ld])
 393     fi
 394     ;;
 395   yes)
 396     ;;
 397   no)
 398     if test x${ENABLE_GOLD} != xyes; then
 399       AC_MSG_WARN([neither ld nor gold are enabled])
 400     fi
 401     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 402     ;;
 403   *)
 404     AC_MSG_ERROR([invalid --enable-ld argument])
 405     ;;
 406 esac
 407
 408 AC_ARG_ENABLE(gprofng,
 409 [AS_HELP_STRING([[--enable-gprofng[=ARG]]],
 410                 [build gprofng @<:@ARG={yes,no}@:>@])],
 411 enable_gprofng=$enableval,
 412 enable_gprofng=yes)
 413 if test "$enable_gprofng" = "yes"; then
 414   case "${target}" in
 415     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux*)
 416     configdirs="$configdirs gprofng"
 417     ;;
 418   esac
 419 fi
 420
 421
 422 # PR gas/19109
 423 # Decide the default method for compressing debug sections.
 424 # Provide a configure time option to override our default.
 425 AC_ARG_ENABLE(compressed_debug_sections,
 426 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 427                 [Enable compressed debug sections for gas, gold or ld by
 428                  default])],
 429 [
 430   if test x"$enable_compressed_debug_sections" = xyes; then
 431     AC_MSG_ERROR([no program with compressed debug sections specified])
 432   fi
 433 ], [enable_compressed_debug_sections=])
 434
 435 # Select default compression algorithm.
 436 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 437 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 438                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 439 [], [default_compressed_debug_sections_algorithm=])
 440
 441 # Configure extra directories which are host specific
 442
 443 case "${host}" in
 444   *-cygwin*)
 445     configdirs="$configdirs libtermcap" ;;
 446 esac
 447
 448 # A target can indicate whether a language isn't supported for some reason.
 449 # Only spaces may be used in this macro; not newlines or tabs.
 450 unsupported_languages=
 451
 452 # Remove more programs from consideration, based on the host or
 453 # target this usually means that a port of the program doesn't
 454 # exist yet.
 455
 456 case "${host}" in
 457   i[[3456789]]86-*-msdosdjgpp*)
 458     noconfigdirs="$noconfigdirs tcl tk itcl"
 459     ;;
 460 esac
 461
 462 # Default to --disable-year2038 until we can handle differences between
 463 # projects that use gnulib (which understands year 2038) and projects that
 464 # do not (like BFD).
 465 AC_ARG_ENABLE(year2038,
 466 AS_HELP_STRING([--enable-year2038],
 467   [enable support for timestamps past the year 2038]),
 468 ENABLE_YEAR2038=$enableval,
 469 ENABLE_YEAR2038=no)
 470 enable_year2038=
 471 if test "${ENABLE_YEAR2038}" = "no" ; then
 472   enable_year2038=no
 473 fi
 474
 475 AC_ARG_ENABLE(libquadmath,
 476 AS_HELP_STRING([--disable-libquadmath],
 477   [do not build libquadmath directory]),
 478 ENABLE_LIBQUADMATH=$enableval,
 479 ENABLE_LIBQUADMATH=yes)
 480 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 481   noconfigdirs="$noconfigdirs target-libquadmath"
 482 fi
 483
 484
 485 AC_ARG_ENABLE(libquadmath-support,
 486 AS_HELP_STRING([--disable-libquadmath-support],
 487   [disable libquadmath support for Fortran]),
 488 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 489 ENABLE_LIBQUADMATH_SUPPORT=yes)
 490 enable_libquadmath_support=
 491 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 492   enable_libquadmath_support=no
 493 fi
 494
 495
 496 AC_ARG_ENABLE(libada,
 497 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 498 ENABLE_LIBADA=$enableval,
 499 ENABLE_LIBADA=yes)
 500 if test "${ENABLE_LIBADA}" != "yes" ; then
 501   noconfigdirs="$noconfigdirs gnattools"
 502 fi
 503
 504 AC_ARG_ENABLE(libssp,
 505 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 506 ENABLE_LIBSSP=$enableval,
 507 ENABLE_LIBSSP=yes)
 508
 509 AC_ARG_ENABLE(libstdcxx,
 510 AS_HELP_STRING([--disable-libstdcxx],
 511   [do not build libstdc++-v3 directory]),
 512 ENABLE_LIBSTDCXX=$enableval,
 513 ENABLE_LIBSTDCXX=default)
 514 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 515   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 516 fi]
 517
 518 # If this is accelerator compiler and its target is intelmic we enable
 519 # target liboffloadmic by default.  If this is compiler with offloading
 520 # for intelmic we enable host liboffloadmic by default.  Otherwise
 521 # liboffloadmic is disabled by default.
 522 AC_ARG_ENABLE([liboffloadmic],
 523 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 524                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 525 [case "$enableval" in
 526   no | host | target)
 527     enable_liboffloadmic=$enableval ;;
 528   *)
 529     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 530 esac],
 531 [if test x"$enable_as_accelerator_for" != x; then
 532   case "${target}" in
 533     *-intelmic-* | *-intelmicemul-*)
 534       enable_liboffloadmic=target
 535       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 536       ;;
 537     *)
 538       enable_liboffloadmic=no
 539       ;;
 540   esac
 541 else
 542   case "${enable_offload_targets}" in
 543     *-intelmic-* | *-intelmicemul-*)
 544       enable_liboffloadmic=host
 545       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 546       ;;
 547     *)
 548       enable_liboffloadmic=no
 549       ;;
 550     esac
 551 fi])
 552 AC_SUBST(extra_liboffloadmic_configure_flags)
 553
 554 # Enable libgomp by default on hosted POSIX systems, and a few others.
 555 if test x$enable_libgomp = x ; then
 556     case "${target}" in
 557     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 558         ;;
 559     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 560         ;;
 561     *-*-solaris2* | *-*-hpux11*)
 562         ;;
 563     *-*-darwin* | *-*-aix*)
 564         ;;
 565     nvptx*-*-* | amdgcn*-*-*)
 566         ;;
 567     *)
 568         noconfigdirs="$noconfigdirs target-libgomp"
 569         ;;
 570     esac
 571 fi
 572
 573 # Disable libatomic on unsupported systems.
 574 if test -d ${srcdir}/libatomic; then
 575     if test x$enable_libatomic = x; then
 576         AC_MSG_CHECKING([for libatomic support])
 577         if (srcdir=${srcdir}/libatomic; \
 578                 . ${srcdir}/configure.tgt; \
 579                 test -n "$UNSUPPORTED")
 580         then
 581             AC_MSG_RESULT([no])
 582             noconfigdirs="$noconfigdirs target-libatomic"
 583         else
 584             AC_MSG_RESULT([yes])
 585         fi
 586     fi
 587 fi
 588
 589 # Disable liboffloadmic on unsupported systems.
 590 if test -d ${srcdir}/liboffloadmic; then
 591     if test x$enable_liboffloadmic != xno; then
 592         AC_MSG_CHECKING([for liboffloadmic support])
 593         if (srcdir=${srcdir}/liboffloadmic; \
 594                 . ${srcdir}/configure.tgt; \
 595                 test -n "$UNSUPPORTED")
 596         then
 597             AC_MSG_RESULT([no])
 598             noconfigdirs="$noconfigdirs target-liboffloadmic"
 599         else
 600             AC_MSG_RESULT([yes])
 601         fi
 602     fi
 603 fi
 604
 605 # Disable libitm on unsupported systems.
 606 if test -d ${srcdir}/libitm; then
 607     if test x$enable_libitm = x; then
 608         AC_MSG_CHECKING([for libitm support])
 609         if (srcdir=${srcdir}/libitm; \
 610                 . ${srcdir}/configure.tgt; \
 611                 test -n "$UNSUPPORTED")
 612         then
 613             AC_MSG_RESULT([no])
 614             noconfigdirs="$noconfigdirs target-libitm"
 615         else
 616             AC_MSG_RESULT([yes])
 617         fi
 618     fi
 619 fi
 620
 621 # Disable libsanitizer on unsupported systems.
 622 if test -d ${srcdir}/libsanitizer; then
 623     if test x$enable_libsanitizer = x; then
 624         AC_MSG_CHECKING([for libsanitizer support])
 625         if (srcdir=${srcdir}/libsanitizer; \
 626                 . ${srcdir}/configure.tgt; \
 627                 test -n "$UNSUPPORTED")
 628         then
 629             AC_MSG_RESULT([no])
 630             noconfigdirs="$noconfigdirs target-libsanitizer"
 631         else
 632             AC_MSG_RESULT([yes])
 633         fi
 634     fi
 635 fi
 636
 637 # Disable libvtv on unsupported systems.
 638 if test -d ${srcdir}/libvtv; then
 639     if test x$enable_libvtv = x; then
 640         AC_MSG_CHECKING([for libvtv support])
 641         if (srcdir=${srcdir}/libvtv; \
 642                 . ${srcdir}/configure.tgt; \
 643                 test "$VTV_SUPPORTED" != "yes")
 644         then
 645             AC_MSG_RESULT([no])
 646             noconfigdirs="$noconfigdirs target-libvtv"
 647         else
 648             AC_MSG_RESULT([yes])
 649         fi
 650     fi
 651 fi
 652
 653 # Disable libquadmath for some systems.
 654 case "${target}" in
 655   avr-*-*)
 656     noconfigdirs="$noconfigdirs target-libquadmath"
 657     ;;
 658   # libquadmath is unused on AIX and libquadmath build process use of
 659   # LD_LIBRARY_PATH can break AIX bootstrap.
 660   powerpc-*-aix* | rs6000-*-aix*)
 661     noconfigdirs="$noconfigdirs target-libquadmath"
 662     ;;
 663 esac
 664
 665 # Disable libssp for some systems.
 666 case "${target}" in
 667   avr-*-*)
 668     # No hosted I/O support.
 669     noconfigdirs="$noconfigdirs target-libssp"
 670     ;;
 671   bpf-*-*)
 672     noconfigdirs="$noconfigdirs target-libssp"
 673     ;;
 674   powerpc-*-aix* | rs6000-*-aix*)
 675     noconfigdirs="$noconfigdirs target-libssp"
 676     ;;
 677   pru-*-*)
 678     # No hosted I/O support.
 679     noconfigdirs="$noconfigdirs target-libssp"
 680     ;;
 681   rl78-*-*)
 682     # libssp uses a misaligned load to trigger a fault, but the RL78
 683     # doesn't fault for those - instead, it gives a build-time error
 684     # for explicit misaligned loads.
 685     noconfigdirs="$noconfigdirs target-libssp"
 686     ;;
 687   visium-*-*)
 688     # No hosted I/O support.
 689     noconfigdirs="$noconfigdirs target-libssp"
 690     ;;
 691 esac
 692
 693 # Disable libstdc++-v3 for some systems.
 694 # Allow user to override this if they pass --enable-libstdcxx
 695 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 696   case "${target}" in
 697     *-*-vxworks*)
 698       # VxWorks uses the Dinkumware C++ library.
 699       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 700       ;;
 701     amdgcn*-*-*)
 702       # Not ported/fails to build when using newlib.
 703       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 704       ;;
 705     arm*-wince-pe*)
 706       # the C++ libraries don't build on top of CE's C libraries
 707       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 708       ;;
 709     avr-*-*)
 710       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 711       ;;
 712     bpf-*-*)
 713       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 714       ;;
 715     ft32-*-*)
 716       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 717       ;;
 718   esac
 719 fi
 720
 721 # Disable C++ on systems where it is known to not work.
 722 # For testing, you can override this with --enable-languages=c++.
 723 case ,${enable_languages}, in
 724   *,c++,*)
 725     ;;
 726   *)
 727       case "${target}" in
 728         bpf-*-*)
 729           unsupported_languages="$unsupported_languages c++"
 730           ;;
 731       esac
 732       ;;
 733 esac
 734
 735 # Disable Objc on systems where it is known to not work.
 736 # For testing, you can override this with --enable-languages=objc.
 737 case ,${enable_languages}, in
 738   *,objc,*)
 739     ;;
 740   *)
 741       case "${target}" in
 742         bpf-*-*)
 743           unsupported_languages="$unsupported_languages objc"
 744           ;;
 745       esac
 746       ;;
 747 esac
 748
 749 # Disable D on systems where it is known to not work.
 750 # For testing, you can override this with --enable-languages=d.
 751 case ,${enable_languages}, in
 752   *,d,*)
 753     ;;
 754   *)
 755     case "${target}" in
 756       bpf-*-*)
 757         unsupported_languages="$unsupported_languages d"
 758         ;;
 759     esac
 760     ;;
 761 esac
 762
 763 # Disable libphobos on unsupported systems.
 764 # For testing, you can override this with --enable-libphobos.
 765 if test -d ${srcdir}/libphobos; then
 766     if test x$enable_libphobos = x; then
 767         AC_MSG_CHECKING([for libphobos support])
 768         if (srcdir=${srcdir}/libphobos; \
 769                 . ${srcdir}/configure.tgt; \
 770                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 771         then
 772             AC_MSG_RESULT([no])
 773             noconfigdirs="$noconfigdirs target-libphobos"
 774         else
 775             AC_MSG_RESULT([yes])
 776         fi
 777     fi
 778 fi
 779
 780 # Disable Fortran for some systems.
 781 case "${target}" in
 782   mmix-*-*)
 783     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 784     unsupported_languages="$unsupported_languages fortran"
 785     ;;
 786   bpf-*-*)
 787     unsupported_languages="$unsupported_languages fortran"
 788     ;;
 789 esac
 790
 791 # Disable libffi for some systems.
 792 case "${target}" in
 793   powerpc-*-darwin*)
 794     ;;
 795   i[[3456789]]86-*-darwin*)
 796     ;;
 797   x86_64-*-darwin[[912]]*)
 798     ;;
 799   *-*-darwin*)
 800     noconfigdirs="$noconfigdirs target-libffi"
 801     ;;
 802   *-*-netware*)
 803     noconfigdirs="$noconfigdirs target-libffi"
 804     ;;
 805   *-*-phoenix*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   *-*-rtems*)
 809     noconfigdirs="$noconfigdirs target-libffi"
 810     ;;
 811   *-*-tpf*)
 812     noconfigdirs="$noconfigdirs target-libffi"
 813     ;;
 814   *-*-uclinux*)
 815     noconfigdirs="$noconfigdirs target-libffi"
 816     ;;
 817   *-*-vxworks*)
 818     noconfigdirs="$noconfigdirs target-libffi"
 819     ;;
 820   aarch64*-*-freebsd*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   alpha*-*-*vms*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826   arm*-*-freebsd*)
 827     noconfigdirs="$noconfigdirs target-libffi"
 828     ;;
 829   arm-wince-pe)
 830     noconfigdirs="$noconfigdirs target-libffi"
 831     ;;
 832   arm*-*-symbianelf*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   bpf-*-*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838   cris-*-* | crisv32-*-*)
 839     case "${target}" in
 840       *-*-linux*)
 841         ;;
 842       *) # See PR46792 regarding target-libffi.
 843         noconfigdirs="$noconfigdirs target-libffi";;
 844     esac
 845     ;;
 846   hppa*64*-*-hpux*)
 847     noconfigdirs="$noconfigdirs target-libffi"
 848     ;;
 849   hppa*-hp-hpux11*)
 850     ;;
 851   hppa*-*-hpux*)
 852     noconfigdirs="$noconfigdirs target-libffi"
 853     ;;
 854   ia64*-*-*vms*)
 855     noconfigdirs="$noconfigdirs target-libffi"
 856     ;;
 857   i[[3456789]]86-w64-mingw*)
 858     noconfigdirs="$noconfigdirs target-libffi"
 859     ;;
 860   i[[3456789]]86-*-mingw*)
 861     noconfigdirs="$noconfigdirs target-libffi"
 862     ;;
 863   x86_64-*-mingw*)
 864     noconfigdirs="$noconfigdirs target-libffi"
 865     ;;
 866   mmix-*-*)
 867     noconfigdirs="$noconfigdirs target-libffi"
 868     ;;
 869   powerpc-*-aix*)
 870     ;;
 871   rs6000-*-aix*)
 872     ;;
 873   ft32-*-*)
 874     noconfigdirs="$noconfigdirs target-libffi"
 875     ;;
 876   *-*-lynxos*)
 877     noconfigdirs="$noconfigdirs target-libffi"
 878     ;;
 879 esac
 880
 881 # Disable the go frontend on systems where it is known to not work. Please keep
 882 # this in sync with contrib/config-list.mk.
 883 case "${target}" in
 884 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 885     unsupported_languages="$unsupported_languages go"
 886     ;;
 887 esac
 888
 889 # Only allow gdbserver on some systems.
 890 if test -d ${srcdir}/gdbserver; then
 891     if test x$enable_gdbserver = x; then
 892         AC_MSG_CHECKING([for gdbserver support])
 893         if (srcdir=${srcdir}/gdbserver; \
 894                 . ${srcdir}/configure.srv; \
 895                 test -n "$UNSUPPORTED")
 896         then
 897             AC_MSG_RESULT([no])
 898             noconfigdirs="$noconfigdirs gdbserver"
 899         else
 900             AC_MSG_RESULT([yes])
 901         fi
 902     fi
 903 fi
 904
 905 # Disable libgo for some systems where it is known to not work.
 906 # For testing, you can easily override this with --enable-libgo.
 907 if test x$enable_libgo = x; then
 908     case "${target}" in
 909     *-*-darwin*)
 910         # PR 46986
 911         noconfigdirs="$noconfigdirs target-libgo"
 912         ;;
 913     *-*-cygwin* | *-*-mingw*)
 914         noconfigdirs="$noconfigdirs target-libgo"
 915         ;;
 916     bpf-*-*)
 917         noconfigdirs="$noconfigdirs target-libgo"
 918         ;;
 919     esac
 920 fi
 921
 922 # Default libgloss CPU subdirectory.
 923 libgloss_dir="$target_cpu"
 924
 925 case "${target}" in
 926   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 927     libgloss_dir=wince
 928     ;;
 929   aarch64*-*-* )
 930     libgloss_dir=aarch64
 931     ;;
 932   arm*-*-*)
 933     libgloss_dir=arm
 934     ;;
 935   cris-*-* | crisv32-*-*)
 936     libgloss_dir=cris
 937     ;;
 938   hppa*-*-*)
 939     libgloss_dir=pa
 940     ;;
 941   i[[3456789]]86-*-*)
 942     libgloss_dir=i386
 943     ;;
 944   loongarch*-*-*)
 945     libgloss_dir=loongarch
 946     ;;
 947   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 948     libgloss_dir=m68hc11
 949     ;;
 950   m68*-*-* | fido-*-*)
 951     libgloss_dir=m68k
 952     ;;
 953   mips*-*-*)
 954     libgloss_dir=mips
 955     ;;
 956   powerpc*-*-*)
 957     libgloss_dir=rs6000
 958     ;;
 959   pru-*-*)
 960     libgloss_dir=pru
 961     ;;
 962   sparc*-*-*)
 963     libgloss_dir=sparc
 964     ;;
 965 esac
 966
 967 # Disable newlib and libgloss for various target OSes.
 968 case "${target}" in
 969   alpha*-dec-osf*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   i[[3456789]]86-*-linux*)
 973     # This section makes it possible to build newlib natively on linux.
 974     # If we are using a cross compiler then don't configure newlib.
 975     if test x${is_cross_compiler} != xno ; then
 976       noconfigdirs="$noconfigdirs target-newlib"
 977     fi
 978     noconfigdirs="$noconfigdirs target-libgloss"
 979     # If we are not using a cross compiler, do configure newlib.
 980     # Note however, that newlib will only be configured in this situation
 981     # if the --with-newlib option has been given, because otherwise
 982     # 'target-newlib' will appear in skipdirs.
 983     ;;
 984   i[[3456789]]86-*-rdos*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990   sparc-*-sunos4*)
 991     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 992     ;;
 993   bpf-*-*)
 994     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 995     ;;
 996   *-*-aix*)
 997     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 998     ;;
 999   *-*-beos*)
1000     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     ;;
1002   *-*-chorusos)
1003     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1004     ;;
1005   *-*-dragonfly*)
1006     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1007     ;;
1008   *-*-freebsd*)
1009     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1010     ;;
1011   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1012     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1013     ;;
1014   *-*-lynxos*)
1015     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1016     ;;
1017   *-*-mingw*)
1018     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1019     ;;
1020   *-*-netbsd*)
1021     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1022     ;;
1023   *-*-netware*)
1024     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1025     ;;
1026   *-*-tpf*)
1027     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1028     ;;
1029   *-*-uclinux*)
1030     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1031     ;;
1032   *-*-vxworks*)
1033     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1034     ;;
1035 esac
1036
1037 case "${target}" in
1038   *-*-chorusos)
1039     ;;
1040   aarch64-*-darwin*)
1041     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1042     noconfigdirs="$noconfigdirs sim target-rda"
1043     ;;
1044   amdgcn*-*-*)
1045     ;;
1046   arm-*-darwin*)
1047     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1048     noconfigdirs="$noconfigdirs sim target-rda"
1049     ;;
1050   powerpc-*-darwin*)
1051     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1052     noconfigdirs="$noconfigdirs sim target-rda"
1053     ;;
1054   i[[3456789]]86-*-darwin*)
1055     noconfigdirs="$noconfigdirs ld gprof"
1056     noconfigdirs="$noconfigdirs sim target-rda"
1057     ;;
1058   x86_64-*-darwin[[912]]*)
1059     noconfigdirs="$noconfigdirs ld gas gprof"
1060     noconfigdirs="$noconfigdirs sim target-rda"
1061     ;;
1062   *-*-darwin*)
1063     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1064     noconfigdirs="$noconfigdirs sim target-rda"
1065     ;;
1066   *-*-dragonfly*)
1067     ;;
1068   *-*-freebsd*)
1069     if test "x$with_gmp" = x \
1070         && ! test -d ${srcdir}/gmp \
1071         && test -f /usr/local/include/gmp.h; then
1072       with_gmp=/usr/local
1073     fi
1074     ;;
1075   *-*-kaos*)
1076     # Remove unsupported stuff on all kaOS configurations.
1077     noconfigdirs="$noconfigdirs target-libgloss"
1078     ;;
1079   *-*-netbsd*)
1080     ;;
1081   *-*-netware*)
1082     ;;
1083   *-*-phoenix*)
1084     noconfigdirs="$noconfigdirs target-libgloss"
1085     ;;
1086   *-*-rtems*)
1087     noconfigdirs="$noconfigdirs target-libgloss"
1088     ;;
1089     # The tpf target doesn't support gdb yet.
1090   *-*-tpf*)
1091     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1092     ;;
1093   *-*-uclinux*)
1094     noconfigdirs="$noconfigdirs target-rda"
1095     ;;
1096   *-*-vxworks*)
1097     ;;
1098   alpha*-dec-osf*)
1099     # ld works, but does not support shared libraries.
1100     # gas doesn't generate exception information.
1101     noconfigdirs="$noconfigdirs gas ld"
1102     ;;
1103   alpha*-*-*vms*)
1104     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1105     ;;
1106   alpha*-*-*)
1107     # newlib is not 64 bit ready
1108     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1109     ;;
1110   bpf-*-*)
1111     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1112     ;;
1113   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1114     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1115     ;;
1116   arc*-*-*)
1117     noconfigdirs="$noconfigdirs sim"
1118     ;;
1119   arm-*-pe*)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   arm-*-riscix*)
1123     noconfigdirs="$noconfigdirs ld target-libgloss"
1124     ;;
1125   avr-*-*)
1126     if test x${with_avrlibc} != xno; then
1127       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1128     fi
1129     ;;
1130   c4x-*-* | tic4x-*-*)
1131     noconfigdirs="$noconfigdirs target-libgloss"
1132     ;;
1133   tic54x-*-*)
1134     noconfigdirs="$noconfigdirs target-libgloss gdb"
1135     ;;
1136   d10v-*-*)
1137     noconfigdirs="$noconfigdirs target-libgloss"
1138     ;;
1139   d30v-*-*)
1140     noconfigdirs="$noconfigdirs gdb"
1141     ;;
1142   fr30-*-elf*)
1143     noconfigdirs="$noconfigdirs gdb"
1144     ;;
1145   ft32-*-*)
1146     noconfigdirs="$noconfigdirs target-rda gprof"
1147     ;;
1148   moxie-*-*)
1149     noconfigdirs="$noconfigdirs"
1150     ;;
1151   h8300*-*-*)
1152     noconfigdirs="$noconfigdirs target-libgloss"
1153     ;;
1154   h8500-*-*)
1155     noconfigdirs="$noconfigdirs target-libgloss"
1156     ;;
1157   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1158     ;;
1159   hppa*64*-*-hpux*)
1160     noconfigdirs="$noconfigdirs gdb"
1161     ;;
1162   hppa*-*-hpux11*)
1163     noconfigdirs="$noconfigdirs gdb ld"
1164     ;;
1165   hppa*64*-*-linux*)
1166     ;;
1167   hppa*-*-linux*)
1168     ;;
1169   hppa*-*-*elf* | \
1170   hppa*-*-lites* | \
1171   hppa*-*-openbsd* | \
1172   hppa*64*-*-*)
1173     ;;
1174   hppa*-*-pro*)
1175     ;;
1176   hppa*-*-*)
1177     noconfigdirs="$noconfigdirs ld"
1178     ;;
1179   i960-*-*)
1180     noconfigdirs="$noconfigdirs gdb"
1181     ;;
1182   ia64*-*-elf*)
1183     # No gdb support yet.
1184     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1185     ;;
1186   ia64*-**-hpux*)
1187     # No ld support yet.
1188     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1189     ;;
1190   ia64*-*-*vms*)
1191     # No ld support yet.
1192     noconfigdirs="$noconfigdirs libgui itcl ld"
1193     ;;
1194   i[[3456789]]86-w64-mingw*)
1195     ;;
1196   i[[3456789]]86-*-mingw*)
1197     target_configdirs="$target_configdirs target-winsup"
1198     ;;
1199   *-*-cygwin*)
1200     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1201     noconfigdirs="$noconfigdirs target-libgloss"
1202     # always build newlib if winsup directory is present.
1203     if test -d "$srcdir/winsup/cygwin"; then
1204       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1205     elif test -d "$srcdir/newlib"; then
1206       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1207     fi
1208     ;;
1209   i[[3456789]]86-*-pe)
1210     noconfigdirs="$noconfigdirs target-libgloss"
1211     ;;
1212   i[[3456789]]86-*-sco3.2v5*)
1213     # The linker does not yet know about weak symbols in COFF,
1214     # and is not configured to handle mixed ELF and COFF.
1215     noconfigdirs="$noconfigdirs ld target-libgloss"
1216     ;;
1217   i[[3456789]]86-*-sco*)
1218     noconfigdirs="$noconfigdirs gprof target-libgloss"
1219     ;;
1220   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1221     noconfigdirs="$noconfigdirs target-libgloss"
1222     ;;
1223   i[[3456789]]86-*-sysv4*)
1224     noconfigdirs="$noconfigdirs target-libgloss"
1225     ;;
1226   i[[3456789]]86-*-beos*)
1227     noconfigdirs="$noconfigdirs gdb"
1228     ;;
1229   i[[3456789]]86-*-rdos*)
1230     noconfigdirs="$noconfigdirs gdb"
1231     ;;
1232   mmix-*-*)
1233     noconfigdirs="$noconfigdirs gdb"
1234     ;;
1235   mt-*-*)
1236     noconfigdirs="$noconfigdirs sim"
1237     ;;
1238   nfp-*-*)
1239     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1240     noconfigdirs="$noconfigdirs $target_libraries"
1241     ;;
1242   pdp11-*-*)
1243     noconfigdirs="$noconfigdirs gdb gprof"
1244     ;;
1245   powerpc-*-aix*)
1246     # copied from rs6000-*-* entry
1247     noconfigdirs="$noconfigdirs gprof"
1248     ;;
1249   powerpc*-*-winnt* | powerpc*-*-pe*)
1250     target_configdirs="$target_configdirs target-winsup"
1251     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1252     # always build newlib.
1253     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1254     ;;
1255     # This is temporary until we can link against shared libraries
1256   powerpcle-*-solaris*)
1257     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1258     ;;
1259   powerpc-*-beos*)
1260     noconfigdirs="$noconfigdirs gdb"
1261     ;;
1262   rs6000-*-lynxos*)
1263     noconfigdirs="$noconfigdirs gprof"
1264     ;;
1265   rs6000-*-aix*)
1266     noconfigdirs="$noconfigdirs gprof"
1267     ;;
1268   rs6000-*-*)
1269     noconfigdirs="$noconfigdirs gprof"
1270     ;;
1271   m68k-apollo-*)
1272     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1273     ;;
1274   microblaze*)
1275     noconfigdirs="$noconfigdirs gprof"
1276     ;;
1277   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1278     if test x$with_newlib = xyes; then
1279       noconfigdirs="$noconfigdirs gprof"
1280     fi
1281     ;;
1282   mips*-*-irix5*)
1283     noconfigdirs="$noconfigdirs gprof target-libgloss"
1284     ;;
1285   mips*-*-irix6*)
1286     noconfigdirs="$noconfigdirs gprof target-libgloss"
1287     ;;
1288   mips*-*-bsd*)
1289     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1290     ;;
1291   mips*-*-linux*)
1292     ;;
1293   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1294   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1295     noconfigdirs="$noconfigdirs ld gas gprof"
1296     ;;
1297   mips*-*-*)
1298     noconfigdirs="$noconfigdirs gprof"
1299     ;;
1300   nvptx*-*-*)
1301     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1302     ;;
1303   sh-*-*)
1304     case "${target}" in
1305       sh*-*-elf)
1306          ;;
1307       *)
1308          noconfigdirs="$noconfigdirs target-libgloss" ;;
1309     esac
1310     ;;
1311   sparc-*-sunos4*)
1312     if test x${is_cross_compiler} = xno ; then
1313            use_gnu_ld=no
1314     fi
1315     ;;
1316   tic6x-*-*)
1317     noconfigdirs="$noconfigdirs sim"
1318     ;;
1319   tilepro*-*-* | tilegx*-*-*)
1320     noconfigdirs="$noconfigdirs sim"
1321     ;;
1322   v810-*-*)
1323     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1324     ;;
1325   vax-*-*)
1326     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1327     ;;
1328   wasm32-*-*)
1329     noconfigdirs="$noconfigdirs ld"
1330     ;;
1331   loongarch*-*-linux*)
1332     ;;
1333   loongarch*-*-*)
1334     noconfigdirs="$noconfigdirs gprof"
1335     ;;
1336 esac
1337
1338 # If we aren't building newlib, then don't build libgloss, since libgloss
1339 # depends upon some newlib header files.
1340 case "${noconfigdirs}" in
1341   *target-libgloss*) ;;
1342   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1343 esac
1344
1345 # Work in distributions that contain no compiler tools, like Autoconf.
1346 host_makefile_frag=/dev/null
1347 if test -d ${srcdir}/config ; then
1348 case "${host}" in
1349   i[[3456789]]86-*-msdosdjgpp*)
1350     host_makefile_frag="config/mh-djgpp"
1351     ;;
1352   *-cygwin*)
1353     ACX_CHECK_CYGWIN_CAT_WORKS
1354     host_makefile_frag="config/mh-cygwin"
1355     ;;
1356   *-mingw*)
1357     host_makefile_frag="config/mh-mingw"
1358     ;;
1359   alpha*-linux*)
1360     host_makefile_frag="config/mh-alpha-linux"
1361     ;;
1362   hppa*-hp-hpux10*)
1363     host_makefile_frag="config/mh-pa-hpux10"
1364     ;;
1365   hppa*-hp-hpux*)
1366     host_makefile_frag="config/mh-pa"
1367     ;;
1368   hppa*-*)
1369     host_makefile_frag="config/mh-pa"
1370     ;;
1371   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1372     host_makefile_frag="config/mh-darwin"
1373     ;;
1374   powerpc-*-aix*)
1375     host_makefile_frag="config/mh-ppc-aix"
1376     ;;
1377   rs6000-*-aix*)
1378     host_makefile_frag="config/mh-ppc-aix"
1379     ;;
1380 esac
1381 fi
1382
1383 if test "${build}" != "${host}" ; then
1384   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1385   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1386   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1387   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1388   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1389   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1390   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1391   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1392   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1393   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1394   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1395   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1396   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1397   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1398   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1399 else
1400   AR_FOR_BUILD="\$(AR)"
1401   AS_FOR_BUILD="\$(AS)"
1402   CC_FOR_BUILD="\$(CC)"
1403   CXX_FOR_BUILD="\$(CXX)"
1404   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1405   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1406   GOC_FOR_BUILD="\$(GOC)"
1407   GDC_FOR_BUILD="\$(GDC)"
1408   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1409   LD_FOR_BUILD="\$(LD)"
1410   NM_FOR_BUILD="\$(NM)"
1411   RANLIB_FOR_BUILD="\$(RANLIB)"
1412   WINDRES_FOR_BUILD="\$(WINDRES)"
1413   WINDMC_FOR_BUILD="\$(WINDMC)"
1414 fi
1415
1416 AC_PROG_CC_C99
1417 AC_PROG_CXX
1418
1419 # We must set the default linker to the linker used by gcc for the correct
1420 # operation of libtool.  If LD is not defined and we are using gcc, try to
1421 # set the LD default to the ld used by gcc.
1422 if test -z "$LD"; then
1423   if test "$GCC" = yes; then
1424     case $build in
1425     *-*-mingw*)
1426       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1427     *)
1428       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1429     esac
1430     case $gcc_prog_ld in
1431     # Accept absolute paths.
1432     [[\\/]* | [A-Za-z]:[\\/]*)]
1433       LD="$gcc_prog_ld" ;;
1434     esac
1435   fi
1436 fi
1437
1438 # Check whether -static-libstdc++ -static-libgcc is supported.
1439 have_static_libs=no
1440 if test "$GCC" = yes; then
1441   saved_LDFLAGS="$LDFLAGS"
1442
1443   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1444   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1445   AC_LANG_PUSH(C++)
1446   AC_LINK_IFELSE([AC_LANG_SOURCE([
1447 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1448 #error -static-libstdc++ not implemented
1449 #endif
1450 int main() {}])],
1451     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1452     [AC_MSG_RESULT([no])])
1453   AC_LANG_POP(C++)
1454
1455   LDFLAGS="$saved_LDFLAGS"
1456 fi
1457
1458 ACX_PROG_GNAT
1459 ACX_PROG_GDC
1460 ACX_PROG_CMP_IGNORE_INITIAL
1461
1462 AC_ARG_ENABLE([bootstrap],
1463 [AS_HELP_STRING([--enable-bootstrap],
1464                 [enable bootstrapping @<:@yes if native build@:>@])],,
1465 enable_bootstrap=default)
1466
1467 # Issue errors and warnings for invalid/strange bootstrap combinations.
1468 if test -r $srcdir/gcc/configure; then
1469   have_compiler=yes
1470 else
1471   have_compiler=no
1472 fi
1473
1474 case "$have_compiler:$host:$target:$enable_bootstrap" in
1475   *:*:*:no) ;;
1476
1477   # Default behavior.  Enable bootstrap if we have a compiler
1478   # and we are in a native configuration.
1479   yes:$build:$build:default)
1480     enable_bootstrap=yes ;;
1481
1482   *:*:*:default)
1483     enable_bootstrap=no ;;
1484
1485   # We have a compiler and we are in a native configuration, bootstrap is ok
1486   yes:$build:$build:yes)
1487     ;;
1488
1489   # Other configurations, but we have a compiler.  Assume the user knows
1490   # what he's doing.
1491   yes:*:*:yes)
1492     AC_MSG_WARN([trying to bootstrap a cross compiler])
1493     ;;
1494
1495   # No compiler: if they passed --enable-bootstrap explicitly, fail
1496   no:*:*:yes)
1497     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1498
1499   # Fail if wrong command line
1500   *)
1501     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1502     ;;
1503 esac
1504
1505 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1506 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1507 # require C++11 (or higher).
1508 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1509   CXX="$CXX -std=c++11"
1510 elif test "$have_compiler" = yes; then
1511   AX_CXX_COMPILE_STDCXX(11)
1512
1513   if test "${build}" != "${host}"; then
1514     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1515   fi
1516 fi
1517
1518 AC_ARG_ENABLE([pgo-build],
1519 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1520                 [enable the PGO build])],
1521 [enable_pgo_build=$enableval],
1522 [enable_pgo_build=no])
1523
1524 # Issue errors and warnings for invalid/strange PGO build combinations.
1525 case "$have_compiler:$host:$target:$enable_pgo_build" in
1526   *:*:*:no) ;;
1527
1528   # Allow the PGO build only if we aren't building a compiler and
1529   # we are in a native configuration.
1530   no:$build:$build:yes | no:$build:$build:lto) ;;
1531
1532   # Disallow the PGO bootstrap if we are building a compiler.
1533   yes:*:*:yes | yes:*:*:lto)
1534     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1535
1536   *)
1537     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1538     ;;
1539 esac
1540
1541 if test "$enable_pgo_build" != "no"; then
1542   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1543   old_CFLAGS="$CFLAGS"
1544   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1545   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1546   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1547                     [PGO_BUILD_GEN_CFLAGS=])
1548   CFLAGS="$old_CFLAGS"
1549   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1550     AC_MSG_RESULT([yes])
1551     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1552   else
1553     AC_MSG_RESULT([no])
1554     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1555   fi
1556
1557   if test "$enable_pgo_build" = "lto"; then
1558     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1559     old_CFLAGS="$CFLAGS"
1560     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1561     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1562     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1563                       [PGO_BUILD_LTO_CFLAGS=])
1564     CFLAGS="$old_CFLAGS"
1565     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1566       AC_MSG_RESULT([yes])
1567     else
1568       AC_MSG_RESULT([no])
1569       AC_MSG_WARN([LTO is disabled for the PGO build])
1570     fi
1571   fi
1572 fi
1573 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1574 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1575 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1576
1577 # Used for setting $lt_cv_objdir
1578 _LT_CHECK_OBJDIR
1579
1580 # Check for GMP, MPFR and MPC
1581 require_gmp=no
1582 require_mpc=no
1583 if test -d ${srcdir}/gcc ; then
1584   require_gmp=yes
1585   require_mpc=yes
1586 fi
1587 if test -d ${srcdir}/gdb ; then
1588   require_gmp=yes
1589 fi
1590
1591 gmplibs="-lmpfr -lgmp"
1592 if test x"$require_mpc" = "xyes" ; then
1593   gmplibs="-lmpc $gmplibs"
1594 fi
1595 gmpinc=
1596 have_gmp=no
1597
1598 # Specify a location for mpc
1599 # check for this first so it ends up on the link line before mpfr.
1600 AC_ARG_WITH(mpc,
1601 [AS_HELP_STRING([--with-mpc=PATH],
1602                 [specify prefix directory for installed MPC package.
1603                  Equivalent to --with-mpc-include=PATH/include
1604                  plus --with-mpc-lib=PATH/lib])])
1605 AC_ARG_WITH(mpc-include,
1606 [AS_HELP_STRING([--with-mpc-include=PATH],
1607                 [specify directory for installed MPC include files])])
1608 AC_ARG_WITH(mpc-lib,
1609 [AS_HELP_STRING([--with-mpc-lib=PATH],
1610                 [specify directory for the installed MPC library])])
1611
1612 if test "x$with_mpc" != x; then
1613   gmplibs="-L$with_mpc/lib $gmplibs"
1614   gmpinc="-I$with_mpc/include $gmpinc"
1615 fi
1616 if test "x$with_mpc_include" != x; then
1617   gmpinc="-I$with_mpc_include $gmpinc"
1618 fi
1619 if test "x$with_mpc_lib" != x; then
1620   gmplibs="-L$with_mpc_lib $gmplibs"
1621 fi
1622 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1623   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1624   gmpinc='-I$$s/mpc/src '"$gmpinc"
1625   # Do not test the mpc version.  Assume that it is sufficient, since
1626   # it is in the source tree, and the library has not been built yet
1627   # but it would be included on the link line in the version check below
1628   # hence making the test fail.
1629   have_gmp=yes
1630 fi
1631
1632 # Specify a location for mpfr
1633 # check for this first so it ends up on the link line before gmp.
1634 AC_ARG_WITH(mpfr,
1635 [AS_HELP_STRING([--with-mpfr=PATH],
1636                 [specify prefix directory for installed MPFR package.
1637                  Equivalent to --with-mpfr-include=PATH/include
1638                  plus --with-mpfr-lib=PATH/lib])])
1639 AC_ARG_WITH(mpfr-include,
1640 [AS_HELP_STRING([--with-mpfr-include=PATH],
1641                 [specify directory for installed MPFR include files])])
1642 AC_ARG_WITH(mpfr-lib,
1643 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1644                 [specify directory for the installed MPFR library])])
1645
1646 if test "x$with_mpfr" != x; then
1647   gmplibs="-L$with_mpfr/lib $gmplibs"
1648   gmpinc="-I$with_mpfr/include $gmpinc"
1649 fi
1650 if test "x$with_mpfr_include" != x; then
1651   gmpinc="-I$with_mpfr_include $gmpinc"
1652 fi
1653 if test "x$with_mpfr_lib" != x; then
1654   gmplibs="-L$with_mpfr_lib $gmplibs"
1655 fi
1656 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1657   # MPFR v3.1.0 moved the sources into a src sub-directory.
1658   if ! test -d ${srcdir}/mpfr/src; then
1659     AC_MSG_ERROR([dnl
1660 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1661   fi
1662   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1663   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1664   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1665   # Do not test the mpfr version.  Assume that it is sufficient, since
1666   # it is in the source tree, and the library has not been built yet
1667   # but it would be included on the link line in the version check below
1668   # hence making the test fail.
1669   have_gmp=yes
1670 fi
1671
1672 # Specify a location for gmp
1673 AC_ARG_WITH(gmp,
1674 [AS_HELP_STRING([--with-gmp=PATH],
1675                 [specify prefix directory for the installed GMP package.
1676                  Equivalent to --with-gmp-include=PATH/include
1677                  plus --with-gmp-lib=PATH/lib])])
1678 AC_ARG_WITH(gmp-include,
1679 [AS_HELP_STRING([--with-gmp-include=PATH],
1680                 [specify directory for installed GMP include files])])
1681 AC_ARG_WITH(gmp-lib,
1682 [AS_HELP_STRING([--with-gmp-lib=PATH],
1683                 [specify directory for the installed GMP library])])
1684
1685
1686 if test "x$with_gmp" != x; then
1687   gmplibs="-L$with_gmp/lib $gmplibs"
1688   gmpinc="-I$with_gmp/include $gmpinc"
1689 fi
1690 if test "x$with_gmp_include" != x; then
1691   gmpinc="-I$with_gmp_include $gmpinc"
1692 fi
1693 if test "x$with_gmp_lib" != x; then
1694   gmplibs="-L$with_gmp_lib $gmplibs"
1695 fi
1696 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1697   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1698   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1699   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1700   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1701   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1702   # Do not test the gmp version.  Assume that it is sufficient, since
1703   # it is in the source tree, and the library has not been built yet
1704   # but it would be included on the link line in the version check below
1705   # hence making the test fail.
1706   have_gmp=yes
1707 fi
1708
1709 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1710   have_gmp=yes
1711   saved_CFLAGS="$CFLAGS"
1712   CFLAGS="$CFLAGS $gmpinc"
1713   # Check for the recommended and required versions of GMP.
1714   AC_MSG_CHECKING([for the correct version of gmp.h])
1715   AC_TRY_COMPILE([#include "gmp.h"],[
1716   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1717   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1718   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1719   choke me
1720   #endif
1721   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1722   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1723   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1724   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1725   choke me
1726   #endif
1727   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1728    [AC_MSG_RESULT([no]); have_gmp=no])
1729
1730   # If we have GMP, check the MPFR version.
1731   if test x"$have_gmp" = xyes; then
1732     # Check for the recommended and required versions of MPFR.
1733     AC_MSG_CHECKING([for the correct version of mpfr.h])
1734     AC_TRY_COMPILE([#include <gmp.h>
1735     #include <mpfr.h>],[
1736     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1737     choke me
1738     #endif
1739     ], [AC_TRY_COMPILE([#include <gmp.h>
1740     #include <mpfr.h>],[
1741     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1742     choke me
1743     #endif
1744     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1745      [AC_MSG_RESULT([no]); have_gmp=no])
1746   fi
1747
1748   # Check for the MPC header version.
1749   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1750     # Check for the recommended and required versions of MPC.
1751     AC_MSG_CHECKING([for the correct version of mpc.h])
1752     AC_TRY_COMPILE([#include <mpc.h>],[
1753     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1754     choke me
1755     #endif
1756     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1757     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1758     choke me
1759     #endif
1760     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1761      [AC_MSG_RESULT([no]); have_gmp=no])
1762   fi
1763
1764   # Now check the MPFR library.
1765   if test x"$have_gmp" = xyes; then
1766     saved_LIBS="$LIBS"
1767     LIBS="$LIBS $gmplibs"
1768     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1769     AC_TRY_LINK([#include <mpfr.h>],[
1770     mpfr_t n;
1771     mpfr_t x;
1772     int t;
1773     mpfr_init (n);
1774     mpfr_init (x);
1775     mpfr_atan2 (n, n, x, MPFR_RNDN);
1776     mpfr_erfc (n, x, MPFR_RNDN);
1777     mpfr_subnormalize (x, t, MPFR_RNDN);
1778     mpfr_clear(n);
1779     mpfr_clear(x);
1780     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1781     LIBS="$saved_LIBS"
1782   fi
1783
1784   # Now check the MPC library
1785   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1786     saved_LIBS="$LIBS"
1787     LIBS="$LIBS $gmplibs"
1788     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1789     AC_TRY_LINK([#include <mpc.h>],[
1790     mpc_t c;
1791     mpc_init2 (c, 53);
1792     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1793     mpc_cosh (c, c, MPC_RNDNN);
1794     mpc_pow (c, c, c, MPC_RNDNN);
1795     mpc_acosh (c, c, MPC_RNDNN);
1796     mpc_clear (c);
1797     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1798     LIBS="$saved_LIBS"
1799   fi
1800
1801   CFLAGS="$saved_CFLAGS"
1802
1803 # The library versions listed in the error message below should match
1804 # the HARD-minimums enforced above.
1805   if test x$have_gmp != xyes; then
1806     if test -d ${srcdir}/gcc ; then
1807       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1808 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1809 their locations.  Source code for these libraries can be found at
1810 their respective hosting sites as well as at
1811 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1812 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1813 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1814 make sure that you have installed both the libraries and the header
1815 files.  They may be located in separate packages.])
1816     else
1817       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1818 Try the --with-gmp and/or --with-mpfr options to specify
1819 their locations.  If you obtained GMP and/or MPFR from a vendor
1820 distribution package, make sure that you have installed both the libraries
1821 and the header files.  They may be located in separate packages.])
1822     fi
1823   fi
1824 fi
1825
1826 # Flags needed for both GMP, MPFR and/or MPC.
1827 AC_SUBST(gmplibs)
1828 AC_SUBST(gmpinc)
1829 AC_SUBST(extra_mpfr_configure_flags)
1830 AC_SUBST(extra_mpc_gmp_configure_flags)
1831 AC_SUBST(extra_mpc_mpfr_configure_flags)
1832 AC_SUBST(extra_isl_gmp_configure_flags)
1833
1834 # Libraries to use for stage1 or when not bootstrapping.
1835 AC_ARG_WITH(stage1-libs,
1836 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1837 [if test "$withval" = "no" -o "$withval" = "yes"; then
1838    stage1_libs=
1839  else
1840    stage1_libs=$withval
1841  fi],
1842 [stage1_libs=])
1843 AC_SUBST(stage1_libs)
1844
1845 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1846 # default is yes if gcc is being built; no otherwise.  The reason for
1847 # this default is that gdb is sometimes linked against GNU Source
1848 # Highlight, which is a shared library that uses C++ exceptions.  In
1849 # this case, -static-libstdc++ will cause crashes.
1850 AC_ARG_WITH(static-standard-libraries,
1851 [AS_HELP_STRING([--with-static-standard-libraries],
1852                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1853 [], [with_static_standard_libraries=auto])
1854 if test "$with_static_standard_libraries" = auto; then
1855   with_static_standard_libraries=$have_compiler
1856 fi
1857
1858 # Linker flags to use for stage1 or when not bootstrapping.
1859 AC_ARG_WITH(stage1-ldflags,
1860 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1861 [if test "$withval" = "no" -o "$withval" = "yes"; then
1862    stage1_ldflags=
1863  else
1864    stage1_ldflags=$withval
1865  fi],
1866 [stage1_ldflags=
1867  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1868  # if supported.  But if the user explicitly specified the libraries to use,
1869  # trust that they are doing what they want.
1870  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1871      -a "$have_static_libs" = yes; then
1872    stage1_ldflags="-static-libstdc++ -static-libgcc"
1873  fi])
1874 AC_SUBST(stage1_ldflags)
1875
1876 # Libraries to use for stage2 and later builds.
1877 AC_ARG_WITH(boot-libs,
1878 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1879 [if test "$withval" = "no" -o "$withval" = "yes"; then
1880    poststage1_libs=
1881  else
1882    poststage1_libs=$withval
1883  fi],
1884 [poststage1_libs=])
1885 AC_SUBST(poststage1_libs)
1886
1887 # Linker flags to use for stage2 and later builds.
1888 AC_ARG_WITH(boot-ldflags,
1889 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1890                 [linker flags for stage2 and later])],
1891 [if test "$withval" = "no" -o "$withval" = "yes"; then
1892    poststage1_ldflags=
1893  else
1894    poststage1_ldflags=$withval
1895  fi],
1896 [poststage1_ldflags=
1897  # In stages 2 and 3, default to linking libstdc++ and libgcc
1898  # statically.  But if the user explicitly specified the libraries to
1899  # use, trust that they are doing what they want.
1900  if test "$poststage1_libs" = ""; then
1901    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1902  fi])
1903 AC_SUBST(poststage1_ldflags)
1904
1905 # GCC GRAPHITE dependency isl.
1906 # Basic setup is inlined here, actual checks are in config/isl.m4
1907
1908 AC_ARG_WITH(isl,
1909   [AS_HELP_STRING(
1910    [--with-isl=PATH],
1911    [Specify prefix directory for the installed isl package.
1912     Equivalent to --with-isl-include=PATH/include
1913     plus --with-isl-lib=PATH/lib])])
1914
1915 # Treat --without-isl as a request to disable
1916 # GRAPHITE support and skip all following checks.
1917 if test "x$with_isl" != "xno"; then
1918   # Check for isl
1919   dnl Provide configure switches and initialize islinc & isllibs
1920   dnl with user input.
1921   ISL_INIT_FLAGS
1922   dnl The versions of isl that work for Graphite
1923   ISL_CHECK_VERSION()
1924   dnl Only execute fail-action, if isl has been requested.
1925   ISL_IF_FAILED([
1926     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1927 fi
1928
1929 # If the isl check failed, disable builds of in-tree variant of isl
1930 if test "x$with_isl" = xno ||
1931    test "x$gcc_cv_isl" = xno; then
1932   noconfigdirs="$noconfigdirs isl"
1933   islinc=
1934 fi
1935
1936 AC_SUBST(isllibs)
1937 AC_SUBST(islinc)
1938
1939 # Check for LTO support.
1940 AC_ARG_ENABLE(lto,
1941 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1942 enable_lto=$enableval,
1943 enable_lto=yes; default_enable_lto=yes)
1944
1945 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1946   build_lto_plugin=yes
1947 ],[if test x"$default_enable_lto" = x"yes" ; then
1948     case $target in
1949       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1950       # On other non-ELF platforms, LTO has yet to be validated.
1951       *) enable_lto=no ;;
1952     esac
1953   else
1954   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1955   # It would also be nice to check the binutils support, but we don't
1956   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1957   # warn during gcc/ subconfigure; unless you're bootstrapping with
1958   # -flto it won't be needed until after installation anyway.
1959     case $target in
1960       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1961       *) if test x"$enable_lto" = x"yes"; then
1962         AC_MSG_ERROR([LTO support is not enabled for this target.])
1963         fi
1964       ;;
1965     esac
1966   fi
1967   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1968   # Build it unless LTO was explicitly disabled.
1969   case $target in
1970     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1971     *) ;;
1972   esac
1973 ])
1974
1975 AC_ARG_ENABLE(linker-plugin-configure-flags,
1976   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1977     [additional flags for configuring linker plugins @<:@none@:>@])],
1978   extra_linker_plugin_configure_flags=$enableval,
1979   extra_linker_plugin_configure_flags=)
1980 AC_SUBST(extra_linker_plugin_configure_flags)
1981 AC_ARG_ENABLE(linker-plugin-flags,
1982   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1983     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1984   extra_linker_plugin_flags=$enableval,
1985   extra_linker_plugin_flags=)
1986 AC_SUBST(extra_linker_plugin_flags)
1987
1988 # Enable --enable-host-shared.
1989 # Checked early to determine whether jit is an 'all' language
1990 AC_ARG_ENABLE(host-shared,
1991 [AS_HELP_STRING([--enable-host-shared],
1992                 [build host code as shared libraries])],
1993 [host_shared=$enableval
1994  case $host in
1995    x86_64-*-darwin* | aarch64-*-darwin*)
1996      if test x$host_shared != xyes ; then
1997        # PIC is the default, and actually cannot be switched off.
1998        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1999        host_shared=yes
2000      fi ;;
2001   *) ;;
2002  esac],
2003 [case $host in
2004   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2005   *) host_shared=no ;;
2006  esac])
2007 AC_SUBST(host_shared)
2008
2009 # By default, C and C++ are the only stage 1 languages.
2010 stage1_languages=,c,
2011
2012 # Target libraries that we bootstrap.
2013 bootstrap_target_libs=,target-libgcc,
2014
2015 # Figure out what language subdirectories are present.
2016 # Look if the user specified --enable-languages="..."; if not, use
2017 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2018 # go away some day.
2019 # NB:  embedded tabs in this IF block -- do not untabify
2020 if test -d ${srcdir}/gcc; then
2021   if test x"${enable_languages+set}" != xset; then
2022     if test x"${LANGUAGES+set}" = xset; then
2023       enable_languages="${LANGUAGES}"
2024         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2025     else
2026       enable_languages=default
2027     fi
2028   else
2029     if test x"${enable_languages}" = x ||
2030        test x"${enable_languages}" = xyes;
2031        then
2032       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2033       exit 1
2034     fi
2035   fi
2036   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2037
2038   # 'f95' is the old name for the 'fortran' language. We issue a warning
2039   # and make the substitution.
2040   case ,${enable_languages}, in
2041     *,f95,*)
2042       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2043       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2044       ;;
2045   esac
2046
2047   # If bootstrapping, C++ must be enabled.
2048   case ",$enable_languages,:$enable_bootstrap" in
2049     *,c++,*:*) ;;
2050     *:yes)
2051       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2052         enable_languages="${enable_languages},c++"
2053       else
2054         AC_MSG_ERROR([bootstrapping requires c++ sources])
2055       fi
2056       ;;
2057   esac
2058
2059   # First scan to see if an enabled language requires some other language.
2060   # We assume that a given config-lang.in will list all the language
2061   # front ends it requires, even if some are required indirectly.
2062   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2063     case ${lang_frag} in
2064       ..) ;;
2065       # The odd quoting in the next line works around
2066       # an apparent bug in bash 1.12 on linux.
2067       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2068       *)
2069         # From the config-lang.in, get $language, $lang_requires, and
2070         # $lang_requires_boot_languages.
2071         language=
2072         lang_requires=
2073         lang_requires_boot_languages=
2074         # set srcdir during sourcing lang_frag to the gcc dir.
2075         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2076         # polutes this shell
2077         saved_srcdir=${srcdir}
2078         srcdir=${srcdir}/gcc . ${lang_frag}
2079         srcdir=${saved_srcdir}
2080         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2081           case ,${enable_languages}, in
2082             *,$other,*) ;;
2083             *,default,*) ;;
2084             *,all,*) ;;
2085             *,$language,*)
2086               echo " \`$other' language required by \`$language'; enabling" 1>&2
2087               enable_languages="${enable_languages},${other}"
2088               ;;
2089           esac
2090         done
2091         for other in ${lang_requires_boot_languages} ; do
2092           if test "$other" != "c"; then
2093             case ,${enable_stage1_languages}, in
2094               *,$other,*) ;;
2095               *,default,*) ;;
2096               *,all,*) ;;
2097               *)
2098                 case ,${enable_languages}, in
2099                   *,$language,*)
2100                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2101                     enable_stage1_languages="$enable_stage1_languages,${other}"
2102                     ;;
2103                 esac
2104                 ;;
2105             esac
2106           fi
2107         done
2108         ;;
2109     esac
2110   done
2111
2112   new_enable_languages=,c,
2113
2114   # If LTO is enabled, add the LTO front end.
2115   if test "$enable_lto" = "yes" ; then
2116     case ,${enable_languages}, in
2117       *,lto,*) ;;
2118       *) enable_languages="${enable_languages},lto" ;;
2119     esac
2120     if test "${build_lto_plugin}" = "yes" ; then
2121       configdirs="$configdirs lto-plugin"
2122     fi
2123   fi
2124
2125   # If we're building an offloading compiler, add the LTO front end.
2126   if test x"$enable_as_accelerator_for" != x ; then
2127     case ,${enable_languages}, in
2128       *,lto,*) ;;
2129       *) enable_languages="${enable_languages},lto" ;;
2130     esac
2131   fi
2132
2133   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2134   potential_languages=,c,
2135
2136   enabled_target_libs=
2137   disabled_target_libs=
2138
2139   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2140     case ${lang_frag} in
2141       ..) ;;
2142       # The odd quoting in the next line works around
2143       # an apparent bug in bash 1.12 on linux.
2144       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2145       *)
2146         # From the config-lang.in, get $language, $target_libs,
2147         # $lang_dirs, $boot_language, and $build_by_default
2148         language=
2149         target_libs=
2150         lang_dirs=
2151         subdir_requires=
2152         boot_language=no
2153         build_by_default=yes
2154         # set srcdir during sourcing.  See above about save & restore
2155         saved_srcdir=${srcdir}
2156         srcdir=${srcdir}/gcc . ${lang_frag}
2157         srcdir=${saved_srcdir}
2158         if test x${language} = x; then
2159           echo "${lang_frag} doesn't set \$language." 1>&2
2160           exit 1
2161         fi
2162
2163         if test "$language" = "c++"; then
2164           boot_language=yes
2165         fi
2166
2167         add_this_lang=no
2168         # C is always enabled, so no need to add it again
2169         if test "$language" != "c"; then
2170           case ,${enable_languages}, in
2171             *,${language},*)
2172               # Language was explicitly selected; include it
2173               add_this_lang=yes
2174               ;;
2175             *,all,*)
2176               # All languages are enabled
2177               add_this_lang=all
2178               ;;
2179             *,default,*)
2180               # 'default' was selected, select it if it is a default language
2181               add_this_lang=${build_by_default}
2182               ;;
2183           esac
2184         fi
2185
2186         # Disable languages that need other directories if these aren't available.
2187         for i in $subdir_requires; do
2188           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2189           case ${add_this_lang} in
2190             yes)
2191               # Specifically requested language; tell them.
2192               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2193               ;;
2194             all)
2195               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2196               add_this_lang=unsupported
2197               ;;
2198             *)
2199               # Silently disable.
2200               add_this_lang=unsupported
2201               ;;
2202           esac
2203         done
2204
2205         # Disable Ada if no preexisting GNAT is available.
2206         case ${add_this_lang}:${language}:${have_gnat} in
2207           yes:ada:no)
2208             # Specifically requested language; tell them.
2209             AC_MSG_ERROR([GNAT is required to build $language])
2210             ;;
2211           all:ada:no)
2212             AC_MSG_WARN([GNAT is required to build $language])
2213             add_this_lang=unsupported
2214             ;;
2215           *:ada:no)
2216             # Silently disable.
2217             add_this_lang=unsupported
2218             ;;
2219         esac
2220
2221         # Disable D if no preexisting GDC is available.
2222         case ${add_this_lang}:${language}:${have_gdc} in
2223           yes:d:no)
2224             # Specifically requested language; tell them.
2225             AC_MSG_ERROR([GDC is required to build $language])
2226            ;;
2227           all:d:no)
2228             AC_MSG_WARN([GDC is required to build $language])
2229             add_this_lang=unsupported
2230             ;;
2231           *:d:no)
2232             # Silently disable.
2233             add_this_lang=unsupported
2234             ;;
2235         esac
2236
2237         # Disable jit if -enable-host-shared not specified
2238         # but not if building for Mingw. All code in Windows
2239         # is position independent code (PIC).
2240         case $target in
2241           *mingw*) ;;
2242           *)
2243           case ${add_this_lang}:${language}:${host_shared} in
2244             yes:jit:no)
2245                    # PR jit/64780: explicitly specify --enable-host-shared
2246             AC_MSG_ERROR([
2247 Enabling language "jit" requires --enable-host-shared.
2248
2249 --enable-host-shared typically slows the rest of the compiler down by
2250 a few %, so you must explicitly enable it.
2251
2252 If you want to build both the jit and the regular compiler, it is often
2253 best to do this via two separate configure/builds, in separate
2254 directories, to avoid imposing the performance cost of
2255 --enable-host-shared on the regular compiler.])
2256                     ;;
2257             all:jit:no)
2258               AC_MSG_WARN([--enable-host-shared required to build $language])
2259               add_this_lang=unsupported
2260               ;;
2261             *:jit:no)
2262               # Silently disable.
2263               add_this_lang=unsupported
2264               ;;
2265                 esac
2266           ;;
2267         esac
2268
2269         # Disable a language that is unsupported by the target.
2270         case "${add_this_lang}: $unsupported_languages " in
2271           no:*) ;;
2272           unsupported:*) ;;
2273           *:*" $language "*)
2274             AC_MSG_WARN([${language} not supported for this target])
2275             add_this_lang=unsupported
2276             ;;
2277         esac
2278
2279         case $add_this_lang in
2280           unsupported)
2281             # Remove language-dependent dirs.
2282             disabled_target_libs="$disabled_target_libs $target_libs"
2283             noconfigdirs="$noconfigdirs $lang_dirs"
2284             ;;
2285           no)
2286             # Remove language-dependent dirs; still show language as supported.
2287             disabled_target_libs="$disabled_target_libs $target_libs"
2288             noconfigdirs="$noconfigdirs $lang_dirs"
2289             potential_languages="${potential_languages}${language},"
2290             ;;
2291           all|yes)
2292             new_enable_languages="${new_enable_languages}${language},"
2293             potential_languages="${potential_languages}${language},"
2294             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2295             enabled_target_libs="$enabled_target_libs $target_libs"
2296             case "${boot_language}:,$enable_stage1_languages," in
2297               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2298                 # Add to (comma-separated) list of stage 1 languages.
2299                 case ",$stage1_languages," in
2300                   *,$language,* | ,yes, | ,all,) ;;
2301                   *) stage1_languages="${stage1_languages}${language}," ;;
2302                 esac
2303                 # We need to bootstrap any supporting libraries.
2304                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2305                 ;;
2306             esac
2307             ;;
2308         esac
2309         ;;
2310     esac
2311   done
2312
2313   # Add target libraries which are only needed for disabled languages
2314   # to noconfigdirs.
2315   if test -n "$disabled_target_libs"; then
2316     for dir in $disabled_target_libs; do
2317       case " $enabled_target_libs " in
2318       *" ${dir} "*) ;;
2319       *) noconfigdirs="$noconfigdirs $dir" ;;
2320       esac
2321     done
2322   fi
2323
2324   AC_ARG_ENABLE(stage1-languages,
2325   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2326                   [choose additional languages to build during
2327                   stage1.  Mostly useful for compiler development])],
2328   [case ,${enable_stage1_languages}, in
2329     ,no,|,,)
2330       # Set it to something that will have no effect in the loop below
2331       enable_stage1_languages=c ;;
2332     ,yes,)
2333       enable_stage1_languages=`echo $new_enable_languages | \
2334         sed -e "s/^,//" -e "s/,$//" ` ;;
2335     *,all,*)
2336       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2337         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2338   esac
2339
2340   # Add "good" languages from enable_stage1_languages to stage1_languages,
2341   # while "bad" languages go in missing_languages.  Leave no duplicates.
2342   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2343     case $potential_languages in
2344       *,$i,*)
2345         case $stage1_languages in
2346           *,$i,*) ;;
2347           *) stage1_languages="$stage1_languages$i," ;;
2348         esac ;;
2349       *)
2350         case $missing_languages in
2351           *,$i,*) ;;
2352           *) missing_languages="$missing_languages$i," ;;
2353         esac ;;
2354      esac
2355   done])
2356
2357   # Remove leading/trailing commas that were added for simplicity
2358   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2359   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2360   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2361   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2362
2363   if test "x$missing_languages" != x; then
2364     AC_MSG_ERROR([
2365 The following requested languages could not be built: ${missing_languages}
2366 Supported languages are: ${potential_languages}])
2367   fi
2368   if test "x$new_enable_languages" != "x$enable_languages"; then
2369     echo The following languages will be built: ${new_enable_languages}
2370     enable_languages="$new_enable_languages"
2371   fi
2372
2373   AC_SUBST(stage1_languages)
2374   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2375 fi
2376
2377 # Handle --disable-<component> generically.
2378 for dir in $configdirs $build_configdirs $target_configdirs ; do
2379   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2380   varname=`echo $dirname | sed -e s/+/_/g`
2381   if eval test x\${enable_${varname}} "=" xno ; then
2382     noconfigdirs="$noconfigdirs $dir"
2383   fi
2384 done
2385
2386 # Check for Boehm's garbage collector
2387 AC_ARG_ENABLE(objc-gc,
2388 [AS_HELP_STRING([--enable-objc-gc],
2389                 [enable use of Boehm's garbage collector with the
2390                  GNU Objective-C runtime])])
2391 AC_ARG_WITH([target-bdw-gc],
2392 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2393                 [specify prefix directory for installed bdw-gc package.
2394                  Equivalent to --with-target-bdw-gc-include=PATH/include
2395                  plus --with-target-bdw-gc-lib=PATH/lib])])
2396 AC_ARG_WITH([target-bdw-gc-include],
2397 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2398                 [specify directories for installed bdw-gc include files])])
2399 AC_ARG_WITH([target-bdw-gc-lib],
2400 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2401                 [specify directories for installed bdw-gc library])])
2402
2403 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2404   AC_MSG_CHECKING([for bdw garbage collector])
2405   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2406     dnl no bdw-gw options, assume default locations
2407     AC_MSG_RESULT([using bdw-gc in default locations])
2408   else
2409     dnl bdw-gw options, first error checking, complete checking in libobjc
2410     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2411       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2412     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2413       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2414     else
2415       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2416     fi
2417   fi
2418 esac
2419
2420 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2421 case ,${enable_languages}, in
2422   *,c++,*)
2423     # Disable libitm, libsanitizer if we're not building libstdc++
2424     case "${noconfigdirs}" in
2425       *target-libstdc++-v3*)
2426         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2427         ;;
2428       *) ;;
2429     esac
2430     ;;
2431   *)
2432     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2433     ;;
2434 esac
2435
2436 # If gcc/ is not in the source tree then we'll not be building a
2437 # target compiler, assume in that case we don't want to build any
2438 # target libraries or tools.
2439 #
2440 # This was added primarily for the benefit for binutils-gdb who reuse
2441 # this configure script, but don't always have target tools available.
2442 if test ! -d ${srcdir}/gcc; then
2443    skipdirs="${skipdirs} ${target_configdirs}"
2444 fi
2445
2446 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2447 # $build_configdirs and $target_configdirs.
2448 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2449
2450 notsupp=""
2451 for dir in . $skipdirs $noconfigdirs ; do
2452   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2453   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2454     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2455     if test -r $srcdir/$dirname/configure ; then
2456       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2457         true
2458       else
2459         notsupp="$notsupp $dir"
2460       fi
2461     fi
2462   fi
2463   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2464     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2465     if test -r $srcdir/$dirname/configure ; then
2466       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2467         true
2468       else
2469         notsupp="$notsupp $dir"
2470       fi
2471     fi
2472   fi
2473   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2474     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2475     if test -r $srcdir/$dirname/configure ; then
2476       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2477         true
2478       else
2479         notsupp="$notsupp $dir"
2480       fi
2481     fi
2482   fi
2483 done
2484
2485 # Quietly strip out all directories which aren't configurable in this tree.
2486 # This relies on all configurable subdirectories being autoconfiscated, which
2487 # is now the case.
2488 build_configdirs_all="$build_configdirs"
2489 build_configdirs=
2490 for i in ${build_configdirs_all} ; do
2491   j=`echo $i | sed -e s/build-//g`
2492   if test -f ${srcdir}/$j/configure ; then
2493     build_configdirs="${build_configdirs} $i"
2494   fi
2495 done
2496
2497 configdirs_all="$configdirs"
2498 configdirs=
2499 for i in ${configdirs_all} ; do
2500   if test -f ${srcdir}/$i/configure ; then
2501     configdirs="${configdirs} $i"
2502   fi
2503 done
2504
2505 target_configdirs_all="$target_configdirs"
2506 target_configdirs=
2507 for i in ${target_configdirs_all} ; do
2508   j=`echo $i | sed -e s/target-//g`
2509   if test -f ${srcdir}/$j/configure ; then
2510     target_configdirs="${target_configdirs} $i"
2511   fi
2512 done
2513
2514 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2515 # so we have to add it after the preceding checks.
2516 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2517 then
2518   case " $configdirs " in
2519     *" libiberty "*)
2520       # If we can build libiberty, we can also build libiberty-linker-plugin.
2521       configdirs="$configdirs libiberty-linker-plugin"
2522       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2523         --with-libiberty=../libiberty-linker-plugin";;
2524     *)
2525       AC_MSG_ERROR([libiberty missing]);;
2526   esac
2527 fi
2528
2529 # Sometimes we have special requirements for the host libiberty.
2530 extra_host_libiberty_configure_flags=
2531 case " $configdirs " in
2532   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2533     # When these are to be built as shared libraries, the same applies to
2534     # libiberty.
2535     extra_host_libiberty_configure_flags=--enable-shared
2536     ;;
2537 esac
2538 AC_SUBST(extra_host_libiberty_configure_flags)
2539
2540 # Sometimes we have special requirements for the host zlib.
2541 extra_host_zlib_configure_flags=
2542 case " $configdirs " in
2543   *" bfd "*)
2544     # When bfd is to be built as a shared library, the same applies to
2545     # zlib.
2546     if test "$enable_shared" = "yes"; then
2547       extra_host_zlib_configure_flags=--enable-host-shared
2548     fi
2549     ;;
2550 esac
2551 AC_SUBST(extra_host_zlib_configure_flags)
2552
2553 # Produce a warning message for the subdirs we can't configure.
2554 # This isn't especially interesting in the Cygnus tree, but in the individual
2555 # FSF releases, it's important to let people know when their machine isn't
2556 # supported by the one or two programs in a package.
2557
2558 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2559   # If $appdirs is non-empty, at least one of those directories must still
2560   # be configured, or we error out.  (E.g., if the gas release supports a
2561   # specified target in some subdirs but not the gas subdir, we shouldn't
2562   # pretend that all is well.)
2563   if test -n "$appdirs" ; then
2564     for dir in $appdirs ; do
2565       if test -r $dir/Makefile.in ; then
2566         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2567           appdirs=""
2568           break
2569         fi
2570         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2571           appdirs=""
2572           break
2573         fi
2574       fi
2575     done
2576     if test -n "$appdirs" ; then
2577       echo "*** This configuration is not supported by this package." 1>&2
2578       exit 1
2579     fi
2580   fi
2581   # Okay, some application will build, or we don't care to check.  Still
2582   # notify of subdirs not getting built.
2583   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2584   echo "    ${notsupp}" 1>&2
2585   echo "    (Any other directories should still work fine.)" 1>&2
2586 fi
2587
2588 case "$host" in
2589   *msdosdjgpp*)
2590     enable_gdbtk=no ;;
2591 esac
2592
2593 # To find our prefix, in gcc_cv_tool_prefix.
2594 ACX_TOOL_DIRS
2595
2596 copy_dirs=
2597
2598 AC_ARG_WITH([build-sysroot],
2599   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2600                   [use sysroot as the system root during the build])],
2601   [if test x"$withval" != x ; then
2602      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2603    fi],
2604   [SYSROOT_CFLAGS_FOR_TARGET=])
2605 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2606
2607 AC_ARG_WITH([debug-prefix-map],
2608   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2609                   [map A to B, C to D ... in debug information])],
2610   [if test x"$withval" != x; then
2611      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2612      for debug_map in $withval; do
2613        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2614      done
2615    fi],
2616   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2617 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2618
2619 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2620 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2621 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2622 # We want to ensure that TARGET libraries (which we know are built with
2623 # gcc) are built with "-O2 -g", so include those options when setting
2624 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2625 if test "x$CFLAGS_FOR_TARGET" = x; then
2626   if test "x${is_cross_compiler}" = xyes; then
2627     CFLAGS_FOR_TARGET="-g -O2"
2628   else
2629     CFLAGS_FOR_TARGET=$CFLAGS
2630     case " $CFLAGS " in
2631       *" -O2 "*) ;;
2632       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2633     esac
2634     case " $CFLAGS " in
2635       *" -g "* | *" -g3 "*) ;;
2636       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2637     esac
2638   fi
2639 fi
2640 AC_SUBST(CFLAGS_FOR_TARGET)
2641
2642 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2643   if test "x${is_cross_compiler}" = xyes; then
2644     CXXFLAGS_FOR_TARGET="-g -O2"
2645   else
2646     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2647     case " $CXXFLAGS " in
2648       *" -O2 "*) ;;
2649       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2650     esac
2651     case " $CXXFLAGS " in
2652       *" -g "* | *" -g3 "*) ;;
2653       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2654     esac
2655   fi
2656 fi
2657 AC_SUBST(CXXFLAGS_FOR_TARGET)
2658
2659 AC_SUBST(LDFLAGS_FOR_TARGET)
2660
2661 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2662 # the named directory are copied to $(tooldir)/sys-include.
2663 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2664   if test x${is_cross_compiler} = xno ; then
2665     echo 1>&2 '***' --with-headers is only supported when cross compiling
2666     exit 1
2667   fi
2668   if test x"${with_headers}" != xyes ; then
2669     x=${gcc_cv_tool_prefix}
2670     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2671   fi
2672 fi
2673
2674 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2675 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2676 # are permitted.
2677 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2678   if test x${is_cross_compiler} = xno ; then
2679     echo 1>&2 '***' --with-libs is only supported when cross compiling
2680     exit 1
2681   fi
2682   if test x"${with_libs}" != xyes ; then
2683     # Copy the libraries in reverse order, so that files in the first named
2684     # library override files in subsequent libraries.
2685     x=${gcc_cv_tool_prefix}
2686     for l in ${with_libs}; do
2687       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2688     done
2689   fi
2690 fi
2691
2692 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2693 #
2694 # This is done by determining whether or not the appropriate directory
2695 # is available, and by checking whether or not specific configurations
2696 # have requested that this magic not happen.
2697 #
2698 # The command line options always override the explicit settings in
2699 # configure.ac, and the settings in configure.ac override this magic.
2700 #
2701 # If the default for a toolchain is to use GNU as and ld, and you don't
2702 # want to do that, then you should use the --without-gnu-as and
2703 # --without-gnu-ld options for the configure script.  Similarly, if
2704 # the default is to use the included zlib and you don't want to do that,
2705 # you should use the --with-system-zlib option for the configure script.
2706
2707 if test x${use_gnu_as} = x &&
2708    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2709   with_gnu_as=yes
2710   extra_host_args="$extra_host_args --with-gnu-as"
2711 fi
2712
2713 if test x${use_gnu_ld} = x &&
2714    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2715   with_gnu_ld=yes
2716   extra_host_args="$extra_host_args --with-gnu-ld"
2717 fi
2718
2719 if test x${use_included_zlib} = x &&
2720    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2721   :
2722 else
2723   with_system_zlib=yes
2724   extra_host_args="$extra_host_args --with-system-zlib"
2725 fi
2726
2727 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2728 # can detect this case.
2729
2730 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2731   with_newlib=yes
2732   extra_host_args="$extra_host_args --with-newlib"
2733 fi
2734
2735 # Handle ${copy_dirs}
2736 set fnord ${copy_dirs}
2737 shift
2738 while test $# != 0 ; do
2739   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2740     :
2741   else
2742     echo Copying $1 to $2
2743
2744     # Use the install script to create the directory and all required
2745     # parent directories.
2746     if test -d $2 ; then
2747       :
2748     else
2749       echo >config.temp
2750       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2751     fi
2752
2753     # Copy the directory, assuming we have tar.
2754     # FIXME: Should we use B in the second tar?  Not all systems support it.
2755     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2756
2757     # It is the responsibility of the user to correctly adjust all
2758     # symlinks.  If somebody can figure out how to handle them correctly
2759     # here, feel free to add the code.
2760
2761     echo $1 > $2/COPIED
2762   fi
2763   shift; shift
2764 done
2765
2766 # Determine a target-dependent exec_prefix that the installed
2767 # gcc will search in.  Keep this list sorted by triplet, with
2768 # the *-*-osname triplets last.
2769 md_exec_prefix=
2770 case "${target}" in
2771   i[[34567]]86-pc-msdosdjgpp*)
2772     md_exec_prefix=/dev/env/DJDIR/bin
2773     ;;
2774   *-*-hpux* | \
2775   *-*-nto-qnx* | \
2776   *-*-solaris2*)
2777     md_exec_prefix=/usr/ccs/bin
2778     ;;
2779 esac
2780
2781 extra_arflags_for_target=
2782 extra_nmflags_for_target=
2783 extra_ranlibflags_for_target=
2784 target_makefile_frag=/dev/null
2785 case "${target}" in
2786   spu-*-*)
2787     target_makefile_frag="config/mt-spu"
2788     ;;
2789   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2790     target_makefile_frag="config/mt-sde"
2791     ;;
2792   mipsisa*-*-elfoabi*)
2793     target_makefile_frag="config/mt-mips-elfoabi"
2794     ;;
2795   mips*-*-*linux* | mips*-*-gnu*)
2796     target_makefile_frag="config/mt-mips-gnu"
2797     ;;
2798   nios2-*-elf*)
2799     target_makefile_frag="config/mt-nios2-elf"
2800     ;;
2801   *-*-linux-android*)
2802     target_makefile_frag="config/mt-android"
2803     ;;
2804   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2805     target_makefile_frag="config/mt-gnu"
2806     ;;
2807   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2808     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2809     # commands to handle both 32-bit and 64-bit objects.  These flags are
2810     # harmless if we're using GNU nm or ar.
2811     extra_arflags_for_target=" -X32_64"
2812     extra_nmflags_for_target=" -B -X32_64"
2813     ;;
2814 esac
2815
2816 alphaieee_frag=/dev/null
2817 case $target in
2818   alpha*-*-*)
2819     # This just makes sure to use the -mieee option to build target libs.
2820     # This should probably be set individually by each library.
2821     alphaieee_frag="config/mt-alphaieee"
2822     ;;
2823 esac
2824
2825 # If --enable-target-optspace always use -Os instead of -O2 to build
2826 # the target libraries, similarly if it is not specified, use -Os
2827 # on selected platforms.
2828 ospace_frag=/dev/null
2829 case "${enable_target_optspace}:${target}" in
2830   yes:*)
2831     ospace_frag="config/mt-ospace"
2832     ;;
2833   :d30v-*)
2834     ospace_frag="config/mt-d30v"
2835     ;;
2836   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2837     ospace_frag="config/mt-ospace"
2838     ;;
2839   no:* | :*)
2840     ;;
2841   *)
2842     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2843     ;;
2844 esac
2845
2846 # Some systems (e.g., one of the i386-aix systems the gas testers are
2847 # using) don't handle "\$" correctly, so don't use it here.
2848 tooldir='${exec_prefix}'/${target_noncanonical}
2849 build_tooldir=${tooldir}
2850
2851 # Create a .gdbinit file which runs the one in srcdir
2852 # and tells GDB to look there for source files.
2853
2854 if test -r ${srcdir}/.gdbinit ; then
2855   case ${srcdir} in
2856     .) ;;
2857     *) cat > ./.gdbinit <<EOF
2858 # ${NO_EDIT}
2859 dir ${srcdir}
2860 dir .
2861 source ${srcdir}/.gdbinit
2862 EOF
2863     ;;
2864   esac
2865 fi
2866
2867 # Make sure that the compiler is able to generate an executable.  If it
2868 # can't, we are probably in trouble.  We don't care whether we can run the
2869 # executable--we might be using a cross compiler--we only care whether it
2870 # can be created.  At this point the main configure script has set CC.
2871 we_are_ok=no
2872 echo "int main () { return 0; }" > conftest.c
2873 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2874 if test $? = 0 ; then
2875   if test -s conftest || test -s conftest.exe ; then
2876     we_are_ok=yes
2877   fi
2878 fi
2879 case $we_are_ok in
2880   no)
2881     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2882     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2883     rm -f conftest*
2884     exit 1
2885     ;;
2886 esac
2887 rm -f conftest*
2888
2889 # Decide which environment variable is used to find dynamic libraries.
2890 case "${host}" in
2891   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2892   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2893   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2894   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2895 esac
2896
2897 # On systems where the dynamic library environment variable is PATH,
2898 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2899 # built executables to PATH.
2900 if test "$RPATH_ENVVAR" = PATH; then
2901   GCC_SHLIB_SUBDIR=/shlib
2902 else
2903   GCC_SHLIB_SUBDIR=
2904 fi
2905
2906 # Adjust the toplevel makefile according to whether bootstrap was selected.
2907 case $enable_bootstrap in
2908   yes)
2909     bootstrap_suffix=bootstrap
2910     BUILD_CONFIG=bootstrap-debug
2911     ;;
2912   no)
2913     bootstrap_suffix=no-bootstrap
2914     BUILD_CONFIG=
2915     ;;
2916 esac
2917
2918 AC_MSG_CHECKING(for default BUILD_CONFIG)
2919
2920 AC_ARG_WITH([build-config],
2921   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2922                   [use config/NAME.mk build configuration])],
2923   [case $with_build_config in
2924    yes) with_build_config= ;;
2925    no) with_build_config= BUILD_CONFIG= ;;
2926    esac])
2927
2928 if test "x${with_build_config}" != x; then
2929   BUILD_CONFIG=$with_build_config
2930 else
2931   case $BUILD_CONFIG in
2932   bootstrap-debug)
2933     if echo "int f (void) { return 0; }" > conftest.c &&
2934        ${CC} -c conftest.c &&
2935        mv conftest.o conftest.o.g0 &&
2936        ${CC} -c -g conftest.c &&
2937        mv conftest.o conftest.o.g &&
2938        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2939       :
2940     else
2941       BUILD_CONFIG=
2942     fi
2943     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2944     ;;
2945   esac
2946 fi
2947 AC_MSG_RESULT($BUILD_CONFIG)
2948 AC_SUBST(BUILD_CONFIG)
2949
2950 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2951 AC_MSG_CHECKING([for --enable-vtable-verify])
2952 AC_ARG_ENABLE(vtable-verify,
2953 [AS_HELP_STRING([--enable-vtable-verify],
2954                 [Enable vtable verification feature])],
2955 [case "$enableval" in
2956  yes) enable_vtable_verify=yes ;;
2957  no)  enable_vtable_verify=no ;;
2958  *)   enable_vtable_verify=no;;
2959  esac],
2960 [enable_vtable_verify=no])
2961 AC_MSG_RESULT($enable_vtable_verify)
2962
2963 # Record target_configdirs and the configure arguments for target and
2964 # build configuration in Makefile.
2965 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2966 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2967 bootstrap_fixincludes=no
2968
2969 # If we are building libgomp, bootstrap it.
2970 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2971   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2972 fi
2973
2974 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2975 # or bootstrap-ubsan, bootstrap it.
2976 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2977   case "$BUILD_CONFIG" in
2978     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2979       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2980       bootstrap_fixincludes=yes
2981       ;;
2982   esac
2983 fi
2984
2985 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2986 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2987    test "$enable_vtable_verify" != no; then
2988   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2989 fi
2990
2991 # If we are building libatomic and the list of enabled languages includes the
2992 # D frontend, bootstrap it.
2993 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2994   case ,${enable_languages}, in
2995     *,d,*)
2996       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2997       ;;
2998   esac
2999 fi
3000
3001 # Determine whether gdb needs tk/tcl or not.
3002 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3003 # and in that case we want gdb to be built without tk.  Ugh!
3004 # In fact I believe gdb is the *only* package directly dependent on tk,
3005 # so we should be able to put the 'maybe's in unconditionally and
3006 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3007 # 100% sure that that's safe though.
3008
3009 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3010 case "$enable_gdbtk" in
3011   no)
3012     GDB_TK="" ;;
3013   yes)
3014     GDB_TK="${gdb_tk}" ;;
3015   *)
3016     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3017     # distro.  Eventually someone will fix this and move Insight, nee
3018     # gdbtk to a separate directory.
3019     if test -d ${srcdir}/gdb/gdbtk ; then
3020       GDB_TK="${gdb_tk}"
3021     else
3022       GDB_TK=""
3023     fi
3024     ;;
3025 esac
3026 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3027 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3028
3029 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3030 # else does, only include them if one of these is built.  The Makefile
3031 # provides the ordering, so it's enough here to add to the list.
3032 case " ${configdirs} " in
3033   *\ gdb\ *)
3034     configdirs="${configdirs} gnulib gdbsupport"
3035     ;;
3036   *\ gdbserver\ *)
3037     configdirs="${configdirs} gnulib gdbsupport"
3038     ;;
3039   *\ sim\ *)
3040     configdirs="${configdirs} gnulib"
3041     ;;
3042 esac
3043
3044 # Strip out unwanted targets.
3045
3046 # While at that, we remove Makefiles if we were started for recursive
3047 # configuration, so that the top-level Makefile reconfigures them,
3048 # like we used to do when configure itself was recursive.
3049
3050 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3051 # but now we're fixing up the Makefile ourselves with the additional
3052 # commands passed to AC_CONFIG_FILES.  Use separate variables
3053 # extrasub-{build,host,target} not because there is any reason to split
3054 # the substitutions up that way, but only to remain below the limit of
3055 # 99 commands in a script, for HP-UX sed.
3056
3057 # Do not nest @if/@endif or @unless/@endunless pairs, because
3058 # configure will not warn you at all.
3059
3060 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3061   yes:yes:*\ gold\ *:*,c++,*) ;;
3062   yes:yes:*\ gold\ *:*)
3063     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3064     ;;
3065 esac
3066
3067 extrasub_build=
3068 for module in ${build_configdirs} ; do
3069   if test -z "${no_recursion}" \
3070      && test -f ${build_subdir}/${module}/Makefile; then
3071     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3072     rm -f ${build_subdir}/${module}/Makefile
3073   fi
3074   extrasub_build="$extrasub_build
3075 /^@if build-$module\$/d
3076 /^@endif build-$module\$/d
3077 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3078 /^@if build-$module-$bootstrap_suffix\$/d
3079 /^@endif build-$module-$bootstrap_suffix\$/d
3080 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3081 done
3082 extrasub_host=
3083 for module in ${configdirs} ; do
3084   if test -z "${no_recursion}"; then
3085     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3086       if test -f ${file}; then
3087         echo 1>&2 "*** removing ${file} to force reconfigure"
3088         rm -f ${file}
3089       fi
3090     done
3091   fi
3092   case ${module},${bootstrap_fixincludes} in
3093     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3094     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3095   esac
3096   extrasub_host="$extrasub_host
3097 /^@if $module\$/d
3098 /^@endif $module\$/d
3099 /^@unless $module\$/,/^@endunless $module\$/d
3100 /^@if $module-$host_bootstrap_suffix\$/d
3101 /^@endif $module-$host_bootstrap_suffix\$/d
3102 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3103 done
3104 extrasub_target=
3105 for module in ${target_configdirs} ; do
3106   if test -z "${no_recursion}" \
3107      && test -f ${target_subdir}/${module}/Makefile; then
3108     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3109     rm -f ${target_subdir}/${module}/Makefile
3110   fi
3111
3112   # We only bootstrap target libraries listed in bootstrap_target_libs.
3113   case $bootstrap_target_libs in
3114     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3115     *) target_bootstrap_suffix=no-bootstrap ;;
3116   esac
3117
3118   extrasub_target="$extrasub_target
3119 /^@if target-$module\$/d
3120 /^@endif target-$module\$/d
3121 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3122 /^@if target-$module-$target_bootstrap_suffix\$/d
3123 /^@endif target-$module-$target_bootstrap_suffix\$/d
3124 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3125 done
3126
3127 # Do the final fixup along with target modules.
3128 extrasub_target="$extrasub_target
3129 /^@if /,/^@endif /d
3130 /^@unless /d
3131 /^@endunless /d"
3132
3133 if test "$enable_pgo_build" != "no"; then
3134   extrasub_build="$extrasub_build
3135 /^@if pgo-build\$/d
3136 /^@endif pgo-build\$/d"
3137 fi
3138
3139 # Create the serialization dependencies.  This uses a temporary file.
3140
3141 AC_ARG_ENABLE([serial-configure],
3142 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3143                 [force sequential configuration of
3144                  sub-packages for the host, target or build
3145                  machine, or all sub-packages])])
3146
3147 case ${enable_serial_configure} in
3148   yes)
3149     enable_serial_build_configure=yes
3150     enable_serial_host_configure=yes
3151     enable_serial_target_configure=yes
3152     ;;
3153 esac
3154
3155 # These force 'configure's to be done one at a time, to avoid problems
3156 # with contention over a shared config.cache.
3157 rm -f serdep.tmp
3158 echo '# serdep.tmp' > serdep.tmp
3159 olditem=
3160 test "x${enable_serial_build_configure}" = xyes &&
3161 for item in ${build_configdirs} ; do
3162   case ${olditem} in
3163     "") ;;
3164     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3165   esac
3166   olditem=${item}
3167 done
3168 olditem=
3169 test "x${enable_serial_host_configure}" = xyes &&
3170 for item in ${configdirs} ; do
3171   case ${olditem} in
3172     "") ;;
3173     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3174   esac
3175   olditem=${item}
3176 done
3177 olditem=
3178 test "x${enable_serial_target_configure}" = xyes &&
3179 for item in ${target_configdirs} ; do
3180   case ${olditem} in
3181     "") ;;
3182     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3183   esac
3184   olditem=${item}
3185 done
3186 serialization_dependencies=serdep.tmp
3187 AC_SUBST_FILE(serialization_dependencies)
3188
3189 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3190 # target, nonopt, and variable assignments.  These are the ones we
3191 # might not want to pass down to subconfigures.  The exception being
3192 # --cache-file=/dev/null, which is used to turn off the use of cache
3193 # files altogether, and which should be passed on to subconfigures.
3194 # Also strip program-prefix, program-suffix, and program-transform-name,
3195 # so that we can pass down a consistent program-transform-name.
3196 baseargs=
3197 tbaseargs=
3198 keep_next=no
3199 skip_next=no
3200 eval "set -- $ac_configure_args"
3201 for ac_arg
3202 do
3203   if test X"$skip_next" = X"yes"; then
3204     skip_next=no
3205     continue
3206   fi
3207   if test X"$keep_next" = X"yes"; then
3208     case $ac_arg in
3209       *\'*)
3210         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3211     esac
3212     baseargs="$baseargs '$ac_arg'"
3213     tbaseargs="$tbaseargs '$ac_arg'"
3214     keep_next=no
3215     continue
3216   fi
3217
3218   # Handle separated arguments.  Based on the logic generated by
3219   # autoconf 2.59.
3220   case $ac_arg in
3221     *=* | --config-cache | -C | -disable-* | --disable-* \
3222       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3223       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3224       | -with-* | --with-* | -without-* | --without-* | --x)
3225       separate_arg=no
3226       ;;
3227     -*)
3228       separate_arg=yes
3229       ;;
3230     *)
3231       separate_arg=no
3232       ;;
3233   esac
3234
3235   skip_targ=no
3236   case $ac_arg in
3237 changequote(,)
3238   --with-* | --without-*)
3239     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3240
3241     case $libopt in
3242     *[-_]include)
3243       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3244       ;;
3245     *[-_]lib)
3246       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3247       ;;
3248     *)
3249       lib=$libopt
3250       ;;
3251     esac
3252 changequote([,])
3253
3254     case $lib in
3255     mpc | mpfr | gmp | isl)
3256       # If we're processing --with-$lib, --with-$lib-include or
3257       # --with-$lib-lib, for one of the libs above, and target is
3258       # different from host, don't pass the current argument to any
3259       # target library's configure.
3260       if test x$is_cross_compiler = xyes; then
3261         skip_targ=yes
3262       fi
3263       ;;
3264     esac
3265     ;;
3266   esac
3267
3268   case "$ac_arg" in
3269     --cache-file=/dev/null | \
3270     -cache-file=/dev/null )
3271       # Handled here to avoid the test to skip args below.
3272       baseargs="$baseargs '$ac_arg'"
3273       tbaseargs="$tbaseargs '$ac_arg'"
3274       # Assert: $separate_arg should always be no.
3275       keep_next=$separate_arg
3276       ;;
3277     --no*)
3278       continue
3279       ;;
3280     --c* | \
3281     --sr* | \
3282     --ho* | \
3283     --bu* | \
3284     --t* | \
3285     --program-* | \
3286     -cache_file* | \
3287     -srcdir* | \
3288     -host* | \
3289     -build* | \
3290     -target* | \
3291     -program-prefix* | \
3292     -program-suffix* | \
3293     -program-transform-name* )
3294       skip_next=$separate_arg
3295       continue
3296       ;;
3297     -*)
3298       # An option.  Add it.
3299       case $ac_arg in
3300         *\'*)
3301           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3302       esac
3303       baseargs="$baseargs '$ac_arg'"
3304       if test X"$skip_targ" = Xno; then
3305         tbaseargs="$tbaseargs '$ac_arg'"
3306       fi
3307       keep_next=$separate_arg
3308       ;;
3309     *)
3310       # Either a variable assignment, or a nonopt (triplet).  Don't
3311       # pass it down; let the Makefile handle this.
3312       continue
3313       ;;
3314   esac
3315 done
3316 # Remove the initial space we just introduced and, as these will be
3317 # expanded by make, quote '$'.
3318 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3319
3320 # Add in --program-transform-name, after --program-prefix and
3321 # --program-suffix have been applied to it.  Autoconf has already
3322 # doubled dollar signs and backslashes in program_transform_name; we want
3323 # the backslashes un-doubled, and then the entire thing wrapped in single
3324 # quotes, because this will be expanded first by make and then by the shell.
3325 # Also, because we want to override the logic in subdir configure scripts to
3326 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3327 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3328 ${program_transform_name}
3329 EOF_SED
3330 gcc_transform_name=`cat conftestsed.out`
3331 rm -f conftestsed.out
3332 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3333 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3334 if test "$silent" = yes; then
3335   baseargs="$baseargs --silent"
3336   tbaseargs="$tbaseargs --silent"
3337 fi
3338
3339 baseargs="$baseargs --disable-option-checking"
3340 tbaseargs="$tbaseargs --disable-option-checking"
3341
3342 if test "$enable_year2038" = no; then
3343   baseargs="$baseargs --disable-year2038"
3344   tbaseargs="$tbaseargs --disable-year2038"
3345 fi
3346
3347 # Record and document user additions to sub configure arguments.
3348 AC_ARG_VAR([build_configargs],
3349            [additional configure arguments for build directories])
3350 AC_ARG_VAR([host_configargs],
3351            [additional configure arguments for host directories])
3352 AC_ARG_VAR([target_configargs],
3353            [additional configure arguments for target directories])
3354
3355 # For the build-side libraries, we just need to pretend we're native,
3356 # and not use the same cache file.  Multilibs are neither needed nor
3357 # desired.  We can't even use the same cache file for all build-side
3358 # libraries, as they're compiled differently; some with C, some with
3359 # C++ or with different feature-enabling options.
3360 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3361
3362 # For host modules, accept cache file option, or specification as blank.
3363 case "${cache_file}" in
3364 "") # empty
3365   cache_file_option="" ;;
3366 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3367   cache_file_option="--cache-file=${cache_file}" ;;
3368 *) # relative path
3369   cache_file_option="--cache-file=../${cache_file}" ;;
3370 esac
3371
3372 # Host dirs don't like to share a cache file either, horribly enough.
3373 # This seems to be due to autoconf 2.5x stupidity.
3374 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3375
3376 target_configargs="$target_configargs ${tbaseargs}"
3377
3378 # Passing a --with-cross-host argument lets the target libraries know
3379 # whether they are being built with a cross-compiler or being built
3380 # native.  However, it would be better to use other mechanisms to make the
3381 # sorts of decisions they want to make on this basis.  Please consider
3382 # this option to be deprecated.  FIXME.
3383 if test x${is_cross_compiler} = xyes ; then
3384   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3385 fi
3386
3387 # Special user-friendly check for native x86_64-linux build, if
3388 # multilib is not explicitly enabled.
3389 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3390   x86_64-*linux*:yes:$build:$build:)
3391     # Make sure we have a development environment that handles 32-bit
3392     dev64=no
3393     echo "int main () { return 0; }" > conftest.c
3394     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3395     if test $? = 0 ; then
3396       if test -s conftest || test -s conftest.exe ; then
3397         dev64=yes
3398       fi
3399     fi
3400     rm -f conftest*
3401     if test x${dev64} != xyes ; then
3402       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3403     fi
3404     ;;
3405 esac
3406
3407 # Default to --enable-multilib.
3408 if test x${enable_multilib} = x ; then
3409   target_configargs="--enable-multilib ${target_configargs}"
3410 fi
3411
3412 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3413 # changed from the earlier setting of with_newlib.
3414 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3415   target_configargs="--with-newlib ${target_configargs}"
3416 fi
3417
3418 # Different target subdirs use different values of certain variables
3419 # (notably CXX).  Worse, multilibs use *lots* of different values.
3420 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3421 # it doesn't automatically accept command-line overrides of them.
3422 # This means it's not safe for target subdirs to share a cache file,
3423 # which is disgusting, but there you have it.  Hopefully this can be
3424 # fixed in future.  It's still worthwhile to use a cache file for each
3425 # directory.  I think.
3426
3427 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3428 # We need to pass --target, as newer autoconf's requires consistency
3429 # for target_alias and gcc doesn't manage it consistently.
3430 target_configargs="--cache-file=./config.cache ${target_configargs}"
3431
3432 FLAGS_FOR_TARGET=
3433 case " $target_configdirs " in
3434  *" newlib "*)
3435   case " $target_configargs " in
3436   *" --with-newlib "*)
3437    case "$target" in
3438     *-cygwin*)
3439       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3440       ;;
3441    esac
3442
3443    # If we're not building GCC, don't discard standard headers.
3444    if test -d ${srcdir}/gcc; then
3445      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3446
3447      if test "${build}" != "${host}"; then
3448        # On Canadian crosses, CC_FOR_TARGET will have already been set
3449        # by `configure', so we won't have an opportunity to add -Bgcc/
3450        # to it.  This is right: we don't want to search that directory
3451        # for binaries, but we want the header files in there, so add
3452        # them explicitly.
3453        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3454
3455        # Someone might think of using the pre-installed headers on
3456        # Canadian crosses, in case the installed compiler is not fully
3457        # compatible with the compiler being built.  In this case, it
3458        # would be better to flag an error than risking having
3459        # incompatible object files being constructed.  We can't
3460        # guarantee that an error will be flagged, but let's hope the
3461        # compiler will do it, when presented with incompatible header
3462        # files.
3463      fi
3464    fi
3465
3466    case "${target}-${is_cross_compiler}" in
3467    i[[3456789]]86-*-linux*-no)
3468       # Here host == target, so we don't need to build gcc,
3469       # so we don't want to discard standard headers.
3470       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3471       ;;
3472    *)
3473       # If we're building newlib, use its generic headers last, but search
3474       # for any libc-related directories first (so make it the last -B
3475       # switch).
3476       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3477
3478       # If we're building libgloss, find the startup file, simulator library
3479       # and linker script.
3480       case " $target_configdirs " in
3481         *" libgloss "*)
3482         # Look for startup file, simulator library and maybe linker script.
3483         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3484         # Look for libnosys.a in case the target needs it.
3485         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3486         # Most targets have the linker script in the source directory.
3487         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3488         ;;
3489       esac
3490       ;;
3491    esac
3492    ;;
3493   esac
3494   ;;
3495 esac
3496
3497 case "$target" in
3498   x86_64-*mingw* | *-w64-mingw*)
3499   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3500   # however, use a symlink named 'mingw' in ${prefix} .
3501     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3502     ;;
3503   *-mingw*)
3504   # MinGW can't be handled as Cygwin above since it does not use newlib.
3505     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3506     ;;
3507 esac
3508
3509 # Allow the user to override the flags for
3510 # our build compiler if desired.
3511 if test x"${build}" = x"${host}" ; then
3512   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3513   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3514   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3515   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3516 fi
3517
3518 # On Canadian crosses, we'll be searching the right directories for
3519 # the previously-installed cross compiler, so don't bother to add
3520 # flags for directories within the install tree of the compiler
3521 # being built; programs in there won't even run.
3522 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3523   # Search for pre-installed headers if nothing else fits.
3524   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3525 fi
3526
3527 if test "x${use_gnu_ld}" = x &&
3528    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3529   # Arrange for us to find uninstalled linker scripts.
3530   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3531 fi
3532
3533 # Search for other target-specific linker scripts and such.
3534 case "${target}" in
3535   mep*)
3536     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3537     ;;
3538   # The VxWorks support for shared libraries is getting in
3539   # incrementally.  Make sure it doesn't get activated implicitly:
3540   *vxworks*)
3541     if test "${enable_shared-unset}" = unset ; then
3542       enable_shared=no
3543       # So the build of libraries knows ...
3544       target_configargs="${target_configargs} --disable-shared"
3545       # So gcc knows ...
3546       host_configargs="${host_configargs} --disable-shared"
3547     fi
3548     ;;
3549 esac
3550
3551 # Makefile fragments.
3552 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3553 do
3554   eval fragval=\$$frag
3555   if test $fragval != /dev/null; then
3556     eval $frag=${srcdir}/$fragval
3557   fi
3558 done
3559 AC_SUBST_FILE(host_makefile_frag)
3560 AC_SUBST_FILE(target_makefile_frag)
3561 AC_SUBST_FILE(alphaieee_frag)
3562 AC_SUBST_FILE(ospace_frag)
3563
3564 # Miscellanea: directories, flags, etc.
3565 AC_SUBST(RPATH_ENVVAR)
3566 AC_SUBST(GCC_SHLIB_SUBDIR)
3567 AC_SUBST(tooldir)
3568 AC_SUBST(build_tooldir)
3569 AC_SUBST(CONFIGURE_GDB_TK)
3570 AC_SUBST(GDB_TK)
3571 AC_SUBST(INSTALL_GDB_TK)
3572
3573 # Build module lists & subconfigure args.
3574 AC_SUBST(build_configargs)
3575 AC_SUBST(build_configdirs)
3576
3577 # Host module lists & subconfigure args.
3578 AC_SUBST(host_configargs)
3579 AC_SUBST(configdirs)
3580 AC_SUBST(target_configdirs)
3581
3582 # Target module lists & subconfigure args.
3583 AC_SUBST(target_configargs)
3584
3585
3586 # Build tools.
3587 AC_SUBST(AR_FOR_BUILD)
3588 AC_SUBST(AS_FOR_BUILD)
3589 AC_SUBST(CC_FOR_BUILD)
3590 AC_SUBST(CFLAGS_FOR_BUILD)
3591 AC_SUBST(CPP_FOR_BUILD)
3592 AC_SUBST(CPPFLAGS_FOR_BUILD)
3593 AC_SUBST(CXXFLAGS_FOR_BUILD)
3594 AC_SUBST(CXX_FOR_BUILD)
3595 AC_SUBST(DLLTOOL_FOR_BUILD)
3596 AC_SUBST(DSYMUTIL_FOR_BUILD)
3597 AC_SUBST(GFORTRAN_FOR_BUILD)
3598 AC_SUBST(GOC_FOR_BUILD)
3599 AC_SUBST(GDC_FOR_BUILD)
3600 AC_SUBST(LDFLAGS_FOR_BUILD)
3601 AC_SUBST(LD_FOR_BUILD)
3602 AC_SUBST(NM_FOR_BUILD)
3603 AC_SUBST(RANLIB_FOR_BUILD)
3604 AC_SUBST(WINDMC_FOR_BUILD)
3605 AC_SUBST(WINDRES_FOR_BUILD)
3606
3607 # Generate default definitions for YACC, M4, LEX and other programs that run
3608 # on the build machine.  These are used if the Makefile can't locate these
3609 # programs in objdir.
3610 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3611
3612 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3613 case " $build_configdirs " in
3614   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3615 esac
3616
3617 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3618 case " $build_configdirs " in
3619   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3620 esac
3621
3622 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3623 case " $build_configdirs " in
3624   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3625 esac
3626
3627 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3628 case " $build_configdirs " in
3629   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3630   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3631 esac
3632
3633 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3634 case " $build_configdirs " in
3635   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3636 esac
3637
3638 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3639 case " $build_configdirs " in
3640   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3641   *)
3642 changequote(,)
3643     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3644     # higher, else we use the "missing" dummy.
3645     if ${MAKEINFO} --version \
3646        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3647       :
3648     else
3649       MAKEINFO="$MISSING makeinfo"
3650     fi
3651     ;;
3652 changequote([,])
3653 esac
3654
3655 # FIXME: expect and dejagnu may become build tools?
3656
3657 AC_CHECK_PROGS(EXPECT, expect, expect)
3658 case " $configdirs " in
3659   *" expect "*)
3660     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3661     ;;
3662 esac
3663
3664 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3665 case " $configdirs " in
3666   *" dejagnu "*)
3667     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3668     ;;
3669 esac
3670
3671
3672 # Host tools.
3673 NCN_STRICT_CHECK_TOOLS(AR, ar)
3674 NCN_STRICT_CHECK_TOOLS(AS, as)
3675 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3676 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3677 NCN_STRICT_CHECK_TOOLS(LD, ld)
3678 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3679 NCN_STRICT_CHECK_TOOLS(NM, nm)
3680 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3681 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3682 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3683 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3684 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3685 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3686 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3687 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3688 AC_SUBST(CC)
3689 AC_SUBST(CXX)
3690 AC_SUBST(CFLAGS)
3691 AC_SUBST(CXXFLAGS)
3692 AC_SUBST(GDC)
3693 AC_SUBST(GDCFLAGS)
3694 AC_SUBST(PKG_CONFIG_PATH)
3695
3696 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3697 AR_PLUGIN_OPTION=
3698 RANLIB_PLUGIN_OPTION=
3699 if test -n "$PLUGIN_OPTION"; then
3700   if $AR --help 2>&1 | grep -q "\--plugin"; then
3701     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3702   fi
3703   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3704     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3705   fi
3706 fi
3707 AC_SUBST(AR_PLUGIN_OPTION)
3708 AC_SUBST(RANLIB_PLUGIN_OPTION)
3709
3710 # Target tools.
3711 AC_ARG_WITH([build-time-tools],
3712   [AS_HELP_STRING([--with-build-time-tools=PATH],
3713                   [use given path to find target tools during the build])],
3714   [case x"$withval" in
3715      x/*) ;;
3716      *)
3717        with_build_time_tools=
3718        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3719        ;;
3720    esac],
3721   [with_build_time_tools=])
3722
3723 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3724 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3725 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3726 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3727 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3728 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3729
3730 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3731 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3732 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3733 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3734 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3735 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3736 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3737 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3738 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3739 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3740 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3741 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3742 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3743 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3744 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3745
3746 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3747
3748 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3749 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3750 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3751 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3752 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3753                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3754                 c++)
3755 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3756                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3757                 c++)
3758 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3759 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3760 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3761 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3762                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3763 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3764                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3765 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3766                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3767 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3768 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3769 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3770 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3771 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3772 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3773 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3774 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3775 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3776 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3777 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3778
3779 AC_SUBST(FLAGS_FOR_TARGET)
3780 AC_SUBST(RAW_CXX_FOR_TARGET)
3781
3782 # Certain tools may need extra flags.
3783 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3784 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3785 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3786
3787 # When building target libraries, except in a Canadian cross, we use
3788 # the same toolchain as the compiler we just built.
3789 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3790 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3791 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3792 if test $host = $build; then
3793   case " $configdirs " in
3794     *" gcc "*)
3795       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3796       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3797       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3798       ;;
3799   esac
3800 fi
3801
3802 AC_SUBST(COMPILER_AS_FOR_TARGET)
3803 AC_SUBST(COMPILER_LD_FOR_TARGET)
3804 AC_SUBST(COMPILER_NM_FOR_TARGET)
3805
3806 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3807 AC_ARG_ENABLE(maintainer-mode,
3808 [AS_HELP_STRING([--enable-maintainer-mode],
3809                 [enable make rules and dependencies not useful
3810                  (and sometimes confusing) to the casual installer])],
3811       USE_MAINTAINER_MODE=$enableval,
3812       USE_MAINTAINER_MODE=no)
3813 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3814 AC_SUBST(MAINTAINER_MODE_TRUE)
3815 AC_SUBST(MAINTAINER_MODE_FALSE)
3816 if test "$USE_MAINTAINER_MODE" = yes; then
3817   MAINTAINER_MODE_TRUE=
3818   MAINTAINER_MODE_FALSE='#'
3819 else
3820   MAINTAINER_MODE_TRUE='#'
3821   MAINTAINER_MODE_FALSE=
3822 fi
3823 MAINT=$MAINTAINER_MODE_TRUE
3824 AC_SUBST(MAINT)dnl
3825
3826 # ---------------------
3827 # GCC bootstrap support
3828 # ---------------------
3829
3830 # Stage specific cflags for build.
3831 stage1_cflags="-g"
3832 case $build in
3833   vax-*-*)
3834     case ${GCC} in
3835       yes) stage1_cflags="-g -Wa,-J" ;;
3836       *) stage1_cflags="-g -J" ;;
3837     esac ;;
3838 esac
3839
3840 AC_SUBST(stage1_cflags)
3841
3842 # Enable --enable-checking in stage1 of the compiler.
3843 AC_ARG_ENABLE(stage1-checking,
3844 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3845                 [choose additional checking for stage1 of the compiler])],
3846 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3847 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3848   # For --disable-checking or implicit --enable-checking=release, avoid
3849   # setting --enable-checking=gc in the default stage1 checking for LTO
3850   # bootstraps.  See PR62077.
3851   case $BUILD_CONFIG in
3852     *lto*)
3853       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3854     *)
3855       stage1_checking=--enable-checking=yes,types;;
3856   esac
3857   if test "x$enable_checking" = x && \
3858      test -d ${srcdir}/gcc && \
3859      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3860     stage1_checking=--enable-checking=yes,types,extra
3861   fi
3862 else
3863   stage1_checking=--enable-checking=$enable_checking,types
3864 fi])
3865 AC_SUBST(stage1_checking)
3866
3867 # Enable -Werror in bootstrap stage2 and later.
3868 AC_ARG_ENABLE(werror,
3869 [AS_HELP_STRING([--enable-werror],
3870                 [enable -Werror in bootstrap stage2 and later])],
3871 [
3872 case ${enable_werror} in
3873   yes) stage2_werror_flag="--enable-werror-always" ;;
3874   *) stage2_werror_flag="" ;;
3875 esac
3876 ],
3877 [
3878 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3879   case $BUILD_CONFIG in
3880   bootstrap-debug)
3881       stage2_werror_flag="--enable-werror-always" ;;
3882   "")
3883       stage2_werror_flag="--enable-werror-always" ;;
3884   esac
3885 fi
3886 ])
3887
3888 AC_SUBST(stage2_werror_flag)
3889
3890 # Specify what files to not compare during bootstrap.
3891
3892 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3893 case "$target" in
3894   hppa*64*-*-hpux*) ;;
3895   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3896   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3897 esac
3898 AC_SUBST(compare_exclusions)
3899
3900 AC_CONFIG_FILES([Makefile],
3901   [sed "$extrasub_build" Makefile |
3902    sed "$extrasub_host" |
3903    sed "$extrasub_target" > mf$$
3904    mv -f mf$$ Makefile],
3905   [extrasub_build="$extrasub_build"
3906    extrasub_host="$extrasub_host"
3907    extrasub_target="$extrasub_target"])
3908 AC_OUTPUT