configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.61)
   5 AC_INIT([barry], [0.10], [barry-devel@lists.sourceforge.net])
   6 #AM_CONFIG_HEADER(config.h)
   7 AC_CONFIG_SRCDIR([src/barry.h])
   8 AC_CONFIG_HEADERS([config.h:config.h.in])
   9 AM_INIT_AUTOMAKE
  10
  11 AC_USE_SYSTEM_EXTENSIONS
  12
  13 # Checks for programs.
  14 AC_PROG_CC
  15 AC_PROG_CXX
  16 AC_PROG_MAKE_SET
  17 AC_PROG_LIBTOOL
  18
  19 AC_LANG([C++])
  20
  21 # generates LIBUSB_CFLAGS and LIBUSB_LIBS for us
  22 PKG_CHECK_MODULES([LIBUSB], [libusb],
  23         [],
  24         [echo "ERROR: Libusb not found automatically... build may fail if you don't specify --with-libusb";LIBUSB_CFLAGS="-I/usr/include" LIBUSB_LIBS="-lusb"])
  25
  26 AC_ARG_WITH(libusb,
  27         [  --with-libusb=<path>    root path of libusb installation],
  28         [LIBUSB_CFLAGS="-I$with_libusb/include"
  29          LIBUSB_LIBS="-L$with_libusb/lib -lusb"],
  30         [])
  31
  32 AC_ARG_WITH(boost,
  33         AC_HELP_STRING(--with-boost[=path],
  34                 [root path of boost installation (no arg defaults to 'yes' and uses system path]),
  35         use_boost=$withval,  use_boost=no )
  36
  37 if test x"$use_boost" != "xyes" ; then
  38         if test x"$use_boost" != "xno" ; then
  39                 BOOST_LIB_PATH=$use_boost/lib
  40                 BOOST_INC_PATH=$use_boost/include
  41                 BOOST_ENABLED="true"
  42         fi
  43 else
  44         BOOST_LIB_PATH="/usr/lib"
  45         BOOST_INC_PATH="/usr/include"
  46         BOOST_ENABLED="true"
  47 fi
  48
  49 PKG_CHECK_MODULES([OPENSSL], [openssl])
  50
  51 pkgconfigdir=${libdir}/pkgconfig
  52 AC_SUBST(pkgconfigdir)
  53
  54 AC_SUBST(BOOST_LIB_PATH)
  55 AC_SUBST(BOOST_INC_PATH)
  56 AC_SUBST(LIBUSB_CFLAGS)
  57 AC_SUBST(LIBUSB_LIBS)
  58
  59 AM_CONDITIONAL([WITH_BOOST], [test "$BOOST_ENABLED" = "true"])
  60
  61 # Checks for libraries.
  62 #AC_CHECK_LIB([IOKit], [main])
  63 AC_CHECK_LIB([pthread], [main])
  64 #AC_CHECK_LIB([libusb], [libusb_init])
  65
  66 # Checks for header files.
  67 AC_HEADER_DIRENT
  68 AC_HEADER_STDC
  69 AC_CHECK_HEADERS([assert.h stdint.h time.h])
  70
  71 # Checks for typedefs, structures, and compiler characteristics.
  72 #AC_TYPE_SIZE_T
  73 AC_HEADER_TIME
  74 AC_STRUCT_TM
  75
  76 #
  77 # Checks for library functions.
  78 #
  79
  80 # checks that are buggy and need a C compiler only
  81 AC_LANG([C])
  82 AC_FUNC_STRNLEN
  83 if test $ac_cv_func_strnlen_working = yes ; then
  84         AC_DEFINE([HAVE_WORKING_STRNLEN], 1,
  85                 [Define to 1 if a working strnlen exists.])
  86 fi
  87 if test $ac_cv_func_strnlen_working = no ; then
  88         AC_DEFINE([HAVE_WORKING_STRNLEN], 0,
  89                 [Define to 1 if a working strnlen exists, 0 if not.])
  90 fi
  91
  92 # checks that work with C++
  93 AC_LANG([C++])
  94 AC_FUNC_CLOSEDIR_VOID
  95 AC_PROG_GCC_TRADITIONAL
  96 #AC_FUNC_MALLOC
  97 #AC_FUNC_MKTIME
  98 #AC_FUNC_REALLOC
  99 AC_FUNC_SELECT_ARGTYPES
 100 #AC_FUNC_STAT
 101
 102 AC_CHECK_FUNCS([bzero gettimeofday memset select strcasecmp strchr strerror strtol strtoul])
 103 AC_C_BIGENDIAN
 104
 105 AC_CONFIG_FILES([Makefile
 106                  src/Makefile
 107                  tools/Makefile
 108                  examples/Makefile
 109                  man/Makefile
 110                  libbarry-0.pc])
 111
 112 #
 113 # nested packages
 114 #
 115 AC_ARG_ENABLE([gui], [AC_HELP_STRING([--enable-gui], [build the gui])])
 116 if test "$enable_gui" = yes; then
 117         AC_CONFIG_SUBDIRS([gui])
 118 fi
 119 AC_ARG_ENABLE([opensync-plugin], [AC_HELP_STRING([--enable-opensync-plugin], [build the opensync plugin])])
 120 if test "$enable_opensync_plugin" = yes; then
 121         AC_CONFIG_SUBDIRS([opensync-plugin])
 122 fi
 123 if test "$enable_gui" = yes || test "$enable_opensync_plugin" = yes; then
 124         export TREE_BUILD_CXXFLAGS="-I`pwd`"
 125         export TREE_BUILD_LDFLAGS="-L`pwd`/src"
 126         export PKG_CONFIG_PATH="`pwd`:$PKG_CONFIG_PATH"
 127 fi
 128
 129 AC_OUTPUT
 130