configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 # 2004, 2006, 2007, 2008, 2009, 2010, 2011, 2012 Free Software
   5 # Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.68])
  21 AC_INIT([GNU Automake], [1.11.3b], [bug-automake@gnu.org])
  22
  23 AC_CONFIG_SRCDIR([automake.in])
  24 AC_CONFIG_AUX_DIR([lib])
  25
  26 AM_SILENT_RULES([yes])
  27
  28 AC_CANONICAL_BUILD
  29
  30 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  31 # way we can run Autoconf tests from configure (or from the test
  32 # suite) without being bothered by `missing'.  Likewise for autom4te,
  33 # autoreconf, autoheader, and autoupdate.
  34 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  35 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  36 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  37 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  38 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  39
  40 AM_INIT_AUTOMAKE([1.10a dist-xz filename-length-max=99 color-tests parallel-tests])
  41
  42 # The API version is the base version.  We must guarantee
  43 # compatibility for all releases with the same API version.
  44 # Our current rule is that:
  45 # * All releases, including the prereleases, in an X.Y series
  46 #   are compatible.  So 1.5.1c is compatible with 1.5.
  47 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  48 #   aren't the same.
  49 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  50 AC_SUBST([APIVERSION])
  51
  52 # A versioned directory, defined here for convenience.
  53 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  54
  55 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  56 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  57 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  58 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  59
  60 AC_PATH_PROG([PERL], [perl])
  61 if test -z "$PERL"; then
  62    AC_MSG_ERROR([perl not found])
  63 fi
  64 # Save details about the selected perl interpreter in config.log.
  65 AM_RUN_LOG([$PERL --version])
  66 $PERL -e 'require 5.006;' || {
  67    AC_MSG_ERROR(
  68 [perl 5.6 or better is required; perl 5.8.2 or better
  69 is recommended.  If you have several perl versions
  70 installed, select the one Automake should use using
  71   ./configure PERL=/path/to/perl])
  72 }
  73
  74 # We require ithreads support, and version 5.7.2 for CLONE.
  75 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  76 [if $PERL -e '
  77     require 5.007_002;
  78     use Config;
  79     if ($Config{useithreads})
  80       {
  81         require threads;
  82         import threads;
  83         require Thread::Queue;
  84         import Thread::Queue;
  85         exit 0;
  86       }
  87     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  88 then
  89   am_cv_prog_PERL_ithreads=yes
  90 else
  91   am_cv_prog_PERL_ithreads=no
  92 fi])
  93 if test $am_cv_prog_PERL_ithreads = yes; then
  94   PERL_THREADS=1;
  95 else
  96   PERL_THREADS=0;
  97 fi
  98 AC_SUBST([PERL_THREADS])
  99
 100 # The test suite will skip some tests if tex is absent.
 101 AC_CHECK_PROG([TEX], [tex], [tex])
 102 # Save details about the selected TeX program in config.log.
 103 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 104 # for input from the terminal.
 105 AM_RUN_LOG([$TEX --version </dev/null])
 106
 107 # Generate man pages.
 108 AM_MISSING_PROG([HELP2MAN], [help2man])
 109
 110 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 111 # deletion of any files created (such as those added to
 112 # autom4te.cache).  We used to perform only the last of the three
 113 # following tests, but some users were unable to figure out that their
 114 # installation was broken since --version appeared to work.
 115
 116 required_autoconf_version=2.62
 117 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 118 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 119 then
 120   am_cv_autoconf_installed=yes
 121 else
 122   am_cv_autoconf_installed=no
 123 fi])
 124 if test "$am_cv_autoconf_installed" = no; then
 125   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 126     Please make sure it is installed and in your PATH.])
 127 fi
 128
 129 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 130 [mkdir conftest
 131 echo 'AC''_INIT' > conftest/conftest.ac
 132 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 133 then
 134   am_cv_autoconf_works=yes
 135 else
 136   am_cv_autoconf_works=no
 137 fi
 138 rm -rf conftest])
 139 if test "$am_cv_autoconf_works" = no; then
 140   AC_MSG_ERROR([The installed version of autoconf does not work.
 141     Please check config.log for error messages before this one.])
 142 fi
 143
 144 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 145 [mkdir conftest
 146 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 147 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 148 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 149 then
 150   am_cv_autoconf_version=yes
 151 else
 152   am_cv_autoconf_version=no
 153 fi
 154 rm -rf conftest])
 155 if test "$am_cv_autoconf_version" = no; then
 156   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 157 fi
 158
 159 # Test for ln.  We need use it to install the versioned binaries.
 160 AC_MSG_CHECKING([whether ln works])
 161 AC_CACHE_VAL([am_cv_prog_ln], [
 162 rm -f conftest conftest.file
 163 : >conftest.file
 164 if ln conftest.file conftest 2>/dev/null; then
 165   am_cv_prog_ln=ln
 166 else
 167   am_cv_prog_ln='cp -p'
 168 fi
 169 rm -f conftest conftest.file])
 170 AC_SUBST([LN], [$am_cv_prog_ln])
 171 result=no
 172 test "x$am_cv_prog_ln" = xln && result=yes
 173 AC_MSG_RESULT([$result])
 174
 175 # The amount we should wait after modifying files depends on the platform.
 176 # On Windows '95, '98 and ME, files modifications have 2-seconds
 177 # granularity and can be up to 3 seconds in the future w.r.t. the
 178 # system clock.  When it is important to ensure one file is older
 179 # than another we wait at least 5 seconds between creations.
 180 case $build in
 181   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 182   *)               MODIFICATION_DELAY=2;;
 183 esac
 184 AC_SUBST([MODIFICATION_DELAY])
 185
 186 # Test for things needed by the test suite.
 187 AC_PROG_EGREP
 188 AC_PROG_FGREP
 189
 190 AC_CACHE_CHECK([whether /bin/sh has working 'set -e' with exit trap],
 191 [am_cv_sh_errexit_works],
 192 [if /bin/sh -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 193 then
 194   am_cv_sh_errexit_works=yes
 195 else
 196   am_cv_sh_errexit_works=no
 197 fi
 198 ])
 199 if test $am_cv_sh_errexit_works = no; then
 200   AC_MSG_WARN([`${MAKE-make} check' will leave leftover directories tests/*.dir])
 201   AC_MSG_WARN([you can clean them up manually using `${MAKE-make} clean' or])
 202   AC_MSG_WARN([`cd tests && ${MAKE-make} clean-local-check'])
 203   dnl restore font-lock: `
 204 fi
 205 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 206
 207 AC_CONFIG_FILES([
 208   Makefile
 209   contrib/Makefile
 210   doc/Makefile
 211   lib/Automake/Makefile
 212   lib/Makefile
 213   lib/am/Makefile
 214   m4/Makefile
 215   tests/Makefile
 216   tests/defs
 217 ])
 218 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 219                 [chmod +x tests/aclocal-${APIVERSION}],
 220                 [APIVERSION=$APIVERSION])
 221 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 222                 [chmod +x tests/automake-${APIVERSION}])
 223
 224 AC_OUTPUT
 225
 226 # Inform the user if this version of automake is a beta release or
 227 # a development snapshot.
 228 # According to HACKING, the version of a development snapshot should
 229 # end with an "odd" letter (a, c, ...), the version of a test release
 230 # should end wit an "even" letter (b, d, ...).
 231
 232 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 233 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 234
 235 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 236   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 237   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 238   { print \"development snapshot\"; }"]`
 239
 240 test "$am_release_type" = stable || cat <<EOF
 241
 242 WARNING: You are about to use a $am_release_type of automake.
 243 WARNING: It might easily suffer from new bugs or regressions.
 244 WARNING: You are strongly advised not to use it in production code.
 245
 246 Please report bugs, problems and feedback to <bug-automake@gnu.org>.
 247 EOF
 248
 249 AS_EXIT([0])