configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2024 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.17.0.90], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([bin/automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([-Wall -Werror dist-xz filename-length-max=99
  43                   no-define no-dependencies])
  44
  45 # Keep this on a line of its own, since it must be found and processed
  46 # by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2024
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 APIVERSION=1.17
  53 AC_SUBST([APIVERSION])
  54
  55 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  56 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  57 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  58 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  59 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  60
  61 # Our build system is bootstrapped with the bleeding-edge versions of
  62 # aclocal and automake, hence the remake rules must use those versions
  63 # as well.  The extra quoting is to cater to cases when the build
  64 # directory contains whitespace or shell metacharacters.
  65 ACLOCAL="\"`pwd`/pre-inst-env\" aclocal-$APIVERSION"
  66 AUTOMAKE="\"`pwd`/pre-inst-env\" automake-$APIVERSION"
  67
  68 AC_PROG_LN_S
  69
  70 AC_PATH_PROG([PERL], [perl])
  71 case $PERL in
  72  '')
  73    AC_MSG_ERROR([perl not found])
  74    ;;
  75  *' '* | *'     '*)
  76   AC_MSG_ERROR([The path to your Perl contains spaces or tabs.
  77 This would cause build failures later or unusable programs.
  78 Please use a path without spaces and try again.])
  79   ;;
  80 esac
  81
  82 # Save details about the selected perl interpreter in config.log.
  83 AM_RUN_LOG([$PERL --version])
  84 $PERL -e 'require 5.006;' || {
  85    AC_MSG_ERROR(
  86 [perl 5.6 or better is required; perl 5.10 or better
  87 is recommended.  If you have several perl versions
  88 installed, select the one Automake should use using
  89   ./configure PERL=/path/to/perl])
  90 }
  91
  92 # The test suite will skip some tests if tex is absent.
  93 AC_CHECK_PROG([TEX], [tex], [tex])
  94 # Save details about the selected TeX program in config.log.
  95 # Redirect input from /dev/null, as TeX might otherwise hang waiting
  96 # for input from the terminal.
  97 AM_RUN_LOG([$TEX --version </dev/null])
  98
  99 # The test suite will skip some tests if no lex or yacc program is
 100 # available.
 101 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 102 #  1. we don't want flex (resp. bison) to be preferred to system lex
 103 #     (resp. system yacc);
 104 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 105 #     by default;
 106 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 107 #     LEXLIB to be calculated and/or AC_SUBST'd;
 108 #  4. we prefer that the YACC and LEX variables are not reported in the
 109 #     configure help screen.
 110 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 111 AC_CHECK_PROGS([LEX], [lex flex], [false])
 112
 113 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 114 # deletion of any files created (such as those added to
 115 # autom4te.cache).  We used to perform only the last of the three
 116 # following tests, but some users were unable to figure out that their
 117 # installation was broken since --version appeared to work.
 118
 119 AC_SUBST([required_autoconf_version], [2.65])
 120 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 121 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 122 then
 123   am_cv_autoconf_installed=yes
 124 else
 125   am_cv_autoconf_installed=no
 126 fi])
 127 if test "$am_cv_autoconf_installed" = no; then
 128   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 129     Please make sure it is installed and in your PATH.])
 130 fi
 131
 132 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 133 [mkdir conftest
 134 printf '%s\n' > conftest/conftest.ac \
 135   'AC''_INIT([smoke-test], [1])' \
 136   'AC''_OUTPUT'
 137 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 138 then
 139   am_cv_autoconf_works=yes
 140 else
 141   am_cv_autoconf_works=no
 142 fi
 143 rm -rf conftest])
 144 if test "$am_cv_autoconf_works" = no; then
 145   AC_MSG_ERROR([The installed version of autoconf does not work.
 146     Please check config.log for error messages before this one.])
 147 fi
 148
 149 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 150 [mkdir conftest
 151 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 152 printf '%s\n' > conftest/conftest.ac \
 153   'AC'"_PREREQ([[$required_autoconf_version]])" \
 154   'AC''_INIT([smoke-test], [1])' \
 155   'AC''_OUTPUT'
 156 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 157 then
 158   am_cv_autoconf_version=yes
 159 else
 160   am_cv_autoconf_version=no
 161 fi
 162 rm -rf conftest])
 163 if test "$am_cv_autoconf_version" = no; then
 164   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 165 fi
 166
 167 # Test for ln.  We need use it to install the versioned binaries.
 168 AC_MSG_CHECKING([whether ln works])
 169 AC_CACHE_VAL([am_cv_prog_ln], [
 170 rm -f conftest conftest.file
 171 : >conftest.file
 172 if ln conftest.file conftest 2>/dev/null; then
 173   am_cv_prog_ln=ln
 174 else
 175   am_cv_prog_ln='cp -p'
 176 fi
 177 rm -f conftest conftest.file])
 178 AC_SUBST([LN], [$am_cv_prog_ln])
 179 result=no
 180 test "x$am_cv_prog_ln" = xln && result=yes
 181 AC_MSG_RESULT([$result])
 182
 183 ## ------------------------------------------- ##
 184 ##  Test for things needed by the test suite.  ##
 185 ## ------------------------------------------- ##
 186
 187 AC_PROG_EGREP
 188 AC_PROG_FGREP
 189
 190 # The test suite needs to know the resolution of timestamps
 191 # supported by the filesystem hosting the build.  The value
 192 # will be acceptable to 'sleep' on this system.
 193 MTIME_RESOLUTION=$am_cv_filesystem_timestamp_resolution
 194 if test -z "$MTIME_RESOLUTION"; then
 195   AC_MSG_NOTICE(am_cv_filesystem_timestamp_resolution strangely not set; using 1)
 196   MTIME_RESOLUTION=1
 197 fi
 198 AC_SUBST([MTIME_RESOLUTION])
 199
 200 dnl FIXME: could we extract this in a simpler way through autoconf
 201 dnl FIXME: idioms or internals?
 202 AC_DEFUN(
 203   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
 204   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
 205
 206 dnl
 207 dnl Arguments to this macro:
 208 dnl
 209 dnl   $1 - shell to test
 210 dnl   $2 - description of the tested feature
 211 dnl   $3 - shell code used to check the feature; to indicate success,
 212 dnl        it can either exit with status 77, or have the last command
 213 dnl        returning with exit status of zero
 214 dnl   $4 - shell code to execute if the check on the shell is successful
 215 dnl        (defaults to nothing)
 216 dnl   $5 - shell code to execute if the check on the shell is not
 217 dnl        successful (defaults to nothing)
 218 dnl
 219 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
 220   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
 221   AC_MSG_CHECKING([whether $1 $2])
 222   if { $1 -c "$am_bourne_compatible
 223 AS_ESCAPE([$3])
 224 test \$? -eq 0 || exit 1
 225 # Use 77 to indicate success (rather than 0), in case some shell
 226 # acts like Solaris 10's /bin/sh, exiting successfully on some
 227 # syntax errors.
 228 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
 229   then
 230     AC_MSG_RESULT([yes])
 231     $4
 232   else
 233     AC_MSG_RESULT([no])
 234     $5
 235   fi])
 236
 237 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
 238 # -----------------------------------------
 239 #
 240 # Check if the given shell is good enough to run our test scripts.
 241 # Inspired to gnulib's 'tests/init.sh'.
 242 #
 243 # We require POSIX and XSI features (e.g., '$(...)' for command
 244 # substitutions, '$((...))' for shell arithmetic, and support for
 245 # '${var#...}' and '${var%...}' parameter expansions).
 246 #
 247 # We require that the shell can correctly trap EXIT when 'set -e' is in
 248 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
 249 #
 250 # We want to able to define shell aliases with the same name of shell
 251 # builtins.
 252 #
 253 # We also prefer shells that, when 'set -x' is in effect, do not also
 254 # redirect traces upon stderr redirections.  For example,
 255 #  $ set -x; echo x 2>file
 256 # would emit "+ echo x" into file with older zsh versions.  Similarly,
 257 #   $ set -x; P=1 true 2>file
 258 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
 259 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
 260 #
 261 # Use '$am_score' to indicate the degree of acceptability of the shell.
 262 # A score of "10" means that the shell is good enough for our needs;
 263 # a score of "9" means that the shell has some minor bugs or limitation,
 264 # but is still (barely) acceptable for our uses.  Any other score means
 265 # that the shell is broken or unfit.
 266 #
 267 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
 268   [am_score=10
 269   while :; do
 270
 271     _AM_CHECK_SHELL_FEATURE([$1],
 272       [supports \$(cmd)],
 273       [test "$(echo x)" = x],
 274       [], [am_score=1; break])
 275
 276     _AM_CHECK_SHELL_FEATURE([$1],
 277       [supports \$((expr))],
 278       [test $((1 + 2 * 3)) = 7],
 279       [], [am_score=1; break])
 280
 281     _AM_CHECK_SHELL_FEATURE([$1],
 282       [supports \${@%:@var}],
 283       [zero='' one='x' twelve=' foobar baz!' \
 284         && test ${@%:@zero} -eq 0 \
 285         && test ${@%:@one} -eq 1 \
 286         && test ${@%:@twelve} -eq 12],
 287       [], [am_score=1; break])
 288
 289     _AM_CHECK_SHELL_FEATURE([$1],
 290       [supports \${var@%:@glob} and \${var%glob}],
 291       [v=a/b/c \
 292         && test ${v@%:@*/} = b/c \
 293         && test ${v@%:@@%:@*/} = c \
 294         && test ${v%/*} = a/b \
 295         && test ${v%%/*} = a],
 296       [], [am_score=1; break])
 297
 298     _AM_CHECK_SHELL_FEATURE([$1],
 299       [preserves exit traps with "set -e"],
 300       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
 301       [], [am_score=1; break])
 302
 303     _AM_CHECK_SHELL_FEATURE([$1],
 304       [can define exit traps in a shell function],
 305       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
 306       [], [am_score=1; break])
 307
 308     _AM_CHECK_SHELL_FEATURE([$1],
 309       [corrupts stderr with "set -x"],
 310       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
 311       [am_score=9], [])
 312
 313     echo 'return 34' > conftest-return.sh
 314     echo 'ok=no' >> conftest-return.sh
 315     _AM_CHECK_SHELL_FEATURE([$1],
 316       [can return early from "dot-sourced" files],
 317       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
 318       [rm -f conftest-return.sh],
 319       [rm -f conftest-return.sh; am_score=1; break])
 320
 321     echo 'alias false=echo' > conftest-alias.sh
 322     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
 323     _AM_CHECK_SHELL_FEATURE([$1],
 324       [supports alias named like shell builtins],
 325       [. ./conftest-alias.sh],
 326       [rm -f conftest-alias.sh],
 327       [rm -f conftest-alias.sh; am_score=1; break])
 328
 329     _AM_CHECK_SHELL_FEATURE([$1],
 330       [supports "test -e"],
 331       [test -e config.log && test -e . && test ! -e nonesuch],
 332       [], [am_score=1; break])
 333
 334     break
 335   done])
 336
 337 # These messages only goes to the config.log file.
 338 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
 339
 340 AC_CACHE_VAL(
 341   [ac_cv_AM_TEST_RUNNER_SHELL],
 342   [if test "$AM_TEST_RUNNER_SHELL"; then
 343     # Let the user override it.
 344     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
 345   else
 346     ac_cv_AM_TEST_RUNNER_SHELL=no
 347     am_candidate_shells=${CONFIG_SHELL-}
 348     # For the benefit of Solaris.
 349     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
 350     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
 351       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
 352       if test -n "$am_candidate_sh"; then
 353         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
 354       fi
 355       AM_SUBST_NOTMAKE([am_candidate_sh])
 356       # Must nullify these in order not to interfere with the checks in
 357       # the next loop.
 358       AS_UNSET([am_candidate_sh])
 359       AS_UNSET([ac_cv_path_am_candidate_sh])
 360     done
 361     AS_UNSET([am_PATH]) # Not required anymore
 362     for am_sh in $am_candidate_shells; do
 363       am_score=0
 364       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
 365       if test $am_score -eq 9; then
 366         # The shell is barely acceptable for our needs.  We might
 367         # still find one that is even better, so continue looking.
 368         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
 369         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 370       elif test $am_score -eq 10; then
 371         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
 372         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 373         break
 374       fi
 375     done
 376   fi
 377   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
 378
 379 if test $AM_TEST_RUNNER_SHELL = no; then
 380   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
 381                                 enough to be used in our testsuite])])
 382 else
 383   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
 384 fi
 385
 386 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
 387            [a sturdy POSIX shell for our testsuite])
 388
 389
 390 ###########################################################################
 391
 392 # Look for C, C++ and fortran compilers to be used in the testsuite.
 393
 394 dnl We don't want to abort our configuration script if no C compiler is
 395 dnl available, as such a compiler is only required to run part of the
 396 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 397 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 398 dnl easy way to obtain this behavior, so we'll need a few hacks.
 399
 400 dnl We want the body of this macro to expand as a single shell statement,
 401 dnl thus we wrap it into { ... } brackets.
 402 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 403   AC_MSG_WARN([$1])
 404   am__failed=yes
 405   break
 406 } ])
 407
 408 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 409   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 410   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 411   am__failed=no
 412   while :; do
 413      $1
 414      break
 415   done
 416   AS_IF([test $am__failed = yes], [$2])
 417   # We have to clear these cache variables, so that future checks on
 418   # compilers for different languages won't be confused.
 419   unset ac_cv_objext ac_cv_exeext
 420   # We also need to meddle with the autoconf internals to ensure that
 421   # checks to find object and executable extensions will be run anew.
 422   # FIXME: In the long run, the better thing to do would be to fix
 423   # FIXME: autoconf instead ...
 424   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 425   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 426   m4_popdef([AC_MSG_FAILURE])
 427   m4_popdef([AC_MSG_ERROR])
 428 ])
 429
 430 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 431   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 432
 433 # Prefer generic compilers to GNU ones when possible.  This will ensure
 434 # more testsuite coverage "in the wild".
 435 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 436 # deliberate; for more discussion and rationale, see:
 437 # <https://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 438
 439 AC_MSG_NOTICE([will now look for generic compilers])
 440
 441 # C compiler.
 442 _AM_COMPILER_CAN_FAIL(dnl
 443   [AC_PROG_CC([cc gcc])],
 444   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 445
 446 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 447
 448 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
 449 # we must avoid looking for 'CC', because that would be the same as
 450 # 'cc', and could cause $CXX to point to the C compiler, instead of
 451 # to a C++ compiler as expected (see automake bugs #11893 and #10766).
 452 # Similarly, we must avoid looking for 'RCC', as that can point to the
 453 # Qt4 "Resource Compiler": <http://doc.qt.digia.com/4.2/rcc.html>
 454 # And we avoid looking for 'KCC' as that can be a kerberos tool under
 455 # macOS systems.
 456 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
 457   # Case-insensitive file system, don't look for CC.
 458   am_CC= am_RCC= am_KCC=
 459 else
 460   am_CC=CC am_RCC=RCC am_KCC=KCC
 461 fi
 462
 463 # The list of C++ compilers here has been copied, pasted and edited
 464 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 465 # Keep it in sync, or better again, find out a way to avoid this code
 466 # duplication.
 467 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 468   [aCC $am_CC FCC $am_KCC $am_RCC xlC_r xlC c++ cxx cc++ gpp g++ clang++])],
 469   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 470
 471 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 472
 473 # The lists of Fortran compilers here has been copied, pasted and edited
 474 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 475 # Keep it in sync, or better again, find out a way to avoid this code
 476 # duplication.
 477
 478 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 479   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 480   [xlf90 f90 armflang flang pgf90 pghpf epcf90 g95 gfortran])],
 481   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 482
 483 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 484
 485 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 486   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 armflang flang gfortran])],
 487   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 488
 489 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 490
 491 # Some tests will need the GNU compilers.  Searching for them here would
 492 # be overkill, since our testsuite already handles their search and setup
 493 # pretty well.  But in case the compilers already found are the GNU ones,
 494 # we want to use them in the testsuite where GNU compilers are required.
 495 # Also, in case the compilers detected above (at configure time) are not
 496 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 497 # FFLAGS detected for them with the GNU compilers too, since it's likely
 498 # they won't be compatible.  So we allow the user to define variants of
 499 # these variables for the GNU compilers separately.
 500
 501 AC_MSG_NOTICE([will now look for GNU compilers])
 502
 503 # GNU C compiler.
 504 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 505 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 506 if test $am_CC_is_GNU = yes; then
 507   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 508   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 509 else
 510   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 511 fi
 512 if test "$GNU_CC" != false; then
 513   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 514         [AC_MSG_WARN([botched installation for GNU C compiler])
 515          _AM_SKIP_COMP_TESTS([GNU C])])
 516 fi
 517
 518 # GNU C++ compiler.
 519 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 520 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 521 if test $am_CXX_is_GNU = yes; then
 522   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 523   GNU_CXX=$CXX
 524   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 525 else
 526   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 527 fi
 528 if test "$GNU_CXX" != false; then
 529   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 530         [AC_MSG_WARN([botched installation for GNU C++ compiler])
 531          _AM_SKIP_COMP_TESTS([GNU C++])])
 532 fi
 533
 534 # GNU Fortran compiler.
 535 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 536 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 537 if test $am_FC_is_GNU = yes; then
 538   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 539   GNU_FC=$FC
 540   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 541 else
 542   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 543 fi
 544 if test "$GNU_FC" != false; then
 545   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 546         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 547          _AM_SKIP_COMP_TESTS([GNU Fortran])])
 548 fi
 549
 550 # GNU Fortran 77 compiler.
 551 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 552 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 553 if test $am_F77_is_GNU = yes; then
 554   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 555   GNU_F77=$F77
 556   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 557 else
 558   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 559 fi
 560 if test "$GNU_F77" != false; then
 561   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 562         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 563         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 564 fi
 565
 566 # GNU Java compiler.
 567 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 568 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 569 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 570 if test "$GNU_GCJ" != false; then
 571   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 572         [AC_MSG_WARN([botched installation for GNU Java compiler])
 573         _AM_SKIP_COMP_TESTS([GNU Java])])
 574 fi
 575
 576 # If we have been able to find at least a working compiler above, we
 577 # know what the object and executable extensions for this platform are.
 578 OBJEXT=${ac_cv_objext-UNKNOWN}
 579 EXEEXT=${ac_cv_exeext-UNKNOWN}
 580 AC_SUBST([OBJEXT])
 581 AC_SUBST([EXEEXT])
 582
 583 ###########################################################################
 584
 585 ## ---------------------- ##
 586 ##  Create output files.  ##
 587 ## ---------------------- ##
 588
 589 AC_CONFIG_FILES([Makefile])
 590 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 591 AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
 592 AC_OUTPUT
 593
 594 # Inform the user if this version of automake is a beta release or
 595 # a development snapshot. Except, as of 1.17 (January 2024), don't bother.
 596 # Just call all pretests development snapshots.
 597 #
 598 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 599
 600 # This won't match anything as of 1.17, since we switched to
 601 # .90-numbered test releases. But if we wanted to, according to HACKING,
 602 # the version of a development snapshot should end with an odd number
 603 # (91, 93, ...) and a beta release should end with an even number (90,
 604 # 92, ...).
 605 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]" # no match
 606
 607 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 608   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 609   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 610   { print \"development snapshot\"; }"]`
 611
 612 # '$silent' is set to yes if configure is passed the '--quiet' option.
 613 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
 614
 615 WARNING: You are about to use a $am_release_type of automake.
 616 WARNING: It could well suffer from new bugs or regressions.
 617 WARNING: You are strongly advised not to use it in production code.
 618
 619 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>,
 620 since that is the whole point of a test release.
 621 EOF
 622
 623 AS_EXIT([0])