configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 # 2004, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_INIT([GNU Automake], [1.11.0a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR(automake.in)
  22 AC_CONFIG_AUX_DIR(lib)
  23
  24 AC_CANONICAL_BUILD
  25
  26 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  27 # way we can run Autoconf tests from configure (or from the test
  28 # suite) without being bothered by `missing'.  Likewise for autoheader.
  29 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  30 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  31
  32 AM_INIT_AUTOMAKE([1.10a dist-bzip2 filename-length-max=99 color-tests parallel-tests])
  33
  34 # The API version is the base version.  We must guarantee
  35 # compatibility for all releases with the same API version.
  36 # Our current rule is that:
  37 # * All releases, including the prereleases, in an X.Y series
  38 #   are compatible.  So 1.5.1c is compatible with 1.5.
  39 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  40 #   aren't the same.
  41 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  42 AC_SUBST([APIVERSION])
  43
  44 # A versioned directory, defined here for convenience.
  45 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  46
  47 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  48 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  49 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  50 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  51
  52 AC_PATH_PROG(PERL, perl)
  53 if test -z "$PERL"; then
  54    AC_MSG_ERROR([perl not found])
  55 fi
  56 $PERL -e 'require 5.006;' || {
  57    AC_MSG_ERROR(
  58 [perl 5.6 or better is required; perl 5.8.2 or better
  59 is recommended.  If you have several perl versions
  60 installed, select the one Automake should use using
  61   ./configure PERL=/path/to/perl])
  62 }
  63
  64 # We require ithreads support, and version 5.7.2 for CLONE.
  65 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  66 [if $PERL -e '
  67     require 5.007_002;
  68     use Config;
  69     if ($Config{useithreads})
  70       {
  71         require threads;
  72         import threads;
  73         require Thread::Queue;
  74         import Thread::Queue;
  75         exit 0;
  76       }
  77     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  78 then
  79   am_cv_prog_PERL_ithreads=yes
  80 else
  81   am_cv_prog_PERL_ithreads=no
  82 fi])
  83 if test $am_cv_prog_PERL_ithreads = yes; then
  84   PERL_THREADS=1;
  85 else
  86   PERL_THREADS=0;
  87 fi
  88 AC_SUBST([PERL_THREADS])
  89
  90 # The test suite will skip some tests if tex is absent.
  91 AC_CHECK_PROG([TEX], [tex], [tex])
  92
  93 # Generate man pages.
  94 AM_MISSING_PROG([HELP2MAN], [help2man])
  95
  96 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
  97 # deletion of any files created (such as those added to
  98 # autom4te.cache).  We used to perform only the last of the three
  99 # following tests, but some users were unable to figure out that their
 100 # installation was broken since --version appeared to work.
 101
 102 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 103 [if AM_RUN_LOG([eval $am_AUTOCONF --version]);
 104 then
 105   am_cv_autoconf_installed=yes
 106 else
 107   am_cv_autoconf_installed=no
 108 fi])
 109 if test "$am_cv_autoconf_installed" = no; then
 110   AC_MSG_ERROR([Autoconf 2.60 or better is required.
 111     Please make sure it is installed and in your PATH.])
 112 fi
 113
 114 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 115 [mkdir conftest
 116 echo 'AC''_INIT' > conftest/conftest.ac
 117 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 118 then
 119   am_cv_autoconf_works=yes
 120 else
 121   am_cv_autoconf_works=no
 122 fi
 123 rm -rf conftest])
 124 if test "$am_cv_autoconf_works" = no; then
 125   AC_MSG_ERROR([The installed version of autoconf does not work.
 126     Please check config.log for error messages before this one.])
 127 fi
 128
 129 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 130 [mkdir conftest
 131 echo 'AC''_PREREQ([[2.62]])' > conftest/conftest.ac
 132 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 133 then
 134   am_cv_autoconf_version=yes
 135 else
 136   am_cv_autoconf_version=no
 137 fi
 138 rm -rf conftest])
 139 if test "$am_cv_autoconf_version" = no; then
 140   AC_MSG_ERROR([Autoconf 2.61a-341 or better is required.])
 141 fi
 142
 143 # Test for ln.  We need use it to install the versioned binaries.
 144 AC_MSG_CHECKING([whether ln works])
 145 AC_CACHE_VAL([am_cv_prog_ln], [
 146 rm -f conftest conftest.file
 147 : >conftest.file
 148 if ln conftest.file conftest 2>/dev/null; then
 149   am_cv_prog_ln=ln
 150 else
 151   am_cv_prog_ln='cp -p'
 152 fi
 153 rm -f conftest conftest.file])
 154 AC_SUBST([LN], [$am_cv_prog_ln])
 155 result=no
 156 test "x$am_cv_prog_ln" = xln && result=yes
 157 AC_MSG_RESULT([$result])
 158
 159 # The amount we should wait after modifying files depends on the platform.
 160 # On Windows '95, '98 and ME, files modifications have 2-seconds
 161 # granularity and can be up to 3 seconds in the future w.r.t. the
 162 # system clock.  When it is important to ensure one file is older
 163 # than another we wait at least 5 seconds between creations.
 164 case $build in
 165   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 166   *)               MODIFICATION_DELAY=2;;
 167 esac
 168 AC_SUBST([MODIFICATION_DELAY])
 169
 170 # Test for things needed by the test suite.
 171 AC_PROG_EGREP
 172 AC_PROG_FGREP
 173
 174 AC_CACHE_CHECK([whether /bin/sh has working 'set -e' with exit trap],
 175 [am_cv_sh_errexit_works],
 176 [if /bin/sh -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 177 then
 178   am_cv_sh_errexit_works=yes
 179 else
 180   am_cv_sh_errexit_works=no
 181 fi
 182 ])
 183 if test $am_cv_sh_errexit_works = no; then
 184   AC_MSG_WARN([`${MAKE-make} check' will leave leftover directories tests/*.dir])
 185   AC_MSG_WARN([you can clean them up manually using `${MAKE-make} clean' or])
 186   AC_MSG_WARN([`cd tests && ${MAKE-make} clean-local-check'])
 187   dnl restore font-lock: `
 188 fi
 189 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 190
 191 AC_CONFIG_FILES([
 192   Makefile
 193   doc/Makefile
 194   lib/Automake/Makefile
 195   lib/Automake/tests/Makefile
 196   lib/Makefile
 197   lib/am/Makefile
 198   m4/Makefile
 199   tests/Makefile
 200   tests/defs
 201 ])
 202 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 203                 [chmod +x tests/aclocal-${APIVERSION}],
 204                 [APIVERSION=$APIVERSION])
 205 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 206                 [chmod +x tests/automake-${APIVERSION}])
 207
 208 AC_OUTPUT