tests/local.at

   1 # M4 macros used in building Autoconf test suites.        -*- Autotest -*-
   2
   3 # Copyright (C) 2000-2016 Free Software Foundation, Inc.
   4
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 m4_version_prereq([2.57])
  19
  20 # Used in many tests.
  21 m4_pattern_allow([^AS_EXIT$])
  22 m4_pattern_allow([^m4_(define|shift)$])
  23
  24 # Programs this package provides
  25 AT_TESTED([autom4te autoconf autoheader autoupdate autoreconf ifnames])
  26
  27 # Enable colored test output.
  28 AT_COLOR_TESTS
  29
  30 ## ---------------- ##
  31 ## Utility macros.  ##
  32 ## ---------------- ##
  33
  34 # AT_CMP(FILE-1, FILE-2)
  35 # ----------------------
  36 # Check FILE-1 and FILE-2 for equality, like `cmp FILE-1 FILE-2'.
  37 m4_define([AT_CMP],
  38 [m4_ifval([$2],, [m4_fatal([AT_CMP takes two arguments.])])[]dnl
  39 AT_CHECK([$at_diff "$1" "$2"])
  40 ])# AT_CMP
  41
  42
  43 ## ---------------- ##
  44 ## Testing syntax.  ##
  45 ## ---------------- ##
  46
  47 # AT_CHECK_SHELL_SYNTAX(PROGRAM)
  48 # ------------------------------
  49 # If the shell handles `-n' well, use it to check the syntax of PROGRAM;
  50 # otherwise, do nothing.  ksh93 -n also spits outs loads of warnings
  51 # about older constructs, but we don't care about the warnings.
  52 m4_define([AT_CHECK_SHELL_SYNTAX],
  53 [AT_SKIP_IF([test "$ac_cv_sh_n_works" != yes])
  54 AT_CHECK([/bin/sh -n $1], [], [], [ignore])])
  55
  56 m4_define([AT_CHECK_PERL_SYNTAX],
  57 [AT_CHECK([autom4te_perllibdir=$abs_top_srcdir/lib $PERL -c "$abs_top_builddir"/bin/$1],
  58           0, [], [ignore])])
  59
  60 ## ------------------ ##
  61 ## Testing autom4te.  ##
  62 ## ------------------ ##
  63
  64
  65 # AT_CHECK_M4(COMMAND, [EXIT-STATUS = 0], STDOUT, STDERR)
  66 # -------------------------------------------------------
  67 # If stderr is specified, normalize the observed stderr.
  68 # This (using GNU M4 1.4.6)
  69 #
  70 #  /usr/local/bin/m4:script.4s:1: cannot open `foo': No such file or directory
  71 #  autom4te: /usr/local/bin/m4 failed with exit status: 1
  72 #
  73 # or this (GNU M4 1.4.11)
  74 #
  75 #  /usr/local/bin/m4:script.4s:1: include: cannot open `foo': No such file or directory
  76 #  autom4te: /usr/local/bin/m4 failed with exit status: 1
  77 #
  78 # or this (GNU M4 1.4 installed as gm4)
  79 #
  80 #  script.4s:1: /usr/local/bin/gm4: Cannot open foo: No such file or directory
  81 #  autom4te: /usr/local/bin/gm4 failed with exit status: 1
  82 #
  83 # or this (GNU M4 1.4.13 installed as m4-1.4.13):
  84 #
  85 #  /usr/bin/m4-1.4.13:script.4s:1: include: cannot open `foo': No such file or directory
  86 #  autom4te: /usr/bin/m4-1.4.13 failed with exit status: 1
  87 #
  88 # becomes
  89 #
  90 #  m4:script.4s:1: cannot open `foo': No such file or directory
  91 #  autom4te: m4 failed with exit status: 1
  92 #
  93 # We use the following sed patterns:
  94 #
  95 #     (m4): ?(file): ?(line):
  96 # or  (file): ?(line): ?(m4):
  97 # to  m4:(file):(line):
  98 #
  99 # and
 100 #     m4:(file):(line): Cannot open foo:
 101 # or  m4:(file):(line): include: cannot open `foo':
 102 # to  m4:(file):(line): cannot open `foo':
 103 #
 104 # and
 105 #     autom4te: [^ ]m4
 106 # or  autom4te: [^ ]m4.exe
 107 # to  autom4te: m4
 108 #
 109 # Moreover, DJGPP error messages include the error code in brackets;
 110 # remove the error code during normalization.
 111 #
 112 m4_define([AT_CHECK_M4],
 113 [AT_CHECK([$1], [$2], [$3],
 114           m4_case([$4], [], [], [ignore], [ignore], [stderr]))
 115 m4_case([$4], [], [], [ignore], [],
 116 [AT_CHECK([[mv stderr stderr-raw &&
 117    sed 's/^[^:]*m4[-.ex0-9]*: *\([^:]*:\) *\([0-9][0-9]*: \)/m4:\1\2/
 118         s/^\([^:]*:\) *\([0-9][0-9]*:\)[^:]*m4[-.ex0-9]*: /m4:\1\2 /
 119         s/: C\(annot open \)\([^`:]*\):/: c\1`\2'\'':/
 120         s/: include:\( cannot open\)/:\1/
 121         s/^autom4te: [^ ]*m4[.ex]* /autom4te: m4 /
 122         s/ (E[A-Z]*)$//
 123     ' stderr-raw >&2]], [0], [], [$4])])
 124 ])
 125
 126 # AT_CHECK_AUTOM4TE(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 127 # -----------------------------------------------------------
 128 m4_define([AT_CHECK_AUTOM4TE],
 129 [AT_CHECK_M4([autom4te $1], [$2], [$3], [$4])])
 130
 131
 132
 133 ## ----------------- ##
 134 ## Testing M4sugar.  ##
 135 ## ----------------- ##
 136
 137
 138 # AT_DATA_M4SUGAR(FILE-NAME, CONTENTS)
 139 # ------------------------------------
 140 # Escape the invalid tokens with @&t@.
 141 m4_define([AT_DATA_M4SUGAR],
 142 [AT_DATA([$1],
 143 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\)\(_\)\|\(d\)\(nl\)],
 144               [\1\3\5@&t@\2\4\6])])])
 145
 146
 147 # AT_CHECK_M4SUGAR(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 148 # ----------------------------------------------------------
 149 m4_define([AT_CHECK_M4SUGAR],
 150 [AT_KEYWORDS([m4sugar])
 151 AT_CHECK_AUTOM4TE([--language=m4sugar script.4s -o script $1],
 152                    [$2], [$3], [$4])])
 153
 154
 155
 156 ## -------------- ##
 157 ## Testing M4sh.  ##
 158 ## -------------- ##
 159
 160
 161 # AT_DATA_M4SH(FILE-NAME, CONTENTS)
 162 # ---------------------------------
 163 # Escape the invalid tokens with @&t@.
 164 m4_define([AT_DATA_M4SH],
 165 [AT_DATA([$1],
 166 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\|AS\)\(_\)\|\(d\)\(nl\)],
 167               [\1\3\5@&t@\2\4\6])])])
 168
 169
 170 # AT_CHECK_M4SH(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 171 # -------------------------------------------------------
 172 m4_define([AT_CHECK_M4SH],
 173 [AT_CHECK_AUTOM4TE([--language=m4sh script.as -o script $1],
 174                    [$2], [$3], [$4])])
 175
 176
 177
 178 ## ------------------ ##
 179 ## Testing Autoconf.  ##
 180 ## ------------------ ##
 181
 182
 183 # AT_DATA_AUTOCONF(FILE-NAME, CONTENTS)
 184 # -------------------------------------
 185 # Escape the invalid tokens with @&t@.
 186 m4_define([AT_DATA_AUTOCONF],
 187 [AT_DATA([$1],
 188 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\|AS\|AC\)\(_\)\|\(d\)\(nl\)],
 189               [\1\3\5@&t@\2\4\6])])])
 190
 191
 192
 193 # AT_CONFIGURE_AC(BODY)
 194 # ---------------------
 195 # Create a full configure.ac running BODY, with a config header set up,
 196 # AC_OUTPUT, and environment checking hooks.
 197 m4_define([AT_CONFIGURE_AC],
 198 [AT_DATA([configure.ac],
 199 [[AC_INIT
 200 AC_CONFIG_HEADERS(config.h:config.hin)
 201 AC_STATE_SAVE(before)]
 202 $1
 203 [AC_OUTPUT
 204 AC_STATE_SAVE(after)
 205 ]])
 206 cp "$abs_top_srcdir/build-aux/install-sh" \
 207    "$abs_top_srcdir/build-aux/config.guess" \
 208    "$abs_top_srcdir/build-aux/config.sub" .
 209 cp "$abs_top_srcdir/tests/statesave.m4" aclocal.m4
 210 ])# AT_CONFIGURE_AC
 211
 212
 213 # AT_CHECK_AUTOCONF(ARGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 214 # ----------------------------------------------------------
 215 # We always use "--force", to prevent problems with timestamps if the testsuite
 216 # were running too fast.
 217 m4_define([AT_CHECK_AUTOCONF],
 218 [AT_CHECK_M4([autoconf --force $1], [$2], [$3], [$4])
 219 if test -s configure && test "$ac_cv_sh_n_works" = yes; then
 220   AT_CHECK_SHELL_SYNTAX([configure])
 221 fi
 222 ])
 223
 224
 225 # AT_CHECK_AUTOHEADER(ARGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 226 # ------------------------------------------------------------
 227 m4_define([AT_CHECK_AUTOHEADER],
 228 [AT_CHECK([autoheader $1], [$2], [$3], [$4])
 229 ])
 230
 231
 232 # AT_CHECK_CONFIGURE(END-COMMAND,
 233 #                    [EXIT-STATUS = 0],
 234 #                    [STDOUT = IGNORE], STDERR)
 235 # ---------------------------------------------
 236 # `abs_top_srcdir' is needed so that `./configure' finds install-sh.
 237 # Using --srcdir is more expensive.
 238 m4_define([AT_CHECK_CONFIGURE],
 239 [AT_CAPTURE_FILE([config.log])[]dnl
 240  AT_CHECK([./configure $configure_options $1],
 241           [$2],
 242           m4_default([$3], [ignore]), [$4])])
 243
 244
 245 # AT_CHECK_ENV
 246 # ------------
 247 # Check that the full configure run remained in its variable name space,
 248 # and cleaned up tmp files.
 249 #
 250 # Perhaps grep -E is not supported, or perhaps it chokes on such a big regex.
 251 # In this case just don't pay attention to the env.  It would be great
 252 # to keep the error message but we can't: that would break AT_CHECK.
 253 #
 254 # FreeBSD sh may intermingle the trace output from the egrep and grep
 255 # commands in the pipe, so turn off tracing for these.
 256 #
 257 # Some tests might exit prematurely when they find a problem, in
 258 # which case `env-after' is probably missing.  Don't check it then.
 259 #
 260 # Here are the variables `configure' may modify during execution:
 261 # - ^as_
 262 #   M4sh's shell name space.
 263 # - ^ac_
 264 #   Autoconf's shell name space.
 265 # - prefix and exec_prefix
 266 #   are kept undefined (NONE) until AC_OUTPUT which then sets them to
 267 #   `/usr/local' and `${prefix}' for make.
 268 # - (host|build|target)(_(alias|cpu|vendor|os))?
 269 #   Set by AC_CANONICAL_(HOST|BUILD|TARGET).
 270 # - cross_compiling
 271 #   Set by AC_INIT.
 272 # - interpval
 273 #   Set by AC_SYS_INTERPRETER.
 274 # - CONFIG_STATUS and DEFS
 275 #   Set by AC_OUTPUT.
 276 # - AC_SUBST'ed variables
 277 #   (FIXME: Generate a list of these automatically.)
 278 # - _|@|.[*#?$].|argv|ARGC|LINENO|OLDPWD|PIPESTATUS|RANDOM|SECONDS
 279 #   Some variables some shells use and change.
 280 #   `.[*#?$].' catches `$#' etc. which are displayed like this:
 281 #      | '!'=18186
 282 #      | '#'=0
 283 #      | '$'=6908
 284 #
 285 m4_define([AT_CHECK_ENV],
 286 [m4_divert_once([PREPARE_TESTS], [_AT_CHECK_ENV])dnl
 287 AT_CHECK([at_check_env])])
 288 m4_define([_AT_CHECK_ENV],
 289 [AS_FUNCTION_DESCRIBE([at_check_env], [],
 290 [Compare the directory and environment state both before and after a run,
 291 and return non-zero status if they differ inappropriately.])
 292 at_check_env ()
 293 {
 294 # Compare directory listings.
 295 test -f state-ls.before ||
 296   AS_ERROR([state-ls.before not present])
 297 test -f state-ls.after \
 298   && { $at_diff state-ls.before state-ls.after || return 1; }
 299 # Compare variable space dumps.
 300 if test -f state-env.before && test -f state-env.after; then
 301   set +x
 302   grep_failed=false
 303   for act_file in state-env.before state-env.after
 304   do
 305     ($EGREP -v '^(m4_join([|],
 306       [a[cs]_.*],
 307       [(exec_)?prefix|DEFS|CONFIG_STATUS],
 308       [CC|CFLAGS|CPP|GCC|CXX|CXXFLAGS|CXXCPP|GXX|F77|FFLAGS|FLIBS|G77],
 309       [ERL|ERLC|ERLCFLAGS|ERLANG_PATH_ERL|ERLANG_ROOT_DIR|ERLANG_LIB_DIR],
 310       [ERLANG_LIB_DIR_.*|ERLANG_LIB_VER_.*|ERLANG_INSTALL_LIB_DIR],
 311       [ERLANG_INSTALL_LIB_DIR_.*|ERLANG_ERTS_VER|OBJC|OBJCPP|OBJCFLAGS],
 312       [OBJCXX|OBJCXXCPP|OBJCXXFLAGS],
 313       [GOC|GOFLAGS],
 314       [OPENMP_CFLAGS],
 315       [LIBS|LIB@&t@OBJS|LTLIBOBJS|LDFLAGS],
 316       [INSTALL(_(DATA|PROGRAM|SCRIPT))?],
 317       [CYGWIN|ISC|MINGW32|MINIX|EMXOS2|XENIX|EXEEXT|OBJEXT],
 318       [X_(CFLAGS|(EXTRA_|PRE_)?LIBS)|x_(includes|libraries)|(have|no)_x],
 319       [(host|build|target)(_(alias|cpu|vendor|os))?],
 320       [cross_compiling|U],
 321       [interpval|PATH_SEPARATOR],
 322       [GFC|F77_DUMMY_MAIN|f77_(case|underscore)],
 323       [FC(_DUMMY_MAIN|FLAGS|LIBS|FLAGS_[fF]|_MODEXT|_MODINC|_MODOUT|_DEFINE)?],
 324       [ALLOCA|GETLOADAVG_LIBS|KMEM_GROUP|NEED_SETGID|POW_LIB],
 325       [AWK|LEX|LEXLIB|LEX_OUTPUT_ROOT|LN_S|M4|MKDIR_P|RANLIB|SET_MAKE|YACC],
 326       [GREP|[EF]GREP|SED],
 327       [[_@]|.[*#?$].],
 328       [argv|ARGC|LINENO|OLDPWD|PIPESTATUS|RANDOM|SECONDS]))=' \
 329      $act_file ||
 330        test $? -eq 1 || echo failed >&2
 331     ) 2>stderr-$act_file |
 332       # There may be variables spread on several lines; remove latter lines.
 333       $GREP '^m4_defn([m4_re_word])=' >clean-$act_file ||
 334         test $? -eq 1 || grep_failed=:
 335     test -s stderr-$act_file && grep_failed=:
 336   done
 337   $at_traceon
 338   $grep_failed || $at_diff clean-state-env.before clean-state-env.after
 339 fi
 340 } [#]at_check_env])
 341
 342
 343 # AT_CONFIG_CMP(VAR-FILE-A, VAR-FILE-B)
 344 # -------------------------------------
 345 # Check the outcomes of two configure runs for equality by comparing dumps of
 346 # their shell variables.  VAR-FILE-A and VAR-FILE-B are two `set'-style shell
 347 # variable space dumps.
 348 #
 349 # We permit variance between runs in the following shell variables:
 350 # - ^as_
 351 #   M4sh's shell name space.
 352 # - ^ac_, excluding ^ac_cv_
 353 #   Autoconf's private shell name space.
 354 # - PPID [bash, zsh]
 355 # - RANDOM [zsh]
 356 # - SECONDS [zsh]
 357 # - '$' [zsh]
 358 # - argv [zsh]
 359 # - ARGC [zsh]
 360 #
 361 # Furthermore, it is okay for a non-cache variable initialized to empty in one
 362 # run to be unset in another run.  This happens when, for example, cache update
 363 # code tries a number of values in LIBS and eventually restores LIBS to its
 364 # original value. If LIBS was previously unset, it will have become set and
 365 # empty.  (OTOH, cache variables indicate the result of the test even if they
 366 # are empty, so we have to be strict about them.)
 367 #
 368 # Lines that do not look like `foo=bar' are probably latter lines of
 369 # multiline values; trim them.
 370 #
 371 m4_define([AT_CONFIG_CMP],
 372 [for act_file in $1 $2
 373 do
 374   $SED '/^ac_cv_/ b
 375         /^m4_defn([m4_re_word])=./ !d
 376         /^[[^=]]*='\'''\''$/ d
 377         /^a[[cs]]_/ d
 378         /^OLDPWD=/ d
 379         /^PPID=/ d
 380         /^RANDOM=/ d
 381         /^SECONDS=/ d
 382         /'\'\\\$\''=/ d
 383         /^argv=/ d
 384         /^ARGC=/ d
 385         ' $act_file >at_config_vars-$act_file
 386 done
 387 AT_CMP([at_config_vars-$1], [at_config_vars-$2])[]dnl
 388 ])# AT_CONFIG_CMP
 389
 390
 391 # AT_CHECK_DEFINES(CONTENT)
 392 # -------------------------
 393 # Verify that config.h, once stripped, is CONTENT.
 394 # Stripping consists of keeping CPP lines (i.e. containing a hash),
 395 # but those of automatically checked features (STDC_HEADERS etc.)
 396 # and symbols (PACKAGE_...).
 397 # AT_CHECK_HEADER is a better name, but too close from AC_CHECK_HEADER.
 398 m4_define([AT_CHECK_DEFINES],
 399 [AT_CHECK([[sed '/#/!d
 400 /INTTYPES/d
 401 /MEMORY/d
 402 /PACKAGE_/d
 403 /STDC_HEADERS/d
 404 /STDINT/d
 405 /STDLIB/d
 406 /STRING/d
 407 /SYS_STAT/d
 408 /SYS_TYPES/d
 409 /UNISTD/d' config.h]],,
 410           [$1])])
 411
 412
 413 # AT_CHECK_AUTOUPDATE
 414 # -------------------
 415 m4_define([AT_CHECK_AUTOUPDATE],
 416 [AT_CHECK([autoupdate $1], [$2], [$3], [$4])
 417 ])
 418
 419
 420 # _AT_CHECK_AC_MACRO(AC-BODY, PRE-TESTS)
 421 # --------------------------------------
 422 # Create a minimalist configure.ac running the macro named
 423 # NAME-OF-THE-MACRO, check that autoconf runs on that script,
 424 # and that the shell runs correctly the configure.
 425 m4_define([_AT_CHECK_AC_MACRO],
 426 [AT_CONFIGURE_AC([$1])
 427 $2
 428 AT_CHECK_AUTOCONF
 429 AT_CHECK_AUTOHEADER
 430 AT_CHECK_CONFIGURE
 431 AT_CHECK_ENV
 432 ])# _AT_CHECK_AC_MACRO
 433
 434
 435 # AT_CHECK_MACRO(MACRO, [MACRO-USE], [ADDITIONAL-CMDS],
 436 #                [AUTOCONF-FLAGS = -W obsolete])
 437 # -----------------------------------------------------
 438 # Create a minimalist configure.ac running the macro named
 439 # NAME-OF-THE-MACRO, check that autoconf runs on that script,
 440 # and that the shell runs correctly the configure.
 441 #
 442 # We run `configure' twice, both times with a cache, and compare
 443 # the environment after each run to detect inconsistencies.
 444 #
 445 # New macros are not expected to depend upon obsolete macros.
 446 m4_define([AT_CHECK_MACRO],
 447 [AT_SETUP([$1])
 448
 449 AT_CONFIGURE_AC([m4_default([$2], [$1])])
 450
 451 AT_CHECK_AUTOCONF([m4_default([$4], [-W obsolete])])
 452 AT_CHECK_AUTOHEADER
 453
 454 for at_run in r1 r2
 455 do
 456     AT_CHECK_CONFIGURE([-C])
 457     cp -f state-env.after state-env.$at_run
 458     cp -f config.h config-h.$at_run
 459     AT_CHECK_ENV
 460 done
 461
 462 AT_CMP([config-h.r1], [config-h.r2])
 463 AT_CONFIG_CMP([state-env.r1], [state-env.r2])
 464
 465 $3
 466
 467 AT_CLEANUP[]dnl
 468 ])# AT_CHECK_MACRO
 469
 470
 471 # AT_CHECK_MACRO_CROSS(MACRO, [MACRO-USE], [ADDITIONAL-CMDS],
 472 #                      [AUTOCONF-FLAGS = -W obsolete])
 473 # -----------------------------------------------------------
 474 # Like the previous one, but creates two checks: for native
 475 # compile and for cross-compile.
 476 m4_define([AT_CHECK_MACRO_CROSS],
 477 [AT_CHECK_MACRO($@)
 478 AT_CHECK_MACRO([$1 (cross compile)],
 479   [AT_KEYWORDS([cross])
 480   # Exercise the code used when cross-compiling.
 481   cross_compiling=yes
 482   ac_tool_warned=yes
 483   m4_default([$2], [$1])],
 484   [$3], [$4])
 485 ])
 486
 487
 488 # AT_CHECK_AU_MACRO(MACRO)
 489 # ------------------------
 490 # Create a minimalist configure.ac running the macro named
 491 # NAME-OF-THE-MACRO, autoupdate this script, check that autoconf runs
 492 # on that script, and that the shell runs correctly the configure.
 493 #
 494 # Updated configure.ac shall not depend upon obsolete macros, which votes
 495 # in favor of `-W obsolete', but since many of these macros leave a message
 496 # to be removed by the user once her code is adjusted, let's not check.
 497 #
 498 # Remove config.hin to avoid `autoheader: config.hin is unchanged'.
 499 m4_define([AT_CHECK_AU_MACRO],
 500 [AT_SETUP([$1])
 501 AT_KEYWORDS([autoupdate])
 502
 503 AT_CONFIGURE_AC([$1])
 504
 505 AT_CHECK_AUTOCONF
 506 AT_CHECK_AUTOHEADER
 507 AT_CHECK_CONFIGURE
 508 AT_CHECK_ENV
 509
 510 rm config.hin
 511 AT_CHECK_AUTOUPDATE([], 0, [], ignore)
 512 AT_CHECK([grep '^$1$' configure.ac], 1)
 513
 514 AT_CHECK_AUTOCONF
 515 AT_CHECK_AUTOHEADER
 516 AT_CHECK_CONFIGURE
 517 AT_CHECK_ENV
 518
 519 AT_CLEANUP[]dnl
 520 ])# AT_CHECK_AU_MACRO
 521
 522
 523
 524 ## ----------------------- ##
 525 ## Launch the test suite.  ##
 526 ## ----------------------- ##
 527
 528 AT_INIT