rbutil/rbutilqt/rbutilqt.pro

   1 unix:!mac {
   2     CCACHE = $$system(which ccache)
   3     !isEmpty(CCACHE) {
   4         message("using ccache")
   5         QMAKE_CXX = ccache g++
   6         QMAKE_CC = ccache gcc
   7     }
   8 }
   9
  10 OBJECTS_DIR = build/o
  11 UI_DIR = build/ui
  12 MOC_DIR = build/moc
  13 RCC_DIR = build/rcc
  14
  15 SOURCES += rbutilqt.cpp \
  16            main.cpp \
  17  install.cpp \
  18  httpget.cpp \
  19  configure.cpp \
  20  zip/zip.cpp \
  21  zip/unzip.cpp \
  22  installzip.cpp \
  23  installbootloader.cpp \
  24  progressloggergui.cpp \
  25  installtalkwindow.cpp \
  26  talkfile.cpp \
  27  autodetection.cpp \
  28  ../ipodpatcher/ipodpatcher.c \
  29  ../sansapatcher/sansapatcher.c \
  30  irivertools/irivertools.cpp \
  31  irivertools/md5sum.cpp  \
  32  browsedirtree.cpp \
  33  installthemes.cpp \
  34  uninstall.cpp \
  35  uninstallwindow.cpp \
  36  browseof.cpp \
  37  preview.cpp
  38
  39 HEADERS += rbutilqt.h \
  40  install.h \
  41  httpget.h \
  42  configure.h \
  43  zip/zip.h \
  44  zip/unzip.h \
  45  zip/zipentry_p.h \
  46  zip/unzip_p.h \
  47  zip/zip_p.h \
  48  version.h \
  49  installzip.h \
  50  installbootloader.h \
  51  installtalkwindow.h \
  52  talkfile.h \
  53  autodetection.h \
  54  progressloggerinterface.h \
  55  progressloggergui.h \
  56  ../ipodpatcher/ipodpatcher.h \
  57  ../ipodpatcher/ipodio.h \
  58  ../ipodpatcher/parttypes.h \
  59  ../sansapatcher/sansapatcher.h \
  60  ../sansapatcher/sansaio.h \
  61  irivertools/irivertools.h \
  62  irivertools/md5sum.h \
  63  irivertools/h100sums.h \
  64  irivertools/h120sums.h \
  65  irivertools/h300sums.h \
  66  irivertools/checksums.h \
  67  browsedirtree.h \
  68  installthemes.h \
  69  uninstall.h \
  70  uninstallwindow.h \
  71  browseof.h \
  72  preview.h
  73
  74 # Needed by QT on Win
  75 INCLUDEPATH = . irivertools zip zlib ../ipodpatcher ../sansapatcher
  76
  77 TEMPLATE = app
  78 dbg {
  79     CONFIG += debug thread qt warn_on
  80     DEFINES -= QT_NO_DEBUG_OUTPUT
  81     message("debug")
  82 }
  83 !dbg {
  84     CONFIG += release thread qt
  85     DEFINES += QT_NO_DEBUG_OUTPUT
  86     message("release")
  87 }
  88
  89 TARGET = rbutilqt
  90
  91 FORMS += rbutilqtfrm.ui \
  92  aboutbox.ui \
  93  installfrm.ui \
  94  installprogressfrm.ui \
  95  configurefrm.ui \
  96  browsedirtreefrm.ui \
  97  installtalkfrm.ui \
  98  installthemesfrm.ui \
  99  uninstallfrm.ui \
 100  browseoffrm.ui \
 101  previewfrm.ui
 102
 103 RESOURCES += rbutilqt.qrc
 104
 105 TRANSLATIONS += rbutil_de.ts \
 106  rbutil_fr.ts \
 107  rbutil_zh_CN.ts \
 108  rbutil_zh_TW.ts
 109 QT += network
 110 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 111
 112 win32 {
 113     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 114     SOURCES +=  ../sansapatcher/sansaio-win32.c
 115     RC_FILE = rbutilqt.rc
 116 }
 117
 118 unix {
 119     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 120     SOURCES +=  ../sansapatcher/sansaio-posix.c
 121 }
 122
 123 macx {
 124     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 125     CONFIG+=x86 ppc
 126 }
 127 unix {
 128     LIBS += -lusb
 129 }
 130
 131 static {
 132     QTPLUGIN += qtaccessiblewidgets
 133     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 134     DEFINES += STATIC
 135     message("using static plugin")
 136 }
 137