rbutil/rbutilqt/rbutilqt.pro

   1 unix:!mac {
   2     CCACHE = $$system(which ccache)
   3     !isEmpty(CCACHE) {
   4         message("using ccache")
   5         QMAKE_CXX = ccache g++
   6         QMAKE_CC = ccache gcc
   7     }
   8 }
   9
  10 OBJECTS_DIR = build/o
  11 UI_DIR = build/ui
  12 MOC_DIR = build/moc
  13 RCC_DIR = build/rcc
  14
  15 # add a custom rule for pre-building librbspeex
  16 rbspeex.commands = @$(MAKE) -C ../../tools/rbspeex librbspeex.a
  17 QMAKE_EXTRA_TARGETS += rbspeex
  18 PRE_TARGETDEPS += rbspeex
  19
  20 # rule for creating ctags file
  21 tags.commands = ctags -R --c++-kinds=+p --fields=+iaS --extra=+q $(SOURCES)
  22 tags.depends = $(SOURCES)
  23 QMAKE_EXTRA_TARGETS += tags
  24
  25 # add a custom rule for making the translations
  26 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent rbutilqt.pro
  27 QMAKE_EXTRA_TARGETS += lrelease
  28 !dbg {
  29     PRE_TARGETDEPS += lrelease
  30 }
  31
  32
  33 SOURCES += rbutilqt.cpp \
  34            main.cpp \
  35  install.cpp \
  36  httpget.cpp \
  37  configure.cpp \
  38  zip/zip.cpp \
  39  zip/unzip.cpp \
  40  installzip.cpp \
  41  installbootloader.cpp \
  42  progressloggergui.cpp \
  43  installtalkwindow.cpp \
  44  talkfile.cpp \
  45  autodetection.cpp \
  46  ../ipodpatcher/ipodpatcher.c \
  47  ../sansapatcher/sansapatcher.c \
  48  irivertools/irivertools.cpp \
  49  irivertools/md5sum.cpp  \
  50  browsedirtree.cpp \
  51  installthemes.cpp \
  52  uninstall.cpp \
  53  uninstallwindow.cpp \
  54  utils.cpp \
  55  browseof.cpp \
  56  preview.cpp \
  57  encoders.cpp \
  58  encodersgui.cpp \
  59  tts.cpp \
  60  ttsgui.cpp \
  61  ../../tools/wavtrim.c \
  62  ../../tools/voicefont.c \
  63  voicefile.cpp \
  64  createvoicewindow.cpp \
  65  rbsettings.cpp \
  66  rbunzip.cpp \
  67  rbzip.cpp \
  68  sysinfo.cpp \
  69  detect.cpp
  70
  71 HEADERS += rbutilqt.h \
  72  install.h \
  73  httpget.h \
  74  configure.h \
  75  zip/zip.h \
  76  zip/unzip.h \
  77  zip/zipentry_p.h \
  78  zip/unzip_p.h \
  79  zip/zip_p.h \
  80  version.h \
  81  installzip.h \
  82  installbootloader.h \
  83  installtalkwindow.h \
  84  talkfile.h \
  85  autodetection.h \
  86  progressloggerinterface.h \
  87  progressloggergui.h \
  88  ../ipodpatcher/ipodpatcher.h \
  89  ../ipodpatcher/ipodio.h \
  90  ../ipodpatcher/parttypes.h \
  91  ../sansapatcher/sansapatcher.h \
  92  ../sansapatcher/sansaio.h \
  93  irivertools/irivertools.h \
  94  irivertools/md5sum.h \
  95  irivertools/h100sums.h \
  96  irivertools/h120sums.h \
  97  irivertools/h300sums.h \
  98  irivertools/checksums.h \
  99  browsedirtree.h \
 100  installthemes.h \
 101  uninstall.h \
 102  uninstallwindow.h \
 103  utils.h \
 104  browseof.h \
 105  preview.h \
 106  encoders.h \
 107  encodersgui.h \
 108  tts.h \
 109  ttsgui.h \
 110  ../../tools/wavtrim.h \
 111  ../../tools/voicefont.h \
 112  voicefile.h \
 113  createvoicewindow.h \
 114  rbsettings.h \
 115  rbunzip.h \
 116  rbzip.h \
 117  sysinfo.h \
 118  detect.h
 119
 120 # Needed by QT on Win
 121 INCLUDEPATH = . irivertools zip zlib ../ipodpatcher ../sansapatcher ../../tools/rbspeex ../../tools
 122
 123 LIBS += -L../../tools/rbspeex -lrbspeex
 124
 125 TEMPLATE = app
 126 dbg {
 127     CONFIG += debug thread qt warn_on
 128     DEFINES -= QT_NO_DEBUG_OUTPUT
 129     message("debug")
 130 }
 131 !dbg {
 132     CONFIG += release thread qt
 133     DEFINES += QT_NO_DEBUG_OUTPUT
 134     message("release")
 135 }
 136
 137 TARGET = rbutilqt
 138
 139 FORMS += rbutilqtfrm.ui \
 140  aboutbox.ui \
 141  installfrm.ui \
 142  progressloggerfrm.ui \
 143  configurefrm.ui \
 144  browsedirtreefrm.ui \
 145  installtalkfrm.ui \
 146  installthemesfrm.ui \
 147  uninstallfrm.ui \
 148  browseoffrm.ui \
 149  previewfrm.ui \
 150  rbspeexcfgfrm.ui \
 151  encexescfgfrm.ui \
 152  ttsexescfgfrm.ui \
 153  sapicfgfrm.ui \
 154  createvoicefrm.ui \
 155  sysinfofrm.ui
 156
 157 RESOURCES += rbutilqt.qrc
 158 win32 {
 159     RESOURCES += rbutilqt-win.qrc
 160 }
 161 !dbg {
 162     RESOURCES += rbutilqt-lang.qrc
 163 }
 164
 165 TRANSLATIONS += rbutil_de.ts \
 166  rbutil_fr.ts \
 167  rbutil_nl.ts \
 168  rbutil_tr.ts \
 169  rbutil_zh_CN.ts \
 170  rbutil_zh_TW.ts
 171 QT += network
 172 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 173
 174 win32 {
 175     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 176     SOURCES +=  ../sansapatcher/sansaio-win32.c
 177     RC_FILE = rbutilqt.rc
 178     LIBS += -lsetupapi -lnetapi32
 179 }
 180
 181 unix {
 182     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 183     SOURCES +=  ../sansapatcher/sansaio-posix.c
 184 }
 185 unix:!static {
 186     LIBS += -lusb
 187 }
 188 unix:static {
 189     # force statically linking of libusb. Libraries that are appended
 190     # later will get linked dynamically again.
 191     LIBS += -Wl,-Bstatic -lusb -Wl,-Bdynamic
 192 }
 193
 194 macx {
 195     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 196     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4
 197     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4
 198     CONFIG+=x86 ppc
 199     LIBS += -L/usr/local/lib -framework IOKit
 200     INCLUDEPATH += /usr/local/include
 201     QMAKE_INFO_PLIST = Info.plist
 202     RC_FILE = icons/rbutilqt.icns
 203 }
 204
 205 static {
 206     QTPLUGIN += qtaccessiblewidgets
 207     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 208     DEFINES += STATIC
 209     message("using static plugin")
 210 }
 211
 212 unix {
 213     target.path = /usr/local/bin
 214     INSTALLS += target
 215 }
 216