rbutil/rbutilqt/rbutilqt.pro

   1 unix:!mac {
   2     CCACHE = $$system(which ccache)
   3     !isEmpty(CCACHE) {
   4         message("using ccache")
   5         QMAKE_CXX = ccache g++
   6         QMAKE_CC = ccache gcc
   7     }
   8 }
   9
  10 OBJECTS_DIR = build/o
  11 UI_DIR = build/ui
  12 MOC_DIR = build/moc
  13 RCC_DIR = build/rcc
  14
  15 SOURCES += rbutilqt.cpp \
  16            main.cpp \
  17  install.cpp \
  18  httpget.cpp \
  19  configure.cpp \
  20  zip/zip.cpp \
  21  zip/unzip.cpp \
  22  installzip.cpp \
  23  installbootloader.cpp \
  24  progressloggergui.cpp \
  25  installtalkwindow.cpp \
  26  talkfile.cpp \
  27  autodetection.cpp \
  28  ../ipodpatcher/ipodpatcher.c \
  29  ../sansapatcher/sansapatcher.c \
  30  irivertools/irivertools.cpp \
  31  irivertools/md5sum.cpp  \
  32  browsedirtree.cpp \
  33  installthemes.cpp \
  34  uninstall.cpp \
  35  uninstallwindow.cpp \
  36  utils.cpp \
  37  browseof.cpp \
  38  preview.cpp
  39
  40 HEADERS += rbutilqt.h \
  41  install.h \
  42  httpget.h \
  43  configure.h \
  44  zip/zip.h \
  45  zip/unzip.h \
  46  zip/zipentry_p.h \
  47  zip/unzip_p.h \
  48  zip/zip_p.h \
  49  version.h \
  50  installzip.h \
  51  installbootloader.h \
  52  installtalkwindow.h \
  53  talkfile.h \
  54  autodetection.h \
  55  progressloggerinterface.h \
  56  progressloggergui.h \
  57  ../ipodpatcher/ipodpatcher.h \
  58  ../ipodpatcher/ipodio.h \
  59  ../ipodpatcher/parttypes.h \
  60  ../sansapatcher/sansapatcher.h \
  61  ../sansapatcher/sansaio.h \
  62  irivertools/irivertools.h \
  63  irivertools/md5sum.h \
  64  irivertools/h100sums.h \
  65  irivertools/h120sums.h \
  66  irivertools/h300sums.h \
  67  irivertools/checksums.h \
  68  browsedirtree.h \
  69  installthemes.h \
  70  uninstall.h \
  71  uninstallwindow.h \
  72  utils.h \
  73  browseof.h \
  74  preview.h
  75
  76 # Needed by QT on Win
  77 INCLUDEPATH = . irivertools zip zlib ../ipodpatcher ../sansapatcher
  78
  79 TEMPLATE = app
  80 dbg {
  81     CONFIG += debug thread qt warn_on
  82     DEFINES -= QT_NO_DEBUG_OUTPUT
  83     message("debug")
  84 }
  85 !dbg {
  86     CONFIG += release thread qt
  87     DEFINES += QT_NO_DEBUG_OUTPUT
  88     message("release")
  89 }
  90
  91 TARGET = rbutilqt
  92
  93 FORMS += rbutilqtfrm.ui \
  94  aboutbox.ui \
  95  installfrm.ui \
  96  installprogressfrm.ui \
  97  configurefrm.ui \
  98  browsedirtreefrm.ui \
  99  installtalkfrm.ui \
 100  installthemesfrm.ui \
 101  uninstallfrm.ui \
 102  browseoffrm.ui \
 103  previewfrm.ui
 104
 105 RESOURCES += rbutilqt.qrc
 106
 107 TRANSLATIONS += rbutil_de.ts \
 108  rbutil_fr.ts \
 109  rbutil_zh_CN.ts \
 110  rbutil_zh_TW.ts
 111 QT += network
 112 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 113
 114 win32 {
 115     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 116     SOURCES +=  ../sansapatcher/sansaio-win32.c
 117     RC_FILE = rbutilqt.rc
 118     LIBS += -lsetupapi
 119 }
 120
 121 unix {
 122     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 123     SOURCES +=  ../sansapatcher/sansaio-posix.c
 124     LIBS += -lusb
 125 }
 126
 127 macx {
 128     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 129     CONFIG+=x86 ppc
 130 }
 131
 132 static {
 133     QTPLUGIN += qtaccessiblewidgets
 134     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 135     DEFINES += STATIC
 136     message("using static plugin")
 137 }
 138