configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL$
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33
  34 AC_CANONICAL_HOST
  35
  36 template=
  37 AC_MSG_CHECKING([which template to use])
  38
  39 PGAC_ARG_REQ(with, template, [],
  40 [
  41   case $withval in
  42     list)   echo; ls "$srcdir/src/template"; exit;;
  43     *)      if test -f "$srcdir/src/template/$with_template" ; then
  44               template=$withval
  45             else
  46               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  47             fi;;
  48   esac
  49 ],
  50 [
  51 # --with-template not given
  52
  53 case $host_os in
  54      aix*) template=aix ;;
  55     bsdi*) template=bsdi ;;
  56   cygwin*) template=cygwin ;;
  57   darwin*) template=darwin ;;
  58     dgux*) template=dgux ;;
  59  freebsd*) template=freebsd ;;
  60     hpux*) template=hpux ;;
  61     irix*) template=irix ;;
  62  linux*|gnu*|k*bsd*-gnu)
  63            template=linux ;;
  64    mingw*) template=win32 ;;
  65   netbsd*) template=netbsd ;;
  66 nextstep*) template=nextstep ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sunos*) template=sunos4 ;;
  72  sysv4.2*)
  73         case $host_vendor in
  74           univel) template=univel ;;
  75         esac ;;
  76    sysv4*) template=svr4 ;;
  77    sysv5*) template=unixware ;;
  78   ultrix*) template=ultrix4 ;;
  79 esac
  80
  81   if test x"$template" = x"" ; then
  82     AC_MSG_ERROR([[
  83 *******************************************************************
  84 PostgreSQL has apparently not been ported to your platform yet.
  85 To try a manual configuration, look into the src/template directory
  86 for a similar platform and use the '--with-template=' option.
  87
  88 Please also contact <pgsql-ports@postgresql.org> to see about
  89 rectifying this.  Include the above 'checking host system type...'
  90 line.
  91 *******************************************************************
  92 ]])
  93   fi
  94
  95 ])
  96
  97 AC_MSG_RESULT([$template])
  98
  99 PORTNAME=$template
 100 AC_SUBST(PORTNAME)
 101
 102 # Initialize default assumption that we do not need separate assembly code
 103 # for TAS (test-and-set).  This can be overridden by the template file
 104 # when it's executed.
 105 need_tas=no
 106 tas_file=dummy.s
 107
 108
 109
 110 ##
 111 ## Command line options
 112 ##
 113
 114 #
 115 # Add non-standard directories to the include path
 116 #
 117 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 118
 119
 120 #
 121 # Add non-standard directories to the library search path
 122 #
 123 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 124              [LIBRARY_DIRS=$withval])
 125
 126 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 127              [LIBRARY_DIRS=$withval])
 128
 129
 130 #
 131 # 64-bit integer date/time storage: enabled by default.
 132 #
 133 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 134 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [  --disable-integer-datetimes  disable 64-bit integer date/time support],
 135               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 136                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 137 AC_MSG_RESULT([$enable_integer_datetimes])
 138
 139
 140 #
 141 # NLS
 142 #
 143 AC_MSG_CHECKING([whether NLS is wanted])
 144 PGAC_ARG_OPTARG(enable, nls,
 145                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 146                 [],
 147                 [WANTED_LANGUAGES=$enableval],
 148                 [AC_DEFINE(ENABLE_NLS, 1,
 149                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 150 AC_MSG_RESULT([$enable_nls])
 151 AC_SUBST(enable_nls)
 152 AC_SUBST(WANTED_LANGUAGES)
 153
 154 #
 155 # Default port number (--with-pgport), default 5432
 156 #
 157 AC_MSG_CHECKING([for default port number])
 158 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   set default port number [[5432]]],
 159              [default_port=$withval],
 160              [default_port=5432])
 161 AC_MSG_RESULT([$default_port])
 162 # Need both of these because some places want an integer and some a string
 163 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 164 [Define to the default TCP port number on which the server listens and
 165 to which clients will try to connect.  This can be overridden at run-time,
 166 but it's convenient if your clients have the right default compiled in.
 167 (--with-pgport=PORTNUM)])
 168 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 169                    [Define to the default TCP port number as a string constant.])
 170 AC_SUBST(default_port)
 171
 172 #
 173 # Option to disable shared libraries
 174 #
 175 PGAC_ARG_BOOL(enable, shared, yes,
 176               [  --disable-shared        do not build shared libraries])
 177 AC_SUBST(enable_shared)
 178
 179 #
 180 # '-rpath'-like feature can be disabled
 181 #
 182 PGAC_ARG_BOOL(enable, rpath, yes,
 183               [  --disable-rpath         do not embed shared library search path in executables])
 184 AC_SUBST(enable_rpath)
 185
 186 #
 187 # Spinlocks
 188 #
 189 PGAC_ARG_BOOL(enable, spinlocks, yes,
 190               [  --disable-spinlocks     do not use spinlocks])
 191
 192 #
 193 # --enable-debug adds -g to compiler flags
 194 #
 195 PGAC_ARG_BOOL(enable, debug, no,
 196               [  --enable-debug          build with debugging symbols (-g)])
 197 AC_SUBST(enable_debug)
 198
 199 #
 200 # --enable-profiling enables gcc profiling
 201 #
 202 PGAC_ARG_BOOL(enable, profiling, no,
 203               [  --enable-profiling      build with profiling enabled ])
 204 AC_SUBST(enable_profiling)
 205
 206 #
 207 # DTrace
 208 #
 209 PGAC_ARG_BOOL(enable, dtrace, no,
 210               [  --enable-dtrace         build with DTrace support],
 211 [AC_DEFINE([ENABLE_DTRACE], 1,
 212            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 213 AC_CHECK_PROGS(DTRACE, dtrace)
 214 if test -z "$DTRACE"; then
 215   AC_MSG_ERROR([dtrace not found])
 216 fi
 217 AC_SUBST(DTRACEFLAGS)])
 218 AC_SUBST(enable_dtrace)
 219
 220 #
 221 # Block size
 222 #
 223 AC_MSG_CHECKING([for block size])
 224 PGAC_ARG_REQ(with, blocksize, [  --with-blocksize=BLOCKSIZE  set table block size in kB [[8]]],
 225              [blocksize=$withval],
 226              [blocksize=8])
 227 case ${blocksize} in
 228   1) BLCKSZ=1024;;
 229   2) BLCKSZ=2048;;
 230   4) BLCKSZ=4096;;
 231   8) BLCKSZ=8192;;
 232  16) BLCKSZ=16384;;
 233  32) BLCKSZ=32768;;
 234   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 235 esac
 236 AC_MSG_RESULT([${blocksize}kB])
 237
 238 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 239  Size of a disk block --- this also limits the size of a tuple.  You
 240  can set it bigger if you need bigger tuples (although TOAST should
 241  reduce the need to have large tuples, since fields can be spread
 242  across multiple tuples).
 243
 244  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 245  is currently 2^15 (32768).  This is determined by the 15-bit widths
 246  of the lp_off and lp_len fields in ItemIdData (see
 247  include/storage/itemid.h).
 248
 249  Changing BLCKSZ requires an initdb.
 250 ])
 251
 252 #
 253 # Relation segment size
 254 #
 255 AC_MSG_CHECKING([for segment size])
 256 PGAC_ARG_REQ(with, segsize, [  --with-segsize=SEGSIZE  set table segment size in GB [[1]]],
 257              [segsize=$withval],
 258              [segsize=1])
 259 # this expression is set up to avoid unnecessary integer overflow
 260 # blocksize is already guaranteed to be a factor of 1024
 261 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 262 test $? -eq 0 || exit 1
 263 AC_MSG_RESULT([${segsize}GB])
 264
 265 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 266  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 267  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 268  relations bigger than that are divided into multiple files.
 269
 270  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 271  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 272  have large file support enabled.  By default, we make the limit 1 GB
 273  to avoid any possible integer-overflow problems within the OS.
 274  A limit smaller than necessary only means we divide a large
 275  relation into more chunks than necessary, so it seems best to err
 276  in the direction of a small limit.
 277
 278  A power-of-2 value is recommended to save a few cycles in md.c,
 279  but is not absolutely required.
 280
 281  Changing RELSEG_SIZE requires an initdb.
 282 ])
 283
 284 #
 285 # WAL block size
 286 #
 287 AC_MSG_CHECKING([for WAL block size])
 288 PGAC_ARG_REQ(with, wal-blocksize, [  --with-wal-blocksize=BLOCKSIZE  set WAL block size in kB [[8]]],
 289              [wal_blocksize=$withval],
 290              [wal_blocksize=8])
 291 case ${wal_blocksize} in
 292   1) XLOG_BLCKSZ=1024;;
 293   2) XLOG_BLCKSZ=2048;;
 294   4) XLOG_BLCKSZ=4096;;
 295   8) XLOG_BLCKSZ=8192;;
 296  16) XLOG_BLCKSZ=16384;;
 297  32) XLOG_BLCKSZ=32768;;
 298  64) XLOG_BLCKSZ=65536;;
 299   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 300 esac
 301 AC_MSG_RESULT([${wal_blocksize}kB])
 302
 303 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 304  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 305  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 306  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 307  buffers, else direct I/O may fail.
 308
 309  Changing XLOG_BLCKSZ requires an initdb.
 310 ])
 311
 312 #
 313 # WAL segment size
 314 #
 315 AC_MSG_CHECKING([for WAL segment size])
 316 PGAC_ARG_REQ(with, wal-segsize, [  --with-wal-segsize=SEGSIZE  set WAL segment size in MB [[16]]],
 317              [wal_segsize=$withval],
 318              [wal_segsize=16])
 319 case ${wal_segsize} in
 320   1) ;;
 321   2) ;;
 322   4) ;;
 323   8) ;;
 324  16) ;;
 325  32) ;;
 326  64) ;;
 327   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 328 esac
 329 AC_MSG_RESULT([${wal_segsize}MB])
 330
 331 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 332  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 333  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 334  XLOG_BLCKSZ).
 335
 336  Changing XLOG_SEG_SIZE requires an initdb.
 337 ])
 338
 339 #
 340 # C compiler
 341 #
 342
 343 # For historical reasons you can also use --with-CC to specify the C compiler
 344 # to use, although the standard way to do this is to set the CC environment
 345 # variable.
 346 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 347
 348 case $template in
 349   aix) pgac_cc_list="gcc xlc";;
 350  irix) pgac_cc_list="cc";; # no gcc
 351     *) pgac_cc_list="gcc cc";;
 352 esac
 353
 354 AC_PROG_CC([$pgac_cc_list])
 355
 356 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 357 # but has idiosyncrasies of its own.  We assume icc will define
 358 # __INTEL_COMPILER regardless of CFLAGS.
 359 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 360 choke me
 361 @%:@endif], [ICC=[yes]], [ICC=[no]])
 362
 363 unset CFLAGS
 364
 365 #
 366 # Read the template
 367 #
 368 . "$srcdir/src/template/$template" || exit
 369
 370 # CFLAGS are selected so:
 371 # If the user specifies something in the environment, that is used.
 372 # else:  If the template file set something, that is used.
 373 # else:  If the compiler is GCC, then we use -O2.
 374 # else:  If the compiler is something else, then we use -0.
 375
 376 if test "$ac_env_CFLAGS_set" = set; then
 377   CFLAGS=$ac_env_CFLAGS_value
 378 elif test "${CFLAGS+set}" = set; then
 379   : # (keep what template set)
 380 elif test "$GCC" = yes; then
 381   CFLAGS="-O2"
 382 else
 383   # if the user selected debug mode, don't use -O
 384   if test "$enable_debug" != yes; then
 385     CFLAGS="-O"
 386   fi
 387 fi
 388
 389 # Some versions of GCC support some additional useful warning flags.
 390 # Check whether they are supported, and add them to CFLAGS if so.
 391 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 392
 393 if test "$GCC" = yes -a "$ICC" = no; then
 394   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 395   # These work in some but not all gcc versions
 396   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 397   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 398   # Disable strict-aliasing rules; needed for gcc 3.3+
 399   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 400   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 401   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 402 elif test "$ICC" = yes; then
 403   # Intel's compiler has a bug/misoptimization in checking for
 404   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 405   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 406   # Make sure strict aliasing is off (though this is said to be the default)
 407   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 408 elif test x"${CC}" = x"xlc"; then
 409   # AIX xlc has to have strict aliasing turned off too
 410   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 411 fi
 412
 413 # supply -g if --enable-debug
 414 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 415   CFLAGS="$CFLAGS -g"
 416 fi
 417
 418 # enable profiling if --enable-profiling
 419 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 420   if test "$GCC" = yes; then
 421     AC_DEFINE([PROFILE_PID_DIR], 1,
 422            [Define to 1 to allow profiling output to be saved separately for each process.])
 423     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 424   else
 425     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 426   fi
 427 fi
 428
 429 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 430
 431 # We already have this in Makefile.win32, but configure needs it too
 432 if test "$PORTNAME" = "win32"; then
 433   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 434 fi
 435
 436 # Check if the compiler still works with the template settings
 437 AC_MSG_CHECKING([whether the C compiler still works])
 438 AC_TRY_LINK([], [return 0;],
 439   [AC_MSG_RESULT(yes)],
 440   [AC_MSG_RESULT(no)
 441    AC_MSG_ERROR([cannot proceed])])
 442
 443 # Defend against gcc -ffast-math
 444 if test "$GCC" = yes; then
 445 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 446 choke me
 447 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 448 fi
 449
 450 AC_PROG_CPP
 451 AC_SUBST(GCC)
 452
 453 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
 454 # This is much easier than trying to filter LIBS to the minimum for each
 455 # executable.  (Note that shared libraries won't use this switch, though.)
 456 # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
 457 if test "$PORTNAME" != "darwin"; then
 458   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed])
 459 else
 460   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs])
 461 fi
 462
 463 # Create compiler version string
 464 if test x"$GCC" = x"yes" ; then
 465   cc_string="GCC `${CC} --version | sed q`"
 466 else
 467   cc_string=$CC
 468 fi
 469 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 470                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 471                    [A string containing the version number, platform, and C compiler])
 472
 473
 474 #
 475 # Set up TAS assembly code if needed; the template file has now had its
 476 # chance to request this.
 477 #
 478 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 479
 480 if test "$need_tas" = yes ; then
 481   TAS=tas.o
 482 else
 483   TAS=""
 484 fi
 485 AC_SUBST(TAS)
 486
 487
 488 #
 489 # Automatic dependency tracking
 490 #
 491 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 492               [autodepend=yes])
 493 AC_SUBST(autodepend)
 494
 495
 496 #
 497 # Enable assert checks
 498 #
 499 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 500               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 501                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 502
 503
 504 #
 505 # Include directories
 506 #
 507 ac_save_IFS=$IFS
 508 IFS="${IFS}${PATH_SEPARATOR}"
 509 # SRCH_INC comes from the template file
 510 for dir in $with_includes $SRCH_INC; do
 511   if test -d "$dir"; then
 512     INCLUDES="$INCLUDES -I$dir"
 513   else
 514     AC_MSG_WARN([*** Include directory $dir does not exist.])
 515   fi
 516 done
 517 IFS=$ac_save_IFS
 518 AC_SUBST(INCLUDES)
 519
 520
 521 #
 522 # Library directories
 523 #
 524 ac_save_IFS=$IFS
 525 IFS="${IFS}${PATH_SEPARATOR}"
 526 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 527 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 528   if test -d "$dir"; then
 529     LIBDIRS="$LIBDIRS -L$dir"
 530   else
 531     AC_MSG_WARN([*** Library directory $dir does not exist.])
 532   fi
 533 done
 534 IFS=$ac_save_IFS
 535
 536 #
 537 # Enable thread-safe client libraries
 538 #
 539 AC_MSG_CHECKING([allow thread-safe client libraries])
 540 if test "$PORTNAME" != "win32"; then
 541 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 542 else
 543 # Win32 should always use threads
 544 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 545 fi
 546
 547 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
 548 if test "$enable_thread_safety" = yes -o \
 549         "$enable_thread_safety_force" = yes; then
 550   enable_thread_safety="yes"    # for 'force'
 551   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 552           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 553 fi
 554 AC_MSG_RESULT([$enable_thread_safety])
 555 AC_SUBST(enable_thread_safety)
 556
 557 #
 558 # Optionally build Tcl modules (PL/Tcl)
 559 #
 560 AC_MSG_CHECKING([whether to build with Tcl])
 561 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 562 AC_MSG_RESULT([$with_tcl])
 563 AC_SUBST([with_tcl])
 564
 565 # We see if the path to the Tcl/Tk configuration scripts is specified.
 566 # This will override the use of tclsh to find the paths to search.
 567
 568 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 569
 570 #
 571 # Optionally build Perl modules (PL/Perl)
 572 #
 573 AC_MSG_CHECKING([whether to build Perl modules])
 574 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 575 AC_MSG_RESULT([$with_perl])
 576 AC_SUBST(with_perl)
 577
 578 #
 579 # Optionally build Python modules (PL/Python)
 580 #
 581 AC_MSG_CHECKING([whether to build Python modules])
 582 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 583 AC_MSG_RESULT([$with_python])
 584 AC_SUBST(with_python)
 585
 586 #
 587 # GSSAPI
 588 #
 589 AC_MSG_CHECKING([whether to build with GSSAPI support])
 590 PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
 591 [
 592   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 593   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 594 ])
 595 AC_MSG_RESULT([$with_gssapi])
 596 AC_SUBST(with_gssapi)
 597
 598 #
 599 # Kerberos 5
 600 #
 601 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 602 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 603 [
 604   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 605   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 606 ])
 607 AC_MSG_RESULT([$with_krb5])
 608 AC_SUBST(with_krb5)
 609
 610
 611 AC_SUBST(krb_srvtab)
 612
 613
 614 #
 615 # Kerberos configuration parameters
 616 #
 617 PGAC_ARG_REQ(with, krb-srvnam,
 618              [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
 619              [],
 620              [with_krb_srvnam="postgres"])
 621 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 622                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 623
 624
 625 #
 626 # PAM
 627 #
 628 AC_MSG_CHECKING([whether to build with PAM support])
 629 PGAC_ARG_BOOL(with, pam, no,
 630               [  --with-pam              build with PAM support],
 631               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 632 AC_MSG_RESULT([$with_pam])
 633 AC_SUBST(with_pam)
 634
 635
 636 #
 637 # LDAP
 638 #
 639 AC_MSG_CHECKING([whether to build with LDAP support])
 640 PGAC_ARG_BOOL(with, ldap, no,
 641               [  --with-ldap             build with LDAP support],
 642               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 643 AC_MSG_RESULT([$with_ldap])
 644 AC_SUBST(with_ldap)
 645
 646
 647 #
 648 # Bonjour
 649 #
 650 AC_MSG_CHECKING([whether to build with Bonjour support])
 651 PGAC_ARG_BOOL(with, bonjour, no,
 652               [  --with-bonjour          build with Bonjour support],
 653               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 654 AC_MSG_RESULT([$with_bonjour])
 655 AC_SUBST(with_bonjour)
 656
 657
 658 #
 659 # OpenSSL
 660 #
 661 AC_MSG_CHECKING([whether to build with OpenSSL support])
 662 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 663               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 664 AC_MSG_RESULT([$with_openssl])
 665 AC_SUBST(with_openssl)
 666
 667
 668 #
 669 # Readline
 670 #
 671 PGAC_ARG_BOOL(with, readline, yes,
 672               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 673 # readline on MinGW has problems with backslashes in psql and other bugs.
 674 # This is particularly a problem with non-US code pages.
 675 # Therefore disable its use until we understand the cause. 2004-07-20
 676 if test "$PORTNAME" = "win32"; then
 677   if test "$with_readline" = yes; then
 678     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 679     with_readline=no
 680   fi
 681 fi
 682
 683
 684 #
 685 # Prefer libedit
 686 #
 687 PGAC_ARG_BOOL(with, libedit-preferred, no,
 688               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 689
 690
 691 #
 692 # OSSP UUID library
 693 #
 694 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        use OSSP UUID library when building contrib/uuid-ossp])
 695 AC_SUBST(with_ossp_uuid)
 696
 697
 698 #
 699 # XML
 700 #
 701 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 702               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 703
 704 if test "$with_libxml" = yes ; then
 705   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 706   if test -n "$XML2_CONFIG"; then
 707     for pgac_option in `$XML2_CONFIG --cflags`; do
 708       case $pgac_option in
 709         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 710       esac
 711     done
 712     for pgac_option in `$XML2_CONFIG --libs`; do
 713       case $pgac_option in
 714         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 715       esac
 716     done
 717   fi
 718 fi
 719
 720 AC_SUBST(with_libxml)
 721
 722 #
 723 # XSLT
 724 #
 725 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          use XSLT support when building contrib/xml2],
 726               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 727
 728
 729 AC_SUBST(with_libxslt)
 730
 731 #
 732 # tzdata
 733 #
 734 PGAC_ARG_REQ(with, system-tzdata,
 735              [  --with-system-tzdata=DIR  use system time zone data in DIR])
 736 AC_SUBST(with_system_tzdata)
 737
 738 #
 739 # Zlib
 740 #
 741 PGAC_ARG_BOOL(with, zlib, yes,
 742               [  --without-zlib          do not use Zlib])
 743 AC_SUBST(with_zlib)
 744
 745 #
 746 # Elf
 747 #
 748
 749 # Assume system is ELF if it predefines __ELF__ as 1,
 750 # otherwise believe host_os based default.
 751 case $host_os in
 752     freebsd1*|freebsd2*) elf=no;;
 753     freebsd3*|freebsd4*) elf=yes;;
 754 esac
 755
 756 AC_EGREP_CPP(yes,
 757 [#if __ELF__
 758   yes
 759 #endif
 760 ],
 761 [ELF_SYS=true],
 762 [if test "X$elf" = "Xyes" ; then
 763   ELF_SYS=true
 764 else
 765   ELF_SYS=
 766 fi])
 767 AC_SUBST(ELF_SYS)
 768
 769 #
 770 # Assignments
 771 #
 772
 773 CPPFLAGS="$CPPFLAGS $INCLUDES"
 774 LDFLAGS="$LDFLAGS $LIBDIRS"
 775
 776 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 777 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 778
 779 AC_ARG_VAR(LDFLAGS_SL)
 780
 781 PGAC_PROG_LD
 782 AC_SUBST(LD)
 783 AC_SUBST(with_gnu_ld)
 784 case $host_os in sysv5*)
 785   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 786   [
 787     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 788     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 789     LDFLAGS=$pgac_save_LDFLAGS
 790   ])
 791   ld_R_works=$pgac_cv_prog_ld_R
 792   AC_SUBST(ld_R_works)
 793 esac
 794 AC_PROG_RANLIB
 795 PGAC_CHECK_STRIP
 796
 797 AC_PATH_PROG(TAR, tar)
 798 AC_PROG_LN_S
 799 AC_PROG_AWK
 800
 801 PGAC_PATH_YACC
 802 PGAC_PATH_FLEX
 803
 804 PGAC_PATH_PERL
 805 if test "$with_perl" = yes; then
 806   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 807   PGAC_CHECK_PERL_EMBED_LDFLAGS
 808 fi
 809
 810 if test "$with_python" = yes; then
 811   PGAC_PATH_PYTHON
 812   PGAC_CHECK_PYTHON_EMBED_SETUP
 813 fi
 814
 815 # Supply a numeric version string for use by 3rd party add-ons
 816 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 817 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 818 tr '.' '        ' |
 819 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 820 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 821
 822 ##
 823 ## Libraries
 824 ##
 825 ## Most libraries are included only if they demonstrably provide a function
 826 ## we need, but libm is an exception: always include it, because there are
 827 ## too many compilers that play cute optimization games that will break
 828 ## probes for standard functions such as pow().
 829 ##
 830
 831 AC_CHECK_LIB(m, main)
 832 AC_SEARCH_LIBS(setproctitle, util)
 833 AC_SEARCH_LIBS(dlopen, dl)
 834 AC_SEARCH_LIBS(socket, [socket wsock32])
 835 AC_SEARCH_LIBS(shl_load, dld)
 836 # We only use libld in port/dynloader/aix.c
 837 case $host_os in
 838      aix*)
 839         AC_SEARCH_LIBS(ldopen, ld)
 840         ;;
 841 esac
 842 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 843 AC_SEARCH_LIBS(crypt, crypt)
 844 # Solaris:
 845 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 846 # Cygwin:
 847 AC_SEARCH_LIBS(shmget, cygipc)
 848
 849 if test "$with_readline" = yes; then
 850   PGAC_CHECK_READLINE
 851   if test x"$pgac_cv_check_readline" = x"no"; then
 852     AC_MSG_ERROR([readline library not found
 853 If you have readline already installed, see config.log for details on the
 854 failure.  It is possible the compiler isn't looking in the proper directory.
 855 Use --without-readline to disable readline support.])
 856   fi
 857 fi
 858
 859 if test "$with_zlib" = yes; then
 860   AC_CHECK_LIB(z, inflate, [],
 861                [AC_MSG_ERROR([zlib library not found
 862 If you have zlib already installed, see config.log for details on the
 863 failure.  It is possible the compiler isn't looking in the proper directory.
 864 Use --without-zlib to disable zlib support.])])
 865 fi
 866
 867 if test "$enable_spinlocks" = yes; then
 868   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 869 else
 870   AC_MSG_WARN([
 871 *** Not using spinlocks will cause poor performance.])
 872 fi
 873
 874 if test "$with_gssapi" = yes ; then
 875   if test "$PORTNAME" != "win32"; then
 876     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 877                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 878   else
 879     LIBS="$LIBS -lgssapi32"
 880   fi
 881 fi
 882
 883 if test "$with_krb5" = yes ; then
 884   if test "$PORTNAME" != "win32"; then
 885      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 886                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 887      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 888                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 889   else
 890      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 891                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 892   fi
 893 fi
 894
 895 if test "$with_openssl" = yes ; then
 896   dnl Order matters!
 897   if test "$PORTNAME" != "win32"; then
 898      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 899      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 900   else
 901      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 902      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 903   fi
 904 fi
 905
 906 if test "$with_pam" = yes ; then
 907   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 908 fi
 909
 910 if test "$with_libxml" = yes ; then
 911   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 912 fi
 913
 914 if test "$with_libxslt" = yes ; then
 915   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 916 fi
 917
 918 # for contrib/uuid-ossp
 919 if test "$with_ossp_uuid" = yes ; then
 920   AC_CHECK_LIB(ossp-uuid, uuid_export,
 921     [OSSP_UUID_LIBS="-lossp-uuid"],
 922     [AC_CHECK_LIB(uuid, uuid_export,
 923       [OSSP_UUID_LIBS="-luuid"],
 924       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 925 fi
 926 AC_SUBST(OSSP_UUID_LIBS)
 927
 928
 929 ##
 930 ## Header files
 931 ##
 932
 933 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 934 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 935
 936 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 937 # netinet/in.h is included first.
 938 AC_CHECK_HEADERS(netinet/in.h)
 939 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 940 [AC_INCLUDES_DEFAULT
 941 #ifdef HAVE_NETINET_IN_H
 942 #include <netinet/in.h>
 943 #endif
 944 ])
 945
 946 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 947   AC_CHECK_HEADERS(readline/readline.h, [],
 948         [AC_CHECK_HEADERS(readline.h, [],
 949                 [AC_MSG_ERROR([readline header not found
 950 If you have readline already installed, see config.log for details on the
 951 failure.  It is possible the compiler isn't looking in the proper directory.
 952 Use --without-readline to disable readline support.])])])
 953   AC_CHECK_HEADERS(readline/history.h, [],
 954         [AC_CHECK_HEADERS(history.h, [],
 955                 [AC_MSG_ERROR([history header not found
 956 If you have readline already installed, see config.log for details on the
 957 failure.  It is possible the compiler isn't looking in the proper directory.
 958 Use --without-readline to disable readline support.])])])
 959 fi
 960
 961 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 962 # Some installations of libedit usurp /usr/include/readline/, which seems
 963 # bad practice, since in combined installations readline will have its headers
 964 # there.  We might have to resort to AC_EGREP checks to make sure we found
 965 # the proper header...
 966   AC_CHECK_HEADERS(editline/readline.h, [],
 967         [AC_CHECK_HEADERS(readline.h, [],
 968                 [AC_CHECK_HEADERS(readline/readline.h, [],
 969                         [AC_MSG_ERROR([readline header not found
 970 If you have libedit already installed, see config.log for details on the
 971 failure.  It is possible the compiler isn't looking in the proper directory.
 972 Use --without-readline to disable libedit support.])])])])
 973 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 974 # not be there at all.  Hence, don't complain if not found.  We must check
 975 # though, since in yet other versions it is an independent header.
 976   AC_CHECK_HEADERS(editline/history.h, [],
 977         [AC_CHECK_HEADERS(history.h, [],
 978                 [AC_CHECK_HEADERS(readline/history.h)])])
 979 fi
 980
 981 if test "$with_zlib" = yes; then
 982   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 983 If you have zlib already installed, see config.log for details on the
 984 failure.  It is possible the compiler isn't looking in the proper directory.
 985 Use --without-zlib to disable zlib support.])])
 986 fi
 987
 988 if test "$with_gssapi" = yes ; then
 989   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
 990         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
 991 fi
 992
 993 if test "$with_krb5" = yes ; then
 994   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 995 fi
 996
 997 if test "$with_openssl" = yes ; then
 998   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 999   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1000   AC_CHECK_FUNCS([ERR_set_mark])
1001 fi
1002
1003 if test "$with_pam" = yes ; then
1004   AC_CHECK_HEADERS(security/pam_appl.h, [],
1005                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1006                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1007 fi
1008
1009 if test "$with_libxml" = yes ; then
1010   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1011 fi
1012
1013 if test "$with_libxslt" = yes ; then
1014   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1015 fi
1016
1017 if test "$with_ldap" = yes ; then
1018   if test "$PORTNAME" != "win32"; then
1019      AC_CHECK_HEADERS(ldap.h, [],
1020                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1021   else
1022      AC_CHECK_HEADERS(winldap.h, [],
1023                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1024                       [AC_INCLUDES_DEFAULT
1025 #include <windows.h>
1026                       ])
1027   fi
1028 fi
1029
1030 if test "$with_bonjour" = yes ; then
1031   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1032 fi
1033
1034 # for contrib/uuid-ossp
1035 if test "$with_ossp_uuid" = yes ; then
1036   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1037     AC_CHECK_HEADERS(uuid.h, [],
1038       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1039 fi
1040
1041
1042 ##
1043 ## Types, structures, compiler characteristics
1044 ##
1045
1046 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1047 AC_C_BIGENDIAN
1048 AC_C_CONST
1049 AC_C_INLINE
1050 AC_C_STRINGIZE
1051 PGAC_C_SIGNED
1052 AC_C_VOLATILE
1053 PGAC_C_FUNCNAME_SUPPORT
1054 PGAC_STRUCT_TIMEZONE
1055 PGAC_UNION_SEMUN
1056 PGAC_STRUCT_SOCKADDR_UN
1057 PGAC_STRUCT_SOCKADDR_STORAGE
1058 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1059 PGAC_STRUCT_ADDRINFO
1060
1061 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1062 [#include <sys/param.h>
1063 #include <sys/types.h>
1064 #include <sys/socket.h>
1065 #include <sys/ucred.h>])
1066
1067 AC_CHECK_TYPES([struct option], [], [],
1068 [#ifdef HAVE_GETOPT_H
1069 #include <getopt.h>
1070 #endif])
1071
1072 if test "$with_zlib" = yes; then
1073   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1074   # did not).  While we could work around the lack of z_streamp, it
1075   # seems unwise to encourage people to use such old zlib versions...
1076   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1077 Use --without-zlib to disable zlib support.])],
1078                 [#include <zlib.h>])
1079 fi
1080
1081 if test "$with_krb5" = yes; then
1082 # Check for differences between MIT and Heimdal (KTH) releases
1083   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1084                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1085                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1086                                      [#include <krb5.h>])],
1087                    [#include <krb5.h>])
1088   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1089                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1090                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1091                                      [#include <krb5.h>])],
1092                    [#include <krb5.h>])
1093
1094 # Win32 requires headers to be loaded for __stdcall, so can't use
1095 # AC_CHECK_FUNCS here.
1096   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1097   AC_TRY_LINK([#include <krb5.h>],
1098               [krb5_free_unparsed_name(NULL,NULL);],
1099               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1100 AC_MSG_RESULT(yes)],
1101               [AC_MSG_RESULT(no)])
1102 fi
1103
1104
1105 ##
1106 ## Functions, global variables
1107 ##
1108
1109 PGAC_VAR_INT_TIMEZONE
1110 AC_FUNC_ACCEPT_ARGTYPES
1111 PGAC_FUNC_GETTIMEOFDAY_1ARG
1112
1113 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1114
1115 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1116 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1117 AC_CHECK_DECLS([strlcat, strlcpy])
1118 # This is probably only present on Darwin, but may as well check always
1119 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1120
1121 HAVE_IPV6=no
1122 AC_CHECK_TYPE([struct sockaddr_in6],
1123         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1124          HAVE_IPV6=yes],
1125         [],
1126 [$ac_includes_default
1127 #include <netinet/in.h>])
1128 AC_SUBST(HAVE_IPV6)
1129
1130 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1131 [AC_TRY_LINK(
1132 [#include <machine/vmparam.h>
1133 #include <sys/exec.h>
1134 ],
1135 [PS_STRINGS->ps_nargvstr = 1;
1136 PS_STRINGS->ps_argvstr = "foo";],
1137 [pgac_cv_var_PS_STRINGS=yes],
1138 [pgac_cv_var_PS_STRINGS=no])])
1139 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1140   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1141 fi
1142
1143
1144 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1145 # is missing.  Yes, there are machines that have only one.  We may
1146 # also decide to use snprintf.c if snprintf() is present but does not
1147 # have all the features we need --- see below.
1148
1149 if test "$PORTNAME" = "win32"; then
1150   # Win32 gets snprintf.c built unconditionally.
1151   #
1152   # To properly translate all NLS languages strings, we must support the
1153   # *printf() %$ format, which allows *printf() arguments to be selected
1154   # by position in the translated string.
1155   #
1156   # libintl versions < 0.13 use the native *printf() functions, and Win32
1157   # *printf() doesn't understand %$, so we must use our /port versions,
1158   # which do understand %$. libintl versions >= 0.13 include their own
1159   # *printf versions on Win32.  The libintl 0.13 release note text is:
1160   #
1161   #   C format strings with positions, as they arise when a translator
1162   #   needs to reorder a sentence, are now supported on all platforms.
1163   #   On those few platforms (NetBSD and Woe32) for which the native
1164   #   printf()/fprintf()/... functions don't support such format
1165   #   strings, replacements are provided through <libintl.h>.
1166   #
1167   # We could use libintl >= 0.13's *printf() if we were sure that we had
1168   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1169   # to guarantee that, it is best to just use our own, so we are sure to
1170   # get %$ support. In include/port.h we disable the *printf() macros
1171   # that might have been defined by libintl.
1172   #
1173   # We do this unconditionally whether NLS is used or not so we are sure
1174   # that all Win32 libraries and binaries behave the same.
1175   pgac_need_repl_snprintf=yes
1176 else
1177   pgac_need_repl_snprintf=no
1178   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1179   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1180 fi
1181
1182
1183 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1184 # include/c.h will provide declarations.  Note this is a separate test
1185 # from whether the functions exist in the C library --- there are
1186 # systems that have the functions but don't bother to declare them :-(
1187
1188 AC_CHECK_DECLS([snprintf, vsnprintf])
1189
1190
1191 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1192 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1193 [AC_TRY_LINK([
1194 #include <math.h>
1195 double glob_double;
1196 ],
1197 [return isinf(glob_double) ? 0 : 1;],
1198 [ac_cv_func_isinf=yes],
1199 [ac_cv_func_isinf=no])])
1200
1201 if test $ac_cv_func_isinf = yes ; then
1202   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1203 else
1204   AC_LIBOBJ(isinf)
1205   # Look for a way to implement a substitute for isinf()
1206   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1207 fi
1208
1209 # Some versions of libedit contain strlcpy(); so disregard that library while
1210 # checking for these standard libc functions.
1211 pgac_save_LIBS="$LIBS"
1212 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1213
1214 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1215
1216 LIBS="$pgac_save_LIBS"
1217
1218 # System's version of getaddrinfo(), if any, may be used only if we found
1219 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1220 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1221 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1222 # because we want to use our own getaddrinfo.c on Windows anyway.)
1223 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1224   AC_REPLACE_FUNCS([getaddrinfo])
1225 else
1226   AC_LIBOBJ(getaddrinfo)
1227 fi
1228
1229 # Similarly, use system's getopt_long() only if system provides struct option.
1230 # Solaris' getopt() doesn't do what we want for long options, so always use
1231 # our versions on that platform.
1232 if test "$PORTNAME" = "solaris"; then
1233   AC_LIBOBJ(getopt)
1234   AC_LIBOBJ(getopt_long)
1235 elif test x"$ac_cv_type_struct_option" = xyes ; then
1236   AC_REPLACE_FUNCS([getopt_long])
1237 else
1238   AC_LIBOBJ(getopt_long)
1239 fi
1240
1241 # Win32 support
1242 if test "$PORTNAME" = "win32"; then
1243 AC_REPLACE_FUNCS(gettimeofday)
1244 AC_LIBOBJ(kill)
1245 AC_LIBOBJ(open)
1246 AC_LIBOBJ(rand)
1247 AC_LIBOBJ(win32error)
1248 AC_DEFINE([HAVE_SYMLINK], 1,
1249           [Define to 1 if you have the `symlink' function.])
1250 fi
1251
1252 if test "$with_readline" = yes; then
1253   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1254   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1255   AC_CHECK_FUNCS([replace_history_entry])
1256 fi
1257
1258
1259 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1260 dnl (especially on GNU libc)
1261 dnl See also comments in c.h.
1262 AC_MSG_CHECKING(for sigsetjmp)
1263 AC_TRY_LINK([#include <setjmp.h>],
1264             [sigjmp_buf x; sigsetjmp(x, 1);],
1265             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1266 AC_MSG_RESULT(yes)],
1267             [AC_MSG_RESULT(no)])
1268
1269 AC_DECL_SYS_SIGLIST
1270
1271 AC_CHECK_FUNC(syslog,
1272               [AC_CHECK_HEADER(syslog.h,
1273                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1274
1275 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1276 [AC_TRY_LINK([#include <unistd.h>],
1277   [extern int optreset; optreset = 1;],
1278   [pgac_cv_var_int_optreset=yes],
1279   [pgac_cv_var_int_optreset=no])])
1280 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1281   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1282 fi
1283
1284 AC_CHECK_FUNCS([strtoll strtoq], [break])
1285 AC_CHECK_FUNCS([strtoull strtouq], [break])
1286
1287 # Check for one of atexit() or on_exit()
1288 AC_CHECK_FUNCS(atexit, [],
1289                [AC_CHECK_FUNCS(on_exit, [],
1290                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1291
1292 AC_REPLACE_FUNCS(fseeko)
1293 case $host_os in
1294         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1295         bsdi*|netbsd*)
1296                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1297                 ac_cv_func_fseeko=yes;;
1298         *)
1299                 AC_FUNC_FSEEKO;;
1300 esac
1301
1302
1303 #
1304 # Pthreads
1305 #
1306 # For each platform, we need to know about any special compile and link
1307 # libraries, and whether the normal C function names are thread-safe.
1308 # See the comment at the top of src/port/thread.c for more information.
1309 # WIN32 doesn't need the pthread tests;  it always uses threads
1310 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1311 ACX_PTHREAD     # set thread flags
1312
1313 # Some platforms use these, so just defineed them.  They can't hurt if they
1314 # are not supported.
1315 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1316
1317
1318 # At this point, we don't want to muck with the compiler name for threading.
1319 # Let's see who fails, perhaps AIX.  2004-04-23
1320 if test "$PTHREAD_CC" != "$CC"; then
1321 AC_MSG_ERROR([
1322 PostgreSQL does not support platforms that require a special compiler
1323 for thread safety.])
1324 fi
1325
1326 if test "$THREAD_SUPPORT" = no; then
1327 AC_MSG_ERROR([cannot enable threads on this platform
1328 This platform is known to not support thread-safe programs.  For details,
1329 compile and run src/bin/pg_thread_test.])
1330 fi
1331
1332 # Check for *_r functions
1333 _CFLAGS="$CFLAGS"
1334 _LIBS="$LIBS"
1335 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1336 LIBS="$LIBS $PTHREAD_LIBS"
1337
1338 if test "$PORTNAME" != "win32"; then
1339 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1340 fi
1341
1342 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1343
1344 # Do test here with the proper thread flags
1345 PGAC_FUNC_GETPWUID_R_5ARG
1346 PGAC_FUNC_STRERROR_R_INT
1347
1348 CFLAGS="$_CFLAGS"
1349 LIBS="$_LIBS"
1350
1351 else
1352 # do not use values from template file
1353 PTHREAD_CFLAGS=
1354 PTHREAD_LIBS=
1355 fi
1356
1357 AC_SUBST(PTHREAD_CFLAGS)
1358 AC_SUBST(PTHREAD_LIBS)
1359
1360
1361 # We can test for libldap_r only after we know PTHREAD_LIBS
1362 if test "$with_ldap" = yes ; then
1363   _LIBS="$LIBS"
1364   if test "$PORTNAME" != "win32"; then
1365     AC_CHECK_LIB(ldap, ldap_bind, [],
1366                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1367                  [$EXTRA_LDAP_LIBS])
1368     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1369     if test "$enable_thread_safety" = yes; then
1370       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1371       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1372                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1373                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1374       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1375     else
1376       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1377     fi
1378   else
1379     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1380     LDAP_LIBS_FE="-lwldap32"
1381     LDAP_LIBS_BE="-lwldap32"
1382   fi
1383   LIBS="$_LIBS"
1384 fi
1385 AC_SUBST(LDAP_LIBS_FE)
1386 AC_SUBST(LDAP_LIBS_BE)
1387
1388
1389 # This test makes sure that run tests work at all.  Sometimes a shared
1390 # library is found by the linker, but the runtime linker can't find it.
1391 # This check should come after all modifications of compiler or linker
1392 # variables, and before any other run tests.
1393 AC_MSG_CHECKING([test program])
1394 AC_TRY_RUN([int main() { return 0; }],
1395 [AC_MSG_RESULT(ok)],
1396 [AC_MSG_RESULT(failed)
1397 AC_MSG_ERROR([[
1398 Could not execute a simple test program.  This may be a problem
1399 related to locating shared libraries.  Check the file 'config.log'
1400 for the exact reason.]])],
1401 [AC_MSG_RESULT([cross-compiling])])
1402
1403 # --------------------
1404 # Run tests below here
1405 # --------------------
1406
1407 # Force use of our snprintf if system's doesn't do arg control
1408 # See comment above at snprintf test for details.
1409 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1410   PGAC_FUNC_PRINTF_ARG_CONTROL
1411   if test $pgac_cv_printf_arg_control != yes ; then
1412     pgac_need_repl_snprintf=yes
1413   fi
1414 fi
1415
1416
1417 dnl Check to see if we have a working 64-bit integer type.
1418 dnl This breaks down into two steps:
1419 dnl (1) figure out if the compiler has a 64-bit int type with working
1420 dnl arithmetic, and if so
1421 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1422 dnl snprintf is the only library routine we really need for int8 support.)
1423 dnl It's entirely possible to have a compiler that handles a 64-bit type
1424 dnl when the C library doesn't; this is fairly likely when using gcc on
1425 dnl an older platform, for example.
1426 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1427 dnl we force our own version of snprintf() to be used instead.
1428 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1429
1430 PGAC_TYPE_64BIT_INT([long int])
1431
1432 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1433   PGAC_TYPE_64BIT_INT([long long int])
1434 fi
1435
1436
1437 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1438
1439 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1440   AC_TRY_COMPILE([
1441 #define INT64CONST(x)  x##LL
1442 long long int foo = INT64CONST(0x1234567890123456);
1443 ],
1444         [],
1445         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1446         [])
1447 fi
1448
1449
1450 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1451 # we found we need to use "long long int", better check.  We cope with
1452 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1453 # work, fall back to our own snprintf emulation (which we know uses %lld).
1454
1455 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1456   if test $pgac_need_repl_snprintf = no; then
1457     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1458     if test "$LONG_LONG_INT_FORMAT" = ""; then
1459       # Force usage of our own snprintf, since system snprintf is broken
1460       pgac_need_repl_snprintf=yes
1461       LONG_LONG_INT_FORMAT='%lld'
1462     fi
1463   else
1464     # Here if we previously decided we needed to use our own snprintf
1465     LONG_LONG_INT_FORMAT='%lld'
1466   fi
1467   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1468   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1469   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1470 else
1471   # Here if we are not using 'long long int' at all
1472   INT64_FORMAT='"%ld"'
1473   UINT64_FORMAT='"%lu"'
1474 fi
1475
1476 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1477                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1478
1479 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1480                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1481
1482 # Now we have checked all the reasons to replace snprintf
1483 if test $pgac_need_repl_snprintf = yes; then
1484   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1485   AC_LIBOBJ(snprintf)
1486 fi
1487
1488 # Need a #define for the size of Datum (unsigned long)
1489 AC_CHECK_SIZEOF([unsigned long])
1490
1491 # And one for the size of size_t (enables tweaks for > 32bit address space)
1492 AC_CHECK_SIZEOF([size_t])
1493
1494 # Decide whether float4 is passed by value: user-selectable, enabled by default
1495 AC_MSG_CHECKING([whether to build with float4 passed by value])
1496 PGAC_ARG_BOOL(enable, float4-byval, yes, [  --disable-float4-byval  disable float4 passed by value],
1497               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1498                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1499                float4passbyval=true],
1500               [float4passbyval=false])
1501 AC_MSG_RESULT([$enable_float4_byval])
1502 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1503
1504 # Decide whether float8 is passed by value.
1505 # Note: this setting also controls int8 and related types such as timestamp.
1506 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1507 # If not, trying to select it is an error.
1508 AC_MSG_CHECKING([whether to build with float8 passed by value])
1509 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1510   PGAC_ARG_BOOL(enable, float8-byval, yes, [  --disable-float8-byval  disable float8 passed by value])
1511 else
1512   PGAC_ARG_BOOL(enable, float8-byval, no, [  --disable-float8-byval  disable float8 passed by value])
1513   if test "$enable_float8_byval" = yes ; then
1514     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1515   fi
1516 fi
1517 if test "$enable_float8_byval" = yes ; then
1518   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1519             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1520   float8passbyval=true
1521 else
1522   float8passbyval=false
1523 fi
1524 AC_MSG_RESULT([$enable_float8_byval])
1525 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1526
1527 # Determine memory alignment requirements for the basic C data types.
1528
1529 AC_CHECK_ALIGNOF(short)
1530 AC_CHECK_ALIGNOF(int)
1531 AC_CHECK_ALIGNOF(long)
1532 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1533   AC_CHECK_ALIGNOF(long long int)
1534 fi
1535 AC_CHECK_ALIGNOF(double)
1536
1537 # Compute maximum alignment of any basic type.
1538 # We assume long's alignment is at least as strong as char, short, or int;
1539 # but we must check long long (if it exists) and double.
1540
1541 MAX_ALIGNOF=$ac_cv_alignof_long
1542 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1543   MAX_ALIGNOF=$ac_cv_alignof_double
1544 fi
1545 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1546   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1547 fi
1548 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1549
1550
1551 # Some platforms predefine the types int8, int16, etc.  Only check
1552 # a (hopefully) representative subset.
1553 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1554 [#include <stdio.h>
1555 #ifdef HAVE_SUPPORTDEFS_H
1556 #include <SupportDefs.h>
1557 #endif])
1558
1559 # We also check for sig_atomic_t, which *should* be defined per ANSI
1560 # C, but is missing on some old platforms.
1561 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1562
1563
1564 # If the user did not disable integer datetimes, check that
1565 # there is a working 64-bit integral type to use.
1566 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1567    test x"$HAVE_LONG_INT_64" = x"no" &&
1568    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1569    test x"$HAVE_INT64" = x"no" ; then
1570   AC_MSG_ERROR([
1571 Integer-based datetime support requires a 64-bit integer type,
1572 but no such type could be found. The --disable-integer-datetimes
1573 configure option can be used to disable integer-based storage
1574 of datetime values.])
1575 fi
1576
1577
1578 if test "$PORTNAME" != "win32"
1579 then
1580 PGAC_FUNC_POSIX_SIGNALS
1581 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1582   AC_MSG_ERROR([
1583 Thread-safety requires POSIX signals, which are not supported by this
1584 operating system.])
1585 fi
1586 fi
1587
1588 if test $ac_cv_func_fseeko = yes; then
1589 AC_SYS_LARGEFILE
1590 fi
1591
1592 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1593 AC_CHECK_SIZEOF([off_t])
1594
1595 # If we don't have largefile support, can't handle segsize >= 2GB.
1596 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1597    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1598 fi
1599
1600 # SunOS doesn't handle negative byte comparisons properly with +/- return
1601 AC_FUNC_MEMCMP
1602
1603
1604 # Select semaphore implementation type.
1605 if test "$PORTNAME" != "win32"; then
1606   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1607     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1608     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1609   else
1610     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1611       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1612       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1613     else
1614       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1615       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1616     fi
1617   fi
1618 else
1619   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1620   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1621 fi
1622
1623
1624 # Select shared-memory implementation type.
1625 if test "$PORTNAME" != "win32"; then
1626   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1627   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1628 else
1629   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1630   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1631 fi
1632
1633 # If not set in template file, set bytes to use libc memset()
1634 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1635   MEMSET_LOOP_LIMIT=1024
1636 fi
1637 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1638
1639
1640 if test "$enable_nls" = yes ; then
1641   PGAC_CHECK_GETTEXT
1642 fi
1643
1644 # Check for Tcl configuration script tclConfig.sh
1645 if test "$with_tcl" = yes; then
1646     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1647     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1648                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1649     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1650     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1651     ac_save_CPPFLAGS=$CPPFLAGS
1652     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1653     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1654     CPPFLAGS=$ac_save_CPPFLAGS
1655 fi
1656
1657 #
1658 # Check for DocBook and tools
1659 #
1660 PGAC_PROG_NSGMLS
1661 PGAC_PROG_JADE
1662 PGAC_CHECK_DOCBOOK(4.2)
1663 PGAC_PATH_DOCBOOK_STYLESHEETS
1664 PGAC_PATH_COLLATEINDEX
1665 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1666
1667 # Thread testing
1668
1669 # We have to run the thread test near the end so we have all our symbols
1670 # defined.  Cross compiling throws a warning.
1671 #
1672 if test "$enable_thread_safety_force" = yes; then
1673 if test "$PORTNAME" != "win32"
1674 then
1675   AC_MSG_WARN([
1676 *** Skipping thread test program.  --enable-thread-safety-force was used.
1677 *** Run the program in src/test/thread on the your machine and add proper
1678 *** locking function calls to your applications to guarantee thread safety.
1679 ])
1680 else
1681 AC_MSG_WARN([*** skipping thread test on Win32])
1682 fi
1683 elif test "$enable_thread_safety" = yes; then
1684 if test "$PORTNAME" != "win32"
1685 then
1686 AC_MSG_CHECKING([thread safety of required library functions])
1687
1688 _CFLAGS="$CFLAGS"
1689 _LIBS="$LIBS"
1690 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1691 LIBS="$LIBS $PTHREAD_LIBS"
1692 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1693   [AC_MSG_RESULT(yes)],
1694   [AC_MSG_RESULT(no)
1695   AC_MSG_ERROR([thread test program failed
1696 This platform is not thread-safe.  Check the file 'config.log'for the
1697 exact reason.
1698
1699 You can use the configure option --enable-thread-safety-force to force
1700 threads to be enabled.  But you must then run the program in
1701 src/test/thread and add locking function calls to your applications to
1702 guarantee thread safety.])],
1703   [AC_MSG_RESULT(maybe)
1704   AC_MSG_WARN([
1705 *** Skipping thread test program because of cross-compile build.
1706 *** Run the program in src/test/thread on the target machine.
1707 ])])
1708 CFLAGS="$_CFLAGS"
1709 LIBS="$_LIBS"
1710 else
1711 AC_MSG_WARN([*** skipping thread test on Win32])
1712 fi
1713 fi
1714
1715 # prepare build tree if outside source tree
1716 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1717 # Note 2: /bin/pwd might be better than shell's built-in at getting
1718 #         a symlink-free name.
1719 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1720   vpath_build=no
1721 else
1722   vpath_build=yes
1723   if test "$no_create" != yes; then
1724     _AS_ECHO_N([preparing build tree... ])
1725     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1726     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1727       || AC_MSG_ERROR(failed)
1728     AC_MSG_RESULT(done)
1729   fi
1730 fi
1731 AC_SUBST(vpath_build)
1732
1733
1734 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1735
1736 AC_CONFIG_LINKS([
1737   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1738   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1739   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1740   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1741   src/include/pg_config_os.h:src/include/port/${template}.h
1742   src/Makefile.port:src/makefiles/Makefile.${template}
1743 ])
1744
1745 if test "$PORTNAME" = "win32"; then
1746 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1747 # Links sometimes fail undetected on Mingw -
1748 # so here we detect it and warn the user
1749 for FILE in $CONFIG_LINKS
1750  do
1751         # test -e works for symlinks in the MinGW console
1752         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1753  done
1754 ])
1755 fi
1756
1757 AC_CONFIG_HEADERS([src/include/pg_config.h],
1758 [
1759 # Update timestamp for pg_config.h (see Makefile.global)
1760 echo >src/include/stamp-h
1761 ])
1762
1763 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1764
1765 AC_OUTPUT
1766
1767 # Warn about unknown options
1768 PGAC_ARG_CHECK