CMakeLua/Modules/FindLibXml2.cmake

   1 # - Try to find LibXml2
   2 # Once done this will define
   3 #
   4 #  LIBXML2_FOUND - system has LibXml2
   5 #  LIBXML2_INCLUDE_DIR - the LibXml2 include directory
   6 #  LIBXML2_LIBRARIES - the libraries needed to use LibXml2
   7 #  LIBXML2_DEFINITIONS - Compiler switches required for using LibXml2
   8
   9 # Copyright (c) 2006, Alexander Neundorf, <neundorf@kde.org>
  10 #
  11 # Redistribution and use is allowed according to the terms of the BSD license.
  12 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
  13
  14
  15 IF (LIBXML2_INCLUDE_DIR AND LIBXML2_LIBRARIES)
  16    # in cache already
  17    SET(LibXml2_FIND_QUIETLY TRUE)
  18 ENDIF (LIBXML2_INCLUDE_DIR AND LIBXML2_LIBRARIES)
  19
  20 IF (NOT WIN32)
  21    # use pkg-config to get the directories and then use these values
  22    # in the FIND_PATH() and FIND_LIBRARY() calls
  23    INCLUDE(UsePkgConfig)
  24    PKGCONFIG(libxml-2.0 _LibXml2IncDir _LibXml2LinkDir _LibXml2LinkFlags _LibXml2Cflags)
  25    SET(LIBXML2_DEFINITIONS ${_LibXml2Cflags})
  26 ENDIF (NOT WIN32)
  27
  28 FIND_PATH(LIBXML2_INCLUDE_DIR libxml/xpath.h
  29    PATHS
  30    ${_LibXml2IncDir}
  31    PATH_SUFFIXES libxml2
  32    )
  33
  34 FIND_LIBRARY(LIBXML2_LIBRARIES NAMES xml2 libxml2
  35    PATHS
  36    ${_LibXml2LinkDir}
  37    )
  38
  39 INCLUDE(FindPackageHandleStandardArgs)
  40
  41 # handle the QUIETLY and REQUIRED arguments and set LIBXML2_FOUND to TRUE if
  42 # all listed variables are TRUE
  43 FIND_PACKAGE_HANDLE_STANDARD_ARGS(LibXml2 DEFAULT_MSG LIBXML2_LIBRARIES LIBXML2_INCLUDE_DIR)
  44
  45 MARK_AS_ADVANCED(LIBXML2_INCLUDE_DIR LIBXML2_LIBRARIES)
  46