CMakeLua/Modules/FindKDE4.cmake

   1 # Find KDE4 and provide all necessary variables and macros to compile software for it.
   2 # It looks for KDE 4 in the following directories in the given order:
   3 #  CMAKE_INSTALL_PREFIX
   4 #  KDEDIRS
   5 #  /opt/kde4
   6 #
   7 # Please look in FindKDE4Internal.cmake and KDE4Macros.cmake for more information.
   8 # They are installed with the KDE 4 libraries in $KDEDIRS/share/apps/cmake/modules/.
   9 #
  10 # Author: Alexander Neundorf <neundorf@kde.org>
  11
  12 FILE(TO_CMAKE_PATH "$ENV{KDEDIRS}" _KDEDIRS)
  13
  14 # For KDE4 kde-config has been renamed to kde4-config
  15 FIND_PROGRAM(KDE4_KDECONFIG_EXECUTABLE NAMES kde4-config
  16    PATH_SUFFIXES bin               # the suffix is for the paths coming from KDEDIRS
  17    PATHS
  18    ${CMAKE_INSTALL_PREFIX}/bin
  19    ${_KDEDIRS}
  20    /opt/kde4/bin
  21    NO_DEFAULT_PATH
  22    )
  23
  24 FIND_PROGRAM(KDE4_KDECONFIG_EXECUTABLE NAMES kde4-config )
  25
  26 IF (KDE4_KDECONFIG_EXECUTABLE)
  27    # then ask kde4-config for the kde data dirs
  28    EXECUTE_PROCESS(COMMAND "${KDE4_KDECONFIG_EXECUTABLE}" --path data OUTPUT_VARIABLE _data_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  29
  30    FILE(TO_CMAKE_PATH "${_data_DIR}" _data_DIR)
  31
  32    # then check the data dirs for FindKDE4Internal.cmake
  33    FIND_PATH(KDE4_DATA_DIR cmake/modules/FindKDE4Internal.cmake ${_data_DIR})
  34
  35    # if it has been found...
  36    IF (KDE4_DATA_DIR)
  37
  38       SET(CMAKE_MODULE_PATH  ${CMAKE_MODULE_PATH} ${KDE4_DATA_DIR}/cmake/modules)
  39
  40       IF (KDE4_FIND_QUIETLY)
  41          SET(_quiet QUIET)
  42       ENDIF (KDE4_FIND_QUIETLY)
  43
  44       IF (KDE4_FIND_REQUIRED)
  45          SET(_req REQUIRED)
  46       ENDIF (KDE4_FIND_REQUIRED)
  47
  48       # use FindKDE4Internal.cmake to do the rest
  49       FIND_PACKAGE(KDE4Internal ${_req} ${_quiet})
  50    ELSE (KDE4_DATA_DIR)
  51       IF (KDE4_FIND_REQUIRED)
  52          MESSAGE(FATAL_ERROR "ERROR: cmake/modules/FindKDE4Internal.cmake not found in ${_data_DIR}")
  53       ENDIF (KDE4_FIND_REQUIRED)
  54    ENDIF (KDE4_DATA_DIR)
  55
  56 ELSE (KDE4_KDECONFIG_EXECUTABLE)
  57    IF (KDE4_FIND_REQUIRED)
  58       MESSAGE(FATAL_ERROR "ERROR: Could not find KDE4 kde4-config")
  59    ENDIF (KDE4_FIND_REQUIRED)
  60 ENDIF (KDE4_KDECONFIG_EXECUTABLE)
  61