CMakeLua/Modules/FindKDE4.cmake

   1 # Find KDE4 and provide all necessary variables and macros to compile software for it.
   2 # It looks for KDE 4 in the following directories in the given order:
   3 #  CMAKE_INSTALL_PREFIX
   4 #  KDEDIRS
   5 #  /opt/kde4
   6 #
   7 # Please look in FindKDE4Internal.cmake and KDE4Macros.cmake for more information.
   8 # They are installed with the KDE 4 libraries in $KDEDIRS/share/apps/cmake/modules/.
   9 #
  10 # Author: Alexander Neundorf <neundorf@kde.org>
  11
  12 FILE(TO_CMAKE_PATH "$ENV{KDEDIRS}" _KDEDIRS)
  13
  14 # when cross compiling, searching kde4-config in order to run it later on
  15 # doesn't make a lot of sense. We'll have to do something about this.
  16 # Searching always in the target environment ? Then we get at least the correct one,
  17 # still it can't be used to run it. Alex
  18
  19 # For KDE4 kde-config has been renamed to kde4-config
  20 FIND_PROGRAM(KDE4_KDECONFIG_EXECUTABLE NAMES kde4-config
  21    # the suffix must be used since KDEDIRS can be a list of directories which don't have bin/ appended
  22    PATH_SUFFIXES bin
  23    PATHS
  24    ${CMAKE_INSTALL_PREFIX}
  25    ${_KDEDIRS}
  26    /opt/kde4
  27    NO_DEFAULT_PATH
  28    ONLY_CMAKE_FIND_ROOT_PATH
  29    )
  30
  31 FIND_PROGRAM(KDE4_KDECONFIG_EXECUTABLE NAMES kde4-config ONLY_CMAKE_FIND_ROOT_PATH)
  32
  33 IF (NOT KDE4_KDECONFIG_EXECUTABLE)
  34    IF (KDE4_FIND_REQUIRED)
  35       MESSAGE(FATAL_ERROR "ERROR: Could not find KDE4 kde4-config")
  36    ENDIF (KDE4_FIND_REQUIRED)
  37 ENDIF (NOT KDE4_KDECONFIG_EXECUTABLE)
  38
  39
  40 # when cross compiling, KDE4_DATA_DIR may be already preset
  41 IF(NOT KDE4_DATA_DIR)
  42    IF(CMAKE_CROSSCOMPILING)
  43       # when cross compiling, don't run kde4-config but use its location as install dir
  44       GET_FILENAME_COMPONENT(KDE4_DATA_DIR "${KDE4_KDECONFIG_EXECUTABLE}" PATH)
  45       GET_FILENAME_COMPONENT(KDE4_DATA_DIR "${KDE4_DATA_DIR}" PATH)
  46    ELSE(CMAKE_CROSSCOMPILING)
  47       # then ask kde4-config for the kde data dirs
  48       EXECUTE_PROCESS(COMMAND "${KDE4_KDECONFIG_EXECUTABLE}" --path data OUTPUT_VARIABLE _data_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  49       FILE(TO_CMAKE_PATH "${_data_DIR}" _data_DIR)
  50       # then check the data dirs for FindKDE4Internal.cmake
  51       FIND_PATH(KDE4_DATA_DIR cmake/modules/FindKDE4Internal.cmake ${_data_DIR})
  52    ENDIF(CMAKE_CROSSCOMPILING)
  53 ENDIF(NOT KDE4_DATA_DIR)
  54
  55 # if it has been found...
  56 IF (KDE4_DATA_DIR)
  57
  58    SET(CMAKE_MODULE_PATH  ${CMAKE_MODULE_PATH} ${KDE4_DATA_DIR}/cmake/modules)
  59
  60    IF (KDE4_FIND_QUIETLY)
  61       SET(_quiet QUIET)
  62    ENDIF (KDE4_FIND_QUIETLY)
  63
  64    IF (KDE4_FIND_REQUIRED)
  65       SET(_req REQUIRED)
  66    ENDIF (KDE4_FIND_REQUIRED)
  67
  68    # use FindKDE4Internal.cmake to do the rest
  69    FIND_PACKAGE(KDE4Internal ${_req} ${_quiet})
  70 ELSE (KDE4_DATA_DIR)
  71    IF (KDE4_FIND_REQUIRED)
  72       MESSAGE(FATAL_ERROR "ERROR: cmake/modules/FindKDE4Internal.cmake not found in ${_data_DIR}")
  73    ENDIF (KDE4_FIND_REQUIRED)
  74 ENDIF (KDE4_DATA_DIR)