m4/libxml2.m4

   1 # Configure paths for LIBXML2
   2 # Simon Josefsson 2020-02-12
   3 # Fix autoconf 2.70+ warnings
   4 # Mike Hommey 2004-06-19
   5 # use CPPFLAGS instead of CFLAGS
   6 # Toshio Kuratomi 2001-04-21
   7 # Adapted from:
   8 # Configure paths for GLIB
   9 # Owen Taylor     97-11-3
  10
  11 dnl AM_PATH_XML2([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
  12 dnl Test for XML, and define XML_CPPFLAGS and XML_LIBS
  13 dnl
  14 AC_DEFUN([AM_PATH_XML2],[
  15 AC_ARG_WITH(xml-prefix,
  16             [  --with-xml-prefix=PFX   Prefix where libxml is installed (optional)],
  17             xml_config_prefix="$withval", xml_config_prefix="")
  18 AC_ARG_WITH(xml-exec-prefix,
  19             [  --with-xml-exec-prefix=PFX Exec prefix where libxml is installed (optional)],
  20             xml_config_exec_prefix="$withval", xml_config_exec_prefix="")
  21 AC_ARG_ENABLE(xmltest,
  22               [  --disable-xmltest       Do not try to compile and run a test LIBXML program],,
  23               enable_xmltest=yes)
  24
  25   if test x$xml_config_exec_prefix != x ; then
  26      xml_config_args="$xml_config_args"
  27      if test x${XML2_CONFIG+set} != xset ; then
  28         XML2_CONFIG=$xml_config_exec_prefix/bin/xml2-config
  29      fi
  30   fi
  31   if test x$xml_config_prefix != x ; then
  32      xml_config_args="$xml_config_args --prefix=$xml_config_prefix"
  33      if test x${XML2_CONFIG+set} != xset ; then
  34         XML2_CONFIG=$xml_config_prefix/bin/xml2-config
  35      fi
  36   fi
  37
  38   AC_PATH_PROG(XML2_CONFIG, xml2-config, no)
  39   min_xml_version=ifelse([$1], ,2.0.0,[$1])
  40   AC_MSG_CHECKING(for libxml - version >= $min_xml_version)
  41   no_xml=""
  42   if test "$XML2_CONFIG" = "no" ; then
  43     no_xml=yes
  44   else
  45     XML_CPPFLAGS=`$XML2_CONFIG $xml_config_args --cflags`
  46     XML_LIBS=`$XML2_CONFIG $xml_config_args --libs`
  47     xml_config_major_version=`$XML2_CONFIG $xml_config_args --version | \
  48            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  49     xml_config_minor_version=`$XML2_CONFIG $xml_config_args --version | \
  50            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  51     xml_config_micro_version=`$XML2_CONFIG $xml_config_args --version | \
  52            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  53     if test "x$enable_xmltest" = "xyes" ; then
  54       ac_save_CPPFLAGS="$CPPFLAGS"
  55       ac_save_LIBS="$LIBS"
  56       CPPFLAGS="$CPPFLAGS $XML_CPPFLAGS"
  57       LIBS="$XML_LIBS $LIBS"
  58 dnl
  59 dnl Now check if the installed libxml is sufficiently new.
  60 dnl (Also sanity checks the results of xml2-config to some extent)
  61 dnl
  62       rm -f conf.xmltest
  63       AC_RUN_IFELSE(
  64             [AC_LANG_SOURCE([[
  65 #include <stdlib.h>
  66 #include <stdio.h>
  67 #include <string.h>
  68 #include <libxml/xmlversion.h>
  69
  70 int
  71 main()
  72 {
  73   int xml_major_version, xml_minor_version, xml_micro_version;
  74   int major, minor, micro;
  75   char *tmp_version;
  76
  77   system("touch conf.xmltest");
  78
  79   /* Capture xml2-config output via autoconf/configure variables */
  80   /* HP/UX 9 (%@#!) writes to sscanf strings */
  81   tmp_version = (char *)strdup("$min_xml_version");
  82   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
  83      printf("%s, bad version string from xml2-config\n", "$min_xml_version");
  84      exit(1);
  85    }
  86    free(tmp_version);
  87
  88    /* Capture the version information from the header files */
  89    tmp_version = (char *)strdup(LIBXML_DOTTED_VERSION);
  90    if (sscanf(tmp_version, "%d.%d.%d", &xml_major_version, &xml_minor_version, &xml_micro_version) != 3) {
  91      printf("%s, bad version string from libxml includes\n", "LIBXML_DOTTED_VERSION");
  92      exit(1);
  93    }
  94    free(tmp_version);
  95
  96  /* Compare xml2-config output to the libxml headers */
  97   if ((xml_major_version != $xml_config_major_version) ||
  98       (xml_minor_version != $xml_config_minor_version) ||
  99       (xml_micro_version != $xml_config_micro_version))
 100     {
 101       printf("*** libxml header files (version %d.%d.%d) do not match\n",
 102          xml_major_version, xml_minor_version, xml_micro_version);
 103       printf("*** xml2-config (version %d.%d.%d)\n",
 104          $xml_config_major_version, $xml_config_minor_version, $xml_config_micro_version);
 105       return 1;
 106     }
 107 /* Compare the headers to the library to make sure we match */
 108   /* Less than ideal -- doesn't provide us with return value feedback,
 109    * only exits if there's a serious mismatch between header and library.
 110    */
 111     LIBXML_TEST_VERSION;
 112
 113     /* Test that the library is greater than our minimum version */
 114     if ((xml_major_version > major) ||
 115         ((xml_major_version == major) && (xml_minor_version > minor)) ||
 116         ((xml_major_version == major) && (xml_minor_version == minor) &&
 117         (xml_micro_version >= micro)))
 118       {
 119         return 0;
 120        }
 121      else
 122       {
 123         printf("\n*** An old version of libxml (%d.%d.%d) was found.\n",
 124                xml_major_version, xml_minor_version, xml_micro_version);
 125         printf("*** You need a version of libxml newer than %d.%d.%d.\n",
 126            major, minor, micro);
 127         printf("***\n");
 128         printf("*** If you have already installed a sufficiently new version, this error\n");
 129         printf("*** probably means that the wrong copy of the xml2-config shell script is\n");
 130         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 131         printf("*** of LIBXML, but you can also set the XML2_CONFIG environment to point to the\n");
 132         printf("*** correct copy of xml2-config. (In this case, you will have to\n");
 133         printf("*** modify your LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf\n");
 134         printf("*** so that the correct libraries are found at run-time))\n");
 135     }
 136   return 1;
 137 }
 138 ]])],, no_xml=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 139        CPPFLAGS="$ac_save_CPPFLAGS"
 140        LIBS="$ac_save_LIBS"
 141      fi
 142   fi
 143
 144   if test "x$no_xml" = x ; then
 145      AC_MSG_RESULT(yes (version $xml_config_major_version.$xml_config_minor_version.$xml_config_micro_version))
 146      ifelse([$2], , :, [$2])
 147   else
 148      AC_MSG_RESULT(no)
 149      if test "$XML2_CONFIG" = "no" ; then
 150        echo "*** The xml2-config script installed by LIBXML could not be found"
 151        echo "*** If libxml was installed in PREFIX, make sure PREFIX/bin is in"
 152        echo "*** your path, or set the XML2_CONFIG environment variable to the"
 153        echo "*** full path to xml2-config."
 154      else
 155        if test -f conf.xmltest ; then
 156         :
 157        else
 158           echo "*** Could not run libxml test program, checking why..."
 159           CPPFLAGS="$CPPFLAGS $XML_CPPFLAGS"
 160           LIBS="$LIBS $XML_LIBS"
 161           AC_LINK_IFELSE(
 162             [AC_LANG_PROGRAM([[
 163 #include <libxml/xmlversion.h>
 164 #include <stdio.h>
 165 ]],    [[ LIBXML_TEST_VERSION; return 0;]])],
 166         [ echo "*** The test program compiled, but did not run. This usually means"
 167           echo "*** that the run-time linker is not finding LIBXML or finding the wrong"
 168           echo "*** version of LIBXML. If it is not finding LIBXML, you'll need to set your"
 169           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 170           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 171           echo "*** is required on your system"
 172           echo "***"
 173           echo "*** If you have an old version installed, it is best to remove it, although"
 174           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH" ],
 175         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 176           echo "*** exact error that occurred. This usually means LIBXML was incorrectly installed"
 177           echo "*** or that you have moved LIBXML since it was installed. In the latter case, you"
 178           echo "*** may want to edit the xml2-config script: $XML2_CONFIG" ])
 179           CPPFLAGS="$ac_save_CPPFLAGS"
 180           LIBS="$ac_save_LIBS"
 181        fi
 182      fi
 183
 184      XML_CPPFLAGS=""
 185      XML_LIBS=""
 186      ifelse([$3], , :, [$3])
 187   fi
 188   AC_SUBST(XML_CPPFLAGS)
 189   AC_SUBST(XML_LIBS)
 190   rm -f conf.xmltest
 191 ])