configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG_C
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 AC_PROG_LIBTOOL
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link JTAG Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]]])
 118
 119 m4_define([USB_ADAPTERS],
 120         [[[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 121         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 122         [[aice], [Andes JTAG Programmer], [AICE]]])
 123
 124 m4_define([USB0_ADAPTERS],
 125         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 126         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 127         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 128
 129 m4_define([HIDAPI_ADAPTERS],
 130         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]]])
 131
 132 m4_define([HIDAPI_USB1_ADAPTERS],
 133         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 134
 135 m4_define([LIBFTDI_ADAPTERS],
 136         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 137         [[presto], [ASIX Presto Adapter], [PRESTO]],
 138         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 139
 140 m4_define([LIBJAYLINK_ADAPTERS],
 141         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 142
 143
 144 AC_ARG_ENABLE([doxygen-html],
 145   AS_HELP_STRING([--disable-doxygen-html],
 146     [Disable building Doxygen manual as HTML.]),
 147   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 148 AC_SUBST([doxygen_as_html])
 149 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 150 AC_MSG_RESULT([$doxygen_as_html])
 151
 152 AC_ARG_ENABLE([doxygen-pdf],
 153   AS_HELP_STRING([--enable-doxygen-pdf],
 154     [Enable building Doxygen manual as PDF.]),
 155   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 156 AC_SUBST([doxygen_as_pdf])
 157 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 158 AC_MSG_RESULT([$doxygen_as_pdf])
 159
 160 AC_ARG_ENABLE([gccwarnings],
 161   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 162   [gcc_warnings=$enableval], [gcc_warnings=yes])
 163
 164 AC_ARG_ENABLE([wextra],
 165   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 166   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 167
 168 AC_ARG_ENABLE([werror],
 169   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 170   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 171
 172 # set default verbose options, overridden by following options
 173 debug_jtag_io=no
 174 debug_usb_io=no
 175 debug_usb_comms=no
 176
 177 AC_ARG_ENABLE([verbose],
 178   AS_HELP_STRING([--enable-verbose],
 179       [Enable verbose JTAG I/O messages (for debugging).]),
 180   [
 181   debug_jtag_io=$enableval
 182   debug_usb_io=$enableval
 183   debug_usb_comms=$enableval
 184   ], [])
 185
 186 AC_ARG_ENABLE([verbose_jtag_io],
 187   AS_HELP_STRING([--enable-verbose-jtag-io],
 188       [Enable verbose JTAG I/O messages (for debugging).]),
 189   [debug_jtag_io=$enableval], [])
 190
 191 AC_ARG_ENABLE([verbose_usb_io],
 192   AS_HELP_STRING([--enable-verbose-usb-io],
 193       [Enable verbose USB I/O messages (for debugging)]),
 194   [debug_usb_io=$enableval], [])
 195
 196 AC_ARG_ENABLE([verbose_usb_comms],
 197   AS_HELP_STRING([--enable-verbose-usb-comms],
 198       [Enable verbose USB communication messages (for debugging)]),
 199   [debug_usb_comms=$enableval], [])
 200
 201 AC_MSG_CHECKING([whether to enable verbose JTAG I/O messages]);
 202 AC_MSG_RESULT([$debug_jtag_io])
 203 AS_IF([test "x$debug_jtag_io" = "xyes"], [
 204   AC_DEFINE([_DEBUG_JTAG_IO_],[1], [Print verbose JTAG I/O messages])
 205 ])
 206
 207 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 208 AC_MSG_RESULT([$debug_usb_io])
 209 AS_IF([test "x$debug_usb_io" = "xyes"], [
 210   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 211 ])
 212
 213 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 214 AC_MSG_RESULT([$debug_usb_comms])
 215 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 216   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 217 ])
 218
 219 debug_malloc=no
 220 AC_ARG_ENABLE([malloc_logging],
 221   AS_HELP_STRING([--enable-malloc-logging],
 222       [Include free space in logging messages (requires malloc.h).]),
 223   [debug_malloc=$enableval], [])
 224
 225 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 226 AC_MSG_RESULT([$debug_malloc])
 227 AS_IF([test "x$debug_malloc" = "xyes"], [
 228   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 229 ])
 230
 231 AC_ARG_ENABLE([dummy],
 232   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 233   [build_dummy=$enableval], [build_dummy=no])
 234
 235 m4_define([AC_ARG_ADAPTERS], [
 236   m4_foreach([adapter], [$1],
 237         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 238                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 239                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 240                 [], [ADAPTER_VAR([adapter])=$2])
 241   ])
 242 ])
 243
 244 AC_ARG_ADAPTERS([
 245   USB1_ADAPTERS,
 246   USB_ADAPTERS,
 247   USB0_ADAPTERS,
 248   HIDAPI_ADAPTERS,
 249   HIDAPI_USB1_ADAPTERS,
 250   LIBFTDI_ADAPTERS,
 251   LIBJAYLINK_ADAPTERS
 252   ],[auto])
 253
 254 AC_ARG_ENABLE([parport],
 255   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 256   [build_parport=$enableval], [build_parport=no])
 257
 258 AC_ARG_ENABLE([parport_ppdev],
 259   AS_HELP_STRING([--disable-parport-ppdev],
 260       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 261     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 262
 263 AC_ARG_ENABLE([parport_giveio],
 264     AS_HELP_STRING([--enable-parport-giveio],
 265       [Enable use of giveio for parport (for CygWin only)]),
 266     [parport_use_giveio=$enableval], [parport_use_giveio=])
 267
 268 AC_ARG_ENABLE([jtag_vpi],
 269   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 270   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 271
 272 AC_ARG_ENABLE([amtjtagaccel],
 273   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 274   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 275
 276 AC_ARG_ENABLE([zy1000_master],
 277   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 278   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 279
 280 AC_ARG_ENABLE([zy1000],
 281   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 282   [build_zy1000=$enableval], [build_zy1000=no])
 283
 284 AC_ARG_ENABLE([ioutil],
 285   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 286   [build_ioutil=$enableval], [build_ioutil=no])
 287
 288 AS_CASE(["${host_cpu}"],
 289   [arm*], [
 290     AC_ARG_ENABLE([ep93xx],
 291       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 292       [build_ep93xx=$enableval], [build_ep93xx=no])
 293
 294     AC_ARG_ENABLE([at91rm9200],
 295       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 296       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 297
 298     AC_ARG_ENABLE([bcm2835gpio],
 299       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 300       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 301     AC_ARG_ENABLE([imx_gpio],
 302       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 303       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 304   ],
 305   [
 306     build_ep93xx=no
 307     build_at91rm9200=no
 308     build_bcm2835gpio=no
 309     build_imx_gpio=no
 310 ])
 311
 312 AC_ARG_ENABLE([gw16012],
 313   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 314   [build_gw16012=$enableval], [build_gw16012=no])
 315
 316 AC_ARG_ENABLE([oocd_trace],
 317   AS_HELP_STRING([--enable-oocd_trace],
 318   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 319   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 320
 321 AC_ARG_ENABLE([buspirate],
 322   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 323   [build_buspirate=$enableval], [build_buspirate=no])
 324
 325 AC_ARG_ENABLE([sysfsgpio],
 326   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 327   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 328
 329 AS_CASE([$host_os],
 330   [linux*], [],
 331   [
 332     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 333       AC_MSG_ERROR([sysfsgpio is only available on linux])
 334     ])
 335 ])
 336
 337 AC_ARG_ENABLE([minidriver_dummy],
 338   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 339   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 340
 341 AC_ARG_ENABLE([internal-jimtcl],
 342   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 343   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 344
 345 AC_ARG_ENABLE([internal-libjaylink],
 346   AS_HELP_STRING([--disable-internal-libjaylink],
 347   [Disable building internal libjaylink]),
 348   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 349
 350 AC_ARG_ENABLE([target64],
 351   AS_HELP_STRING([--disable-target64], [Disable 64-bit target address]),
 352     [build_target64=$enableval], [build_target64=yes])
 353
 354 build_minidriver=no
 355 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 356 AS_IF([test "x$build_zy1000" = "xyes"], [
 357   AS_IF([test "x$build_minidriver" = "xyes"], [
 358     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 359   ])
 360   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 361       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 362   build_minidriver=yes
 363 ])
 364 AC_MSG_RESULT([$build_zy1000])
 365
 366 AC_ARG_ENABLE([remote-bitbang],
 367   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 368   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 369
 370 AC_MSG_CHECKING([whether to enable dummy minidriver])
 371 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 372   AS_IF([test "x$build_minidriver" = "xyes"], [
 373     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 374   ])
 375   build_minidriver=yes
 376   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 377   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 378       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 379 ])
 380 AC_MSG_RESULT([$build_minidriver_dummy])
 381
 382 AC_MSG_CHECKING([whether standard drivers can be built])
 383 AS_IF([test "x$build_minidriver" = "xyes"], [
 384   AC_MSG_RESULT([no])
 385   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 386   sleep 2
 387 ], [
 388   AC_MSG_RESULT([yes])
 389 ])
 390
 391 AS_CASE(["${host_cpu}"],
 392   [i?86|x86*], [],
 393   [
 394     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 395       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 396     ])
 397     parport_use_ppdev=yes
 398 ])
 399
 400 AS_CASE([$host],
 401   [*-cygwin*], [
 402     is_win32=yes
 403     parport_use_ppdev=no
 404
 405     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 406       [is_mingw=yes],[is_mingw=no])
 407     AS_IF([test "x$is_mingw" = "xyes"], [
 408       AS_IF([test "x$parport_use_giveio" = "xno"], [
 409         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 410       ])
 411       parport_use_giveio=yes
 412       is_cygwin=no
 413     ], [
 414       is_cygwin=yes
 415       # sys/io.h needed under cygwin for parport access
 416       AS_IF([test "x$build_parport" = "xyes"], [
 417         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 418       ])
 419     ])
 420   ],
 421   [*-mingw* | *-msys*], [
 422     is_mingw=yes
 423     is_win32=yes
 424     parport_use_ppdev=no
 425
 426     AS_IF([test "x$parport_use_giveio" = "xno"], [
 427       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 428     ])
 429     parport_use_giveio=yes
 430
 431     AS_IF([test "x$build_buspirate" = "xyes"], [
 432       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 433     ])
 434
 435     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 436   ],
 437   [*darwin*], [
 438     is_darwin=yes
 439
 440     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 441       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 442     ])
 443     parport_use_giveio=no
 444   ],
 445   [
 446     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 447       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 448     ])
 449     parport_use_giveio=no
 450 ])
 451
 452 AS_IF([test "x$is_cygwin" = "xyes"], [
 453     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 454 ], [
 455     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 456 ])
 457
 458 AS_IF([test "x$is_mingw" = "xyes"], [
 459     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 460 ], [
 461     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 462 ])
 463
 464 AS_IF([test "x$is_win32" = "xyes"], [
 465     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 466 ], [
 467     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 468 ])
 469
 470 AS_IF([test "x$is_darwin" = "xyes"], [
 471     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 472 ], [
 473     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 474 ])
 475
 476 AS_IF([test "x$build_parport" = "xyes"], [
 477   build_bitbang=yes
 478   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 479 ], [
 480   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 481 ])
 482
 483 AS_IF([test "x$build_dummy" = "xyes"], [
 484   build_bitbang=yes
 485   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 486 ], [
 487   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 488 ])
 489
 490 AS_IF([test "x$build_ep93xx" = "xyes"], [
 491   build_bitbang=yes
 492   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 493 ], [
 494   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 495 ])
 496
 497 AS_IF([test "x$build_zy1000" = "xyes"], [
 498   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 499 ], [
 500   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 501 ])
 502
 503 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 504   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 505 ], [
 506   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 507 ])
 508
 509 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 510   build_bitbang=yes
 511   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 512 ], [
 513   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 514 ])
 515
 516 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 517   build_bitbang=yes
 518   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 519 ], [
 520   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 521 ])
 522
 523 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 524   build_bitbang=yes
 525   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 526 ], [
 527   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 528 ])
 529
 530 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 531   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 532 ], [
 533   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 534 ])
 535
 536 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 537   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 538 ], [
 539   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 540 ])
 541
 542 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 543   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 544 ], [
 545   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 546 ])
 547
 548 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 549   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 550 ], [
 551   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 552 ])
 553
 554 AS_IF([test "x$build_gw16012" = "xyes"], [
 555   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 556 ], [
 557   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 558 ])
 559
 560 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 561   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 562 ], [
 563   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 564 ])
 565
 566 AS_IF([test "x$build_buspirate" = "xyes"], [
 567   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 568 ], [
 569   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 570 ])
 571
 572 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 573   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 574     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim --with-ext="eventloop array clock regexp stdlib tclcompat" --without-ext="default"])
 575   ], [
 576     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 577   ])
 578 ])
 579
 580 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 581   build_bitbang=yes
 582   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 583 ], [
 584   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 585 ])
 586
 587 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 588   build_bitbang=yes
 589   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 590 ], [
 591   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 592 ])
 593
 594 AS_IF([test "x$build_target64" = "xyes"], [
 595   AC_DEFINE([BUILD_TARGET64], [1], [1 if you want 64-bit addresses.])
 596 ], [
 597   AC_DEFINE([BUILD_TARGET64], [0], [0 if you don't want 64-bit addresses.])
 598 ])
 599
 600
 601 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 602         use_libusb1=yes
 603         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 604         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 605                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 606                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 607         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 608         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 609         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 610                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 611   ], [
 612         use_libusb1=no
 613         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 614 ])
 615
 616 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 617
 618 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 619         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 620                 use_hidapi=yes
 621                 break
 622         ],[
 623                 use_hidapi=no
 624         ])
 625 done
 626
 627 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 628         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 629 ])
 630
 631 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.1],
 632         [use_libjaylink=yes], [use_libjaylink=no])
 633
 634 m4_define([PROCESS_ADAPTERS], [
 635   m4_foreach([adapter], [$1], [
 636         AS_IF([test $2], [
 637                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 638                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 639                 ], [
 640                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 641                 ])
 642         ], [
 643                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 644                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 645                 ])
 646                 ADAPTER_VAR([adapter])=no
 647         ])
 648         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 649   ])
 650 ])
 651
 652 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 653 PROCESS_ADAPTERS([USB_ADAPTERS], ["x$use_libusb1" = "xyes" -o "x$use_libusb0" = "xyes"], [libusb-1.x or libusb-0.1])
 654 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 655 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 656 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 657 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 658 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_libusb1" = "xyes" -a "x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libusb-1.x or libjaylink-0.1])
 659
 660 AS_IF([test "x$build_openjtag" = "xyes"], [
 661   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 662     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 663     build_openjtag=no
 664   ])
 665 ])
 666
 667 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"], [
 668         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 669 ], [
 670         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 671 ])
 672 AM_CONDITIONAL([HLADAPTER], [test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno"])
 673
 674 AS_IF([test "x$enable_jlink" != "xno"], [
 675   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 676     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 677       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 678                 [--enable-subproject-build])
 679     ], [
 680       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 681     ])
 682   ])
 683 ])
 684
 685 # Presto needs the bitq module
 686 AS_IF([test "x$enable_presto" != "xno"], [
 687   build_bitq=yes
 688 ])
 689
 690 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 691 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 692 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 693 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 694 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 695 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 696 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 697 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 698 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 699 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 700 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 701 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 702 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 703 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 704 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 705 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 706 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 707 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 708 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 709 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 710 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 711 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 712 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 713 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 714 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 715 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 716 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 717 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 718 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 719 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 720 AM_CONDITIONAL([TARGET64], [test "x$build_target64" = "xyes"])
 721
 722 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 723 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 724
 725 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 726 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 727
 728 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 729 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 730 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 731 #define _GNU_SOURCE
 732 #include <unistd.h>
 733 #include <stdlib.h>
 734   ]], [[char **ep = environ;]]
 735   )], [
 736     AC_MSG_RESULT([yes])
 737     has_environ=yes
 738   ], [
 739     AC_MSG_RESULT([no])
 740
 741     # Possibility #2: can environ be found in an available library?
 742     AC_MSG_CHECKING([for extern environ])
 743     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 744     extern char **environ;
 745     ]], [[char **ep = environ;]]
 746       )], [
 747         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 748         has_environ=yes
 749       ], [
 750         has_environ=no
 751       ])
 752     AC_MSG_RESULT([${has_environ}])
 753   ])
 754
 755 AS_IF([test "x${has_environ}" != "xyes" ], [
 756   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 757 ])
 758
 759 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 760
 761 # set default gcc warnings
 762 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 763 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 764   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 765   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 766   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 767   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 768 ])
 769 AS_IF([test "x${gcc_werror}" = "xyes"], [
 770   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 771 ])
 772
 773 # overide default gcc cflags
 774 AS_IF([test "x$gcc_warnings" = "xyes"], [
 775   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 776 ])
 777
 778 AC_CONFIG_FILES([
 779   Makefile
 780 ])
 781 AC_OUTPUT
 782
 783 echo
 784 echo
 785 echo OpenOCD configuration summary
 786 echo --------------------------------------------------
 787 m4_foreach([adapter], [USB1_ADAPTERS, USB_ADAPTERS, USB0_ADAPTERS,
 788         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 789         LIBJAYLINK_ADAPTERS],
 790         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 791         AS_CASE([$ADAPTER_VAR([adapter])],
 792                 [auto], [
 793                         echo "$s"yes '(auto)'
 794                 ],
 795                 [yes], [
 796                         echo "$s"yes
 797                 ],
 798                 [no], [
 799                         echo "$s"no
 800         ])
 801 ])
 802 echo
 803
 804 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 805   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 806   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 807   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 808   echo
 809 ])
 810
 811 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 812   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 813   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 814   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 815   echo 'Mailing List.'
 816   echo
 817 ])
 818
 819 AS_IF([test "x$build_ioutil" = "xyes"], [
 820   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 821   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 822   echo 'release. If you regularly depend on this functionality, please report to the'
 823   echo 'OpenOCD Mailing List.'
 824   echo
 825 ])