configure.ac

   1 # SPDX-License-Identifier: GPL-2.0-or-later
   2
   3 AC_PREREQ([2.69])
   4 AC_INIT([openocd], [0.12.0+dev],
   5   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   6 AC_CONFIG_SRCDIR([src/openocd.c])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 m4_include([config_subdir.m4])dnl
  10
  11 # check for makeinfo before calling AM_INIT_AUTOMAKE
  12 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  13 AS_IF([test "x$MAKEINFO" = "x"], [
  14   MAKEINFO='echo makeinfo missing; true'
  15   AC_MSG_WARN([Info documentation will not be built.])
  16 ])
  17 AC_SUBST([MAKEINFO])
  18
  19 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  20
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 AC_LANG([C])
  24 AC_PROG_CC
  25 # autoconf 2.70 obsoletes AC_PROG_CC_C99 and includes it in AC_PROG_CC
  26 m4_version_prereq([2.70],[],[AC_PROG_CC_C99])
  27 AM_PROG_CC_C_O
  28 AC_PROG_RANLIB
  29
  30 # If macro PKG_PROG_PKG_CONFIG is not available, Autoconf generates a misleading error message,
  31 # so check for existence first, and otherwise provide helpful advice.
  32 m4_ifndef([PKG_PROG_PKG_CONFIG], [m4_fatal(m4_normalize([
  33   Macro PKG_PROG_PKG_CONFIG is not available.
  34   It is usually defined in file pkg.m4 provided by package pkg-config.]))])
  35 PKG_PROG_PKG_CONFIG([0.23])
  36
  37 dnl disable checks for C++, Fortran and GNU Java Compiler
  38 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  39 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  40 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  41 AC_DISABLE_SHARED
  42 LT_INIT
  43 AC_SUBST([LIBTOOL_DEPS])
  44
  45 dnl configure checks required for Jim files (these are obsolete w/ C99)
  46 AC_C_CONST
  47 AC_TYPE_LONG_LONG_INT
  48
  49 AC_SEARCH_LIBS([ioperm], [ioperm])
  50 AC_SEARCH_LIBS([dlopen], [dl])
  51 AC_SEARCH_LIBS([openpty], [util])
  52
  53 AC_CHECK_HEADERS([sys/socket.h])
  54 AC_CHECK_HEADERS([elf.h])
  55 AC_EGREP_HEADER(Elf64_Ehdr, [elf.h], [
  56   AC_DEFINE([HAVE_ELF64], [1], [Define to 1 if the system has the type `Elf64_Ehdr'.])
  57 ])
  58 AC_CHECK_HEADERS([fcntl.h])
  59 AC_CHECK_HEADERS([malloc.h])
  60 AC_CHECK_HEADERS([netdb.h])
  61 AC_CHECK_HEADERS([poll.h])
  62 AC_CHECK_HEADERS([strings.h])
  63 AC_CHECK_HEADERS([sys/ioctl.h])
  64 AC_CHECK_HEADERS([sys/param.h])
  65 AC_CHECK_HEADERS([sys/select.h])
  66 AC_CHECK_HEADERS([sys/stat.h])
  67 AC_CHECK_HEADERS([sys/sysctl.h])
  68 AC_CHECK_HEADERS([sys/time.h])
  69 AC_CHECK_HEADERS([sys/types.h])
  70 AC_CHECK_HEADERS([unistd.h])
  71 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h netinet/tcp.h], [], [], [dnl
  72 #include <stdio.h>
  73 #ifdef STDC_HEADERS
  74 # include <stdlib.h>
  75 # include <stddef.h>
  76 #else
  77 # ifdef HAVE_STDLIB_H
  78 #  include <stdlib.h>
  79 # endif
  80 #endif
  81 #ifdef HAVE_SYS_SOCKET_H
  82 # include <sys/socket.h>
  83 #endif
  84 ])
  85
  86 AC_HEADER_ASSERT
  87 AC_HEADER_STDBOOL
  88
  89 AC_C_BIGENDIAN
  90
  91 AC_CHECK_FUNCS([strndup])
  92 AC_CHECK_FUNCS([strnlen])
  93 AC_CHECK_FUNCS([gettimeofday])
  94 AC_CHECK_FUNCS([usleep])
  95 AC_CHECK_FUNCS([realpath])
  96
  97 # guess-rev.sh only exists in the repository, not in the released archives
  98 AC_MSG_CHECKING([whether to build a release])
  99 AS_IF([test -x "$srcdir/guess-rev.sh"], [
 100   build_release=no
 101 ], [
 102   build_release=yes
 103 ])
 104 AC_MSG_RESULT([$build_release])
 105
 106 # Adapter drivers
 107 # 1st column -- configure option
 108 # 2nd column -- description
 109 # 3rd column -- symbol used for both config.h and automake
 110 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 111 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 112 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 113 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 114 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 115
 116 m4_define([USB1_ADAPTERS],
 117         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 118         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 119         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 120         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 121         [[angie], [ANGIE Adapter], [ANGIE]],
 122         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 123         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 124         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 125         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 126         [[cmsis_dap_v2], [CMSIS-DAP v2 Compliant Debugger], [CMSIS_DAP_USB]],
 127         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 128         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 129         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]],
 130         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 131         [[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 132         [[esp_usb_jtag], [Espressif JTAG Programmer], [ESP_USB_JTAG]]])
 133
 134 m4_define([HIDAPI_ADAPTERS],
 135         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP_HID]],
 136         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 137
 138 m4_define([HIDAPI_USB1_ADAPTERS],
 139         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 140
 141 m4_define([LIBFTDI_ADAPTERS],
 142         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 143         [[presto], [ASIX Presto Adapter], [PRESTO]]])
 144
 145 m4_define([LIBFTDI_USB1_ADAPTERS],
 146         [[[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 147
 148 m4_define([LIBGPIOD_ADAPTERS],
 149         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 150
 151 m4_define([LIBJAYLINK_ADAPTERS],
 152         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 153
 154 m4_define([PCIE_ADAPTERS],
 155         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 156
 157 m4_define([SERIAL_PORT_ADAPTERS],
 158         [[[buspirate], [Bus Pirate], [BUS_PIRATE]]])
 159
 160 # The word 'Adapter' in "Dummy Adapter" below must begin with a capital letter
 161 # because there is an M4 macro called 'adapter'.
 162 m4_define([DUMMY_ADAPTER],
 163         [[[dummy], [Dummy Adapter], [DUMMY]]])
 164
 165 m4_define([OPTIONAL_LIBRARIES],
 166         [[[capstone], [Use Capstone disassembly framework], []]])
 167
 168 AC_ARG_ENABLE([doxygen-html],
 169   AS_HELP_STRING([--disable-doxygen-html],
 170     [Disable building Doxygen manual as HTML.]),
 171   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 172 AC_SUBST([doxygen_as_html])
 173 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 174 AC_MSG_RESULT([$doxygen_as_html])
 175
 176 AC_ARG_ENABLE([doxygen-pdf],
 177   AS_HELP_STRING([--enable-doxygen-pdf],
 178     [Enable building Doxygen manual as PDF.]),
 179   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 180 AC_SUBST([doxygen_as_pdf])
 181 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 182 AC_MSG_RESULT([$doxygen_as_pdf])
 183
 184 AC_ARG_ENABLE([gccwarnings],
 185   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 186   [gcc_warnings=$enableval], [gcc_warnings=yes])
 187
 188 AC_ARG_ENABLE([wextra],
 189   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 190   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 191
 192 AC_ARG_ENABLE([werror],
 193   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 194   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 195
 196 # set default verbose options, overridden by following options
 197 debug_usb_io=no
 198 debug_usb_comms=no
 199
 200 AC_ARG_ENABLE([verbose],
 201   AS_HELP_STRING([--enable-verbose],
 202       [Enable verbose JTAG I/O messages (for debugging).]),
 203   [
 204   debug_usb_io=$enableval
 205   debug_usb_comms=$enableval
 206   ], [])
 207
 208 AC_ARG_ENABLE([verbose_usb_io],
 209   AS_HELP_STRING([--enable-verbose-usb-io],
 210       [Enable verbose USB I/O messages (for debugging)]),
 211   [debug_usb_io=$enableval], [])
 212
 213 AC_ARG_ENABLE([verbose_usb_comms],
 214   AS_HELP_STRING([--enable-verbose-usb-comms],
 215       [Enable verbose USB communication messages (for debugging)]),
 216   [debug_usb_comms=$enableval], [])
 217
 218 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 219 AC_MSG_RESULT([$debug_usb_io])
 220 AS_IF([test "x$debug_usb_io" = "xyes"], [
 221   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 222 ])
 223
 224 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 225 AC_MSG_RESULT([$debug_usb_comms])
 226 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 227   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 228 ])
 229
 230 debug_malloc=no
 231 AC_ARG_ENABLE([malloc_logging],
 232   AS_HELP_STRING([--enable-malloc-logging],
 233       [Include free space in logging messages (requires malloc.h).]),
 234   [debug_malloc=$enableval], [])
 235
 236 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 237 AC_MSG_RESULT([$debug_malloc])
 238 AS_IF([test "x$debug_malloc" = "xyes"], [
 239   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 240 ])
 241
 242 AC_ARG_ENABLE([rshim],
 243   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 244   [build_rshim=$enableval], [build_rshim=no])
 245
 246 AC_ARG_ENABLE([dmem],
 247   AS_HELP_STRING([--enable-dmem], [Enable building the dmem driver]),
 248   [build_dmem=$enableval], [build_dmem=no])
 249
 250 m4_define([AC_ARG_ADAPTERS], [
 251   m4_foreach([adapter], [$1],
 252         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 253                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 254                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 255                 [], [ADAPTER_VAR([adapter])=$2])
 256   ])
 257 ])
 258
 259 AC_ARG_ADAPTERS([
 260   USB1_ADAPTERS,
 261   HIDAPI_ADAPTERS,
 262   HIDAPI_USB1_ADAPTERS,
 263   LIBFTDI_ADAPTERS,
 264   LIBFTDI_USB1_ADAPTERS
 265   LIBGPIOD_ADAPTERS,
 266   SERIAL_PORT_ADAPTERS,
 267   LIBJAYLINK_ADAPTERS
 268   ],[auto])
 269
 270 AC_ARG_ADAPTERS([DUMMY_ADAPTER],[no])
 271
 272 AC_ARG_ENABLE([parport],
 273   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 274   [build_parport=$enableval], [build_parport=no])
 275
 276 AC_ARG_ENABLE([parport_ppdev],
 277   AS_HELP_STRING([--disable-parport-ppdev],
 278       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 279     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 280
 281 AC_ARG_ENABLE([parport_giveio],
 282     AS_HELP_STRING([--enable-parport-giveio],
 283       [Enable use of giveio for parport (for CygWin only)]),
 284     [parport_use_giveio=$enableval], [parport_use_giveio=])
 285
 286 AC_ARG_ENABLE([jtag_vpi],
 287   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 288   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 289
 290 AC_ARG_ENABLE([vdebug],
 291   AS_HELP_STRING([--enable-vdebug], [Enable building support for Cadence Virtual Debug Interface]),
 292   [build_vdebug=$enableval], [build_vdebug=no])
 293
 294 AC_ARG_ENABLE([jtag_dpi],
 295   AS_HELP_STRING([--enable-jtag_dpi], [Enable building support for JTAG DPI]),
 296   [build_jtag_dpi=$enableval], [build_jtag_dpi=no])
 297
 298 AC_ARG_ENABLE([amtjtagaccel],
 299   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 300   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 301
 302 AS_CASE(["${host_cpu}"],
 303   [arm*|aarch64], [
 304     AC_ARG_ENABLE([bcm2835gpio],
 305       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 306       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 307     AC_ARG_ENABLE([imx_gpio],
 308       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 309       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 310     AC_ARG_ENABLE([am335xgpio],
 311       AS_HELP_STRING([--enable-am335xgpio], [Enable building support for bitbanging on AM335x (as found in Beaglebones)]),
 312       [build_am335xgpio=$enableval], [build_am335xgpio=no])
 313   ],
 314   [
 315     build_bcm2835gpio=no
 316     build_imx_gpio=no
 317     build_am335xgpio=no
 318 ])
 319
 320 AS_CASE(["${host_cpu}"],
 321   [arm*], [
 322     AC_ARG_ENABLE([ep93xx],
 323       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 324       [build_ep93xx=$enableval], [build_ep93xx=no])
 325
 326     AC_ARG_ENABLE([at91rm9200],
 327       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 328       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 329   ],
 330   [
 331     build_ep93xx=no
 332     build_at91rm9200=no
 333 ])
 334
 335 AC_ARG_ENABLE([gw16012],
 336   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 337   [build_gw16012=$enableval], [build_gw16012=no])
 338
 339 AC_ARG_ENABLE([sysfsgpio],
 340   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 341   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 342
 343 AC_ARG_ENABLE([xlnx_pcie_xvc],
 344   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 345   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 346
 347 AS_CASE([$host_os],
 348   [linux*], [],
 349   [
 350     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 351       AC_MSG_ERROR([sysfsgpio is only available on linux])
 352     ])
 353
 354     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 355       AC_MSG_ERROR([linuxgpiod is only available on linux])
 356     ])
 357
 358     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 359       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 360     ])
 361
 362     AS_CASE([$host_os], [freebsd*], [],
 363     [
 364       AS_IF([test "x$build_rshim" = "xyes"], [
 365         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 366       ])
 367     ])
 368
 369     AS_IF([test "x$build_dmem" = "xyes"], [
 370       AC_MSG_ERROR([dmem is only available on linux])
 371     ])
 372 ])
 373
 374 AC_ARG_ENABLE([internal-jimtcl],
 375   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 376   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 377
 378 AC_ARG_ENABLE([jimtcl-maintainer],
 379   AS_HELP_STRING([--enable-jimtcl-maintainer], [Enable maintainer mode when building internal jimtcl]),
 380   [use_internal_jimtcl_maintainer=$enableval], [use_internal_jimtcl_maintainer=no])
 381
 382 AC_ARG_ENABLE([internal-libjaylink],
 383   AS_HELP_STRING([--enable-internal-libjaylink],
 384   [Enable building internal libjaylink]),
 385   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=no])
 386
 387 AC_ARG_ENABLE([remote-bitbang],
 388   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang driver]),
 389   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 390
 391 AS_CASE(["${host_cpu}"],
 392   [i?86|x86*], [],
 393   [
 394     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 395       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 396     ])
 397     parport_use_ppdev=yes
 398 ])
 399
 400 AS_CASE([$host],
 401   [*-cygwin*], [
 402     is_win32=yes
 403     parport_use_ppdev=no
 404
 405     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 406       [is_mingw=yes],[is_mingw=no])
 407     AS_IF([test "x$is_mingw" = "xyes"], [
 408       AS_IF([test "x$parport_use_giveio" = "xno"], [
 409         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 410       ])
 411       parport_use_giveio=yes
 412       is_cygwin=no
 413     ], [
 414       is_cygwin=yes
 415       # sys/io.h needed under cygwin for parport access
 416       AS_IF([test "x$build_parport" = "xyes"], [
 417         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 418       ])
 419     ])
 420   ],
 421   [*-mingw* | *-msys*], [
 422     is_mingw=yes
 423     is_win32=yes
 424     parport_use_ppdev=no
 425
 426     AS_IF([test "x$parport_use_giveio" = "xno"], [
 427       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 428     ])
 429     parport_use_giveio=yes
 430
 431     AS_IF([test "x$enable_buspirate" = "xyes"], [
 432       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 433     ])
 434
 435     # In case enable_buspirate=auto, make sure it will not be built.
 436     enable_buspirate=no
 437
 438     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 439   ],
 440   [*darwin*], [
 441     is_darwin=yes
 442
 443     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 444       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 445     ])
 446     parport_use_giveio=no
 447   ],
 448   [
 449     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 450       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 451     ])
 452     parport_use_giveio=no
 453 ])
 454
 455 AS_IF([test "x$is_cygwin" = "xyes"], [
 456     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 457 ], [
 458     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 459 ])
 460
 461 AS_IF([test "x$is_mingw" = "xyes"], [
 462     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 463 ], [
 464     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 465 ])
 466
 467 AS_IF([test "x$is_win32" = "xyes"], [
 468     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 469 ], [
 470     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 471 ])
 472
 473 AS_IF([test "x$is_darwin" = "xyes"], [
 474     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 475 ], [
 476     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 477 ])
 478
 479 AS_IF([test "x$build_parport" = "xyes"], [
 480   build_bitbang=yes
 481   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 482 ], [
 483   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 484 ])
 485
 486 AS_IF([test "x$build_rshim" = "xyes"], [
 487   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 488 ], [
 489   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 490 ])
 491
 492 AS_IF([test "x$build_dmem" = "xyes"], [
 493   AC_DEFINE([BUILD_DMEM], [1], [1 if you want to debug via Direct Mem.])
 494 ], [
 495   AC_DEFINE([BUILD_DMEM], [0], [0 if you don't want to debug via Direct Mem.])
 496 ])
 497
 498 AS_IF([test "x$ADAPTER_VAR([dummy])" = "xyes"], [
 499   build_bitbang=yes
 500 ])
 501
 502 AS_IF([test "x$build_ep93xx" = "xyes"], [
 503   build_bitbang=yes
 504   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 505 ], [
 506   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 507 ])
 508
 509 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 510   build_bitbang=yes
 511   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 512 ], [
 513   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 514 ])
 515
 516 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 517   build_bitbang=yes
 518   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 519 ], [
 520   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 521 ])
 522
 523 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 524   build_bitbang=yes
 525   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 526 ], [
 527   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 528 ])
 529
 530 AS_IF([test "x$build_am335xgpio" = "xyes"], [
 531   build_bitbang=yes
 532   AC_DEFINE([BUILD_AM335XGPIO], [1], [1 if you want am335xgpio.])
 533 ], [
 534   AC_DEFINE([BUILD_AM335XGPIO], [0], [0 if you don't want am335xgpio.])
 535 ])
 536
 537 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 538   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 539 ], [
 540   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 541 ])
 542
 543 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 544   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 545 ], [
 546   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 547 ])
 548
 549 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 550   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 551 ], [
 552   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 553 ])
 554
 555 AS_IF([test "x$build_vdebug" = "xyes"], [
 556   AC_DEFINE([BUILD_VDEBUG], [1], [1 if you want Cadence vdebug interface.])
 557 ], [
 558   AC_DEFINE([BUILD_VDEBUG], [0], [0 if you don't want Cadence vdebug interface.])
 559 ])
 560
 561 AS_IF([test "x$build_jtag_dpi" = "xyes"], [
 562   AC_DEFINE([BUILD_JTAG_DPI], [1], [1 if you want JTAG DPI.])
 563 ], [
 564   AC_DEFINE([BUILD_JTAG_DPI], [0], [0 if you don't want JTAG DPI.])
 565 ])
 566
 567
 568 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 569   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 570 ], [
 571   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 572 ])
 573
 574 AS_IF([test "x$build_gw16012" = "xyes"], [
 575   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 576 ], [
 577   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 578 ])
 579
 580 AS_IF([test "x$enable_buspirate" != "xno"], [
 581   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 582 ], [
 583   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 584 ])
 585
 586 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 587   AS_IF([test -f "$srcdir/jimtcl/configure"], [
 588     AS_IF([test "x$use_internal_jimtcl_maintainer" = "xyes"], [
 589       jimtcl_config_options="--disable-install-jim --with-ext=json --minimal --disable-ssl --maintainer"
 590     ], [
 591       jimtcl_config_options="--disable-install-jim --with-ext=json --minimal --disable-ssl"
 592     ])
 593     AX_CONFIG_SUBDIR_OPTION([jimtcl], [$jimtcl_config_options])
 594   ], [
 595     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 596   ])
 597 ], [
 598   PKG_CHECK_MODULES([JIMTCL], [jimtcl >= 0.79], [
 599       have_jimtcl_pkg_config=yes
 600     ], [
 601       have_jimtcl_pkg_config=no
 602       AC_CHECK_HEADER([jim.h], [], [
 603         AC_MSG_ERROR([jimtcl is required but not found via pkg-config and system includes])
 604       ])
 605   ])
 606 ])
 607
 608 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 609   build_bitbang=yes
 610   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang driver.])
 611 ], [
 612   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang driver.])
 613 ])
 614
 615 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 616   build_bitbang=yes
 617   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 618 ], [
 619   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 620 ])
 621
 622 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 623   build_xlnx_pcie_xvc=yes
 624   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 625 ], [
 626   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 627 ])
 628
 629 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 630         use_libusb1=yes
 631         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 632         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 633         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 634         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 635                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 636   ], [
 637         use_libusb1=no
 638         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 639 ])
 640
 641 AC_ARG_WITH([capstone],
 642                 AS_HELP_STRING([--with-capstone], [Use Capstone disassembly library (default=auto)])
 643         , [
 644                 enable_capstone=$withval
 645         ], [
 646                 enable_capstone=auto
 647 ])
 648
 649 AS_IF([test "x$enable_capstone" != xno], [
 650         PKG_CHECK_MODULES([CAPSTONE], [capstone], [
 651                 AC_DEFINE([HAVE_CAPSTONE], [1], [1 if you have Capstone disassembly framework.])
 652         ], [
 653                 if test "x$enable_capstone" != xauto; then
 654                         AC_MSG_ERROR([--with-capstone was given, but test for Capstone failed])
 655                 fi
 656                 enable_capstone=no
 657         ])
 658 ])
 659
 660 AS_IF([test "x$enable_capstone" == xno], [
 661         AC_DEFINE([HAVE_CAPSTONE], [0], [0 if you don't have Capstone disassembly framework.])
 662 ])
 663
 664 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 665         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 666                 use_hidapi=yes
 667                 break
 668         ],[
 669                 use_hidapi=no
 670         ])
 671 done
 672
 673 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [
 674         use_libftdi=yes
 675         PKG_CHECK_EXISTS([libftdi1 >= 1.5],
 676                 [AC_DEFINE([HAVE_LIBFTDI_TCIOFLUSH], [1], [Define if your libftdi has ftdi_tcioflush()])])
 677   ], [
 678         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 679 ])
 680
 681 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod < 2.0], [
 682         use_libgpiod=yes
 683         PKG_CHECK_EXISTS([libgpiod >= 1.5],
 684                 [AC_DEFINE([HAVE_LIBGPIOD1_FLAGS_BIAS], [1], [define if libgpiod v1 has line request flags bias])])
 685 ], [use_libgpiod=no])
 686
 687 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 688         [use_libjaylink=yes], [use_libjaylink=no])
 689
 690 # Arg $1: The adapter name, used to derive option and variable names for the adapter.
 691 # Arg $2: Whether the adapter can be enabled, for example, because
 692 #         its prerequisites are installed in the system.
 693 # Arg $3: What prerequisites are missing, to be shown in an error message
 694 #         if the adapter was requested but cannot be enabled.
 695 m4_define([PROCESS_ADAPTERS], [
 696   m4_foreach([adapter], [$1], [
 697         AS_IF([test $2], [
 698                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 699                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 700                 ], [
 701                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 702                 ])
 703         ], [
 704                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 705                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 706                 ])
 707                 ADAPTER_VAR([adapter])=no
 708                 AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 709         ])
 710         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 711   ])
 712 ])
 713
 714 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 715 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 716 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 717 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 718 PROCESS_ADAPTERS([LIBFTDI_USB1_ADAPTERS], ["x$use_libftdi" = "xyes" -a "x$use_libusb1" = "xyes"], [libftdi and libusb-1.x])
 719 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 720 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 721 PROCESS_ADAPTERS([DUMMY_ADAPTER], [true], [unused])
 722
 723 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 724   build_bitbang=yes
 725 ])
 726
 727 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 728         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 729         AM_CONDITIONAL([HLADAPTER], [true])
 730 ], [
 731         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 732         AM_CONDITIONAL([HLADAPTER], [false])
 733 ])
 734 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 735 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 736 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 737
 738 AS_IF([test "x$enable_jlink" != "xno"], [
 739   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 740     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 741       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 742                 [--enable-subproject-build])
 743     ], [
 744       AC_MSG_ERROR([Internal libjaylink not found, run 'git submodule init' and 'git submodule update'.])
 745     ])
 746   ])
 747 ])
 748
 749 # Presto needs the bitq module
 750 AS_IF([test "x$enable_presto" != "xno"], [
 751   build_bitq=yes
 752 ])
 753
 754 # esp-usb-jtag also needs the bitq module
 755 AS_IF([test "x$enable_esp_usb_jtag" != "xno"], [
 756   build_bitq=yes
 757 ])
 758
 759 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 760 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 761 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 762 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 763 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 764 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 765 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 766 AM_CONDITIONAL([AM335XGPIO], [test "x$build_am335xgpio" = "xyes"])
 767 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 768 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes"])
 769 AM_CONDITIONAL([VDEBUG], [test "x$build_vdebug" = "xyes"])
 770 AM_CONDITIONAL([JTAG_DPI], [test "x$build_jtag_dpi" = "xyes"])
 771 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 772 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 773 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 774 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 775 AM_CONDITIONAL([BUSPIRATE], [test "x$enable_buspirate" != "xno"])
 776 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 777 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 778 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 779 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 780 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 781 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 782 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 783 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 784 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 785 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 786 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 787 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 788 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 789 AM_CONDITIONAL([DMEM], [test "x$build_dmem" = "xyes"])
 790 AM_CONDITIONAL([HAVE_CAPSTONE], [test "x$enable_capstone" != "xno"])
 791
 792 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 793 AM_CONDITIONAL([HAVE_JIMTCL_PKG_CONFIG], [test "x$have_jimtcl_pkg_config" = "xyes"])
 794 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 795
 796 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 797 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 798 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 799 #define _GNU_SOURCE
 800 #include <unistd.h>
 801 #include <stdlib.h>
 802   ]], [[char **ep = environ;]]
 803   )], [
 804     AC_MSG_RESULT([yes])
 805     has_environ=yes
 806   ], [
 807     AC_MSG_RESULT([no])
 808
 809     # Possibility #2: can environ be found in an available library?
 810     AC_MSG_CHECKING([for extern environ])
 811     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 812     extern char **environ;
 813     ]], [[char **ep = environ;]]
 814       )], [
 815         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 816         has_environ=yes
 817       ], [
 818         has_environ=no
 819       ])
 820     AC_MSG_RESULT([${has_environ}])
 821   ])
 822
 823 AS_IF([test "x${has_environ}" != "xyes" ], [
 824   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 825 ])
 826
 827 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 828
 829 # set default gcc warnings
 830 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 831 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 832   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 833   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 834   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 835   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 836   GCC_WARNINGS="${GCC_WARNINGS} -Wpointer-arith"
 837   GCC_WARNINGS="${GCC_WARNINGS} -Wundef"
 838 ])
 839 AS_IF([test "x${gcc_werror}" = "xyes"], [
 840   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 841 ])
 842
 843 # override default gcc cflags
 844 AS_IF([test "x$gcc_warnings" = "xyes"], [
 845   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 846 ])
 847
 848 AC_SUBST(EXTRA_DIST_NEWS, ["$(echo $srcdir/NEWS-*)"])
 849
 850 AC_CONFIG_FILES([
 851   Makefile
 852 ])
 853 AC_OUTPUT
 854
 855 AS_IF([test "x$enable_jlink" != "xno"], [
 856   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 857     AC_MSG_WARN([Using the internal libjaylink is deprecated and will not be possible in the future.])
 858   ]])
 859 )
 860
 861 echo
 862 echo
 863 echo OpenOCD configuration summary
 864 echo --------------------------------------------------
 865 m4_foreach([adapter], [USB1_ADAPTERS,
 866         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 867         LIBFTDI_USB1_ADAPTERS,
 868         LIBGPIOD_ADAPTERS,
 869         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS, SERIAL_PORT_ADAPTERS,
 870         DUMMY_ADAPTER,
 871         OPTIONAL_LIBRARIES],
 872         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 873         AS_CASE([$ADAPTER_VAR([adapter])],
 874                 [auto], [
 875                         echo "$s"yes '(auto)'
 876                 ],
 877                 [yes], [
 878                         echo "$s"yes
 879                 ],
 880                 [no], [
 881                         echo "$s"no
 882         ])
 883 ])
 884 echo