libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  SUBDIRS
  36 dnl Substs:
  37 dnl  glibcxx_builddir     (absolute path)
  38 dnl  glibcxx_srcdir       (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_srcdir=${glibcxx_srcdir}/..
  64   AC_SUBST(glibcxx_builddir)
  65   AC_SUBST(glibcxx_srcdir)
  66   AC_SUBST(toplevel_srcdir)
  67
  68   # We use these options to decide which functions to include.  They are
  69   # set from the top level.
  70   AC_ARG_WITH([target-subdir],
  71     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  72                    [configuring in a subdirectory]))
  73
  74   AC_ARG_WITH([cross-host],
  75     AC_HELP_STRING([--with-cross-host=HOST],
  76                    [configuring with a cross compiler]))
  77
  78   AC_ARG_WITH([newlib],
  79     AC_HELP_STRING([--with-newlib],
  80                    [assume newlib as a system C library]))
  81
  82   # We're almost certainly being configured before anything else which uses
  83   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  84   # we not cache the value of CXX that we "discover" here, because it's set
  85   # to something unique for us and libjava.  Other target libraries need to
  86   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  87   # process by sneakily renaming the cache variable.  This also lets us debug
  88   # the value of "our" CXX in postmortems.
  89   #
  90   # We must also force CXX to /not/ be a precious variable, otherwise the
  91   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  92   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  93   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  94   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  95   #
  96   # -fno-builtin must be present here so that a non-conflicting form of
  97   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  98
  99   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 100   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 101   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 102   save_CXXFLAGS="$CXXFLAGS"
 103   CXXFLAGS="$CXXFLAGS -fno-builtin"
 104   AC_PROG_CC
 105   AC_PROG_CXX
 106   CXXFLAGS="$save_CXXFLAGS"
 107   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108   AC_SUBST(CFLAGS)
 109   AC_SUBST(CXXFLAGS)
 110
 111   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 112   # available).  Uncomment the next line to force a particular method.
 113   AC_PROG_LN_S
 114   #LN_S='cp -p'
 115
 116   AC_CHECK_TOOL(AS, as)
 117   AC_CHECK_TOOL(AR, ar)
 118   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 119
 120   AM_MAINTAINER_MODE
 121
 122   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 123   # which are themselves conditionally expanded.
 124   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 125   ## other macros from doing the same.  This should be automated.)  -pme
 126   need_libmath=no
 127
 128   # Find platform-specific directories containing configuration info.
 129   # Also possibly modify flags used elsewhere, as needed by the platform.
 130   GLIBCXX_CHECK_HOST
 131 ])
 132
 133
 134 dnl
 135 dnl Tests for newer compiler features, or features that are present in newer
 136 dnl compiler versions but not older compiler versions still in use, should
 137 dnl be placed here.
 138 dnl
 139 dnl Defines:
 140 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 141 dnl   new inlining code or the new system_header pragma will die on -Werror.
 142 dnl   Leave it out by default and use maint-mode to use it.
 143 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 144 dnl   compiler supports it and the user has not requested debug mode.
 145 dnl
 146 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 147   # All these tests are for C++; save the language and the compiler flags.
 148   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 149   # found in GLIBCXX_CONFIGURE.
 150   AC_LANG_SAVE
 151   AC_LANG_CPLUSPLUS
 152   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 153   ac_save_CXXFLAGS="$CXXFLAGS"
 154
 155   # Check for maintainer-mode bits.
 156   if test x"$USE_MAINTAINER_MODE" = xno; then
 157     WERROR=''
 158   else
 159     WERROR='-Werror'
 160   fi
 161
 162   # Check for -ffunction-sections -fdata-sections
 163   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 164   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 165   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 166   if test "$ac_test_CXXFLAGS" = set; then
 167     CXXFLAGS="$ac_save_CXXFLAGS"
 168   else
 169     # this is the suspicious part
 170     CXXFLAGS=''
 171   fi
 172   if test x"$ac_fdsections" = x"yes"; then
 173     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 174   fi
 175   AC_MSG_RESULT($ac_fdsections)
 176
 177   AC_LANG_RESTORE
 178   AC_SUBST(WERROR)
 179   AC_SUBST(SECTION_FLAGS)
 180 ])
 181
 182
 183 dnl
 184 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 185 dnl the native linker is in use, all variables will be defined to something
 186 dnl safe (like an empty string).
 187 dnl
 188 dnl Defines:
 189 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 190 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 191 dnl  LD (as a side effect of testing)
 192 dnl Sets:
 193 dnl  with_gnu_ld
 194 dnl  glibcxx_gnu_ld_version (possibly)
 195 dnl
 196 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 197 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 198 dnl
 199 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 200   # If we're not using GNU ld, then there's no point in even trying these
 201   # tests.  Check for that first.  We should have already tested for gld
 202   # by now (in libtool), but require it now just to be safe...
 203   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 204   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 205   AC_REQUIRE([AC_PROG_LD])
 206   AC_REQUIRE([AC_PROG_AWK])
 207
 208   # The name set by libtool depends on the version of libtool.  Shame on us
 209   # for depending on an impl detail, but c'est la vie.  Older versions used
 210   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 211   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 212   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 213   # set (hence we're using an older libtool), then set it.
 214   if test x${with_gnu_ld+set} != xset; then
 215     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 216       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 217       with_gnu_ld=no
 218     else
 219       with_gnu_ld=$ac_cv_prog_gnu_ld
 220     fi
 221   fi
 222
 223   # Start by getting the version number.  I think the libtool test already
 224   # does some of this, but throws away the result.
 225   AC_MSG_CHECKING([for ld version])
 226   changequote(,)
 227   ldver=`$LD --version 2>/dev/null | head -1 | \
 228          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 229   changequote([,])
 230   glibcxx_gnu_ld_version=`echo $ldver | \
 231          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 232   AC_MSG_RESULT($glibcxx_gnu_ld_version)
 233
 234   # Set --gc-sections.
 235   glibcxx_gcsections_min_ld=21602
 236   if test x"$with_gnu_ld" = x"yes" &&
 237         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 238
 239     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 240     # NB: This flag only works reliably after 2.16.1. Configure tests
 241     # for this are difficult, so hard wire a value that should work.
 242
 243     # All these tests are for C++, but run with the "C" compiler driver.
 244     # Need to do this so that g++ won't try to link in libstdc++/libsupc++.
 245     ac_test_CFLAGS="${CFLAGS+set}"
 246     ac_save_CFLAGS="$CFLAGS"
 247     CFLAGS='-x c++ -Wl,--gc-sections'
 248
 249     # Check for -Wl,--gc-sections
 250     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 251     AC_TRY_LINK([ int one(void) { return 1; }
 252      int two(void) { return 2; }
 253         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 254     if test "$ac_gcsections" = "yes"; then
 255       rm -f conftest.c
 256       touch conftest.c
 257       if $CC -c conftest.c; then
 258         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 259            grep "Warning: gc-sections option ignored" > /dev/null; then
 260           ac_gcsections=no
 261         fi
 262       fi
 263       rm -f conftest.c conftest.o conftest
 264     fi
 265     if test "$ac_gcsections" = "yes"; then
 266       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 267     fi
 268     AC_MSG_RESULT($ac_gcsections)
 269
 270     if test "$ac_test_CFLAGS" = set; then
 271       CFLAGS="$ac_save_CFLAGS"
 272     else
 273       # this is the suspicious part
 274       CFLAGS=''
 275     fi
 276   fi
 277
 278   # Set -z,relro.
 279   # Note this is only for shared objects.
 280   ac_ld_relro=no
 281   if test x"$with_gnu_ld" = x"yes"; then
 282     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 283     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 284     if test -n "$cxx_z_relo"; then
 285       OPT_LDFLAGS="-Wl,-z,relro"
 286       ac_ld_relro=yes
 287     fi
 288     AC_MSG_RESULT($ac_ld_relro)
 289   fi
 290
 291   # Set linker optimization flags.
 292   if test x"$with_gnu_ld" = x"yes"; then
 293     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 294   fi
 295
 296   AC_SUBST(SECTION_LDFLAGS)
 297   AC_SUBST(OPT_LDFLAGS)
 298 ])
 299
 300
 301 dnl
 302 dnl Check to see if this target can enable the iconv specializations.
 303 dnl If --disable-c-mbchar was given, no wchar_t specialization is enabled.
 304 dnl (This must have been previously checked, along with the rest of C99
 305 dnl support.) By default, iconv support is disabled.
 306 dnl
 307 dnl Defines:
 308 dnl  _GLIBCXX_USE_ICONV if all the bits are found.
 309 dnl Substs:
 310 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 311 dnl
 312 AC_DEFUN([GLIBCXX_CHECK_ICONV_SUPPORT], [
 313
 314   enable_iconv=no
 315   # Only continue checking if the ISO C99 headers exist and support is on.
 316   if test x"$enable_wchar_t" = xyes; then
 317
 318     # Use iconv for wchar_t to char conversions. As such, check for
 319     # X/Open Portability Guide, version 2 features (XPG2).
 320     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 321     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 322
 323     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 324     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 325     ac_save_LIBS="$LIBS"
 326     LIBS="$LIBS $LIBICONV"
 327     AC_SUBST(LIBICONV)
 328
 329     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 330     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 331
 332     LIBS="$ac_save_LIBS"
 333
 334     if test x"$ac_has_iconv_h" = xyes &&
 335        test x"$ac_has_langinfo_h" = xyes &&
 336        test x"$ac_XPG2funcs" = xyes;
 337     then
 338       AC_DEFINE([_GLIBCXX_USE_ICONV],1,
 339                 [Define if iconv and related functions exist and are usable.])
 340       enable_iconv=yes
 341     fi
 342   fi
 343   AC_MSG_CHECKING([for enabled iconv specializations])
 344   AC_MSG_RESULT($enable_iconv)
 345 ])
 346
 347
 348 dnl
 349 dnl Check for headers for, and arguments to, the setrlimit() function.
 350 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 351 dnl
 352 dnl Defines:
 353 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 354 dnl  various HAVE_LIMIT_* for individual limit names
 355 dnl
 356 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 357   AC_MSG_CHECKING([for RLIMIT_$1])
 358   AC_TRY_COMPILE(
 359     [#include <unistd.h>
 360      #include <sys/time.h>
 361      #include <sys/resource.h>
 362     ],
 363     [ int f = RLIMIT_$1 ; ],
 364     [glibcxx_mresult=1], [glibcxx_mresult=0])
 365   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 366                      [Only used in build directory testsuite_hooks.h.])
 367   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 368   AC_MSG_RESULT($res)
 369 ])
 370
 371 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 372   setrlimit_have_headers=yes
 373   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 374                    [],
 375                    [setrlimit_have_headers=no])
 376   # If don't have the headers, then we can't run the tests now, and we
 377   # won't be seeing any of these during testsuite compilation.
 378   if test $setrlimit_have_headers = yes; then
 379     # Can't do these in a loop, else the resulting syntax is wrong.
 380     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 381     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 382     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 383     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 384     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 385
 386     # Check for rlimit, setrlimit.
 387     AC_CACHE_VAL(ac_setrlimit, [
 388       AC_TRY_COMPILE(
 389         [#include <unistd.h>
 390          #include <sys/time.h>
 391          #include <sys/resource.h>
 392         ],
 393         [struct rlimit r;
 394          setrlimit(0, &r);],
 395         [ac_setrlimit=yes], [ac_setrlimit=no])
 396     ])
 397   fi
 398
 399   AC_MSG_CHECKING([for testsuite resource limits support])
 400   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 401     ac_res_limits=yes
 402     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 403               [Define if using setrlimit to set resource limits during
 404               "make check"])
 405   else
 406     ac_res_limits=no
 407   fi
 408   AC_MSG_RESULT($ac_res_limits)
 409 ])
 410
 411
 412 dnl
 413 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 414 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 415 dnl
 416 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 417   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 418   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 419     AC_TRY_LINK(
 420       [#include <sys/stat.h>],
 421       [struct stat buffer;
 422        fstat(0, &buffer);
 423        S_ISREG(buffer.st_mode);],
 424       [glibcxx_cv_S_ISREG=yes],
 425       [glibcxx_cv_S_ISREG=no])
 426   ])
 427   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 428     AC_TRY_LINK(
 429       [#include <sys/stat.h>],
 430       [struct stat buffer;
 431        fstat(0, &buffer);
 432        S_IFREG & buffer.st_mode;],
 433       [glibcxx_cv_S_IFREG=yes],
 434       [glibcxx_cv_S_IFREG=no])
 435   ])
 436   res=no
 437   if test $glibcxx_cv_S_ISREG = yes; then
 438     AC_DEFINE(HAVE_S_ISREG, 1,
 439               [Define if S_IFREG is available in <sys/stat.h>.])
 440     res=S_ISREG
 441   elif test $glibcxx_cv_S_IFREG = yes; then
 442     AC_DEFINE(HAVE_S_IFREG, 1,
 443               [Define if S_IFREG is available in <sys/stat.h>.])
 444     res=S_IFREG
 445   fi
 446   AC_MSG_RESULT($res)
 447 ])
 448
 449
 450 dnl
 451 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 452 dnl
 453 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 454   AC_MSG_CHECKING([for poll])
 455   AC_CACHE_VAL(glibcxx_cv_POLL, [
 456     AC_TRY_LINK(
 457       [#include <poll.h>],
 458       [struct pollfd pfd[1];
 459        pfd[0].events = POLLIN;
 460        poll(pfd, 1, 0);],
 461       [glibcxx_cv_POLL=yes],
 462       [glibcxx_cv_POLL=no])
 463   ])
 464   if test $glibcxx_cv_POLL = yes; then
 465     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 466   fi
 467   AC_MSG_RESULT($glibcxx_cv_POLL)
 468 ])
 469
 470
 471 dnl
 472 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 473 dnl
 474 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 475   AC_MSG_CHECKING([for writev])
 476   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 477     AC_TRY_LINK(
 478       [#include <sys/uio.h>],
 479       [struct iovec iov[2];
 480        writev(0, iov, 0);],
 481       [glibcxx_cv_WRITEV=yes],
 482       [glibcxx_cv_WRITEV=no])
 483   ])
 484   if test $glibcxx_cv_WRITEV = yes; then
 485     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 486   fi
 487   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 488 ])
 489
 490
 491 dnl
 492 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 493 dnl
 494 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 495   AC_MSG_CHECKING([for int64_t])
 496   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 497     AC_TRY_COMPILE(
 498       [#include <stdint.h>],
 499       [int64_t var;],
 500       [glibcxx_cv_INT64_T=yes],
 501       [glibcxx_cv_INT64_T=no])
 502   ])
 503   if test $glibcxx_cv_INT64_T = yes; then
 504     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 505   fi
 506   AC_MSG_RESULT($glibcxx_cv_INT64_T)
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether LFS support is available.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 514   AC_LANG_SAVE
 515   AC_LANG_CPLUSPLUS
 516   ac_save_CXXFLAGS="$CXXFLAGS"
 517   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 518   AC_MSG_CHECKING([for LFS support])
 519   AC_CACHE_VAL(glibcxx_cv_LFS, [
 520     AC_TRY_LINK(
 521       [#include <unistd.h>
 522        #include <stdio.h>
 523        #include <sys/stat.h>
 524       ],
 525       [FILE* fp;
 526        fopen64("t", "w");
 527        fseeko64(fp, 0, SEEK_CUR);
 528        ftello64(fp);
 529        lseek64(1, 0, SEEK_CUR);
 530        struct stat64 buf;
 531        fstat64(1, &buf);],
 532       [glibcxx_cv_LFS=yes],
 533       [glibcxx_cv_LFS=no])
 534   ])
 535   if test $glibcxx_cv_LFS = yes; then
 536     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 537   fi
 538   AC_MSG_RESULT($glibcxx_cv_LFS)
 539   CXXFLAGS="$ac_save_CXXFLAGS"
 540   AC_LANG_RESTORE
 541 ])
 542
 543
 544 dnl
 545 dnl Check for whether a fully dynamic basic_string implementation should
 546 dnl be turned on, that does not put empty objects in per-process static
 547 dnl memory (mostly useful together with shared memory allocators, see PR
 548 dnl libstdc++/16612 for details).
 549 dnl
 550 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 551 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 552 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 553 dnl       Where DEFAULT is either `yes' or `no'.
 554 dnl
 555 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 556   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 557   if test $enable_fully_dynamic_string = yes; then
 558     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING, 1,
 559               [Define if a fully dynamic basic_string is wanted.])
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Does any necessary configuration of the testsuite directory.  Generates
 566 dnl the testsuite_hooks.h header.
 567 dnl
 568 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 569 dnl
 570 dnl Sets:
 571 dnl  enable_abi_check
 572 dnl  GLIBCXX_TEST_WCHAR_T
 573 dnl  GLIBCXX_TEST_THREAD
 574 dnl Substs:
 575 dnl  baseline_dir
 576 dnl
 577 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 578   if $GLIBCXX_IS_NATIVE ; then
 579     # Do checks for resource limit functions.
 580     GLIBCXX_CHECK_SETRLIMIT
 581
 582     # Look for setenv, so that extended locale tests can be performed.
 583     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 584   fi
 585
 586   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 587      test $enable_symvers != no; then
 588     case "$host" in
 589       *-*-cygwin*)
 590         enable_abi_check=no ;;
 591       *)
 592         enable_abi_check=yes ;;
 593     esac
 594   else
 595     # Only build this as native, since automake does not understand
 596     # CXX_FOR_BUILD.
 597     enable_abi_check=no
 598   fi
 599
 600   # Export file names for ABI checking.
 601   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}\$(MULTISUBDIR)"
 602   AC_SUBST(baseline_dir)
 603 ])
 604
 605
 606 dnl
 607 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 608 dnl
 609 dnl Substs:
 610 dnl  GLIBCXX_INCLUDES
 611 dnl  TOPLEVEL_INCLUDES
 612 dnl
 613 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 614   # Used for every C++ compile we perform.
 615   GLIBCXX_INCLUDES="\
 616 -I$glibcxx_builddir/include/$host_alias \
 617 -I$glibcxx_builddir/include \
 618 -I$glibcxx_srcdir/libsupc++"
 619
 620   # For Canadian crosses, pick this up too.
 621   if test $CANADIAN = yes; then
 622     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 623   fi
 624
 625   # Stuff in the actual top level.  Currently only used by libsupc++ to
 626   # get unwind* headers from the gcc dir.
 627   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 628   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 629
 630   # Now, export this to all the little Makefiles....
 631   AC_SUBST(GLIBCXX_INCLUDES)
 632   AC_SUBST(TOPLEVEL_INCLUDES)
 633 ])
 634
 635
 636 dnl
 637 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 638 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 639 dnl
 640 dnl Substs:
 641 dnl  OPTIMIZE_CXXFLAGS
 642 dnl  WARN_FLAGS
 643 dnl
 644 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 645   # Optimization flags that are probably a good idea for thrill-seekers. Just
 646   # uncomment the lines below and make, everything else is ready to go...
 647   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 648   OPTIMIZE_CXXFLAGS=
 649   AC_SUBST(OPTIMIZE_CXXFLAGS)
 650
 651   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 652   AC_SUBST(WARN_FLAGS)
 653 ])
 654
 655
 656 dnl
 657 dnl All installation directory information is determined here.
 658 dnl
 659 dnl Substs:
 660 dnl  gxx_install_dir
 661 dnl  glibcxx_prefixdir
 662 dnl  glibcxx_toolexecdir
 663 dnl  glibcxx_toolexeclibdir
 664 dnl
 665 dnl Assumes cross_compiling bits already done, and with_cross_host in
 666 dnl particular.
 667 dnl
 668 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 669   glibcxx_toolexecdir=no
 670   glibcxx_toolexeclibdir=no
 671   glibcxx_prefixdir=$prefix
 672
 673   AC_MSG_CHECKING([for gxx-include-dir])
 674   AC_ARG_WITH([gxx-include-dir],
 675     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 676                    [installation directory for include files]),
 677     [case "$withval" in
 678       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 679       no)  gxx_include_dir=no ;;
 680       *)   gxx_include_dir=$withval ;;
 681      esac],
 682     [gxx_include_dir=no])
 683   AC_MSG_RESULT($gxx_include_dir)
 684
 685   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 686   AC_ARG_ENABLE([version-specific-runtime-libs],
 687     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 688                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 689     [case "$enableval" in
 690       yes) version_specific_libs=yes ;;
 691       no)  version_specific_libs=no ;;
 692       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 693      esac],
 694     [version_specific_libs=no])
 695   AC_MSG_RESULT($version_specific_libs)
 696
 697   # Default case for install directory for include files.
 698   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 699     gxx_include_dir='${prefix}/include/c++/${gcc_version}'
 700   fi
 701
 702   # Version-specific runtime libs processing.
 703   if test $version_specific_libs = yes; then
 704     # Need the gcc compiler version to know where to install libraries
 705     # and header files if --enable-version-specific-runtime-libs option
 706     # is selected.  FIXME: these variables are misnamed, there are
 707     # no executables installed in _toolexecdir or _toolexeclibdir.
 708     if test x"$gxx_include_dir" = x"no"; then
 709       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 710     fi
 711     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 712     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 713   fi
 714
 715   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 716   # Install a library built with a cross compiler in tooldir, not libdir.
 717   if test x"$glibcxx_toolexecdir" = x"no"; then
 718     if test -n "$with_cross_host" &&
 719        test x"$with_cross_host" != x"no"; then
 720       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 721       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 722     else
 723       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 724       glibcxx_toolexeclibdir='${libdir}'
 725     fi
 726     multi_os_directory=`$CXX -print-multi-os-directory`
 727     case $multi_os_directory in
 728       .) ;; # Avoid trailing /.
 729       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 730     esac
 731   fi
 732
 733   AC_MSG_CHECKING([for install location])
 734   AC_MSG_RESULT($gxx_include_dir)
 735
 736   AC_SUBST(glibcxx_prefixdir)
 737   AC_SUBST(gxx_include_dir)
 738   AC_SUBST(glibcxx_toolexecdir)
 739   AC_SUBST(glibcxx_toolexeclibdir)
 740 ])
 741
 742
 743 dnl
 744 dnl GLIBCXX_ENABLE
 745 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 746 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 747 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 748 dnl
 749 dnl See docs/html/17_intro/configury.html#enable for documentation.
 750 dnl
 751 m4_define([GLIBCXX_ENABLE],[dnl
 752 m4_define([_g_switch],[--enable-$1])dnl
 753 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 754  AC_ARG_ENABLE($1,_g_help,
 755   m4_bmatch([$5],
 756    [^permit ],
 757      [[
 758       case "$enableval" in
 759        m4_bpatsubst([$5],[permit ])) ;;
 760        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 761           dnl Idea for future:  generate a URL pointing to
 762           dnl "onlinedocs/configopts.html#whatever"
 763       esac
 764      ]],
 765    [^$],
 766      [[
 767       case "$enableval" in
 768        yes|no) ;;
 769        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 770       esac
 771      ]],
 772    [[$5]]),
 773   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 774 m4_undefine([_g_switch])dnl
 775 m4_undefine([_g_help])dnl
 776 ])
 777
 778
 779 dnl
 780 dnl Check for ISO/IEC 9899:1999 "C99" support.
 781 dnl
 782 dnl --enable-c99 defines _GLIBCXX_USE_C99
 783 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 784 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 785 dnl       Where DEFAULT is either `yes' or `no'.
 786 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 787 dnl
 788 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 789   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 790
 791   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos
 792   # even if C99 support is turned off.
 793   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 794   AC_MSG_CHECKING([for mbstate_t])
 795   AC_TRY_COMPILE([#include <wchar.h>],
 796   [mbstate_t teststate;],
 797   have_mbstate_t=yes, have_mbstate_t=no)
 798   AC_MSG_RESULT($have_mbstate_t)
 799   if test x"$have_mbstate_t" = xyes; then
 800     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 801   fi
 802
 803   if test x"$enable_c99" = x"yes"; then
 804
 805   AC_LANG_SAVE
 806   AC_LANG_CPLUSPLUS
 807
 808   # Check for the existence of <math.h> functions used if C99 is enabled.
 809   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 810   AC_CACHE_VAL(ac_c99_math, [
 811   AC_TRY_COMPILE([#include <math.h>],
 812                  [fpclassify(0.0);
 813                   isfinite(0.0);
 814                   isinf(0.0);
 815                   isnan(0.0);
 816                   isnormal(0.0);
 817                   signbit(0.0);
 818                   isgreater(0.0,0.0);
 819                   isgreaterequal(0.0,0.0);
 820                   isless(0.0,0.0);
 821                   islessequal(0.0,0.0);
 822                   islessgreater(0.0,0.0);
 823                   islessgreater(0.0,0.0);
 824                   isunordered(0.0,0.0);
 825                  ],[ac_c99_math=yes], [ac_c99_math=no])
 826   ])
 827   AC_MSG_RESULT($ac_c99_math)
 828   if test x"$ac_c99_math" = x"yes"; then
 829     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 830               [Define if C99 functions or macros in <math.h> should be imported
 831               in <cmath> in namespace std.])
 832   fi
 833
 834   # Check for the existence of <complex.h> complex math functions.
 835   # This is necessary even though libstdc++ uses the builtin versions
 836   # of these functions, because if the builtin cannot be used, a reference
 837   # to the library function is emitted.
 838   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 839   ac_c99_complex=no;
 840   if test x"$ac_has_complex_h" = x"yes"; then
 841     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 842     AC_TRY_COMPILE([#include <complex.h>],
 843                    [typedef __complex__ float float_type; float_type tmpf;
 844                     cabsf(tmpf);
 845                     cargf(tmpf);
 846                     ccosf(tmpf);
 847                     ccoshf(tmpf);
 848                     cexpf(tmpf);
 849                     clogf(tmpf);
 850                     csinf(tmpf);
 851                     csinhf(tmpf);
 852                     csqrtf(tmpf);
 853                     ctanf(tmpf);
 854                     ctanhf(tmpf);
 855                     cpowf(tmpf, tmpf);
 856                     typedef __complex__ double double_type; double_type tmpd;
 857                     cabs(tmpd);
 858                     carg(tmpd);
 859                     ccos(tmpd);
 860                     ccosh(tmpd);
 861                     cexp(tmpd);
 862                     clog(tmpd);
 863                     csin(tmpd);
 864                     csinh(tmpd);
 865                     csqrt(tmpd);
 866                     ctan(tmpd);
 867                     ctanh(tmpd);
 868                     cpow(tmpd, tmpd);
 869                     typedef __complex__ long double ld_type; ld_type tmpld;
 870                     cabsl(tmpld);
 871                     cargl(tmpld);
 872                     ccosl(tmpld);
 873                     ccoshl(tmpld);
 874                     cexpl(tmpld);
 875                     clogl(tmpld);
 876                     csinl(tmpld);
 877                     csinhl(tmpld);
 878                     csqrtl(tmpld);
 879                     ctanl(tmpld);
 880                     ctanhl(tmpld);
 881                     cpowl(tmpld, tmpld);
 882                    ],[ac_c99_complex=yes], [ac_c99_complex=no])
 883   fi
 884   AC_MSG_RESULT($ac_c99_complex)
 885   if test x"$ac_c99_complex" = x"yes"; then
 886     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 887               [Define if C99 functions in <complex.h> should be used in
 888               <complex>. Using compiler builtins for these functions requires
 889               corresponding C99 library functions to be present.])
 890   fi
 891
 892   # Check for the existence in <stdio.h> of vscanf, et. al.
 893   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 894   AC_CACHE_VAL(ac_c99_stdio, [
 895   AC_TRY_COMPILE([#include <stdio.h>
 896                   #include <stdarg.h>
 897                   void foo(char* fmt, ...)
 898                   {
 899                     va_list args; va_start(args, fmt);
 900                     vfscanf(stderr, "%i", args);
 901                     vscanf("%i", args);
 902                     vsnprintf(fmt, 0, "%i", args);
 903                     vsscanf(fmt, "%i", args);
 904                   }],
 905                  [snprintf("12", 0, "%i");],
 906                  [ac_c99_stdio=yes], [ac_c99_stdio=no])
 907   ])
 908   AC_MSG_RESULT($ac_c99_stdio)
 909
 910   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 911   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 912   AC_CACHE_VAL(ac_c99_stdlib, [
 913   AC_TRY_COMPILE([#include <stdlib.h>],
 914                  [char* tmp;
 915                   strtof("gnu", &tmp);
 916                   strtold("gnu", &tmp);
 917                   strtoll("gnu", &tmp, 10);
 918                   strtoull("gnu", &tmp, 10);
 919                   llabs(10);
 920                   lldiv(10,1);
 921                   atoll("10");
 922                   _Exit(0);
 923                   lldiv_t mydivt;],[ac_c99_stdlib=yes], [ac_c99_stdlib=no])
 924   ])
 925   AC_MSG_RESULT($ac_c99_stdlib)
 926
 927   # Check for the existence in <wchar.h> of wcstoull, WEOF, etc.
 928   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 929   ac_c99_wchar=no;
 930   if test x"$ac_has_wchar_h" = xyes &&
 931      test x"$ac_has_wctype_h" = xyes; then
 932     AC_TRY_COMPILE([#include <wchar.h>
 933                     #include <stddef.h>
 934                     wint_t i;
 935                     long l = WEOF;
 936                     long j = WCHAR_MIN;
 937                     long k = WCHAR_MAX;
 938                     namespace test
 939                     {
 940                       using ::btowc;
 941                       using ::fgetwc;
 942                       using ::fgetws;
 943                       using ::fputwc;
 944                       using ::fputws;
 945                       using ::fwide;
 946                       using ::fwprintf;
 947                       using ::fwscanf;
 948                       using ::getwc;
 949                       using ::getwchar;
 950                       using ::mbrlen;
 951                       using ::mbrtowc;
 952                       using ::mbsinit;
 953                       using ::mbsrtowcs;
 954                       using ::putwc;
 955                       using ::putwchar;
 956                       using ::swprintf;
 957                       using ::swscanf;
 958                       using ::ungetwc;
 959                       using ::vfwprintf;
 960                       using ::vswprintf;
 961                       using ::vwprintf;
 962                       using ::wcrtomb;
 963                       using ::wcscat;
 964                       using ::wcschr;
 965                       using ::wcscmp;
 966                       using ::wcscoll;
 967                       using ::wcscpy;
 968                       using ::wcscspn;
 969                       using ::wcsftime;
 970                       using ::wcslen;
 971                       using ::wcsncat;
 972                       using ::wcsncmp;
 973                       using ::wcsncpy;
 974                       using ::wcspbrk;
 975                       using ::wcsrchr;
 976                       using ::wcsrtombs;
 977                       using ::wcsspn;
 978                       using ::wcsstr;
 979                       using ::wcstod;
 980                       using ::wcstok;
 981                       using ::wcstol;
 982                       using ::wcstold;
 983                       using ::wcstoll;
 984                       using ::wcstoul;
 985                       using ::wcstoull;
 986                       using ::wcsxfrm;
 987                       using ::wctob;
 988                       using ::wmemchr;
 989                       using ::wmemcmp;
 990                       using ::wmemcpy;
 991                       using ::wmemmove;
 992                       using ::wmemset;
 993                       using ::wprintf;
 994                       using ::wscanf;
 995                     }
 996                    ],[],[ac_c99_wchar=yes], [ac_c99_wchar=no])
 997
 998     # Checks for wide character functions that may not be present.
 999     # Injection of these is wrapped with guard macros.
1000     # NB: only put functions here, instead of immediately above, if
1001     # absolutely necessary.
1002     AC_TRY_COMPILE([#include <wchar.h>
1003                     namespace test { using ::vfwscanf; } ], [],
1004                    [AC_DEFINE(HAVE_VFWSCANF,1,
1005                         [Defined if vfwscanf exists.])],[])
1006
1007     AC_TRY_COMPILE([#include <wchar.h>
1008                     namespace test { using ::vswscanf; } ], [],
1009                    [AC_DEFINE(HAVE_VSWSCANF,1,
1010                         [Defined if vswscanf exists.])],[])
1011
1012     AC_TRY_COMPILE([#include <wchar.h>
1013                     namespace test { using ::vwscanf; } ], [],
1014                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1015
1016     AC_TRY_COMPILE([#include <wchar.h>
1017                     namespace test { using ::wcstof; } ], [],
1018                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1019
1020     AC_TRY_COMPILE([#include <wctype.h>],
1021                    [ wint_t t; int i = iswblank(t);],
1022                    [AC_DEFINE(HAVE_ISWBLANK,1,
1023                         [Defined if iswblank exists.])],[])
1024
1025     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1026     AC_MSG_RESULT($ac_c99_wchar)
1027   fi
1028
1029   # Option parsed, now set things appropriately.
1030   if test x"$ac_c99_math" = x"no" ||
1031      test x"$ac_c99_complex" = x"no" ||
1032      test x"$ac_c99_stdio" = x"no" ||
1033      test x"$ac_c99_stdlib" = x"no" ||
1034      test x"$ac_c99_wchar" = x"no"; then
1035     enable_c99=no;
1036   else
1037     AC_DEFINE(_GLIBCXX_USE_C99, 1,
1038     [Define if C99 functions or macros from <wchar.h>, <math.h>,
1039     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1040   fi
1041
1042   AC_LANG_RESTORE
1043   fi
1044
1045   AC_MSG_CHECKING([for fully enabled ISO C99 support])
1046   AC_MSG_RESULT($enable_c99)
1047 ])
1048
1049
1050 dnl
1051 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1052 dnl facilities in Chapter 8, "C compatibility".
1053 dnl
1054 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1055
1056   AC_LANG_SAVE
1057   AC_LANG_CPLUSPLUS
1058
1059   # Check for the existence of <complex.h> complex math functions used
1060   # by tr1/complex.
1061   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1062   ac_c99_complex_tr1=no;
1063   if test x"$ac_has_complex_h" = x"yes"; then
1064     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1065     AC_TRY_COMPILE([#include <complex.h>],
1066                    [typedef __complex__ float float_type; float_type tmpf;
1067                     cacosf(tmpf);
1068                     casinf(tmpf);
1069                     catanf(tmpf);
1070                     cacoshf(tmpf);
1071                     casinhf(tmpf);
1072                     catanhf(tmpf);
1073                     typedef __complex__ double double_type; double_type tmpd;
1074                     cacos(tmpd);
1075                     casin(tmpd);
1076                     catan(tmpd);
1077                     cacosh(tmpd);
1078                     casinh(tmpd);
1079                     catanh(tmpd);
1080                     typedef __complex__ long double ld_type; ld_type tmpld;
1081                     cacosl(tmpld);
1082                     casinl(tmpld);
1083                     catanl(tmpld);
1084                     cacoshl(tmpld);
1085                     casinhl(tmpld);
1086                     catanhl(tmpld);
1087                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1088   fi
1089   AC_MSG_RESULT($ac_c99_complex_tr1)
1090   if test x"$ac_c99_complex_tr1" = x"yes"; then
1091     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1092               [Define if C99 functions in <complex.h> should be used in
1093               <tr1/complex>. Using compiler builtins for these functions
1094               requires corresponding C99 library functions to be present.])
1095   fi
1096
1097   # Check for the existence of <ctype.h> functions.
1098   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1099   AC_CACHE_VAL(ac_c99_ctype_tr1, [
1100   AC_TRY_COMPILE([#include <ctype.h>],
1101                  [int ch;
1102                   int ret;
1103                   ret = isblank(ch);
1104                  ],[ac_c99_ctype_tr1=yes], [ac_c99_ctype_tr1=no])
1105   ])
1106   AC_MSG_RESULT($ac_c99_ctype_tr1)
1107   if test x"$ac_c99_ctype_tr1" = x"yes"; then
1108     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1109               [Define if C99 functions in <ctype.h> should be imported in
1110               <tr1/cctype> in namespace std::tr1.])
1111   fi
1112
1113   # Check for the existence of <fenv.h> functions.
1114   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1115   ac_c99_fenv_tr1=no;
1116   if test x"$ac_has_fenv_h" = x"yes"; then
1117     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1118     AC_TRY_COMPILE([#include <fenv.h>],
1119                    [int except, mode;
1120                     fexcept_t* pflag;
1121                     fenv_t* penv;
1122                     int ret;
1123                     ret = feclearexcept(except);
1124                     ret = fegetexceptflag(pflag, except);
1125                     ret = feraiseexcept(except);
1126                     ret = fesetexceptflag(pflag, except);
1127                     ret = fetestexcept(except);
1128                     ret = fegetround();
1129                     ret = fesetround(mode);
1130                     ret = fegetenv(penv);
1131                     ret = feholdexcept(penv);
1132                     ret = fesetenv(penv);
1133                     ret = feupdateenv(penv);
1134                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1135   fi
1136   AC_MSG_RESULT($ac_c99_fenv_tr1)
1137   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1138     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1139               [Define if C99 functions in <fenv.h> should be imported in
1140               <tr1/cfenv> in namespace std::tr1.])
1141   fi
1142
1143   # Check for the existence of <stdint.h> types.
1144   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1145   AC_CACHE_VAL(ac_c99_stdint_tr1, [
1146   AC_TRY_COMPILE([#include <stdint.h>],
1147                  [typedef int8_t          my_int8_t;
1148                   typedef int16_t         my_int16_t;
1149                   typedef int32_t         my_int32_t;
1150                   typedef int64_t         my_int64_t;
1151                   typedef int_fast8_t     my_int_fast8_t;
1152                   typedef int_fast16_t    my_int_fast16_t;
1153                   typedef int_fast32_t    my_int_fast32_t;
1154                   typedef int_fast64_t    my_int_fast64_t;
1155                   typedef int_least8_t    my_int_least8_t;
1156                   typedef int_least16_t   my_int_least16_t;
1157                   typedef int_least32_t   my_int_least32_t;
1158                   typedef int_least64_t   my_int_least64_t;
1159                   typedef intmax_t        my_intmax_t;
1160                   typedef intptr_t        my_intptr_t;
1161                   typedef uint8_t         my_uint8_t;
1162                   typedef uint16_t        my_uint16_t;
1163                   typedef uint32_t        my_uint32_t;
1164                   typedef uint64_t        my_uint64_t;
1165                   typedef uint_fast8_t    my_uint_fast8_t;
1166                   typedef uint_fast16_t   my_uint_fast16_t;
1167                   typedef uint_fast32_t   my_uint_fast32_t;
1168                   typedef uint_fast64_t   my_uint_fast64_t;
1169                   typedef uint_least8_t   my_uint_least8_t;
1170                   typedef uint_least16_t  my_uint_least16_t;
1171                   typedef uint_least32_t  my_uint_least32_t;
1172                   typedef uint_least64_t  my_uint_least64_t;
1173                   typedef uintmax_t       my_uintmax_t;
1174                   typedef uintptr_t       my_uintptr_t;
1175                  ],[ac_c99_stdint_tr1=yes], [ac_c99_stdint_tr1=no])
1176   ])
1177   AC_MSG_RESULT($ac_c99_stdint_tr1)
1178   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1179     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1180               [Define if C99 types in <stdint.h> should be imported in
1181               <tr1/cstdint> in namespace std::tr1.])
1182   fi
1183
1184   # Check for the existence of <math.h> functions.
1185   AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1186   AC_CACHE_VAL(ac_c99_math_tr1, [
1187   AC_TRY_COMPILE([#include <math.h>],
1188                  [acosh(0.0);
1189                   acoshf(0.0f);
1190                   acoshl(0.0l);
1191                   asinh(0.0);
1192                   asinhf(0.0f);
1193                   asinhl(0.0l);
1194                   atanh(0.0);
1195                   atanhf(0.0f);
1196                   atanhl(0.0l);
1197                   cbrt(0.0);
1198                   cbrtf(0.0f);
1199                   cbrtl(0.0l);
1200                   copysign(0.0, 0.0);
1201                   copysignf(0.0f, 0.0f);
1202                   copysignl(0.0l, 0.0l);
1203                   erf(0.0);
1204                   erff(0.0f);
1205                   erfl(0.0l);
1206                   erfc(0.0);
1207                   erfcf(0.0f);
1208                   erfcl(0.0l);
1209                   exp2(0.0);
1210                   exp2f(0.0f);
1211                   exp2l(0.0l);
1212                   expm1(0.0);
1213                   expm1f(0.0f);
1214                   expm1l(0.0l);
1215                   fdim(0.0, 0.0);
1216                   fdimf(0.0f, 0.0f);
1217                   fdiml(0.0l, 0.0l);
1218                   fma(0.0, 0.0, 0.0);
1219                   fmaf(0.0f, 0.0f, 0.0f);
1220                   fmal(0.0l, 0.0l, 0.0l);
1221                   fmax(0.0, 0.0);
1222                   fmaxf(0.0f, 0.0f);
1223                   fmaxl(0.0l, 0.0l);
1224                   fmin(0.0, 0.0);
1225                   fminf(0.0f, 0.0f);
1226                   fminl(0.0l, 0.0l);
1227                   hypot(0.0, 0.0);
1228                   hypotf(0.0f, 0.0f);
1229                   hypotl(0.0l, 0.0l);
1230                   ilogb(0.0);
1231                   ilogbf(0.0f);
1232                   ilogbl(0.0l);
1233                   lgamma(0.0);
1234                   lgammaf(0.0f);
1235                   lgammal(0.0l);
1236                   llrint(0.0);
1237                   llrintf(0.0f);
1238                   llrintl(0.0l);
1239                   llround(0.0);
1240                   llroundf(0.0f);
1241                   llroundl(0.0l);
1242                   log1p(0.0);
1243                   log1pf(0.0f);
1244                   log1pl(0.0l);
1245                   log2(0.0);
1246                   log2f(0.0f);
1247                   log2l(0.0l);
1248                   logb(0.0);
1249                   logbf(0.0f);
1250                   logbl(0.0l);
1251                   lrint(0.0);
1252                   lrintf(0.0f);
1253                   lrintl(0.0l);
1254                   lround(0.0);
1255                   lroundf(0.0f);
1256                   lroundl(0.0l);
1257                   nan(0);
1258                   nanf(0);
1259                   nanl(0);
1260                   nearbyint(0.0);
1261                   nearbyintf(0.0f);
1262                   nearbyintl(0.0l);
1263                   nextafter(0.0, 0.0);
1264                   nextafterf(0.0f, 0.0f);
1265                   nextafterl(0.0l, 0.0l);
1266                   nexttoward(0.0, 0.0);
1267                   nexttowardf(0.0f, 0.0f);
1268                   nexttowardl(0.0l, 0.0l);
1269                   remainder(0.0, 0.0);
1270                   remainderf(0.0f, 0.0f);
1271                   remainderl(0.0l, 0.0l);
1272                   remquo(0.0, 0.0, 0);
1273                   remquo(0.0f, 0.0f, 0);
1274                   remquo(0.0l, 0.0l, 0);
1275                   rint(0.0);
1276                   rintf(0.0f);
1277                   rintl(0.0l);
1278                   round(0.0);
1279                   roundf(0.0f);
1280                   roundl(0.0l);
1281                   scalbln(0.0, 0l);
1282                   scalblnf(0.0f, 0l);
1283                   scalblnl(0.0l, 0l);
1284                   scalbn(0.0, 0);
1285                   scalbnf(0.0f, 0);
1286                   scalbnl(0.0l, 0);
1287                   tgamma(0.0);
1288                   tgammaf(0.0f);
1289                   tgammal(0.0l);
1290                   trunc(0.0);
1291                   truncf(0.0f);
1292                   truncl(0.0l);
1293                  ],[ac_c99_math_tr1=yes], [ac_c99_math_tr1=no])
1294   ])
1295   AC_MSG_RESULT($ac_c99_math_tr1)
1296   if test x"$ac_c99_math_tr1" = x"yes"; then
1297     AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1298               [Define if C99 functions or macros in <math.h> should be imported
1299               in <tr1/cmath> in namespace std::tr1.])
1300   fi
1301
1302   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1303   # sense if the previous check fails, per C99, 7.8/1).
1304   ac_c99_inttypes_tr1=no;
1305   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1306     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1307     AC_TRY_COMPILE([#include <inttypes.h>],
1308                    [intmax_t i, numer, denom, base;
1309                     const char* s;
1310                     char** endptr;
1311                     intmax_t ret = imaxabs(i);
1312                     imaxdiv_t dret = imaxdiv(numer, denom);
1313                     ret = strtoimax(s, endptr, base);
1314                     uintmax_t uret = strtoumax(s, endptr, base);
1315                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1316   fi
1317   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1318   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1319     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1320               [Define if C99 functions in <inttypes.h> should be imported in
1321               <tr1/cinttypes> in namespace std::tr1.])
1322   fi
1323
1324   AC_LANG_RESTORE
1325 ])
1326
1327
1328 dnl
1329 dnl Check for what type of C headers to use.
1330 dnl
1331 dnl --enable-cheaders= [does stuff].
1332 dnl --disable-cheaders [does not do anything, really].
1333 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1334 dnl       Where DEFAULT is either `c' or `c_std'.
1335 dnl
1336 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1337   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1338     [construct "C" headers for g++], [permit c|c_std])
1339   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1340
1341   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1342
1343   AC_SUBST(C_INCLUDE_DIR)
1344   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1345   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1346   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1347 ])
1348
1349
1350 dnl
1351 dnl Check for which locale library to use.  The choice is mapped to
1352 dnl a subdirectory of config/locale.
1353 dnl
1354 dnl Default is generic.
1355 dnl
1356 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1357   AC_MSG_CHECKING([for C locale to use])
1358   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1359     [use MODEL for target locale package],
1360     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1361
1362   # If they didn't use this option switch, or if they specified --enable
1363   # with no specific model, we'll have to look for one.  If they
1364   # specified --disable (???), do likewise.
1365   if test $enable_clocale = no || test $enable_clocale = yes; then
1366      enable_clocale=auto
1367   fi
1368
1369   # Either a known package, or "auto"
1370   enable_clocale_flag=$enable_clocale
1371
1372   # Probe for locale support if no specific model is specified.
1373   # Default to "generic".
1374   if test $enable_clocale_flag = auto; then
1375     case ${target_os} in
1376       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1377         AC_EGREP_CPP([_GLIBCXX_ok], [
1378         #include <features.h>
1379         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1380           _GLIBCXX_ok
1381         #endif
1382         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1383
1384         # Test for bugs early in glibc-2.2.x series
1385           if test $enable_clocale_flag = gnu; then
1386           AC_TRY_RUN([
1387           #define _GNU_SOURCE 1
1388           #include <locale.h>
1389           #include <string.h>
1390           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1391           extern __typeof(newlocale) __newlocale;
1392           extern __typeof(duplocale) __duplocale;
1393           extern __typeof(strcoll_l) __strcoll_l;
1394           #endif
1395           int main()
1396           {
1397               const char __one[] = "Äuglein Augmen";
1398               const char __two[] = "Äuglein";
1399               int i;
1400               int j;
1401               __locale_t        loc;
1402                __locale_t        loc_dup;
1403               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1404               loc_dup = __duplocale(loc);
1405               i = __strcoll_l(__one, __two, loc);
1406               j = __strcoll_l(__one, __two, loc_dup);
1407               return 0;
1408           }
1409           ],
1410           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1411           [enable_clocale_flag=generic])
1412           fi
1413
1414         # ... at some point put __strxfrm_l tests in as well.
1415         ;;
1416       darwin* | freebsd*)
1417         enable_clocale_flag=darwin
1418         ;;
1419       *)
1420         enable_clocale_flag=generic
1421         ;;
1422     esac
1423   fi
1424
1425   # Deal with gettext issues.  Default to not using it (=no) until we detect
1426   # support for it later.  Let the user turn it off via --e/d, but let that
1427   # default to on for easier handling.
1428   USE_NLS=no
1429   AC_ARG_ENABLE(nls,
1430     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1431     [],
1432     [enable_nls=yes])
1433
1434   # Set configure bits for specified locale package
1435   case ${enable_clocale_flag} in
1436     generic)
1437       AC_MSG_RESULT(generic)
1438
1439       CLOCALE_H=config/locale/generic/c_locale.h
1440       CLOCALE_CC=config/locale/generic/c_locale.cc
1441       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1442       CCOLLATE_CC=config/locale/generic/collate_members.cc
1443       CCTYPE_CC=config/locale/generic/ctype_members.cc
1444       CMESSAGES_H=config/locale/generic/messages_members.h
1445       CMESSAGES_CC=config/locale/generic/messages_members.cc
1446       CMONEY_CC=config/locale/generic/monetary_members.cc
1447       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1448       CTIME_H=config/locale/generic/time_members.h
1449       CTIME_CC=config/locale/generic/time_members.cc
1450       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1451       ;;
1452     darwin)
1453       AC_MSG_RESULT(darwin or freebsd)
1454
1455       CLOCALE_H=config/locale/generic/c_locale.h
1456       CLOCALE_CC=config/locale/generic/c_locale.cc
1457       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1458       CCOLLATE_CC=config/locale/generic/collate_members.cc
1459       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1460       CMESSAGES_H=config/locale/generic/messages_members.h
1461       CMESSAGES_CC=config/locale/generic/messages_members.cc
1462       CMONEY_CC=config/locale/generic/monetary_members.cc
1463       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1464       CTIME_H=config/locale/generic/time_members.h
1465       CTIME_CC=config/locale/generic/time_members.cc
1466       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1467       ;;
1468
1469     gnu)
1470       AC_MSG_RESULT(gnu)
1471
1472       # Declare intention to use gettext, and add support for specific
1473       # languages.
1474       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1475       ALL_LINGUAS="de fr"
1476
1477       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1478       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1479       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1480         USE_NLS=yes
1481       fi
1482       # Export the build objects.
1483       for ling in $ALL_LINGUAS; do \
1484         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1485         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1486       done
1487       AC_SUBST(glibcxx_MOFILES)
1488       AC_SUBST(glibcxx_POFILES)
1489
1490       CLOCALE_H=config/locale/gnu/c_locale.h
1491       CLOCALE_CC=config/locale/gnu/c_locale.cc
1492       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1493       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1494       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1495       CMESSAGES_H=config/locale/gnu/messages_members.h
1496       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1497       CMONEY_CC=config/locale/gnu/monetary_members.cc
1498       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1499       CTIME_H=config/locale/gnu/time_members.h
1500       CTIME_CC=config/locale/gnu/time_members.cc
1501       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1502       ;;
1503     ieee_1003.1-2001)
1504       AC_MSG_RESULT(IEEE 1003.1)
1505
1506       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1507       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1508       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1509       CCOLLATE_CC=config/locale/generic/collate_members.cc
1510       CCTYPE_CC=config/locale/generic/ctype_members.cc
1511       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1512       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1513       CMONEY_CC=config/locale/generic/monetary_members.cc
1514       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1515       CTIME_H=config/locale/generic/time_members.h
1516       CTIME_CC=config/locale/generic/time_members.cc
1517       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1518       ;;
1519   esac
1520
1521   # This is where the testsuite looks for locale catalogs, using the
1522   # -DLOCALEDIR define during testsuite compilation.
1523   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1524   AC_SUBST(glibcxx_localedir)
1525
1526   # A standalone libintl (e.g., GNU libintl) may be in use.
1527   if test $USE_NLS = yes; then
1528     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1529     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1530   fi
1531   if test $USE_NLS = yes; then
1532     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
1533               [Define if NLS translations are to be used.])
1534   fi
1535
1536   AC_SUBST(USE_NLS)
1537   AC_SUBST(CLOCALE_H)
1538   AC_SUBST(CMESSAGES_H)
1539   AC_SUBST(CCODECVT_CC)
1540   AC_SUBST(CCOLLATE_CC)
1541   AC_SUBST(CCTYPE_CC)
1542   AC_SUBST(CMESSAGES_CC)
1543   AC_SUBST(CMONEY_CC)
1544   AC_SUBST(CNUMERIC_CC)
1545   AC_SUBST(CTIME_H)
1546   AC_SUBST(CTIME_CC)
1547   AC_SUBST(CLOCALE_CC)
1548   AC_SUBST(CLOCALE_INTERNAL_H)
1549 ])
1550
1551
1552 dnl
1553 dnl Check for which std::allocator base class to use.  The choice is
1554 dnl mapped from a subdirectory of include/ext.
1555 dnl
1556 dnl Default is new.
1557 dnl
1558 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1559   AC_MSG_CHECKING([for std::allocator base class])
1560   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1561     [use KIND for target std::allocator base],
1562     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1563
1564   # If they didn't use this option switch, or if they specified --enable
1565   # with no specific model, we'll have to look for one.  If they
1566   # specified --disable (???), do likewise.
1567   if test $enable_libstdcxx_allocator = no ||
1568      test $enable_libstdcxx_allocator = yes;
1569   then
1570      enable_libstdcxx_allocator=auto
1571   fi
1572
1573   # Either a known package, or "auto". Auto implies the default choice
1574   # for a particular platform.
1575   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1576
1577   # Probe for host-specific support if no specific model is specified.
1578   # Default to "new".
1579   if test $enable_libstdcxx_allocator_flag = auto; then
1580     case ${target_os} in
1581       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1582         enable_libstdcxx_allocator_flag=new
1583         ;;
1584       *)
1585         enable_libstdcxx_allocator_flag=new
1586         ;;
1587     esac
1588   fi
1589   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1590
1591
1592   # Set configure bits for specified locale package
1593   case ${enable_libstdcxx_allocator_flag} in
1594     bitmap)
1595       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1596       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1597       ;;
1598     malloc)
1599       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1600       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1601       ;;
1602     mt)
1603       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1604       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1605       ;;
1606     new)
1607       ALLOCATOR_H=config/allocator/new_allocator_base.h
1608       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1609       ;;
1610     pool)
1611       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1612       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1613       ;;
1614   esac
1615
1616   AC_SUBST(ALLOCATOR_H)
1617   AC_SUBST(ALLOCATOR_NAME)
1618 ])
1619
1620
1621 dnl
1622 dnl Check for whether the Boost-derived checks should be turned on.
1623 dnl
1624 dnl --enable-concept-checks turns them on.
1625 dnl --disable-concept-checks leaves them off.
1626 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1627 dnl       Where DEFAULT is either `yes' or `no'.
1628 dnl
1629 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1630   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1631   if test $enable_concept_checks = yes; then
1632     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
1633               [Define to use concept checking code from the boost libraries.])
1634   fi
1635 ])
1636
1637
1638 dnl
1639 dnl Check for which I/O library to use:  stdio, or something specific.
1640 dnl
1641 dnl Default is stdio.
1642 dnl
1643 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1644   AC_MSG_CHECKING([for underlying I/O to use])
1645   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1646     [use target-specific I/O package], [permit stdio])
1647
1648   # Now that libio has been removed, you can have any color you want as long
1649   # as it's black.  This is one big no-op until other packages are added, but
1650   # showing the framework never hurts.
1651   case ${enable_cstdio} in
1652     stdio)
1653       CSTDIO_H=config/io/c_io_stdio.h
1654       BASIC_FILE_H=config/io/basic_file_stdio.h
1655       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1656       AC_MSG_RESULT(stdio)
1657       ;;
1658   esac
1659
1660   AC_SUBST(CSTDIO_H)
1661   AC_SUBST(BASIC_FILE_H)
1662   AC_SUBST(BASIC_FILE_CC)
1663 ])
1664
1665
1666 dnl
1667 dnl Check for "unusual" flags to pass to the compiler while building.
1668 dnl
1669 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1670 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1671 dnl --disable-cxx-flags passes nothing.
1672 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1673 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1674 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1675 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1676 dnl       If "default flags" is an empty string, the effect is the same
1677 dnl       as --disable or --enable=no.
1678 dnl
1679 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1680   AC_MSG_CHECKING([for extra compiler flags for building])
1681   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1682     [pass compiler FLAGS when building library],
1683     [case "x$enable_cxx_flags" in
1684       xno | x)   enable_cxx_flags= ;;
1685       x-*)       ;;
1686       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1687      esac])
1688
1689   # Run through flags (either default or command-line) and set anything
1690   # extra (e.g., #defines) that must accompany particular g++ options.
1691   if test -n "$enable_cxx_flags"; then
1692     for f in $enable_cxx_flags; do
1693       case "$f" in
1694         -fhonor-std)  ;;
1695         -*)  ;;
1696         *)   # and we're trying to pass /what/ exactly?
1697              AC_MSG_ERROR([compiler flags start with a -]) ;;
1698       esac
1699     done
1700   fi
1701
1702   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1703   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1704   AC_SUBST(EXTRA_CXX_FLAGS)
1705 ])
1706
1707
1708 dnl
1709 dnl Check to see if debugging libraries are to be built.
1710 dnl
1711 dnl --enable-libstdcxx-debug
1712 dnl builds a separate set of debugging libraries in addition to the
1713 dnl normal (shared, static) libstdc++ binaries.
1714 dnl
1715 dnl --disable-libstdcxx-debug
1716 dnl builds only one (non-debug) version of libstdc++.
1717 dnl
1718 dnl --enable-libstdcxx-debug-flags=FLAGS
1719 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1720 dnl
1721 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1722 dnl       Where DEFAULT is either `yes' or `no'.
1723 dnl
1724 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1725   AC_MSG_CHECKING([for additional debug build])
1726   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1727   AC_MSG_RESULT($enable_libstdcxx_debug)
1728   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1729 ])
1730
1731
1732 dnl
1733 dnl Check for explicit debug flags.
1734 dnl
1735 dnl --enable-libstdcxx-debug-flags='-O1'
1736 dnl is a general method for passing flags to be used when
1737 dnl building debug libraries with --enable-debug.
1738 dnl
1739 dnl --disable-libstdcxx-debug-flags does nothing.
1740 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1741 dnl       If "default flags" is an empty string, the effect is the same
1742 dnl       as --disable or --enable=no.
1743 dnl
1744 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1745   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1746     [pass compiler FLAGS when building debug library],
1747     [case "x$enable_libstdcxx_debug_flags" in
1748       xno | x)    enable_libstdcxx_debug_flags= ;;
1749       x-*)        ;;
1750       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1751      esac])
1752
1753   # Option parsed, now set things appropriately
1754   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1755   AC_SUBST(DEBUG_FLAGS)
1756
1757   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1758 ])
1759
1760
1761 dnl
1762 dnl Check if the user only wants a freestanding library implementation.
1763 dnl
1764 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1765 dnl installing only the headers required by [17.4.1.3] and the language
1766 dnl support library.  More than that will be built (to keep the Makefiles
1767 dnl conveniently clean), but not installed.
1768 dnl
1769 dnl Sets:
1770 dnl  is_hosted  (yes/no)
1771 dnl
1772 dnl Defines:
1773 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1774 dnl
1775 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1776   AC_ARG_ENABLE([hosted-libstdcxx],
1777     AC_HELP_STRING([--disable-hosted-libstdcxx],
1778                    [only build freestanding C++ runtime support]),,
1779     [case "$host" in
1780         arm*-*-symbianelf*)
1781             enable_hosted_libstdcxx=no
1782             ;;
1783         *)
1784             enable_hosted_libstdcxx=yes
1785             ;;
1786      esac])
1787   if test "$enable_hosted_libstdcxx" = no; then
1788     AC_MSG_NOTICE([Only freestanding libraries will be built])
1789     is_hosted=no
1790     hosted_define=0
1791     enable_abi_check=no
1792     enable_libstdcxx_pch=no
1793   else
1794     is_hosted=yes
1795     hosted_define=1
1796   fi
1797   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1798   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1799     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1800 ])
1801
1802
1803 dnl
1804 dnl Check for template specializations for the 'long long' type.
1805 dnl The result determines only whether 'long long' I/O is enabled; things
1806 dnl like numeric_limits<> specializations are always available.
1807 dnl
1808 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1809 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1810 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1811 dnl       Where DEFAULT is either `yes' or `no'.
1812 dnl
1813 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1814   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
1815   if test $enable_long_long = yes; then
1816     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
1817               [Define if code specialized for long long should be used.])
1818   fi
1819   AC_MSG_CHECKING([for enabled long long specializations])
1820   AC_MSG_RESULT([$enable_long_long])
1821 ])
1822
1823
1824 dnl
1825 dnl Check for template specializations for the 'wchar_t' type.
1826 dnl
1827 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
1828 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
1829 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
1830 dnl       Where DEFAULT is either `yes' or `no'.
1831 dnl
1832 dnl Necessary support (probed along with C99 support) must also be present.
1833 dnl
1834 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
1835   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
1836   if test x"$ac_c99_wchar" = x"yes" && test x"$enable_wchar_t" = x"yes"; then
1837     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
1838               [Define if code specialized for wchar_t should be used.])
1839   fi
1840   AC_MSG_CHECKING([for enabled wchar_t specializations])
1841   AC_MSG_RESULT([$enable_wchar_t])
1842 ])
1843
1844
1845 dnl
1846 dnl Check to see if building and using a C++ precompiled header can be done.
1847 dnl
1848 dnl --enable-libstdcxx-pch=yes
1849 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1850 dnl may work, after some light-hearted attempts to puzzle out compiler
1851 dnl support, flip bits on in include/Makefile.am
1852 dnl
1853 dnl --disable-libstdcxx-pch
1854 dnl turns off attempts to use or build stdc++.h.gch.
1855 dnl
1856 dnl Substs:
1857 dnl  glibcxx_PCHFLAGS
1858 dnl
1859 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1860   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1861   if test $enable_libstdcxx_pch = yes; then
1862     AC_CACHE_CHECK([for compiler with PCH support],
1863       [glibcxx_cv_prog_CXX_pch],
1864       [ac_save_CXXFLAGS="$CXXFLAGS"
1865        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1866        AC_LANG_SAVE
1867        AC_LANG_CPLUSPLUS
1868        echo '#include <math.h>' > conftest.h
1869        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1870                           -o conftest.h.gch 1>&5 2>&1 &&
1871                 echo '#error "pch failed"' > conftest.h &&
1872           echo '#include "conftest.h"' > conftest.cc &&
1873                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1874        then
1875          glibcxx_cv_prog_CXX_pch=yes
1876        else
1877          glibcxx_cv_prog_CXX_pch=no
1878        fi
1879        rm -f conftest*
1880        CXXFLAGS=$ac_save_CXXFLAGS
1881        AC_LANG_RESTORE
1882       ])
1883     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1884   fi
1885
1886   AC_MSG_CHECKING([for enabled PCH])
1887   AC_MSG_RESULT([$enable_libstdcxx_pch])
1888
1889   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1890   if test $enable_libstdcxx_pch = yes; then
1891     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1892   else
1893     glibcxx_PCHFLAGS=""
1894   fi
1895   AC_SUBST(glibcxx_PCHFLAGS)
1896 ])
1897
1898
1899 dnl
1900 dnl Check for exception handling support.  If an explicit enable/disable
1901 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1902 dnl target may or may not support call frame exceptions.
1903 dnl
1904 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1905 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1906 dnl Neither one forces an attempt at detection.
1907 dnl
1908 dnl Defines:
1909 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1910 dnl
1911 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1912   AC_MSG_CHECKING([for exception model to use])
1913   AC_LANG_SAVE
1914   AC_LANG_CPLUSPLUS
1915   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1916     [force use of builtin_setjmp for exceptions],
1917     [permit yes|no|auto])
1918
1919   if test $enable_sjlj_exceptions = auto; then
1920     # Botheration.  Now we've got to detect the exception model.  Link tests
1921     # against libgcc.a are problematic since we've not been given proper -L
1922     # bits for single-tree newlib and libgloss.
1923     #
1924     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1925     cat > conftest.$ac_ext << EOF
1926 [#]line __oline__ "configure"
1927 struct S { ~S(); };
1928 void bar();
1929 void foo()
1930 {
1931   S s;
1932   bar();
1933 }
1934 EOF
1935     old_CXXFLAGS="$CXXFLAGS"
1936     CXXFLAGS=-S
1937     if AC_TRY_EVAL(ac_compile); then
1938       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1939         enable_sjlj_exceptions=yes
1940       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1941         enable_sjlj_exceptions=no
1942       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
1943         enable_sjlj_exceptions=no
1944       fi
1945     fi
1946     CXXFLAGS="$old_CXXFLAGS"
1947     rm -f conftest*
1948   fi
1949
1950   # This is a tad weird, for hysterical raisins.  We have to map
1951   # enable/disable to two different models.
1952   case $enable_sjlj_exceptions in
1953     yes)
1954       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1955         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1956       ac_exception_model_name=sjlj
1957       ;;
1958     no)
1959       ac_exception_model_name="call frame"
1960       ;;
1961     *)
1962       AC_MSG_ERROR([unable to detect exception model])
1963       ;;
1964   esac
1965  AC_LANG_RESTORE
1966  AC_MSG_RESULT($ac_exception_model_name)
1967 ])
1968
1969
1970 dnl
1971 dnl Add version tags to symbols in shared library (or not), additionally
1972 dnl marking other symbols as private/local (or not).
1973 dnl
1974 dnl --enable-symvers=style adds a version script to the linker call when
1975 dnl       creating the shared library.  The choice of version script is
1976 dnl       controlled by 'style'.
1977 dnl --disable-symvers does not.
1978 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1979 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1980 dnl       choose a default style based on linker characteristics.  Passing
1981 dnl       'no' disables versioning.
1982 dnl
1983 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1984
1985 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1986   [enables symbol versioning of the shared library],
1987   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export])
1988
1989 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1990 # don't know enough about $LD to do tricks...
1991 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1992
1993 # Turn a 'yes' into a suitable default.
1994 if test x$enable_symvers = xyes ; then
1995   if test $enable_shared = no || test "x$LD" = x ; then
1996     enable_symvers=no
1997   else
1998     if test $with_gnu_ld = yes ; then
1999       enable_symvers=gnu
2000     else
2001       case ${target_os} in
2002         darwin*)
2003           enable_symvers=darwin ;;
2004         *)
2005           enable_symvers=no ;;
2006       esac
2007     fi
2008   fi
2009 fi
2010
2011 # Check to see if 'darwin' or 'darwin-export' can win.
2012 if test x$enable_symvers = xdarwin-export ; then
2013     enable_symvers=darwin
2014 fi
2015
2016 # Check to see if 'gnu' can win.
2017 if test $enable_symvers = gnu || test $enable_symvers = gnu-versioned-namespace; then
2018   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2019   AC_MSG_CHECKING([for shared libgcc])
2020   ac_save_CFLAGS="$CFLAGS"
2021   CFLAGS=' -lgcc_s'
2022   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
2023   CFLAGS="$ac_save_CFLAGS"
2024   if test $glibcxx_shared_libgcc = no; then
2025     cat > conftest.c <<EOF
2026 int main (void) { return 0; }
2027 EOF
2028 changequote(,)dnl
2029     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
2030                              -shared -shared-libgcc -o conftest.so \
2031                              conftest.c -v 2>&1 >/dev/null \
2032                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
2033 changequote([,])dnl
2034     rm -f conftest.c conftest.so
2035     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
2036       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
2037       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
2038       CFLAGS="$ac_save_CFLAGS"
2039     fi
2040   fi
2041   AC_MSG_RESULT($glibcxx_shared_libgcc)
2042
2043   # For GNU ld, we need at least this version.  The format is described in
2044   # GLIBCXX_CHECK_LINKER_FEATURES above.
2045   glibcxx_min_gnu_ld_version=21400
2046
2047   # If no shared libgcc, can't win.
2048   if test $glibcxx_shared_libgcc != yes; then
2049       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
2050       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
2051       AC_MSG_WARN([=== Symbol versioning will be disabled.])
2052       enable_symvers=no
2053   elif test $with_gnu_ld != yes ; then
2054     # just fail for now
2055     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
2056     AC_MSG_WARN([=== you are not using the GNU linker.])
2057     AC_MSG_WARN([=== Symbol versioning will be disabled.])
2058     enable_symvers=no
2059   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
2060     # The right tools, the right setup, but too old.  Fallbacks?
2061     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
2062     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
2063     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
2064     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
2065     AC_MSG_WARN([=== Symbol versioning will be disabled.])
2066     enable_symvers=no
2067   fi
2068 fi
2069
2070 # Everything parsed; figure out what file to use.
2071 case $enable_symvers in
2072   no)
2073     SYMVER_FILE=config/abi/pre/none.ver
2074     ;;
2075   gnu)
2076     SYMVER_FILE=config/abi/pre/gnu.ver
2077     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
2078               [Define to use GNU versioning in the shared library.])
2079     ;;
2080   gnu-versioned-namespace)
2081     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
2082     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
2083               [Define to use GNU namespace versioning in the shared library.])
2084     ;;
2085   darwin)
2086     SYMVER_FILE=config/abi/pre/gnu.ver
2087     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
2088               [Define to use darwin versioning in the shared library.])
2089     ;;
2090 esac
2091
2092 if test x$enable_symvers != xno ; then
2093   AC_DEFINE(_GLIBCXX_SYMVER, 1,
2094          [Define to use symbol versioning in the shared library.])
2095 fi
2096
2097 AC_SUBST(SYMVER_FILE)
2098 AC_SUBST(port_specific_symbol_files)
2099 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
2100 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
2101 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
2102 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
2103 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
2104
2105 # Now, set up compatibility support, if any.
2106 # In addition, need this to deal with std::size_t mangling in
2107 # src/compatibility.cc.  In a perfect world, could use
2108 # typeid(std::size_t).name()[0] to do direct substitution.
2109 AC_MSG_CHECKING([for size_t as unsigned int])
2110 ac_save_CFLAGS="$CFLAGS"
2111 CFLAGS="-Werror"
2112 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
2113                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
2114 CFLAGS=$ac_save_CFLAGS
2115 if test "$glibcxx_size_t_is_i" = yes; then
2116   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
2117 fi
2118 AC_MSG_RESULT([$glibcxx_size_t_is_i])
2119
2120 AC_MSG_CHECKING([for ptrdiff_t as int])
2121 ac_save_CFLAGS="$CFLAGS"
2122 CFLAGS="-Werror"
2123 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
2124                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
2125 CFLAGS=$ac_save_CFLAGS
2126 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
2127   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
2128 fi
2129 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
2130 ])
2131
2132
2133 dnl
2134 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
2135 dnl We must stage the required headers so that they will be installed
2136 dnl with the library (unlike libgcc, the STL implementation is provided
2137 dnl solely within headers).  Since we must not inject random user-space
2138 dnl macro names into user-provided C++ code, we first stage into <file>-in
2139 dnl and process to <file> with an output command.  The reason for a two-
2140 dnl stage process here is to correctly handle $srcdir!=$objdir without
2141 dnl having to write complex code (the sed commands to clean the macro
2142 dnl namespace are complex and fragile enough as it is).  We must also
2143 dnl add a relative path so that -I- is supported properly.
2144 dnl
2145 dnl Substs:
2146 dnl  glibcxx_thread_h
2147 dnl
2148 dnl Defines:
2149 dnl  HAVE_GTHR_DEFAULT
2150 dnl
2151 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
2152   AC_MSG_CHECKING([for thread model used by GCC])
2153   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
2154   AC_MSG_RESULT([$target_thread_file])
2155
2156   if test $target_thread_file != single; then
2157     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
2158               [Define if gthr-default.h exists
2159               (meaning that threading support is enabled).])
2160   fi
2161
2162   glibcxx_thread_h=gthr-$target_thread_file.h
2163
2164   dnl Check for __GTHREADS define.
2165   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
2166   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
2167     enable_thread=yes
2168   else
2169    enable_thread=no
2170   fi
2171
2172   AC_SUBST(glibcxx_thread_h)
2173 ])
2174
2175
2176 # Check whether LC_MESSAGES is available in <locale.h>.
2177 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2178 #
2179 # This file file be copied and used freely without restrictions.  It can
2180 # be used in projects which are not available under the GNU Public License
2181 # but which still want to provide support for the GNU gettext functionality.
2182 # Please note that the actual code is *not* freely available.
2183
2184 # serial 1
2185 AC_DEFUN([AC_LC_MESSAGES], [
2186   AC_CHECK_HEADER(locale.h, [
2187     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2188       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2189        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2190     if test $ac_cv_val_LC_MESSAGES = yes; then
2191       AC_DEFINE(HAVE_LC_MESSAGES, 1,
2192                 [Define if LC_MESSAGES is available in <locale.h>.])
2193     fi
2194   ])
2195 ])
2196
2197 # Macros from the top-level gcc directory.
2198 m4_include([../config/tls.m4])
2199