gcc/ada/s-pooloc.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                    S Y S T E M . P O O L _ L O C A L                     --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Memory;
  35
  36 with Unchecked_Conversion;
  37
  38 package body System.Pool_Local is
  39
  40    package SSE renames System.Storage_Elements;
  41    use type SSE.Storage_Offset;
  42
  43    Pointer_Size  : constant SSE.Storage_Offset := Address'Size / Storage_Unit;
  44    Pointers_Size : constant SSE.Storage_Offset := 2 * Pointer_Size;
  45
  46    type Acc_Address is access all Address;
  47    function To_Acc_Address is new Unchecked_Conversion (Address, Acc_Address);
  48
  49    -----------------------
  50    -- Local Subprograms --
  51    -----------------------
  52
  53    function Next (A : Address) return Acc_Address;
  54    pragma Inline (Next);
  55    --  Given an address of a block, return an access to the next block
  56
  57    function Prev (A : Address) return Acc_Address;
  58    pragma Inline (Prev);
  59    --  Given an address of a block, return an access to the previous block
  60
  61    --------------
  62    -- Allocate --
  63    --------------
  64
  65    procedure Allocate
  66      (Pool         : in out Unbounded_Reclaim_Pool;
  67       Address      : out System.Address;
  68       Storage_Size : SSE.Storage_Count;
  69       Alignment    : SSE.Storage_Count)
  70    is
  71       pragma Warnings (Off, Alignment);
  72
  73       Allocated : constant System.Address :=
  74                     Memory.Alloc
  75                       (Memory.size_t (Storage_Size + Pointers_Size));
  76
  77    begin
  78       --  The call to Alloc returns an address whose alignment is compatible
  79       --  with the worst case alignment requirement for the machine; thus the
  80       --  Alignment argument can be safely ignored.
  81
  82       if Allocated = Null_Address then
  83          raise Storage_Error;
  84       else
  85          Address := Allocated + Pointers_Size;
  86          Next (Allocated).all := Pool.First;
  87          Prev (Allocated).all := Null_Address;
  88
  89          if Pool.First /= Null_Address then
  90             Prev (Pool.First).all := Allocated;
  91          end if;
  92
  93          Pool.First := Allocated;
  94       end if;
  95    end Allocate;
  96
  97    ----------------
  98    -- Deallocate --
  99    ----------------
 100
 101    procedure Deallocate
 102      (Pool         : in out Unbounded_Reclaim_Pool;
 103       Address      : System.Address;
 104       Storage_Size : SSE.Storage_Count;
 105       Alignment    : SSE.Storage_Count)
 106    is
 107       pragma Warnings (Off, Storage_Size);
 108       pragma Warnings (Off, Alignment);
 109
 110       Allocated : constant System.Address := Address - Pointers_Size;
 111
 112    begin
 113       if Prev (Allocated).all = Null_Address then
 114          Pool.First := Next (Allocated).all;
 115          Prev (Pool.First).all := Null_Address;
 116       else
 117          Next (Prev (Allocated).all).all := Next (Allocated).all;
 118       end if;
 119
 120       if Next (Allocated).all /= Null_Address then
 121          Prev (Next (Allocated).all).all := Prev (Allocated).all;
 122       end if;
 123
 124       Memory.Free (Allocated);
 125    end Deallocate;
 126
 127    --------------
 128    -- Finalize --
 129    --------------
 130
 131    procedure Finalize (Pool : in out Unbounded_Reclaim_Pool) is
 132       N         : System.Address := Pool.First;
 133       Allocated : System.Address;
 134
 135    begin
 136       while N /= Null_Address loop
 137          Allocated := N;
 138          N := Next (N).all;
 139          Memory.Free (Allocated);
 140       end loop;
 141    end Finalize;
 142
 143    ----------
 144    -- Next --
 145    ----------
 146
 147    function Next (A : Address) return Acc_Address is
 148    begin
 149       return To_Acc_Address (A);
 150    end Next;
 151
 152    ----------
 153    -- Prev --
 154    ----------
 155
 156    function Prev (A : Address) return Acc_Address is
 157    begin
 158       return To_Acc_Address (A + Pointer_Size);
 159    end Prev;
 160
 161 end System.Pool_Local;