libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([xmalloc.c])
   5 AC_CONFIG_MACRO_DIRS([../config])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 if test -z "$ETAGS"; then
  66   ETAGS=etags
  67 fi
  68 AC_SUBST([ETAGS])
  69
  70 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  71 # rely on it - libiberty is built before texinfo.
  72 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  73 if test "x$MAKEINFO" = "x"; then
  74     MAKEINFO="@echo makeinfo missing; true"
  75     BUILD_INFO=
  76 else
  77     BUILD_INFO=info
  78     case "$MAKEINFO" in
  79       */missing\ makeinfo*)
  80         BUILD_INFO=
  81         AC_MSG_WARN([
  82 *** Makeinfo is missing. Info documentation will not be built.])
  83         ;;
  84       *)
  85         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  86           x*\ [[1-3]].* )
  87             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  88             BUILD_INFO=
  89             AC_MSG_WARN([
  90 *** Makeinfo is too old. Info documentation will not be built.])
  91           ;;
  92         esac
  93         ;;
  94     esac
  95 fi
  96 AC_SUBST(MAKEINFO)
  97 AC_SUBST(BUILD_INFO)
  98
  99 AC_CHECK_PROG(PERL, perl, perl, )
 100 if test x"$PERL" = x""; then
 101   HAVE_PERL='#'
 102 else
 103   HAVE_PERL=''
 104 fi
 105 AC_SUBST(HAVE_PERL)
 106
 107 AC_CANONICAL_HOST
 108
 109 dnl When we start using automake:
 110 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 111
 112 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 113 dnl to call AC_CHECK_PROG.
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116
 117 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
 118 if test -n "$PLUGIN_OPTION"; then
 119   if $AR --help 2>&1 | grep -q "\--plugin"; then
 120     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
 121     AC_SUBST(AR_PLUGIN_OPTION)
 122   fi
 123   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
 124     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
 125     AC_SUBST(RANLIB_PLUGIN_OPTION)
 126   fi
 127 fi
 128
 129 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 130 # Add --enable-multilib to configure.
 131 # Default to --enable-multilib
 132 AC_ARG_ENABLE(multilib,
 133 [  --enable-multilib       build many library versions (default)],
 134 [case "$enableval" in
 135   yes) multilib=yes ;;
 136   no)  multilib=no ;;
 137   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 138  esac],
 139               [multilib=yes])
 140
 141 # Even if the default multilib is not a cross compilation,
 142 # it may be that some of the other multilibs are.
 143 if test $cross_compiling = no && test $multilib = yes \
 144    && test "x${with_multisubdir}" != x ; then
 145    cross_compiling=maybe
 146 fi
 147
 148 # We may wish to install the target headers somewhere.
 149 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 150 dnl install-libiberty is disabled by default
 151
 152 AC_ARG_ENABLE(install-libiberty,
 153 [  --enable-install-libiberty       Install headers and library for end users],
 154 enable_install_libiberty=$enableval,
 155 enable_install_libiberty=no)dnl
 156
 157 # Option parsed, now set things appropriately.
 158 case x"$enable_install_libiberty" in
 159   xyes|x)
 160     target_header_dir=libiberty
 161     ;;
 162   xno)
 163     target_header_dir=
 164     ;;
 165   *)
 166     # This could be sanity-checked in various ways...
 167     target_header_dir="${enable_install_libiberty}"
 168     ;;
 169 esac
 170 AC_MSG_RESULT($enable_install_libiberty)
 171 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 172
 173 GCC_NO_EXECUTABLES
 174 AC_PROG_CC
 175 AC_GNU_SOURCE
 176 AC_SYS_LARGEFILE
 177 AC_PROG_CPP_WERROR
 178
 179 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 180                           -Wstrict-prototypes \
 181                           -Wshadow=local], [ac_libiberty_warn_cflags])
 182 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 183
 184 AC_PROG_CC_C_O
 185 # autoconf is lame and doesn't give us any substitution variable for this.
 186 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 187   NO_MINUS_C_MINUS_O=yes
 188 else
 189   OUTPUT_OPTION='-o $@'
 190 fi
 191 AC_SUBST(NO_MINUS_C_MINUS_O)
 192 AC_SUBST(OUTPUT_OPTION)
 193
 194 AC_C_CONST
 195 AC_C_INLINE
 196 AC_C_BIGENDIAN
 197
 198 dnl When we start using libtool:
 199 dnl Default to a non shared library.  This may be overridden by the
 200 dnl configure option --enable-shared.
 201 dnl AM_DISABLE_SHARED
 202
 203 dnl When we start using libtool:
 204 dnl AM_PROG_LIBTOOL
 205
 206 dnl When we start using automake:
 207 dnl AM_CONFIG_HEADER(config.h:config.in)
 208 AC_CONFIG_HEADER(config.h:config.in)
 209
 210 dnl When we start using automake:
 211 dnl AM_MAINTAINER_MODE
 212 dnl AC_EXEEXT
 213
 214 dnl When we start using automake:
 215 dnl AM_PROG_INSTALL
 216 AC_PROG_INSTALL
 217
 218 # Don't build the shared library for build.
 219 if [[ -n "${with_build_subdir}" ]]; then
 220   enable_shared=no
 221 fi
 222
 223 frag=
 224 case "${host}" in
 225   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 226                         frag=mh-aix ;;
 227   *-*-cxux7*)           frag=mh-cxux7 ;;
 228   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 229   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 230   i370-*-opened*)       frag=mh-openedition ;;
 231   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 232 esac
 233
 234 if [[ -n "${frag}" ]]; then
 235   frag=${libiberty_topdir}/libiberty/config/$frag
 236 fi
 237
 238 GCC_PICFLAG
 239
 240 # If they didn't specify --enable-shared, don't generate shared libs.
 241 case "${enable_shared}" in
 242   yes) shared=yes ;;
 243   no) shared=no ;;
 244   "") shared=no ;;
 245   *) shared=yes ;;
 246 esac
 247
 248 # ...unless --enable-host-{shared,pie} was passed from top-level config:
 249 if [[ "${enable_host_shared}" = "yes" ]] || [[ "${enable_host_pie}" = "yes" ]]; then
 250   shared=yes
 251 fi
 252
 253 if [[ "${shared}" != "yes" ]]; then
 254   PICFLAG=
 255 fi
 256 AC_SUBST(PICFLAG)
 257
 258 NOASANFLAG=
 259 case " ${CFLAGS} " in
 260   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 261   *\ -fsanitize=hwaddress\ *) NOASANFLAG=-fno-sanitize=hwaddress ;;
 262 esac
 263 AC_SUBST(NOASANFLAG)
 264
 265 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
 266 AC_SUBST(CET_HOST_FLAGS)
 267
 268 echo "# Warning: this fragment is automatically generated" > temp-frag
 269
 270 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 271   echo "Appending ${frag} to xhost-mkfrag"
 272   echo "# Following fragment copied from ${frag}" >> temp-frag
 273   cat ${frag} >> temp-frag
 274 fi
 275
 276 # record if we want to build shared libs.
 277 if [[ "${shared}" = "yes" ]]; then
 278   echo enable_shared = yes >> temp-frag
 279 else
 280   echo enable_shared = no >> temp-frag
 281 fi
 282
 283 frag=xhost-mkfrag
 284 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 285
 286 host_makefile_frag=${frag}
 287 AC_SUBST_FILE(host_makefile_frag)
 288
 289 # It's OK to check for header files.  Although the compiler may not be
 290 # able to link anything, it had better be able to at least compile
 291 # something.
 292 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h spawn.h)
 293 AC_HEADER_SYS_WAIT
 294 AC_HEADER_TIME
 295
 296 libiberty_AC_DECLARE_ERRNO
 297
 298 # Determine sizes of some types.
 299 AC_CHECK_SIZEOF([int])
 300 AC_CHECK_SIZEOF([long])
 301 AC_CHECK_SIZEOF([size_t])
 302
 303 # Check for presense of long long
 304 AC_CHECK_TYPE([long long],
 305   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 306   [])
 307
 308 # Look for a 64-bit type.
 309 AC_MSG_CHECKING([for a 64-bit type])
 310 AC_CACHE_VAL(liberty_cv_uint64,
 311 [AC_TRY_COMPILE(
 312 [#ifdef HAVE_STDINT_H
 313 #include <stdint.h>
 314 #endif],
 315 [extern uint64_t foo;],
 316 liberty_cv_uint64=uint64_t,
 317 [AC_TRY_COMPILE(
 318 [#ifdef HAVE_LIMITS_H
 319 #include <limits.h>
 320 #endif
 321 #ifndef CHAR_BIT
 322 #define CHAR_BIT 8
 323 #endif],
 324 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 325 liberty_cv_uint64="unsigned long",
 326 [AC_TRY_COMPILE(
 327 [#ifdef HAVE_LIMITS_H
 328 #include <limits.h>
 329 #endif
 330 #ifndef CHAR_BIT
 331 #define CHAR_BIT 8
 332 #endif],
 333 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 334 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 335 AC_MSG_RESULT($liberty_cv_uint64)
 336 if test "$liberty_cv_uint64" != none; then
 337   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 338                      [Define to an unsigned 64-bit type available in the compiler.])
 339 fi
 340
 341 AC_TYPE_INTPTR_T
 342 AC_TYPE_UINTPTR_T
 343 AC_TYPE_SSIZE_T
 344
 345 # Given the above check, we always have uintptr_t or a fallback
 346 # definition.  So define HAVE_UINTPTR_T in case any imported code
 347 # relies on it.
 348 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 349
 350 AC_TYPE_PID_T
 351
 352 # This is the list of functions which libiberty will provide if they
 353 # are not available on the host.
 354
 355 funcs="asprintf"
 356 funcs="$funcs atexit"
 357 funcs="$funcs basename"
 358 funcs="$funcs bcmp"
 359 funcs="$funcs bcopy"
 360 funcs="$funcs bsearch"
 361 funcs="$funcs bzero"
 362 funcs="$funcs calloc"
 363 funcs="$funcs clock"
 364 funcs="$funcs ffs"
 365 funcs="$funcs getcwd"
 366 funcs="$funcs getpagesize"
 367 funcs="$funcs gettimeofday"
 368 funcs="$funcs index"
 369 funcs="$funcs insque"
 370 funcs="$funcs memchr"
 371 funcs="$funcs memcmp"
 372 funcs="$funcs memcpy"
 373 funcs="$funcs memmem"
 374 funcs="$funcs memmove"
 375 funcs="$funcs mempcpy"
 376 funcs="$funcs memset"
 377 funcs="$funcs mkstemps"
 378 funcs="$funcs putenv"
 379 funcs="$funcs random"
 380 funcs="$funcs rename"
 381 funcs="$funcs rindex"
 382 funcs="$funcs setenv"
 383 funcs="$funcs snprintf"
 384 funcs="$funcs sigsetmask"
 385 funcs="$funcs stpcpy"
 386 funcs="$funcs stpncpy"
 387 funcs="$funcs strcasecmp"
 388 funcs="$funcs strchr"
 389 funcs="$funcs strdup"
 390 funcs="$funcs strncasecmp"
 391 funcs="$funcs strndup"
 392 funcs="$funcs strnlen"
 393 funcs="$funcs strrchr"
 394 funcs="$funcs strstr"
 395 funcs="$funcs strtod"
 396 funcs="$funcs strtol"
 397 funcs="$funcs strtoul"
 398 funcs="$funcs strtoll"
 399 funcs="$funcs strtoull"
 400 funcs="$funcs strverscmp"
 401 funcs="$funcs tmpnam"
 402 funcs="$funcs vasprintf"
 403 funcs="$funcs vfprintf"
 404 funcs="$funcs vprintf"
 405 funcs="$funcs vsnprintf"
 406 funcs="$funcs vsprintf"
 407 funcs="$funcs waitpid"
 408 funcs="$funcs setproctitle"
 409
 410 # Also in the old function.def file: alloca, vfork, getopt.
 411
 412 vars="sys_errlist sys_nerr sys_siglist"
 413
 414 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 415  getsysinfo gettimeofday on_exit pipe2 posix_spawn posix_spawnp psignal \
 416  pstat_getdynamic pstat_getstatic \
 417  realpath setrlimit spawnve spawnvpe strerror strsignal sysconf sysctl \
 418  sysmp table times wait3 wait4"
 419
 420 # Darwin has sbrk, but it is deprecated and that produces build-time warnings
 421 # so do not check for it.
 422 case "${host}" in
 423   *-*-darwin*) ;;
 424   *) checkfuncs="$checkfuncs sbrk"
 425 esac
 426
 427 # These are neither executed nor required, but they help keep
 428 # autoheader happy without adding a bunch of text to acconfig.h.
 429 if test "x" = "y"; then
 430   AC_CHECK_FUNCS(asprintf atexit \
 431     basename bcmp bcopy bsearch bzero \
 432     calloc canonicalize_file_name clock \
 433     dup3 \
 434     ffs __fsetlocking \
 435     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 436     index insque \
 437     memchr memcmp memcpy memmem memmove memset mkstemps \
 438     on_exit \
 439     pipe2 posix_spawn posix_spawnp psignal \
 440     pstat_getdynamic pstat_getstatic putenv \
 441     random realpath rename rindex \
 442     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 443      stpcpy stpncpy strcasecmp strchr strdup \
 444      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 445      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 446     table times tmpnam \
 447     vasprintf vfprintf vprintf vsprintf \
 448     wait3 wait4 waitpid)
 449   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull, strnlen])
 450   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 451   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 452   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 453 fi
 454
 455 # For each of these functions, if the host does not provide the
 456 # function we want to put FN.o in LIBOBJS, and if the host does
 457 # provide the function, we want to define HAVE_FN in config.h.
 458
 459 setobjs=
 460 CHECK=
 461 if test -n "${with_target_subdir}"; then
 462
 463   # We are being configured as a target library.  AC_REPLACE_FUNCS
 464   # may not work correctly, because the compiler may not be able to
 465   # link executables.  Note that we may still be being configured
 466   # native.
 467
 468   # If we are being configured for newlib, we know which functions
 469   # newlib provide and which ones we will be expected to provide.
 470
 471   if test "x${with_newlib}" = "xyes"; then
 472     AC_LIBOBJ([asprintf])
 473     AC_LIBOBJ([basename])
 474     AC_LIBOBJ([insque])
 475     AC_LIBOBJ([random])
 476     AC_LIBOBJ([strdup])
 477     AC_LIBOBJ([vasprintf])
 478
 479     for f in $funcs; do
 480       case "$f" in
 481         asprintf | basename | insque | random | strdup | vasprintf)
 482           ;;
 483         *)
 484           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 485           AC_DEFINE_UNQUOTED($n)
 486           ;;
 487       esac
 488     done
 489
 490     # newlib doesnt provide any of the variables in $vars, so we
 491     # dont have to check them here.
 492
 493     # Of the functions in $checkfuncs, newlib only has strerror.
 494     AC_DEFINE(HAVE_STRERROR)
 495
 496     setobjs=yes
 497
 498   fi
 499
 500   # If we are being configured for Mingw, we know which functions
 501   # Mingw provides and which ones we will be expected to provide.
 502
 503   case "${host}" in
 504   *-*-mingw*)
 505     AC_LIBOBJ([asprintf])
 506     AC_LIBOBJ([basename])
 507     AC_LIBOBJ([bcmp])
 508     AC_LIBOBJ([bcopy])
 509     AC_LIBOBJ([bzero])
 510     AC_LIBOBJ([clock])
 511     AC_LIBOBJ([ffs])
 512     AC_LIBOBJ([getpagesize])
 513     AC_LIBOBJ([index])
 514     AC_LIBOBJ([insque])
 515     AC_LIBOBJ([mempcpy])
 516     AC_LIBOBJ([mkstemps])
 517     AC_LIBOBJ([random])
 518     AC_LIBOBJ([rindex])
 519     AC_LIBOBJ([sigsetmask])
 520     AC_LIBOBJ([stpcpy])
 521     AC_LIBOBJ([stpncpy])
 522     AC_LIBOBJ([strndup])
 523     AC_LIBOBJ([strnlen])
 524     AC_LIBOBJ([strverscmp])
 525     AC_LIBOBJ([vasprintf])
 526     AC_LIBOBJ([waitpid])
 527
 528     for f in $funcs; do
 529       case "$f" in
 530         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 531           ;;
 532         *)
 533           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 534           AC_DEFINE_UNQUOTED($n)
 535           ;;
 536       esac
 537     done
 538
 539     # Mingw doesnt provide any of the variables in $vars, so we
 540     # dont have to check them here.
 541
 542     # Of the functions in $checkfuncs, Mingw only has strerror.
 543     AC_DEFINE(HAVE_STRERROR)
 544
 545     setobjs=yes
 546     ;;
 547
 548   *-*-msdosdjgpp)
 549     AC_LIBOBJ([vasprintf])
 550     AC_LIBOBJ([vsnprintf])
 551     AC_LIBOBJ([snprintf])
 552     AC_LIBOBJ([asprintf])
 553
 554     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 555              getcwd getpagesize getrusage gettimeofday \
 556              index insque memchr memcmp memcpy memmove memset psignal \
 557              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 558              strchr strdup strerror strncasecmp strrchr strstr strtod \
 559              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 560              vsprintf waitpid
 561     do
 562       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 563       AC_DEFINE_UNQUOTED($n)
 564     done
 565
 566
 567     setobjs=yes
 568     ;;
 569
 570   esac
 571
 572 else
 573
 574    # Not a target library, so we set things up to run the test suite.
 575    CHECK=really-check
 576
 577 fi
 578
 579 AC_SUBST(CHECK)
 580 AC_SUBST(target_header_dir)
 581
 582 case "${host}" in
 583   *-*-cygwin* | *-*-mingw*)
 584     AC_DEFINE(HAVE_SYS_ERRLIST)
 585     AC_DEFINE(HAVE_SYS_NERR)
 586     ;;
 587 esac
 588
 589 if test -z "${setobjs}"; then
 590   case "${host}" in
 591
 592   *-*-vxworks*)
 593     # Handle VxWorks configuration specially, since on VxWorks the
 594     # libraries are actually on the target board, not in the file
 595     # system.
 596     AC_LIBOBJ([basename])
 597     AC_LIBOBJ([getpagesize])
 598     AC_LIBOBJ([insque])
 599     AC_LIBOBJ([random])
 600     AC_LIBOBJ([strcasecmp])
 601     AC_LIBOBJ([strncasecmp])
 602     AC_LIBOBJ([strdup])
 603     AC_LIBOBJ([vfork])
 604     AC_LIBOBJ([waitpid])
 605     AC_LIBOBJ([vasprintf])
 606     for f in $funcs; do
 607       case "$f" in
 608         basename | getpagesize | insque | random | strcasecmp)
 609           ;;
 610         strncasecmp | strdup | vfork | waitpid | vasprintf)
 611           ;;
 612         *)
 613           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 614           AC_DEFINE_UNQUOTED($n)
 615           ;;
 616       esac
 617     done
 618
 619     # VxWorks doesn't provide any of the variables in $vars, so we
 620     # don't have to check them here.
 621
 622     # Of the functions in $checkfuncs, VxWorks only has strerror.
 623     AC_DEFINE(HAVE_STRERROR)
 624
 625     setobjs=yes
 626     ;;
 627
 628   esac
 629 fi
 630
 631 if test -z "${setobjs}"; then
 632
 633   case "${host}" in
 634
 635   *-*-android*)
 636     # On android, getpagesize is defined in unistd.h as a static inline
 637     # function, which AC_CHECK_FUNCS does not handle properly.
 638     ac_cv_func_getpagesize=yes
 639     ;;
 640
 641   hppa*-*-hpux*)
 642     # Replace system snprintf and vsnprintf with libiberty implementations.
 643     AC_LIBOBJ([snprintf])
 644     AC_LIBOBJ([vsnprintf])
 645     ;;
 646
 647   *-*-mingw32*)
 648     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 649     # macros, so the test below won't find them.
 650     libiberty_cv_var_sys_nerr=yes
 651     libiberty_cv_var_sys_errlist=yes
 652     ;;
 653
 654   *-*-msdosdjgpp*)
 655     # vfork and fork are stubs.
 656     ac_cv_func_vfork_works=no
 657     ;;
 658
 659   *-*-uwin*)
 660     # Under some versions of uwin, vfork is notoriously buggy and the test
 661     # can hang configure; on other versions, vfork exists just as a stub.
 662     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 663     ac_cv_func_vfork_works=no
 664     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 665     # macros (actually, these are imported from a DLL, but the end effect
 666     # is the same), so the test below won't find them.
 667     libiberty_cv_var_sys_nerr=yes
 668     libiberty_cv_var_sys_errlist=yes
 669     ;;
 670
 671   *-*-*vms*)
 672     # Under VMS, vfork works very different than on Unix. The standard test
 673     # won't work, and it isn't easily adaptable. It makes more sense to
 674     # just force it.
 675     ac_cv_func_vfork_works=yes
 676     ;;
 677
 678   esac
 679
 680   # We haven't set the list of objects yet.  Use the standard autoconf
 681   # tests.  This will only work if the compiler works.
 682   AC_ISC_POSIX
 683   AC_REPLACE_FUNCS($funcs)
 684   libiberty_AC_FUNC_C_ALLOCA
 685   AC_FUNC_FORK
 686   if test $ac_cv_func_vfork_works = no; then
 687     AC_LIBOBJ([vfork])
 688   fi
 689   # We only need _doprnt if we might use it to implement v*printf.
 690   if test $ac_cv_func_vprintf != yes \
 691      || test $ac_cv_func_vfprintf != yes \
 692      || test $ac_cv_func_vsprintf != yes; then
 693     AC_REPLACE_FUNCS(_doprnt)
 694   else
 695     AC_CHECK_FUNCS(_doprnt)
 696   fi
 697
 698   for v in $vars; do
 699     AC_MSG_CHECKING([for $v])
 700     AC_CACHE_VAL(libiberty_cv_var_$v,
 701       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern int $v [];]],[[if ($v [0]) return 1;]])],
 702                       [eval "libiberty_cv_var_$v=yes"],
 703                       [eval "libiberty_cv_var_$v=no"])])
 704     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 705       AC_MSG_RESULT(yes)
 706       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 707       AC_DEFINE_UNQUOTED($n)
 708     else
 709       AC_MSG_RESULT(no)
 710     fi
 711   done
 712
 713   # special check for _system_configuration because AIX <4.3.2 do not
 714   # contain the `physmem' member.
 715   AC_MSG_CHECKING([for external symbol _system_configuration])
 716   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 717                         [[double x = _system_configuration.physmem;]])],
 718     [AC_MSG_RESULT([yes])
 719     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 720               [Define if you have the _system_configuration variable.])],
 721     [AC_MSG_RESULT([no])])
 722
 723   AC_CHECK_FUNCS($checkfuncs)
 724   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 725   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc])
 726   case "${host}" in
 727       *-*-darwin*) ;; # Darwin's sbrk implementation is deprecated.
 728       *) AC_CHECK_DECLS([sbrk]);;
 729   esac
 730   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 731   AC_CHECK_DECLS([strverscmp])
 732   AC_CHECK_DECLS([strnlen])
 733   libiberty_NEED_DECLARATION(canonicalize_file_name)
 734 fi
 735
 736 # Figure out which version of pexecute to use.
 737 case "${host}" in
 738      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 739      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 740      *-*-msdos*)                pexecute=pex-msdos  ;;
 741      *)                         pexecute=pex-unix   ;;
 742 esac
 743 AC_SUBST(pexecute)
 744
 745 libiberty_AC_FUNC_STRNCMP
 746
 747 # Install a library built with a cross compiler in $(tooldir) rather
 748 # than $(libdir).
 749 if test -z "${with_cross_host}"; then
 750   INSTALL_DEST=libdir
 751 else
 752   INSTALL_DEST=tooldir
 753 fi
 754 AC_SUBST(INSTALL_DEST)
 755
 756 m4_pattern_allow(LIBOBJS)
 757 L=""
 758 for l in x $LIBOBJS; do
 759   case $l in
 760     x) ;;
 761     *) L="$L ./$l" ;;
 762   esac
 763 done
 764 LIBOBJS="$L"
 765
 766 dnl Required by html and install-html
 767 AC_SUBST(datarootdir)
 768 AC_SUBST(docdir)
 769 AC_SUBST(htmldir)
 770
 771 # We need multilib support, but only if configuring for the target.
 772 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 773 AC_CONFIG_COMMANDS([default],
 774   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 775 if test -n "$CONFIG_FILES"; then
 776   if test -n "${with_target_subdir}"; then
 777     # FIXME: We shouldn't need to set ac_file
 778     ac_file=Makefile
 779     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 780     . ${libiberty_topdir}/config-ml.in
 781   fi
 782 fi]],
 783 [[srcdir=${srcdir}
 784 host=${host}
 785 target=${target}
 786 with_target_subdir=${with_target_subdir}
 787 with_multisubdir=${with_multisubdir}
 788 ac_configure_args="--enable-multilib ${ac_configure_args}"
 789 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 790 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 791 libiberty_topdir=${libiberty_topdir}
 792 ]])
 793 AC_OUTPUT