gcc/testsuite/lib/compat.exp

   1 # Copyright (C) 2002, 2003, 2004, 2005, 2007 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16
  17 # This file was written by Janis Johnson, <janis187@us.ibm.com>
  18
  19
  20 # Test interoperability of two compilers that follow the same ABI, or
  21 # compatibility of two versions of GCC.
  22 #
  23 # Each test has a main program that does nothing but call a function,
  24 # plus two additional source files that contain parts of a program that
  25 # rely on the ABI.  those source files are compiled into relocatable
  26 # object files with both compilers.  Executables are built using various
  27 # combinations of those object files, with the main program compiled
  28 # with the compiler under test and using that compiler's runtime support.
  29
  30 # The including .exp file must define these callback procedures.
  31 if [string match "" [info procs "compat-use-alt-compiler"]] then {
  32     error "Proc compat-use-alt-compiler is not defined."
  33 }
  34 if [string match "" [info procs "compat-use-tst-compiler"]] then {
  35     error "Proc compat-use-tst-compiler is not defined."
  36 }
  37
  38 # Each test is run with each pair of compiler options from this list.
  39 # The first set of options in each pair is used by the compiler under
  40 # test, and the second set is used by the alternate compiler.
  41 # The default option lists can be overridden by
  42 # COMPAT_OPTIONS="[list [list {tst_1} {alt_1}]...[list {tst_n} {alt_n}]]"
  43 # where tst_i and alt_i are lists of options.  You can put this in the
  44 # environment before site.exp is written or add it to site.exp directly.
  45 if ![info exists COMPAT_OPTIONS] {
  46     set COMPAT_OPTIONS [list \
  47         [list {} {}]]
  48 }
  49
  50 set option_list $COMPAT_OPTIONS
  51
  52 # Subsets of tests can be selectively disabled by members of this list:
  53 #  - ATTRIBUTE: disable all tests using the __attribute__ extension,
  54 #  - COMPLEX_INT: disable all tests using the complex integral types extension,
  55 #  - VA: disable all tests using the variable number of arguments feature,
  56 #  - ZERO_ARRAY: disable all tests using the zero-sized arrays extension.
  57 # The default skip lists can be overriden by
  58 # COMPAT_SKIPS="[list {skip_1}...{skip_n}]"
  59 # where skip_i are skip identifiers.  You can put this in the environment
  60 # before site.exp is written or add it to site.exp directly.
  61 if ![info exists COMPAT_SKIPS] {
  62     set COMPAT_SKIPS [list {}]
  63 }
  64
  65 global compat_skip_list
  66 set compat_skip_list $COMPAT_SKIPS
  67
  68 load_lib dg.exp
  69 load_lib gcc-dg.exp
  70
  71 #
  72 # compat-obj -- compile to an object file
  73 #
  74 # SOURCE is the source file
  75 # DEST is the object file
  76 # OPTALL is the list of compiler options to use with all tests
  77 # OPTFILE is the list of compiler options to use with this file
  78 # OPTSTR is the options to print with test messages
  79 # XFAILDATA is the xfail data to be passed to the compiler
  80 #
  81 proc compat-obj { source dest optall optfile optstr xfaildata } {
  82     global testcase
  83     global tool
  84     global compiler_conditional_xfail_data
  85     global compat_skip_list
  86
  87     # Add the skip specifiers.
  88     foreach skip $compat_skip_list {
  89         if { ![string match $skip ""] } {
  90             lappend optall "-DSKIP_$skip"
  91         }
  92     }
  93
  94     # Set up the options for compiling this file.
  95     set options ""
  96     lappend options "additional_flags=$optfile $optall"
  97
  98     set compiler_conditional_xfail_data $xfaildata
  99     set comp_output [${tool}_target_compile "$source" "$dest" object $options]
 100     ${tool}_check_compile "$testcase $dest compile" $optstr $dest $comp_output
 101 }
 102
 103 # compat-run -- link and run an executable
 104 #
 105 # TESTNAME is the mixture of object files to link
 106 # OBJLIST is the list of object files to link
 107 # DEST is the name of the executable
 108 # OPTALL is a list of compiler and linker options to use for all tests
 109 # OPTFILE is a list of compiler and linker options to use for this test
 110 # OPTSTR is the list of options to list in messages
 111 #
 112 proc compat-run { testname objlist dest optall optfile optstr } {
 113     global testcase
 114     global tool
 115
 116     # Check that all of the objects were built successfully.
 117     foreach obj [split $objlist] {
 118         if ![file_on_host exists $obj] then {
 119             unresolved "$testcase $testname link $optstr"
 120             unresolved "$testcase $testname execute $optstr"
 121             return
 122         }
 123     }
 124
 125     # Set up the options for linking this test.
 126     set options ""
 127     lappend options "additional_flags=$optfile $optall"
 128
 129     # Link the objects into an executable.
 130     set comp_output [${tool}_target_compile "$objlist" $dest executable \
 131                      "$options"]
 132     if ![${tool}_check_compile "$testcase $testname link" "" \
 133          $dest $comp_output] then {
 134         unresolved "$testcase $testname execute $optstr"
 135         return
 136     }
 137
 138     # Run the self-checking executable.
 139     if ![string match "*/*" $dest] then {
 140         set dest "./$dest"
 141     }
 142     set result [${tool}_load $dest "" ""]
 143     set status [lindex $result 0]
 144     if { $status == "pass" } then {
 145         file_on_host delete $dest
 146     }
 147     $status "$testcase $testname execute $optstr"
 148 }
 149
 150 #
 151 # compat-get-options-main -- get target requirements for a test and
 152 # options for the primary source file and the test as a whole
 153 #
 154 # SRC is the full pathname of the primary source file.
 155 #
 156 proc compat-get-options-main { src } {
 157     # dg-options sets a variable called dg-extra-tool-flags.
 158     set dg-extra-tool-flags ""
 159     # dg-options sets a variable called tool_flags.
 160     set tool_flags ""
 161
 162     # dg-require-* sets dg-do-what.
 163     upvar dg-do-what dg-do-what
 164
 165     set tmp [dg-get-options $src]
 166     foreach op $tmp {
 167         set cmd [lindex $op 0]
 168         if { ![string compare "dg-options" $cmd] \
 169              || [string match "dg-skip-if" $cmd] \
 170              || [string match "dg-require-*" $cmd]  } {
 171             set status [catch "$op" errmsg]
 172             if { $status != 0 } {
 173                 perror "src: $errmsg for \"$op\"\n"
 174                 unresolved "$src: $errmsg for \"$op\""
 175                 return
 176             }
 177         } elseif { ![string compare "dg-xfail-if" $cmd] } {
 178             warning "compat.exp does not support $cmd in primary source file"
 179         } else {
 180             # Ignore unrecognized dg- commands, but warn about them.
 181             warning "compat.exp does not support $cmd"
 182         }
 183     }
 184
 185     # Return flags to use for compiling the primary source file and for
 186     # linking.
 187     return ${dg-extra-tool-flags}
 188 }
 189
 190 #
 191 # compat-get-options -- get special tool flags to use for a secondary
 192 # source file
 193 #
 194 # SRC is the full pathname of the source file.
 195 # The result is a list of options to use.
 196 #
 197 # This code is copied from proc dg-test in dg.exp from DejaGNU.
 198 #
 199 proc compat-get-options { src } {
 200     # dg-options sets a variable called dg-extra-tool-flags.
 201     set dg-extra-tool-flags ""
 202
 203     # dg-xfail-if sets compiler_conditional_xfail_data.
 204     global compiler_conditional_xfail_data
 205     set compiler_conditional_xfail_data ""
 206
 207     # dg-xfail-if needs access to dg-do-what.
 208     upvar dg-do-what dg-do-what
 209
 210     set tmp [dg-get-options $src]
 211     foreach op $tmp {
 212         set cmd [lindex $op 0]
 213         if { ![string compare "dg-options" $cmd] \
 214              || ![string compare "dg-xfail-if" $cmd] } {
 215             set status [catch "$op" errmsg]
 216             if { $status != 0 } {
 217                 perror "src: $errmsg for \"$op\"\n"
 218                 unresolved "$src: $errmsg for \"$op\""
 219                 return
 220             }
 221         } elseif { [string match "dg-require-*" $cmd] } {
 222             warning "compat.exp does not support $cmd in secondary source files"
 223         } else {
 224             # Ignore unrecognized dg- commands, but warn about them.
 225             warning "compat.exp does not support $cmd"
 226         }
 227     }
 228
 229     return ${dg-extra-tool-flags}
 230 }
 231
 232 #
 233 # compat-execute -- compile with compatible compilers
 234 #
 235 # SRC1 is the full pathname of the main file of the testcase.
 236 # SID identifies a test suite in the names of temporary files.
 237 # USE_ALT is nonzero if we're using an alternate compiler as well as
 238 #   the compiler under test.
 239 #
 240 proc compat-execute { src1 sid use_alt } {
 241     global srcdir tmpdir
 242     global option_list
 243     global tool
 244     global verbose
 245     global testcase
 246     global gluefile
 247     global compiler_conditional_xfail_data
 248     global dg-do-what-default
 249
 250     # Get extra flags for this test from the primary source file, and
 251     # process other dg-* options that this suite supports.  Warn about
 252     # unsupported flags.
 253     verbose "compat-execute: $src1" 1
 254     set dg-do-what [list ${dg-do-what-default} "" P]
 255     set extra_flags_1 [compat-get-options-main $src1]
 256
 257     # Check whether this test is supported for this target.
 258     if { [lindex ${dg-do-what} 1 ] == "N" } {
 259         unsupported "$src1"
 260         verbose "$src1 not supported on this target, skipping it" 3
 261         return
 262     }
 263
 264     # Set up the names of the other source files.
 265     set dir [file dirname $src1]
 266     set ext [file extension $src1]
 267     set base [file rootname $src1]
 268     set base [string range $base [string length $dir] end]
 269     regsub "_main" $base "" base
 270     set src2 "${dir}/${base}_x${ext}"
 271     set src3 "${dir}/${base}_y${ext}"
 272
 273     # Use the dg-options mechanism to specify extra flags for this test.
 274     # The extra flags in each file are used to compile that file, and the
 275     # extra flags in *_main.* are also used for linking.
 276     set extra_flags_2 [compat-get-options $src2]
 277     set compile_xfail_2 $compiler_conditional_xfail_data
 278     set extra_flags_3 [compat-get-options $src3]
 279     set compile_xfail_3 $compiler_conditional_xfail_data
 280
 281     # On the SPU, most of the compat test cases exceed local store size.
 282     # Use automatic overlay support to make them fit.
 283     if { [check_effective_target_spu_auto_overlay] } {
 284         set extra_flags_1 "$extra_flags_1 -Wl,--auto-overlay"
 285         set extra_flags_1 "$extra_flags_1 -ffunction-sections"
 286         set extra_flags_2 "$extra_flags_2 -ffunction-sections"
 287         set extra_flags_3 "$extra_flags_3 -ffunction-sections"
 288     }
 289
 290     # Define the names of the object files.
 291     regsub "sid" "sid_main_tst.o" $sid obj1
 292     regsub "sid" "sid_x_tst.o" $sid obj2_tst
 293     regsub "sid" "sid_x_alt.o" $sid obj2_alt
 294     regsub "sid" "sid_y_tst.o" $sid obj3_tst
 295     regsub "sid" "sid_y_alt.o" $sid obj3_alt
 296
 297     # Get the base name of this test, for use in messages.
 298     set testcase "$src1"
 299     # Remove the $srcdir and $tmpdir prefixes from $src1.  (It would
 300     # be possible to use "regsub" here, if we were careful to escape
 301     # all regular expression characters in $srcdir and $tmpdir, but
 302     # that would be more complicated that this approach.)
 303     if {[string first "$srcdir/" "$src1"] == 0} {
 304         set testcase [string range "$src1" [string length "$srcdir/"] end]
 305     }
 306     if {[string first "$tmpdir/" "$testcase"] == 0} {
 307         set testcase [string range "$testcase" [string length "$tmpdir/"] end]
 308         set testcase "tmpdir-$testcase"
 309     }
 310     regsub "_main.*" $testcase "" testcase
 311     # Set up the base name of executable files so they'll be unique.
 312     regsub -all "\[./\]" $testcase "-" execbase
 313
 314     # If we couldn't rip $srcdir out of `src1' then just do the best we can.
 315     # The point is to reduce the unnecessary noise in the logs.  Don't strip
 316     # out too much because different testcases with the same name can confuse
 317     # `test-tool'.
 318     if [string match "/*" $testcase] then {
 319         set testcase "[file tail [file dirname $src1]]/[file tail $src1]"
 320     }
 321
 322     # Loop through all of the option lists used for this test.
 323
 324     set count 0
 325     foreach option_pair $option_list {
 326
 327         # Pick out each set of options.
 328         set tst_option [lindex $option_pair 0]
 329         set alt_option [lindex $option_pair 1]
 330         set optstr ""
 331         if { ![string match $tst_option ""] \
 332              || ![string match $alt_option ""] } then {
 333             set optstr "\"$tst_option\",\"$alt_option\""
 334         }
 335         verbose "Testing $testcase, $optstr" 1
 336
 337         # There's a unique name for each executable we generate, based on
 338         # the set of options and how the pieces of the tests are compiled.
 339         set execname1 "${execbase}-${count}1"
 340         set execname2 "${execbase}-${count}2"
 341         set execname3 "${execbase}-${count}3"
 342         set execname4 "${execbase}-${count}4"
 343         incr count
 344
 345         file_on_host delete $execname1
 346         file_on_host delete $execname2
 347         file_on_host delete $execname3
 348         file_on_host delete $execname4
 349
 350         # Compile pieces with the alternate compiler; we'll catch problems
 351         # later.  Skip this if we don't have an alternate compiler.
 352         if { $use_alt != 0 } then {
 353             compat-use-alt-compiler
 354             compat-obj "$src2" "$obj2_alt" $alt_option $extra_flags_2 \
 355                        $optstr $compile_xfail_2
 356             compat-obj "$src3" "$obj3_alt" $alt_option $extra_flags_3 \
 357                        $optstr $compile_xfail_3
 358         }
 359
 360         # Compile pieces with the compiler under test.
 361         compat-use-tst-compiler
 362         compat-obj "$src1" "$obj1" $tst_option $extra_flags_1 $optstr ""
 363         compat-obj "$src2" "$obj2_tst" $tst_option $extra_flags_2 \
 364                    $optstr $compile_xfail_2
 365         compat-obj "$src3" "$obj3_tst" $tst_option $extra_flags_3 \
 366                    $optstr $compile_xfail_3
 367
 368         # Link (using the compiler under test), run, and clean up tests.
 369         compat-run "${obj2_tst}-${obj3_tst}" \
 370             "$obj1 $obj2_tst $obj3_tst" $execname1 \
 371             $tst_option $extra_flags_1 $optstr
 372
 373         # If we've got an alternate compiler try some combinations.
 374         if { $use_alt != 0 } then {
 375             compat-run "${obj2_tst}-${obj3_alt}" "$obj1 $obj2_tst $obj3_alt" \
 376                        $execname2 $tst_option $extra_flags_1 $optstr
 377             compat-run "${obj2_alt}-${obj3_tst}" "$obj1 $obj2_alt $obj3_tst" \
 378                        $execname3 $tst_option $extra_flags_1 $optstr
 379             compat-run "${obj2_alt}-${obj3_alt}" "$obj1 $obj2_alt $obj3_alt" \
 380                        $execname4 $tst_option $extra_flags_1 $optstr
 381         }
 382
 383         # Clean up object files.
 384         set files [glob -nocomplain ${sid}_*.o]
 385         if { $files != "" } {
 386             foreach objfile $files {
 387                 if { ![info exists gluefile] || $objfile != $gluefile } {
 388                     eval "file_on_host delete $objfile"
 389                 }
 390             }
 391         }
 392     }
 393 }