gcc/optc-gen.awk

   1 #  Copyright (C) 2003, 2004, 2007, 2008, 2009, 2010
   2 #  Free Software Foundation, Inc.
   3 #  Contributed by Kelley Cook, June 2004.
   4 #  Original code from Neil Booth, May 2003.
   5 #
   6 # This program is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by the
   8 # Free Software Foundation; either version 3, or (at your option) any
   9 # later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; see the file COPYING3.  If not see
  18 # <http://www.gnu.org/licenses/>.
  19
  20 # This Awk script reads in the option records generated from
  21 # opt-gather.awk, combines the flags of duplicate options and generates a
  22 # C file.
  23 #
  24 # This program uses functions from opt-functions.awk
  25 #
  26 # Usage: awk -f opt-functions.awk -f optc-gen.awk \
  27 #            [-v header_name=header.h] < inputfile > options.c
  28
  29 BEGIN {
  30         n_opts = 0
  31         n_langs = 0
  32         n_target_save = 0
  33         quote = "\042"
  34         comma = ","
  35         FS=SUBSEP
  36         # Default the name of header created from opth-gen.awk to options.h
  37         if (header_name == "") header_name="options.h"
  38 }
  39
  40 # Collect the text and flags of each option into an array
  41         {
  42                 if ($1 == "Language") {
  43                         langs[n_langs] = $2
  44                         n_langs++;
  45                 }
  46                 else if ($1 == "TargetSave") {
  47                         # Make sure the declarations are put in source order
  48                         target_save_decl[n_target_save] = $2
  49                         n_target_save++
  50                 }
  51                 else {
  52                         name = opt_args("Mask", $1)
  53                         if (name == "") {
  54                                 opts[n_opts]  = $1
  55                                 flags[n_opts] = $2
  56                                 help[n_opts]  = $3
  57                                 for (i = 4; i <= NF; i++)
  58                                         help[n_opts] = help[n_opts] " " $i
  59                                 n_opts++;
  60                         }
  61                 }
  62         }
  63
  64 # Dump that array of options into a C file.
  65 END {
  66 print "/* This file is auto-generated by optc-gen.awk.  */"
  67 print ""
  68 n_headers = split(header_name, headers, " ")
  69 for (i = 1; i <= n_headers; i++)
  70         print "#include " quote headers[i] quote
  71 print "#include " quote "opts.h" quote
  72 print "#include " quote "intl.h" quote
  73 print ""
  74 print "#ifdef GCC_DRIVER"
  75 print "int target_flags;"
  76 print "#else"
  77 print "#include " quote "flags.h" quote
  78 print "#include " quote "target.h" quote
  79 print "#endif /* GCC_DRIVER */"
  80 print ""
  81
  82 have_save = 0;
  83 for (i = 0; i < n_opts; i++) {
  84         if (flag_set_p("Save", flags[i]))
  85                 have_save = 1;
  86
  87         name = var_name(flags[i]);
  88         if (name == "")
  89                 continue;
  90
  91         if (flag_set_p("VarExists", flags[i])) {
  92                 # Need it for the gcc driver.
  93                 if (name in var_seen)
  94                         continue;
  95                 init = ""
  96                 gcc_driver = 1
  97         }
  98         else {
  99                 init = opt_args("Init", flags[i])
 100                 if (init != "")
 101                         init = " = " init;
 102                 else if (name in var_seen)
 103                         continue;
 104                 gcc_driver = 0
 105         }
 106
 107         if (gcc_driver == 1)
 108                 print "#ifdef GCC_DRIVER"
 109         print "/* Set by -" opts[i] "."
 110         print "   " help[i] "  */"
 111         print var_type(flags[i]) name init ";"
 112         if (gcc_driver == 1)
 113                 print "#endif /* GCC_DRIVER */"
 114         print ""
 115
 116         var_seen[name] = 1;
 117 }
 118
 119 print ""
 120 print "/* Local state variables.  */"
 121 for (i = 0; i < n_opts; i++) {
 122         name = static_var(opts[i], flags[i]);
 123         if (name != "")
 124                 print "static " var_type(flags[i]) name ";"
 125 }
 126 print ""
 127
 128 print "const char * const lang_names[] =\n{"
 129 for (i = 0; i < n_langs; i++) {
 130         macros[i] = "CL_" langs[i]
 131         gsub( "[^A-Za-z0-9_]", "X", macros[i] )
 132         s = substr("         ", length (macros[i]))
 133         print "  " quote langs[i] quote ","
 134     }
 135
 136 print "  0\n};\n"
 137 print "const unsigned int cl_options_count = N_OPTS;\n"
 138 print "const unsigned int cl_lang_count = " n_langs ";\n"
 139
 140 print "const struct cl_option cl_options[] =\n{"
 141
 142 j = 0
 143 for (i = 0; i < n_opts; i++) {
 144         back_chain[i] = "N_OPTS";
 145         indices[opts[i]] = j;
 146         # Combine the flags of identical switches.  Switches
 147         # appear many times if they are handled by many front
 148         # ends, for example.
 149         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 150                 flags[i + 1] = flags[i] " " flags[i + 1];
 151                 if (help[i + 1] == "")
 152                         help[i + 1] = help[i]
 153                 else if (help[i] != "" && help[i + 1] != help[i])
 154                         print "warning: multiple different help strings for " \
 155                                 opts[i] ":\n\t" help[i] "\n\t" help[i + 1] \
 156                                 | "cat 1>&2"
 157                 i++;
 158                 back_chain[i] = "N_OPTS";
 159                 indices[opts[i]] = j;
 160         }
 161         j++;
 162 }
 163
 164 for (i = 0; i < n_opts; i++) {
 165         # With identical flags, pick only the last one.  The
 166         # earlier loop ensured that it has all flags merged,
 167         # and a nonempty help text if one of the texts was nonempty.
 168         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 169                 i++;
 170         }
 171
 172         len = length (opts[i]);
 173         enum = opt_enum(opts[i])
 174
 175         # If this switch takes joined arguments, back-chain all
 176         # subsequent switches to it for which it is a prefix.  If
 177         # a later switch S is a longer prefix of a switch T, T
 178         # will be back-chained to S in a later iteration of this
 179         # for() loop, which is what we want.
 180         if (flag_set_p("Joined.*", flags[i])) {
 181                 for (j = i + 1; j < n_opts; j++) {
 182                         if (substr (opts[j], 1, len) != opts[i])
 183                                 break;
 184                         back_chain[j] = enum;
 185                 }
 186         }
 187
 188         s = substr("                                  ", length (opts[i]))
 189         if (i + 1 == n_opts)
 190                 comma = ""
 191
 192         if (help[i] == "")
 193                 hlp = "0"
 194         else
 195                 hlp = quote help[i] quote;
 196
 197         missing_arg_error = opt_args("MissingArgError", flags[i])
 198         if (missing_arg_error == "")
 199                 missing_arg_error = "0"
 200         else
 201                 missing_arg_error = quote missing_arg_error quote
 202
 203         neg = opt_args("Negative", flags[i]);
 204         if (neg != "")
 205                 idx = indices[neg]
 206         else {
 207                 if (flag_set_p("RejectNegative", flags[i]))
 208                         idx = -1;
 209                 else {
 210                         if (opts[i] ~ "^[Wfm]")
 211                                 idx = indices[opts[i]];
 212                         else
 213                                 idx = -1;
 214                 }
 215         }
 216         # Split the printf after %u to work around an ia64-hp-hpux11.23
 217         # awk bug.
 218         printf("  { %c-%s%c,\n    %s,\n    %s,\n    %s, %u,",
 219                quote, opts[i], quote, hlp, missing_arg_error,
 220                back_chain[i], len)
 221         printf(" %d,\n", idx)
 222         condition = opt_args("Condition", flags[i])
 223         cl_flags = switch_flags(flags[i])
 224         if (condition != "")
 225                 printf("#if %s\n" \
 226                        "    %s,\n" \
 227                        "#else\n" \
 228                        "    CL_DISABLED,\n" \
 229                        "#endif\n",
 230                        condition, cl_flags, cl_flags)
 231         else
 232                 printf("    %s,\n", cl_flags)
 233         printf("    %s, %s }%s\n", var_ref(opts[i], flags[i]),
 234                var_set(flags[i]), comma)
 235 }
 236
 237 print "};"
 238
 239 print "";
 240 print "#if !defined(GCC_DRIVER) && !defined(IN_LIBGCC2) && !defined(IN_TARGET_LIBS)"
 241 print "";
 242 print "/* Save optimization variables into a structure.  */"
 243 print "void";
 244 print "cl_optimization_save (struct cl_optimization *ptr)";
 245 print "{";
 246
 247 n_opt_char = 2;
 248 n_opt_short = 0;
 249 n_opt_int = 0;
 250 n_opt_other = 0;
 251 var_opt_char[0] = "optimize";
 252 var_opt_char[1] = "optimize_size";
 253 var_opt_range["optimize"] = "0, 255";
 254 var_opt_range["optimize_size"] = "0, 255";
 255
 256 # Sort by size to mimic how the structure is laid out to be friendlier to the
 257 # cache.
 258
 259 for (i = 0; i < n_opts; i++) {
 260         if (flag_set_p("Optimization", flags[i])) {
 261                 name = var_name(flags[i])
 262                 if(name == "")
 263                         continue;
 264
 265                 if(name in var_opt_seen)
 266                         continue;
 267
 268                 var_opt_seen[name]++;
 269                 otype = var_type_struct(flags[i]);
 270                 if (otype ~ "^((un)?signed +)?int *$")
 271                         var_opt_int[n_opt_int++] = name;
 272
 273                 else if (otype ~ "^((un)?signed +)?short *$")
 274                         var_opt_short[n_opt_short++] = name;
 275
 276                 else if (otype ~ "^((un)?signed +)?char *$") {
 277                         var_opt_char[n_opt_char++] = name;
 278                         if (otype ~ "^unsigned +char *$")
 279                                 var_opt_range[name] = "0, 255"
 280                         else if (otype ~ "^signed +char *$")
 281                                 var_opt_range[name] = "-128, 127"
 282                 }
 283                 else
 284                         var_opt_other[n_opt_other++] = name;
 285         }
 286 }
 287
 288 for (i = 0; i < n_opt_char; i++) {
 289         name = var_opt_char[i];
 290         if (var_opt_range[name] != "")
 291                 print "  gcc_assert (IN_RANGE (" name ", " var_opt_range[name] "));";
 292 }
 293
 294 print "";
 295 for (i = 0; i < n_opt_other; i++) {
 296         print "  ptr->" var_opt_other[i] " = " var_opt_other[i] ";";
 297 }
 298
 299 for (i = 0; i < n_opt_int; i++) {
 300         print "  ptr->" var_opt_int[i] " = " var_opt_int[i] ";";
 301 }
 302
 303 for (i = 0; i < n_opt_short; i++) {
 304         print "  ptr->" var_opt_short[i] " = " var_opt_short[i] ";";
 305 }
 306
 307 for (i = 0; i < n_opt_char; i++) {
 308         print "  ptr->" var_opt_char[i] " = " var_opt_char[i] ";";
 309 }
 310
 311 print "}";
 312
 313 print "";
 314 print "/* Restore optimization options from a structure.  */";
 315 print "void";
 316 print "cl_optimization_restore (struct cl_optimization *ptr)";
 317 print "{";
 318
 319 for (i = 0; i < n_opt_other; i++) {
 320         print "  " var_opt_other[i] " = ptr->" var_opt_other[i] ";";
 321 }
 322
 323 for (i = 0; i < n_opt_int; i++) {
 324         print "  " var_opt_int[i] " = ptr->" var_opt_int[i] ";";
 325 }
 326
 327 for (i = 0; i < n_opt_short; i++) {
 328         print "  " var_opt_short[i] " = ptr->" var_opt_short[i] ";";
 329 }
 330
 331 for (i = 0; i < n_opt_char; i++) {
 332         print "  " var_opt_char[i] " = ptr->" var_opt_char[i] ";";
 333 }
 334
 335 print "  targetm.override_options_after_change ();";
 336 print "}";
 337
 338 print "";
 339 print "/* Print optimization options from a structure.  */";
 340 print "void";
 341 print "cl_optimization_print (FILE *file,";
 342 print "                       int indent_to,";
 343 print "                       struct cl_optimization *ptr)";
 344 print "{";
 345
 346 print "  fputs (\"\\n\", file);";
 347 for (i = 0; i < n_opt_other; i++) {
 348         print "  if (ptr->" var_opt_other[i] ")";
 349         print "    fprintf (file, \"%*s%s (%#lx)\\n\",";
 350         print "             indent_to, \"\",";
 351         print "             \"" var_opt_other[i] "\",";
 352         print "             (unsigned long)ptr->" var_opt_other[i] ");";
 353         print "";
 354 }
 355
 356 for (i = 0; i < n_opt_int; i++) {
 357         print "  if (ptr->" var_opt_int[i] ")";
 358         print "    fprintf (file, \"%*s%s (%#x)\\n\",";
 359         print "             indent_to, \"\",";
 360         print "             \"" var_opt_int[i] "\",";
 361         print "             ptr->" var_opt_int[i] ");";
 362         print "";
 363 }
 364
 365 for (i = 0; i < n_opt_short; i++) {
 366         print "  if (ptr->" var_opt_short[i] ")";
 367         print "    fprintf (file, \"%*s%s (%#x)\\n\",";
 368         print "             indent_to, \"\",";
 369         print "             \"" var_opt_short[i] "\",";
 370         print "             ptr->" var_opt_short[i] ");";
 371         print "";
 372 }
 373
 374 for (i = 0; i < n_opt_char; i++) {
 375         print "  if (ptr->" var_opt_char[i] ")";
 376         print "    fprintf (file, \"%*s%s (%#x)\\n\",";
 377         print "             indent_to, \"\",";
 378         print "             \"" var_opt_char[i] "\",";
 379         print "             ptr->" var_opt_char[i] ");";
 380         print "";
 381 }
 382
 383 print "}";
 384
 385 print "";
 386 print "/* Save selected option variables into a structure.  */"
 387 print "void";
 388 print "cl_target_option_save (struct cl_target_option *ptr)";
 389 print "{";
 390
 391 n_target_char = 0;
 392 n_target_short = 0;
 393 n_target_int = 0;
 394 n_target_other = 0;
 395
 396 if (have_save) {
 397         for (i = 0; i < n_opts; i++) {
 398                 if (flag_set_p("Save", flags[i])) {
 399                         name = var_name(flags[i])
 400                         if(name == "")
 401                                 name = "target_flags";
 402
 403                         if(name in var_save_seen)
 404                                 continue;
 405
 406                         var_save_seen[name]++;
 407                         otype = var_type_struct(flags[i])
 408                         if (otype ~ "^((un)?signed +)?int *$")
 409                                 var_target_int[n_target_int++] = name;
 410
 411                         else if (otype ~ "^((un)?signed +)?short *$")
 412                                 var_target_short[n_target_short++] = name;
 413
 414                         else if (otype ~ "^((un)?signed +)?char *$") {
 415                                 var_target_char[n_target_char++] = name;
 416                                 if (otype ~ "^unsigned +char *$")
 417                                         var_target_range[name] = "0, 255"
 418                                 else if (otype ~ "^signed +char *$")
 419                                         var_target_range[name] = "-128, 127"
 420                         }
 421                         else
 422                                 var_target_other[n_target_other++] = name;
 423                 }
 424         }
 425 } else {
 426         var_target_int[n_target_int++] = "target_flags";
 427 }
 428
 429 have_assert = 0;
 430 for (i = 0; i < n_target_char; i++) {
 431         name = var_target_char[i];
 432         if (var_target_range[name] != "") {
 433                 have_assert = 1;
 434                 print "  gcc_assert (IN_RANGE (" name ", " var_target_range[name] "));";
 435         }
 436 }
 437
 438 if (have_assert)
 439         print "";
 440
 441 print "  if (targetm.target_option.save)";
 442 print "    targetm.target_option.save (ptr);";
 443 print "";
 444
 445 for (i = 0; i < n_target_other; i++) {
 446         print "  ptr->" var_target_other[i] " = " var_target_other[i] ";";
 447 }
 448
 449 for (i = 0; i < n_target_int; i++) {
 450         print "  ptr->" var_target_int[i] " = " var_target_int[i] ";";
 451 }
 452
 453 for (i = 0; i < n_target_short; i++) {
 454         print "  ptr->" var_target_short[i] " = " var_target_short[i] ";";
 455 }
 456
 457 for (i = 0; i < n_target_char; i++) {
 458         print "  ptr->" var_target_char[i] " = " var_target_char[i] ";";
 459 }
 460
 461 print "}";
 462
 463 print "";
 464 print "/* Restore selected current options from a structure.  */";
 465 print "void";
 466 print "cl_target_option_restore (struct cl_target_option *ptr)";
 467 print "{";
 468
 469 for (i = 0; i < n_target_other; i++) {
 470         print "  " var_target_other[i] " = ptr->" var_target_other[i] ";";
 471 }
 472
 473 for (i = 0; i < n_target_int; i++) {
 474         print "  " var_target_int[i] " = ptr->" var_target_int[i] ";";
 475 }
 476
 477 for (i = 0; i < n_target_short; i++) {
 478         print "  " var_target_short[i] " = ptr->" var_target_short[i] ";";
 479 }
 480
 481 for (i = 0; i < n_target_char; i++) {
 482         print "  " var_target_char[i] " = ptr->" var_target_char[i] ";";
 483 }
 484
 485 # This must occur after the normal variables in case the code depends on those
 486 # variables.
 487 print "";
 488 print "  if (targetm.target_option.restore)";
 489 print "    targetm.target_option.restore (ptr);";
 490
 491 print "}";
 492
 493 print "";
 494 print "/* Print optimization options from a structure.  */";
 495 print "void";
 496 print "cl_target_option_print (FILE *file,";
 497 print "                        int indent,";
 498 print "                        struct cl_target_option *ptr)";
 499 print "{";
 500
 501 print "  fputs (\"\\n\", file);";
 502 for (i = 0; i < n_target_other; i++) {
 503         print "  if (ptr->" var_target_other[i] ")";
 504         print "    fprintf (file, \"%*s%s (%#lx)\\n\",";
 505         print "             indent, \"\",";
 506         print "             \"" var_target_other[i] "\",";
 507         print "             (unsigned long)ptr->" var_target_other[i] ");";
 508         print "";
 509 }
 510
 511 for (i = 0; i < n_target_int; i++) {
 512         print "  if (ptr->" var_target_int[i] ")";
 513         print "    fprintf (file, \"%*s%s (%#x)\\n\",";
 514         print "             indent, \"\",";
 515         print "             \"" var_target_int[i] "\",";
 516         print "             ptr->" var_target_int[i] ");";
 517         print "";
 518 }
 519
 520 for (i = 0; i < n_target_short; i++) {
 521         print "  if (ptr->" var_target_short[i] ")";
 522         print "    fprintf (file, \"%*s%s (%#x)\\n\",";
 523         print "             indent, \"\",";
 524         print "             \"" var_target_short[i] "\",";
 525         print "             ptr->" var_target_short[i] ");";
 526         print "";
 527 }
 528
 529 for (i = 0; i < n_target_char; i++) {
 530         print "  if (ptr->" var_target_char[i] ")";
 531         print "    fprintf (file, \"%*s%s (%#x)\\n\",";
 532         print "             indent, \"\",";
 533         print "             \"" var_target_char[i] "\",";
 534         print "             ptr->" var_target_char[i] ");";
 535         print "";
 536 }
 537
 538 print "";
 539 print "  if (targetm.target_option.print)";
 540 print "    targetm.target_option.print (file, indent, ptr);";
 541
 542 print "}";
 543 print "#endif";
 544
 545 }