gcc/ada/xr_tabls.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             X R  _ T A B L S                             --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  We need comment here saying what this package is???
  28
  29 with GNAT.OS_Lib;
  30
  31 package Xr_Tabls is
  32
  33    -------------------
  34    -- Project files --
  35    -------------------
  36
  37    function ALI_File_Name (Ada_File_Name : String) return String;
  38    --  Returns the ali file name corresponding to Ada_File_Name
  39
  40    procedure Create_Project_File (Name : String);
  41    --  Open and parse a new project file. If the file Name could not be
  42    --  opened or is not a valid project file, then a project file associated
  43    --  with the standard default directories is returned
  44
  45    function Next_Obj_Dir return String;
  46    --  Returns the next directory to visit to find related ali files
  47    --  If there are no more such directories, returns a null string.
  48
  49    function Current_Obj_Dir return String;
  50    --  Returns the obj_dir which was returned by the last Next_Obj_Dir call
  51
  52    procedure Reset_Obj_Dir;
  53    --  Reset the iterator for Obj_Dir
  54
  55    ------------
  56    -- Tables --
  57    ------------
  58
  59    type Declaration_Reference is private;
  60    Empty_Declaration : constant Declaration_Reference;
  61
  62    type Declaration_Array is array (Natural range <>) of Declaration_Reference;
  63    type Declaration_Array_Access is access Declaration_Array;
  64
  65    type File_Reference is private;
  66    Empty_File : constant File_Reference;
  67
  68    type Reference is private;
  69    Empty_Reference : constant Reference;
  70
  71    type Reference_Array is array (Natural range <>) of Reference;
  72    type Reference_Array_Access is access Reference_Array;
  73
  74    procedure Free (Arr : in out Reference_Array_Access);
  75
  76    function Add_Declaration
  77      (File_Ref     : File_Reference;
  78       Symbol       : String;
  79       Line         : Natural;
  80       Column       : Natural;
  81       Decl_Type    : Character;
  82       Remove_Only  : Boolean := False;
  83       Symbol_Match : Boolean := True)
  84       return         Declaration_Reference;
  85    --  Add a new declaration in the table and return the index to it. Decl_Type
  86    --  is the type of the entity Any previous instance of this entity in the
  87    --  htable is removed. If Remove_Only is True, then any previous instance is
  88    --  removed, but the new entity is never inserted. Symbol_Match should be
  89    --  set to False if the name of the symbol doesn't match the pattern from
  90    --  the command line. In that case, the entity will not be output by
  91    --  gnatfind. If Symbol_Match is True, the entity will only be output if the
  92    --  file name itself matches.
  93
  94    procedure Add_Parent
  95      (Declaration : in out Declaration_Reference;
  96       Symbol      : String;
  97       Line        : Natural;
  98       Column      : Natural;
  99       File_Ref    : File_Reference);
 100    --  The parent declaration (Symbol in file File_Ref at position Line and
 101    --  Column) information is added to Declaration.
 102
 103    function Add_To_Xref_File
 104      (File_Name       : String;
 105       Visited         : Boolean := True;
 106       Emit_Warning    : Boolean := False;
 107       Gnatchop_File   : String  := "";
 108       Gnatchop_Offset : Integer := 0)
 109       return            File_Reference;
 110    --  Add a new reference to a file in the table. Ref is used to return the
 111    --  index in the table where this file is stored. Visited is the value which
 112    --  will be used in the table (if True, the file will not be returned by
 113    --  Next_Unvisited_File). If Emit_Warning is True and the ali file does
 114    --  not exist or does not have cross-referencing information, then a
 115    --  warning will be emitted. Gnatchop_File is the name of the file that
 116    --  File_Name was extracted from through a call to "gnatchop -r" (using
 117    --  pragma Source_Reference). Gnatchop_Offset should be the index of the
 118    --  first line of File_Name within the Gnatchop_File.
 119
 120    procedure Add_Line
 121      (File   : File_Reference;
 122       Line   : Natural;
 123       Column : Natural);
 124    --  Add a new reference in a file, which the user has provided on the
 125    --  command line. This is used for an optimized matching algorithm.
 126
 127    procedure Add_Reference
 128      (Declaration   : Declaration_Reference;
 129       File_Ref      : File_Reference;
 130       Line          : Natural;
 131       Column        : Natural;
 132       Ref_Type      : Character;
 133       Labels_As_Ref : Boolean);
 134    --  Add a new reference (Ref_Type = 'r'), body (Ref_Type = 'b') or
 135    --  modification (Ref_Type = 'm') to an entity. If Labels_As_Ref is True,
 136    --  then the references to the entity after the end statements ("end Foo")
 137    --  are counted as actual references. This means that the entity will never
 138    --  be reported as unreferenced (for instance in the case of gnatxref -u).
 139
 140    function Get_Declarations
 141      (Sorted : Boolean := True)
 142       return   Declaration_Array_Access;
 143    --  Return a sorted list of all the declarations in the application.
 144    --  Freeing this array is the responsability of the caller, however it
 145    --  shouldn't free the actual contents of the array, which are pointers
 146    --  to internal data
 147
 148    function References_Count
 149      (Decl       : Declaration_Reference;
 150       Get_Reads  : Boolean := False;
 151       Get_Writes : Boolean := False;
 152       Get_Bodies : Boolean := False)
 153       return       Natural;
 154    --  Return the number of references in Decl for the categories specified
 155    --  by the Get_* parameters (read-only accesses, write accesses and bodies)
 156
 157    function Get_References
 158      (Decl : Declaration_Reference;
 159       Get_Reads  : Boolean := False;
 160       Get_Writes : Boolean := False;
 161       Get_Bodies : Boolean := False)
 162       return       Reference_Array_Access;
 163    --  Return a sorted list of all references to the entity in decl. The
 164    --  parameters Get_* are used to specify what kind of references should be
 165    --  merged and returned (read-only accesses, write accesses and bodies).
 166
 167    function Get_Column (Decl : Declaration_Reference) return String;
 168    function Get_Column (Ref : Reference) return String;
 169
 170    function Get_Declaration
 171      (File_Ref : File_Reference;
 172       Line     : Natural;
 173       Column   : Natural)
 174       return     Declaration_Reference;
 175    --  Returns reference to the declaration found in file File_Ref at the
 176    --  given Line and Column
 177
 178    function Get_Parent
 179      (Decl : Declaration_Reference)
 180       return Declaration_Reference;
 181    --  Returns reference to Decl's parent declaration
 182
 183    function Get_Emit_Warning (File : File_Reference) return Boolean;
 184    --  Returns the Emit_Warning field of the structure
 185
 186    function Get_Gnatchop_File
 187      (File     : File_Reference;
 188       With_Dir : Boolean := False)
 189       return     String;
 190    function Get_Gnatchop_File
 191      (Ref      : Reference;
 192       With_Dir : Boolean := False)
 193       return     String;
 194    function Get_Gnatchop_File
 195      (Decl     : Declaration_Reference;
 196       With_Dir : Boolean := False)
 197       return     String;
 198    --  Return the name of the file that File was extracted from through a
 199    --  call to "gnatchop -r". The file name for File is returned if File
 200    --  was not extracted from such a file. The directory will be given only
 201    --  if With_Dir is True.
 202
 203    function Get_File
 204      (Decl     : Declaration_Reference;
 205       With_Dir : Boolean := False) return String;
 206    pragma Inline (Get_File);
 207    --  Extract column number or file name from reference
 208
 209    function Get_File
 210      (Ref      : Reference;
 211       With_Dir : Boolean := False) return String;
 212    pragma Inline (Get_File);
 213
 214    function Get_File
 215      (File     : File_Reference;
 216       With_Dir : Boolean := False;
 217       Strip    : Natural := 0) return String;
 218    --  Returns the file name (and its directory if With_Dir is True or the user
 219    --  has used the -f switch on the command line. If Strip is not 0, then the
 220    --  last Strip-th "-..." substrings are removed first. For instance, with
 221    --  Strip=2, a file name "parent-child1-child2-child3.ali" would be returned
 222    --  as "parent-child1.ali". This is used when looking for the ALI file to
 223    --  use for a package, since for separates with have to use the parent's
 224    --  ALI. The null string is returned if there is no such parent unit.
 225    --
 226    --  Note that this version of Get_File is not inlined
 227
 228    function Get_File_Ref (Ref : Reference)              return File_Reference;
 229    function Get_Line     (Decl : Declaration_Reference) return String;
 230    function Get_Line     (Ref : Reference)              return String;
 231    function Get_Symbol   (Decl : Declaration_Reference) return String;
 232    function Get_Type     (Decl : Declaration_Reference) return Character;
 233    function Is_Parameter (Decl : Declaration_Reference) return Boolean;
 234    --  Functions that return the contents of a declaration
 235
 236    function Get_Source_Line (Ref : Reference)              return String;
 237    function Get_Source_Line (Decl : Declaration_Reference) return String;
 238    --  Return the source line associated with the reference
 239
 240    procedure Grep_Source_Files;
 241    --  Parse all the source files which have at least one reference, and grep
 242    --  the appropriate source lines so that we'll be able to display them. This
 243    --  function should be called once all the .ali files have been parsed, and
 244    --  only if the appropriate user switch
 245    --  has been used (gnatfind -s).
 246    --
 247    --  Note: To save memory, the strings for the source lines are shared. Thus
 248    --  it is no longer possible to free the references, or we would free the
 249    --  same chunk multiple times. It doesn't matter, though, since this is only
 250    --  called once, prior to exiting gnatfind.
 251
 252    function Longest_File_Name return Natural;
 253    --  Returns the longest file name found
 254
 255    function Match (Decl : Declaration_Reference) return Boolean;
 256    --  Return True if the declaration matches
 257
 258    function Match
 259      (File   : File_Reference;
 260       Line   : Natural;
 261       Column : Natural)
 262       return   Boolean;
 263    --  Returns True if File:Line:Column was given on the command line
 264    --  by the user
 265
 266    function Next_Unvisited_File return File_Reference;
 267    --  Returns the next unvisited library file in the list If there is no more
 268    --  unvisited file, return Empty_File. Two calls to this subprogram will
 269    --  return different files.
 270
 271    procedure Set_Default_Match (Value : Boolean);
 272    --  Set the default value for match in declarations.
 273    --  This is used so that if no file was provided in the
 274    --  command line, then every file match
 275
 276    procedure Reset_Directory (File : File_Reference);
 277    --  Reset the cached directory for file. Next time Get_File is called, the
 278    --  directory willl be recomputed.
 279
 280    procedure Set_Unvisited (File_Ref : File_Reference);
 281    --  Set File_Ref as unvisited. So Next_Unvisited_File will return it
 282
 283    procedure Read_File
 284      (File_Name : String;
 285       Contents  : out GNAT.OS_Lib.String_Access);
 286    --  Reads File_Name into the newly allocated strig Contents. Types.EOF
 287    --  character will be added to the returned Contents to simplify parsing.
 288    --  Name_Error is raised if the file was not found. End_Error is raised if
 289    --  the file could not be read correctly. For most systems correct reading
 290    --  means that the number of bytes read is equal to the file size. The
 291    --  exception is OpenVMS where correct reading means that the number of
 292    --  bytes read is less than or equal to the file size.
 293
 294 private
 295    type Project_File (Src_Dir_Length, Obj_Dir_Length : Natural) is record
 296       Src_Dir : String (1 .. Src_Dir_Length);
 297       Src_Dir_Index : Integer;
 298
 299       Obj_Dir            : String (1 .. Obj_Dir_Length);
 300       Obj_Dir_Index      : Integer;
 301       Last_Obj_Dir_Start : Natural;
 302    end record;
 303
 304    type Project_File_Ptr is access all Project_File;
 305    --  This is actually a list of all the directories to be searched,
 306    --  either for source files or for library files
 307
 308    type Ref_In_File;
 309    type Ref_In_File_Ptr is access all Ref_In_File;
 310
 311    type Ref_In_File is record
 312       Line   : Natural;
 313       Column : Natural;
 314       Next   : Ref_In_File_Ptr := null;
 315    end record;
 316
 317    type File_Record;
 318    type File_Reference is access all File_Record;
 319
 320    Empty_File : constant File_Reference := null;
 321    type Cst_String_Access is access constant String;
 322
 323    procedure Free (Str : in out Cst_String_Access);
 324
 325    type File_Record is record
 326       File            : Cst_String_Access;
 327       Dir             : GNAT.OS_Lib.String_Access;
 328       Lines           : Ref_In_File_Ptr := null;
 329       Visited         : Boolean         := False;
 330       Emit_Warning    : Boolean         := False;
 331       Gnatchop_File   : GNAT.OS_Lib.String_Access   := null;
 332       Gnatchop_Offset : Integer         := 0;
 333       Next            : File_Reference  := null;
 334    end record;
 335    --  Holds a reference to a source file, that was referenced in at least one
 336    --  ALI file. Gnatchop_File will contain the name of the file that File was
 337    --  extracted From. Gnatchop_Offset contains the index of the first line of
 338    --  File within Gnatchop_File. These two fields are used to properly support
 339    --  gnatchop files and pragma Source_Reference.
 340    --
 341    --  Lines is used for files that were given on the command line, to
 342    --  memorize the lines and columns that the user specified.
 343
 344    type Reference_Record;
 345    type Reference is access all Reference_Record;
 346
 347    Empty_Reference : constant Reference := null;
 348
 349    type Reference_Record is record
 350       File        : File_Reference;
 351       Line        : Natural;
 352       Column      : Natural;
 353       Source_Line : Cst_String_Access;
 354       Next        : Reference := null;
 355    end record;
 356    --  File is a reference to the Ada source file
 357    --  Source_Line is the Line as it appears in the source file. This
 358    --  field is only used when the switch is set on the command line of
 359    --  gnatfind.
 360
 361    type Declaration_Record;
 362    type Declaration_Reference is access all Declaration_Record;
 363
 364    Empty_Declaration : constant Declaration_Reference := null;
 365
 366    type Declaration_Record (Symbol_Length : Natural) is record
 367       Key          : Cst_String_Access;
 368       Symbol       : String (1 .. Symbol_Length);
 369       Decl         : Reference;
 370       Is_Parameter : Boolean := False; -- True if entity is subprog param
 371       Decl_Type    : Character;
 372       Body_Ref     : Reference := null;
 373       Ref_Ref      : Reference := null;
 374       Modif_Ref    : Reference := null;
 375       Match        : Boolean := False;
 376       Par_Symbol   : Declaration_Reference := null;
 377       Next         : Declaration_Reference := null;
 378    end record;
 379    --  The lists of referenced (Body_Ref, Ref_Ref and Modif_Ref) are
 380    --  kept unsorted until the results needs to be printed. This saves
 381    --  lots of time while the internal tables are created.
 382
 383    pragma Inline (Get_Column);
 384    pragma Inline (Get_Emit_Warning);
 385    pragma Inline (Get_File_Ref);
 386    pragma Inline (Get_Line);
 387    pragma Inline (Get_Symbol);
 388    pragma Inline (Get_Type);
 389    pragma Inline (Longest_File_Name);
 390 end Xr_Tabls;