gcc/opt-functions.awk

   1 #  Copyright (C) 2003,2004 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 2, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19 # Some common subroutines for use by opt[ch]-gen.awk.
  20
  21 # Return nonzero if FLAGS contains a flag matching REGEX.
  22 function flag_set_p(regex, flags)
  23 {
  24         return (" " flags " ") ~ (" " regex " ")
  25 }
  26
  27 # Return STRING if FLAGS contains a flag matching regexp REGEX,
  28 # otherwise return the empty string.
  29 function test_flag(regex, flags, string)
  30 {
  31         if (flag_set_p(regex, flags))
  32                 return string
  33         return ""
  34 }
  35
  36 # If FLAGS contains a "NAME(...argument...)" flag, return the value
  37 # of the argument.  Return the empty string otherwise.
  38 function opt_args(name, flags)
  39 {
  40         flags = " " flags
  41         if (flags !~ " " name "\\(")
  42                 return ""
  43         sub(".* " name "\\(", "", flags)
  44         sub("\\).*", "", flags)
  45
  46         return flags
  47 }
  48
  49 # Return the Nth comma-separated element of S.  Return the empty string
  50 # if S does not contain N elements.
  51 function nth_arg(n, s)
  52 {
  53         while (n-- > 0) {
  54                 if (s !~ ",")
  55                         return ""
  56                 sub("[^,]*, *", "", s)
  57         }
  58         sub(",.*", "", s)
  59         return s
  60 }
  61
  62 # Return a bitmask of CL_* values for option flags FLAGS.
  63 function switch_flags (flags)
  64 {
  65         result = "0"
  66         for (j = 0; j < n_langs; j++) {
  67                 regex = langs[j]
  68                 gsub ( "\\+", "\\+", regex )
  69                 result = result test_flag(regex, flags, " | " macros[j])
  70         }
  71         result = result \
  72           test_flag("Common", flags, " | CL_COMMON") \
  73           test_flag("Target", flags, " | CL_TARGET") \
  74           test_flag("Joined", flags, " | CL_JOINED") \
  75           test_flag("JoinedOrMissing", flags, " | CL_JOINED | CL_MISSING_OK") \
  76           test_flag("Separate", flags, " | CL_SEPARATE") \
  77           test_flag("RejectNegative", flags, " | CL_REJECT_NEGATIVE") \
  78           test_flag("UInteger", flags, " | CL_UINTEGER") \
  79           test_flag("Undocumented", flags,  " | CL_UNDOCUMENTED") \
  80           test_flag("Report", flags, " | CL_REPORT")
  81         sub( "^0 \\| ", "", result )
  82         return result
  83 }
  84
  85 # If FLAGS includes a Var flag, return the name of the variable it specifies.
  86 # Return the empty string otherwise.
  87 function var_name(flags)
  88 {
  89         return nth_arg(0, opt_args("Var", flags))
  90 }
  91
  92 # Return the type of variable that should be associated with the given flags.
  93 function var_type(flags)
  94 {
  95         if (!flag_set_p("Joined.*", flags))
  96                 return "int "
  97         else if (flag_set_p("UInteger", flags))
  98                 return "int "
  99         else
 100                 return "const char *"
 101 }
 102
 103 # Given that an option has flags FLAGS, return an initializer for the
 104 # "var_cond" and "var_value" fields of its cl_options[] entry.
 105 function var_set(flags)
 106 {
 107         s = nth_arg(1, opt_args("Var", flags))
 108         if (s != "")
 109                 return "CLVC_EQUAL, " s
 110         s = opt_args("Mask", flags);
 111         if (s != "") {
 112                 vn = var_name(flags);
 113                 if (vn)
 114                         return "CLVC_BIT_SET, OPTION_MASK_" s
 115                 else
 116                         return "CLVC_BIT_SET, MASK_" s
 117         }
 118         s = nth_arg(0, opt_args("InverseMask", flags));
 119         if (s != "") {
 120                 vn = var_name(flags);
 121                 if (vn)
 122                         return "CLVC_BIT_CLEAR, OPTION_MASK_" s
 123                 else
 124                         return "CLVC_BIT_CLEAR, MASK_" s
 125         }
 126         if (var_type(flags) == "const char *")
 127                 return "CLVC_STRING, 0"
 128         return "CLVC_BOOLEAN, 0"
 129 }
 130
 131 # Given that an option has flags FLAGS, return an initializer for the
 132 # "flag_var" field of its cl_options[] entry.
 133 function var_ref(flags)
 134 {
 135         name = var_name(flags)
 136         if (name != "")
 137                 return "&" name
 138         if (opt_args("Mask", flags) != "")
 139                 return "&target_flags"
 140         if (opt_args("InverseMask", flags) != "")
 141                 return "&target_flags"
 142         return "0"
 143 }