| blob | 4b031f7117f6b193271e46474640abac8e7172b8 |
1 dnl
2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
3 dnl
4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
5 dnl end of configure. This lets tested variables be reassigned, and the
6 dnl conditional will depend on the final state of the variable. For a simple
7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
8 dnl
9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
11 m4_divert_text([glibcxx_diversion],dnl
12 AM_CONDITIONAL([$1],[$2])
13 )dnl
14 ])dnl
15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
18 dnl
19 dnl Check to see what architecture and operating system we are compiling
20 dnl for. Also, if architecture- or OS-specific flags are required for
21 dnl compilation, pick them up here.
22 dnl
23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
24 . $glibcxx_srcdir/configure.host
25 AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
26 AC_MSG_NOTICE([OS config directory is $os_include_dir])
27 ])
29 dnl
30 dnl Initialize the rest of the library configury. At this point we have
31 dnl variables like $host.
32 dnl
33 dnl Sets:
34 dnl SUBDIRS
35 dnl Substs:
36 dnl glibcxx_builddir (absolute path)
37 dnl glibcxx_srcdir (absolute path)
38 dnl toplevel_builddir (absolute path)
39 dnl toplevel_srcdir (absolute path)
40 dnl with_cross_host
41 dnl with_newlib
42 dnl with_target_subdir
43 dnl plus
44 dnl - the variables in GLIBCXX_CHECK_HOST / configure.host
45 dnl - default settings for all AM_CONFITIONAL test variables
46 dnl - lots of tools, like CC and CXX
47 dnl
48 AC_DEFUN([GLIBCXX_CONFIGURE], [
49 # Keep these sync'd with the list in Makefile.am. The first provides an
50 # expandable list at autoconf time; the second provides an expandable list
51 # (i.e., shell variable) at configure time.
52 m4_define([glibcxx_SUBDIRS],[include libsupc++ src src/c++98 src/c++11 src/filesystem doc po testsuite python])
53 SUBDIRS='glibcxx_SUBDIRS'
55 # These need to be absolute paths, yet at the same time need to
56 # canonicalize only relative paths, because then amd will not unmount
57 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
58 glibcxx_builddir=`${PWDCMD-pwd}`
59 case $srcdir in
60 [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
61 *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
62 esac
63 toplevel_builddir=${glibcxx_builddir}/..
64 toplevel_srcdir=${glibcxx_srcdir}/..
65 AC_SUBST(glibcxx_builddir)
66 AC_SUBST(glibcxx_srcdir)
67 AC_SUBST(toplevel_builddir)
68 AC_SUBST(toplevel_srcdir)
70 # We use these options to decide which functions to include. They are
71 # set from the top level.
72 AC_ARG_WITH([target-subdir],
73 AC_HELP_STRING([--with-target-subdir=SUBDIR],
74 [configuring in a subdirectory]))
76 AC_ARG_WITH([cross-host],
77 AC_HELP_STRING([--with-cross-host=HOST],
78 [configuring with a cross compiler]))
80 AC_ARG_WITH([newlib],
81 AC_HELP_STRING([--with-newlib],
82 [assume newlib as a system C library]))
84 # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
85 # available). Uncomment the next line to force a particular method.
86 AC_PROG_LN_S
87 #LN_S='cp -p'
89 AC_CHECK_TOOL(AS, as)
90 AC_CHECK_TOOL(AR, ar)
91 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
93 AM_MAINTAINER_MODE
95 # Set up safe default values for all subsequent AM_CONDITIONAL tests
96 # which are themselves conditionally expanded.
97 ## (Right now, this only matters for enable_wchar_t, but nothing prevents
98 ## other macros from doing the same. This should be automated.) -pme
100 # Check for C library flavor since GNU/Linux platforms use different
101 # configuration directories depending on the C library in use.
102 AC_EGREP_CPP([_using_uclibc], [
103 #include <stdio.h>
104 #if __UCLIBC__
105 _using_uclibc
106 #endif
107 ], uclibc=yes, uclibc=no)
109 AC_EGREP_CPP([_using_bionic], [
110 #include <stdio.h>
111 #if __BIONIC__
112 _using_bionic
113 #endif
114 ], bionic=yes, bionic=no)
116 # Find platform-specific directories containing configuration info.
117 # Also possibly modify flags used elsewhere, as needed by the platform.
118 GLIBCXX_CHECK_HOST
119 ])
122 dnl
123 dnl Tests for newer compiler features, or features that are present in newer
124 dnl compiler versions but not older compiler versions still in use, should
125 dnl be placed here.
126 dnl
127 dnl Defines:
128 dnl WERROR='-Werror' if requested and possible; g++'s that lack the
129 dnl new inlining code or the new system_header pragma will die on -Werror.
130 dnl Leave it out by default and use maint-mode to use it.
131 dnl SECTION_FLAGS='-ffunction-sections -fdata-sections' if
132 dnl compiler supports it and the user has not requested debug mode.
133 dnl
134 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
135 # All these tests are for C++; save the language and the compiler flags.
136 # The CXXFLAGS thing is suspicious, but based on similar bits previously
137 # found in GLIBCXX_CONFIGURE.
138 AC_LANG_SAVE
139 AC_LANG_CPLUSPLUS
140 ac_test_CXXFLAGS="${CXXFLAGS+set}"
141 ac_save_CXXFLAGS="$CXXFLAGS"
143 # Check for maintainer-mode bits.
144 if test x"$USE_MAINTAINER_MODE" = xno; then
145 WERROR=''
146 else
147 WERROR='-Werror'
148 fi
150 # Check for -ffunction-sections -fdata-sections
151 AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
152 CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
153 AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
154 if test "$ac_test_CXXFLAGS" = set; then
155 CXXFLAGS="$ac_save_CXXFLAGS"
156 else
157 # this is the suspicious part
158 CXXFLAGS=''
159 fi
160 if test x"$ac_fdsections" = x"yes"; then
161 SECTION_FLAGS='-ffunction-sections -fdata-sections'
162 fi
163 AC_MSG_RESULT($ac_fdsections)
165 AC_LANG_RESTORE
166 AC_SUBST(WERROR)
167 AC_SUBST(SECTION_FLAGS)
168 ])
171 dnl
172 dnl Check if the assembler used supports disabling generation of hardware
173 dnl capabilities. This is only supported by Sun as at the moment.
174 dnl
175 dnl Defines:
176 dnl HWCAP_FLAGS='-Wa,-nH' if possible.
177 dnl
178 AC_DEFUN([GLIBCXX_CHECK_ASSEMBLER_HWCAP], [
179 test -z "$HWCAP_FLAGS" && HWCAP_FLAGS=''
181 # Restrict the test to Solaris, other assemblers (e.g. AIX as) have -nH
182 # with a different meaning.
183 case ${target_os} in
184 solaris2*)
185 ac_save_CFLAGS="$CFLAGS"
186 CFLAGS="$CFLAGS -Wa,-nH"
188 AC_MSG_CHECKING([for as that supports -Wa,-nH])
189 AC_TRY_COMPILE([], [return 0;], [ac_hwcap_flags=yes],[ac_hwcap_flags=no])
190 if test "$ac_hwcap_flags" = "yes"; then
191 HWCAP_FLAGS="-Wa,-nH $HWCAP_FLAGS"
192 fi
193 AC_MSG_RESULT($ac_hwcap_flags)
195 CFLAGS="$ac_save_CFLAGS"
196 ;;
197 esac
199 AC_SUBST(HWCAP_FLAGS)
200 ])
203 dnl
204 dnl If GNU ld is in use, check to see if tricky linker opts can be used. If
205 dnl the native linker is in use, all variables will be defined to something
206 dnl safe (like an empty string).
207 dnl
208 dnl Defines:
209 dnl SECTION_LDFLAGS='-Wl,--gc-sections' if possible
210 dnl OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
211 dnl LD (as a side effect of testing)
212 dnl Sets:
213 dnl with_gnu_ld
214 dnl glibcxx_ld_is_gold (set to "no" or "yes")
215 dnl glibcxx_gnu_ld_version (possibly)
216 dnl
217 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
218 dnl set glibcxx_gnu_ld_version to 12345. Zeros cause problems.
219 dnl
220 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
221 # If we're not using GNU ld, then there's no point in even trying these
222 # tests. Check for that first. We should have already tested for gld
223 # by now (in libtool), but require it now just to be safe...
224 test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
225 test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
226 AC_REQUIRE([AC_PROG_LD])
227 AC_REQUIRE([AC_PROG_AWK])
229 # The name set by libtool depends on the version of libtool. Shame on us
230 # for depending on an impl detail, but c'est la vie. Older versions used
231 # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
232 # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
233 # makes sense). We'll test with_gnu_ld everywhere else, so if that isn't
234 # set (hence we're using an older libtool), then set it.
235 if test x${with_gnu_ld+set} != xset; then
236 if test x${ac_cv_prog_gnu_ld+set} != xset; then
237 # We got through "ac_require(ac_prog_ld)" and still not set? Huh?
238 with_gnu_ld=no
239 else
240 with_gnu_ld=$ac_cv_prog_gnu_ld
241 fi
242 fi
244 # Start by getting the version number. I think the libtool test already
245 # does some of this, but throws away the result.
246 glibcxx_ld_is_gold=no
247 if test x"$with_gnu_ld" = x"yes"; then
248 AC_MSG_CHECKING([for ld version])
249 changequote(,)
250 if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
251 glibcxx_ld_is_gold=yes
252 fi
253 ldver=`$LD --version 2>/dev/null |
254 sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
255 changequote([,])
256 glibcxx_gnu_ld_version=`echo $ldver | \
257 $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
258 AC_MSG_RESULT($glibcxx_gnu_ld_version)
259 fi
261 # Set --gc-sections.
262 glibcxx_have_gc_sections=no
263 if test "$glibcxx_ld_is_gold" = "yes"; then
264 if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
265 glibcxx_have_gc_sections=yes
266 fi
267 else
268 glibcxx_gcsections_min_ld=21602
269 if test x"$with_gnu_ld" = x"yes" &&
270 test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
271 glibcxx_have_gc_sections=yes
272 fi
273 fi
274 if test "$glibcxx_have_gc_sections" = "yes"; then
275 # Sufficiently young GNU ld it is! Joy and bunny rabbits!
276 # NB: This flag only works reliably after 2.16.1. Configure tests
277 # for this are difficult, so hard wire a value that should work.
279 ac_test_CFLAGS="${CFLAGS+set}"
280 ac_save_CFLAGS="$CFLAGS"
281 CFLAGS='-Wl,--gc-sections'
283 # Check for -Wl,--gc-sections
284 AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
285 AC_TRY_LINK([ int one(void) { return 1; }
286 int two(void) { return 2; }
287 ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
288 if test "$ac_gcsections" = "yes"; then
289 rm -f conftest.c
290 touch conftest.c
291 if $CC -c conftest.c; then
292 if $LD --gc-sections -o conftest conftest.o 2>&1 | \
293 grep "Warning: gc-sections option ignored" > /dev/null; then
294 ac_gcsections=no
295 fi
296 fi
297 rm -f conftest.c conftest.o conftest
298 fi
299 if test "$ac_gcsections" = "yes"; then
300 SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
301 fi
302 AC_MSG_RESULT($ac_gcsections)
304 if test "$ac_test_CFLAGS" = set; then
305 CFLAGS="$ac_save_CFLAGS"
306 else
307 # this is the suspicious part
308 CFLAGS=''
309 fi
310 fi
312 # Set -z,relro.
313 # Note this is only for shared objects.
314 ac_ld_relro=no
315 if test x"$with_gnu_ld" = x"yes"; then
316 AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
317 cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
318 if test -n "$cxx_z_relo"; then
319 OPT_LDFLAGS="-Wl,-z,relro"
320 ac_ld_relro=yes
321 fi
322 AC_MSG_RESULT($ac_ld_relro)
323 fi
325 # Set linker optimization flags.
326 if test x"$with_gnu_ld" = x"yes"; then
327 OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
328 fi
330 AC_SUBST(SECTION_LDFLAGS)
331 AC_SUBST(OPT_LDFLAGS)
332 ])
335 dnl
336 dnl Check for headers for, and arguments to, the setrlimit() function.
337 dnl Used only in testsuite_hooks.h. Called from GLIBCXX_CONFIGURE_TESTSUITE.
338 dnl
339 dnl Defines:
340 dnl _GLIBCXX_RES_LIMITS if we can set artificial resource limits
341 dnl various HAVE_LIMIT_* for individual limit names
342 dnl
343 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
344 AC_MSG_CHECKING([for RLIMIT_$1])
345 AC_TRY_COMPILE(
346 [#include <unistd.h>
347 #include <sys/time.h>
348 #include <sys/resource.h>
349 ],
350 [ int f = RLIMIT_$1 ; ],
351 [glibcxx_mresult=1], [glibcxx_mresult=0])
352 AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
353 [Only used in build directory testsuite_hooks.h.])
354 if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
355 AC_MSG_RESULT($res)
356 ])
358 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
359 setrlimit_have_headers=yes
360 AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
361 [],
362 [setrlimit_have_headers=no])
363 # If don't have the headers, then we can't run the tests now, and we
364 # won't be seeing any of these during testsuite compilation.
365 if test $setrlimit_have_headers = yes; then
366 # Can't do these in a loop, else the resulting syntax is wrong.
367 GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
368 GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
369 GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
370 GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
371 GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
373 # Check for rlimit, setrlimit.
374 AC_CACHE_VAL(glibcxx_cv_setrlimit, [
375 AC_TRY_COMPILE(
376 [#include <unistd.h>
377 #include <sys/time.h>
378 #include <sys/resource.h>
379 ],
380 [struct rlimit r;
381 setrlimit(0, &r);],
382 [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
383 ])
384 fi
386 AC_MSG_CHECKING([for testsuite resource limits support])
387 if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
388 ac_res_limits=yes
389 AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
390 [Define if using setrlimit to set resource limits during
391 "make check"])
392 else
393 ac_res_limits=no
394 fi
395 AC_MSG_RESULT($ac_res_limits)
396 ])
399 dnl
400 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
401 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
402 dnl
403 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
405 AC_LANG_SAVE
406 AC_LANG_CPLUSPLUS
407 ac_save_CXXFLAGS="$CXXFLAGS"
408 CXXFLAGS="$CXXFLAGS -fno-exceptions"
410 AC_MSG_CHECKING([for S_ISREG or S_IFREG])
411 AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
412 GCC_TRY_COMPILE_OR_LINK(
413 [#include <sys/stat.h>],
414 [struct stat buffer;
415 fstat(0, &buffer);
416 S_ISREG(buffer.st_mode);],
417 [glibcxx_cv_S_ISREG=yes],
418 [glibcxx_cv_S_ISREG=no])
419 ])
420 AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
421 GCC_TRY_COMPILE_OR_LINK(
422 [#include <sys/stat.h>],
423 [struct stat buffer;
424 fstat(0, &buffer);
425 S_IFREG & buffer.st_mode;],
426 [glibcxx_cv_S_IFREG=yes],
427 [glibcxx_cv_S_IFREG=no])
428 ])
429 res=no
430 if test $glibcxx_cv_S_ISREG = yes; then
431 AC_DEFINE(HAVE_S_ISREG, 1,
432 [Define if S_IFREG is available in <sys/stat.h>.])
433 res=S_ISREG
434 elif test $glibcxx_cv_S_IFREG = yes; then
435 AC_DEFINE(HAVE_S_IFREG, 1,
436 [Define if S_IFREG is available in <sys/stat.h>.])
437 res=S_IFREG
438 fi
439 AC_MSG_RESULT($res)
441 CXXFLAGS="$ac_save_CXXFLAGS"
442 AC_LANG_RESTORE
443 ])
446 dnl
447 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
448 dnl
449 AC_DEFUN([GLIBCXX_CHECK_POLL], [
451 AC_LANG_SAVE
452 AC_LANG_CPLUSPLUS
453 ac_save_CXXFLAGS="$CXXFLAGS"
454 CXXFLAGS="$CXXFLAGS -fno-exceptions"
456 AC_MSG_CHECKING([for poll])
457 AC_CACHE_VAL(glibcxx_cv_POLL, [
458 GCC_TRY_COMPILE_OR_LINK(
459 [#include <poll.h>],
460 [struct pollfd pfd[1];
461 pfd[0].events = POLLIN;
462 poll(pfd, 1, 0);],
463 [glibcxx_cv_POLL=yes],
464 [glibcxx_cv_POLL=no])
465 ])
466 if test $glibcxx_cv_POLL = yes; then
467 AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
468 fi
469 AC_MSG_RESULT($glibcxx_cv_POLL)
471 CXXFLAGS="$ac_save_CXXFLAGS"
472 AC_LANG_RESTORE
473 ])
476 dnl
477 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
478 dnl
479 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
481 AC_LANG_SAVE
482 AC_LANG_CPLUSPLUS
483 ac_save_CXXFLAGS="$CXXFLAGS"
484 CXXFLAGS="$CXXFLAGS -fno-exceptions"
486 AC_MSG_CHECKING([for writev])
487 AC_CACHE_VAL(glibcxx_cv_WRITEV, [
488 GCC_TRY_COMPILE_OR_LINK(
489 [#include <sys/uio.h>],
490 [struct iovec iov[2];
491 writev(0, iov, 0);],
492 [glibcxx_cv_WRITEV=yes],
493 [glibcxx_cv_WRITEV=no])
494 ])
495 if test $glibcxx_cv_WRITEV = yes; then
496 AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
497 fi
498 AC_MSG_RESULT($glibcxx_cv_WRITEV)
500 CXXFLAGS="$ac_save_CXXFLAGS"
501 AC_LANG_RESTORE
502 ])
505 dnl
506 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
507 dnl Also check whether int64_t is actually a typedef to long or long long.
508 dnl
509 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
511 AC_LANG_SAVE
512 AC_LANG_CPLUSPLUS
514 AC_MSG_CHECKING([for int64_t])
515 AC_CACHE_VAL(glibcxx_cv_INT64_T, [
516 AC_TRY_COMPILE(
517 [#include <stdint.h>],
518 [int64_t var;],
519 [glibcxx_cv_INT64_T=yes],
520 [glibcxx_cv_INT64_T=no])
521 ])
523 if test $glibcxx_cv_INT64_T = yes; then
524 AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
525 AC_MSG_RESULT($glibcxx_cv_INT64_T)
527 AC_MSG_CHECKING([for int64_t as long])
528 AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
529 AC_TRY_COMPILE(
530 [#include <stdint.h>
531 template<typename, typename> struct same { enum { value = -1 }; };
532 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
533 int array[same<int64_t, long>::value];], [],
534 [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
535 ])
537 if test $glibcxx_cv_int64_t_long = yes; then
538 AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
539 AC_MSG_RESULT($glibcxx_cv_int64_t_long)
540 fi
542 AC_MSG_CHECKING([for int64_t as long long])
543 AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
544 AC_TRY_COMPILE(
545 [#include <stdint.h>
546 template<typename, typename> struct same { enum { value = -1 }; };
547 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
548 int array[same<int64_t, long long>::value];], [],
549 [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
550 ])
552 if test $glibcxx_cv_int64_t_long_long = yes; then
553 AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
554 AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
555 fi
556 fi
558 AC_LANG_RESTORE
559 ])
562 dnl
563 dnl Check whether LFS support is available.
564 dnl
565 AC_DEFUN([GLIBCXX_CHECK_LFS], [
566 AC_LANG_SAVE
567 AC_LANG_CPLUSPLUS
568 ac_save_CXXFLAGS="$CXXFLAGS"
569 CXXFLAGS="$CXXFLAGS -fno-exceptions"
570 AC_MSG_CHECKING([for LFS support])
571 AC_CACHE_VAL(glibcxx_cv_LFS, [
572 GCC_TRY_COMPILE_OR_LINK(
573 [#include <unistd.h>
574 #include <stdio.h>
575 #include <sys/stat.h>
576 ],
577 [FILE* fp;
578 fopen64("t", "w");
579 fseeko64(fp, 0, SEEK_CUR);
580 ftello64(fp);
581 lseek64(1, 0, SEEK_CUR);
582 struct stat64 buf;
583 fstat64(1, &buf);],
584 [glibcxx_cv_LFS=yes],
585 [glibcxx_cv_LFS=no])
586 ])
587 if test $glibcxx_cv_LFS = yes; then
588 AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
589 fi
590 AC_MSG_RESULT($glibcxx_cv_LFS)
591 CXXFLAGS="$ac_save_CXXFLAGS"
592 AC_LANG_RESTORE
593 ])
596 dnl
597 dnl Check for whether a fully dynamic basic_string implementation should
598 dnl be turned on, that does not put empty objects in per-process static
599 dnl memory (mostly useful together with shared memory allocators, see PR
600 dnl libstdc++/16612 for details).
601 dnl
602 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 1
603 dnl --disable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 0
604 dnl otherwise undefined
605 dnl + Usage: GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
606 dnl Where DEFAULT is either `yes' or `no'.
607 dnl
608 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
609 GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
610 if test $enable_fully_dynamic_string = yes; then
611 enable_fully_dynamic_string_def=1
612 else
613 enable_fully_dynamic_string_def=0
614 fi
615 AC_DEFINE_UNQUOTED([_GLIBCXX_FULLY_DYNAMIC_STRING], [${enable_fully_dynamic_string_def}],
616 [Define to 1 if a fully dynamic basic_string is wanted, 0 to disable, undefined for platform defaults])
617 ])
620 dnl
621 dnl Does any necessary configuration of the testsuite directory. Generates
622 dnl the testsuite_hooks.h header.
623 dnl
624 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
625 dnl
626 dnl Sets:
627 dnl enable_abi_check
628 dnl GLIBCXX_TEST_WCHAR_T
629 dnl GLIBCXX_TEST_THREAD
630 dnl Substs:
631 dnl baseline_dir
632 dnl baseline_subdir_switch
633 dnl
634 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
635 if $GLIBCXX_IS_NATIVE ; then
636 # Do checks for resource limit functions.
637 GLIBCXX_CHECK_SETRLIMIT
639 # Look for setenv, so that extended locale tests can be performed.
640 GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
641 fi
643 if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
644 test $enable_symvers != no; then
645 case "$host" in
646 *-*-cygwin*)
647 enable_abi_check=no ;;
648 *)
649 enable_abi_check=yes ;;
650 esac
651 else
652 # Only build this as native, since automake does not understand
653 # CXX_FOR_BUILD.
654 enable_abi_check=no
655 fi
657 # Export file names for ABI checking.
658 baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
659 AC_SUBST(baseline_dir)
660 baseline_subdir_switch="$abi_baseline_subdir_switch"
661 AC_SUBST(baseline_subdir_switch)
662 ])
665 dnl
666 dnl Does any necessary configuration for docbook in the docs directory.
667 dnl
668 dnl XSLTPROC must be set before this
669 dnl
670 dnl Sets:
671 dnl glibcxx_stylesheets
672 dnl Substs:
673 dnl XSL_STYLE_DIR
674 dnl
675 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
677 AC_MSG_CHECKING([for docbook stylesheets for documentation creation])
678 glibcxx_stylesheets=no
679 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
680 glibcxx_stylesheets=yes
681 fi
682 AC_MSG_RESULT($glibcxx_stylesheets)
684 AC_MSG_CHECKING([for local stylesheet directory])
685 glibcxx_local_stylesheets=no
686 if test x"$glibcxx_stylesheets" = x"yes"; then
687 if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
688 glibcxx_local_stylesheets=yes
689 XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
690 fi
691 if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
692 glibcxx_local_stylesheets=yes
693 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
694 fi
695 if test -d /usr/share/xml/docbook/stylesheet/nwalsh5/current; then
696 glibcxx_local_stylesheets=yes
697 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/nwalsh5/current
698 fi
699 fi
700 AC_MSG_RESULT($glibcxx_local_stylesheets)
702 if test x"$glibcxx_local_stylesheets" = x"yes"; then
703 AC_SUBST(XSL_STYLE_DIR)
704 AC_MSG_NOTICE($XSL_STYLE_DIR)
705 else
706 glibcxx_stylesheets=no
707 fi
709 # Check for epub3 dependencies.
710 AC_MSG_CHECKING([for epub3 stylesheets for documentation creation])
711 glibcxx_epub_stylesheets=no
712 if test x"$glibcxx_local_stylesheets" = x"yes"; then
713 if test -f "$XSL_STYLE_DIR/epub3/chunk.xsl"; then
714 glibcxx_epub_stylesheets=yes
715 fi
716 fi
717 AC_MSG_RESULT($glibcxx_epub_stylesheets)
718 AM_CONDITIONAL(BUILD_EPUB, test x"$glibcxx_epub_stylesheets" = x"yes")
720 ])
723 dnl
724 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
725 dnl
726 dnl Substs:
727 dnl GLIBCXX_INCLUDES
728 dnl TOPLEVEL_INCLUDES
729 dnl
730 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
731 # Used for every C++ compile we perform.
732 GLIBCXX_INCLUDES="\
733 -I$glibcxx_builddir/include/$host_alias \
734 -I$glibcxx_builddir/include \
735 -I$glibcxx_srcdir/libsupc++"
737 # For Canadian crosses, pick this up too.
738 if test $CANADIAN = yes; then
739 GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
740 fi
742 # Stuff in the actual top level. Currently only used by libsupc++ to
743 # get unwind* headers from the libgcc dir.
744 #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc -I$(toplevel_srcdir)/include'
745 TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc'
747 # Now, export this to all the little Makefiles....
748 AC_SUBST(GLIBCXX_INCLUDES)
749 AC_SUBST(TOPLEVEL_INCLUDES)
750 ])
753 dnl
754 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
755 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
756 dnl
757 dnl Substs:
758 dnl OPTIMIZE_CXXFLAGS
759 dnl WARN_FLAGS
760 dnl
761 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
762 # Optimization flags that are probably a good idea for thrill-seekers. Just
763 # uncomment the lines below and make, everything else is ready to go...
764 # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
765 # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
766 AC_SUBST(OPTIMIZE_CXXFLAGS)
768 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual -Wabi'
769 AC_SUBST(WARN_FLAGS)
770 ])
773 dnl
774 dnl All installation directory information is determined here.
775 dnl
776 dnl Substs:
777 dnl gxx_install_dir
778 dnl glibcxx_prefixdir
779 dnl glibcxx_toolexecdir
780 dnl glibcxx_toolexeclibdir
781 dnl
782 dnl Assumes cross_compiling bits already done, and with_cross_host in
783 dnl particular.
784 dnl
785 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
786 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
787 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
788 glibcxx_toolexecdir=no
789 glibcxx_toolexeclibdir=no
790 glibcxx_prefixdir=$prefix
792 AC_MSG_CHECKING([for gxx-include-dir])
793 AC_ARG_WITH([gxx-include-dir],
794 AC_HELP_STRING([--with-gxx-include-dir=DIR],
795 [installation directory for include files]),
796 [case "$withval" in
797 yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
798 no) gxx_include_dir=no ;;
799 *) gxx_include_dir=$withval ;;
800 esac],
801 [gxx_include_dir=no])
802 AC_MSG_RESULT($gxx_include_dir)
804 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
805 AC_ARG_ENABLE([version-specific-runtime-libs],
806 AC_HELP_STRING([--enable-version-specific-runtime-libs],
807 [Specify that runtime libraries should be installed in a compiler-specific directory]),
808 [case "$enableval" in
809 yes) version_specific_libs=yes ;;
810 no) version_specific_libs=no ;;
811 *) AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
812 esac],
813 [version_specific_libs=no])
814 AC_MSG_RESULT($version_specific_libs)
816 # Default case for install directory for include files.
817 if test $version_specific_libs = no && test $gxx_include_dir = no; then
818 gxx_include_dir='include/c++/${gcc_version}'
819 if test -n "$with_cross_host" &&
820 test x"$with_cross_host" != x"no"; then
821 gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
822 else
823 gxx_include_dir='${prefix}/'"$gxx_include_dir"
824 fi
825 fi
827 # Version-specific runtime libs processing.
828 if test $version_specific_libs = yes; then
829 # Need the gcc compiler version to know where to install libraries
830 # and header files if --enable-version-specific-runtime-libs option
831 # is selected. FIXME: these variables are misnamed, there are
832 # no executables installed in _toolexecdir or _toolexeclibdir.
833 if test x"$gxx_include_dir" = x"no"; then
834 gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
835 fi
836 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
837 glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
838 fi
840 # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
841 # Install a library built with a cross compiler in tooldir, not libdir.
842 if test x"$glibcxx_toolexecdir" = x"no"; then
843 if test -n "$with_cross_host" &&
844 test x"$with_cross_host" != x"no"; then
845 glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
846 glibcxx_toolexeclibdir='${toolexecdir}/lib'
847 else
848 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
849 glibcxx_toolexeclibdir='${libdir}'
850 fi
851 multi_os_directory=`$CXX -print-multi-os-directory`
852 case $multi_os_directory in
853 .) ;; # Avoid trailing /.
854 *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
855 esac
856 fi
858 AC_MSG_CHECKING([for install location])
859 AC_MSG_RESULT($gxx_include_dir)
861 AC_SUBST(glibcxx_prefixdir)
862 AC_SUBST(gxx_include_dir)
863 AC_SUBST(glibcxx_toolexecdir)
864 AC_SUBST(glibcxx_toolexeclibdir)
865 ])
868 dnl
869 dnl GLIBCXX_ENABLE
870 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
871 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
872 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
873 dnl
874 dnl See manual/appendix_porting.html#appendix.porting.build_hacking for
875 dnl documentation.
876 dnl
877 m4_define([GLIBCXX_ENABLE],[dnl
878 m4_define([_g_switch],[--enable-$1])dnl
879 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
880 AC_ARG_ENABLE([$1],m4_dquote(_g_help),
881 m4_bmatch([$5],
882 [^permit ],
883 [[
884 case "$enableval" in
885 m4_bpatsubst([$5],[permit ])) ;;
886 *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
887 dnl Idea for future: generate a URL pointing to
888 dnl "onlinedocs/configopts.html#whatever"
889 esac
890 ]],
891 [^$],
892 [[
893 case "$enableval" in
894 yes|no) ;;
895 *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
896 esac
897 ]],
898 [[$5]]),
899 [enable_]m4_bpatsubst([$1],-,_)[=][$2])
900 m4_undefine([_g_switch])dnl
901 m4_undefine([_g_help])dnl
902 ])
905 dnl
906 dnl Check for ISO/IEC 9899:1999 "C99" support.
907 dnl
908 dnl --enable-c99 defines _GLIBCXX_USE_C99
909 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
910 dnl + Usage: GLIBCXX_ENABLE_C99[(DEFAULT)]
911 dnl Where DEFAULT is either `yes' or `no'.
912 dnl + If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
913 dnl
914 AC_DEFUN([GLIBCXX_ENABLE_C99], [
915 GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
917 if test x"$enable_c99" = x"yes"; then
919 AC_LANG_SAVE
920 AC_LANG_CPLUSPLUS
922 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
923 # undefined and fake C99 facilities - like pre-standard snprintf - may be
924 # spuriously enabled.
925 # Long term, -std=c++0x could be even better, could manage to explicitly
926 # request C99 facilities to the underlying C headers.
927 ac_save_CXXFLAGS="$CXXFLAGS"
928 CXXFLAGS="$CXXFLAGS -std=c++98"
929 ac_save_LIBS="$LIBS"
930 ac_save_gcc_no_link="$gcc_no_link"
932 if test x$gcc_no_link != xyes; then
933 # Use -fno-exceptions to that the C driver can link these tests without
934 # hitting undefined references to personality routines.
935 CXXFLAGS="$CXXFLAGS -fno-exceptions"
936 AC_CHECK_LIB(m, sin, [
937 LIBS="$LIBS -lm"
938 ], [
939 # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
940 gcc_no_link=yes
941 ])
942 fi
944 # Check for the existence of <math.h> functions used if C99 is enabled.
945 AC_MSG_CHECKING([for ISO C99 support in <math.h>])
946 AC_CACHE_VAL(glibcxx_cv_c99_math, [
947 GCC_TRY_COMPILE_OR_LINK(
948 [#include <math.h>
949 volatile double d1, d2;
950 volatile int i;],
951 [i = fpclassify(d1);
952 i = isfinite(d1);
953 i = isinf(d1);
954 i = isnan(d1);
955 i = isnormal(d1);
956 i = signbit(d1);
957 i = isgreater(d1, d2);
958 i = isgreaterequal(d1, d2);
959 i = isless(d1, d2);
960 i = islessequal(d1, d2);
961 i = islessgreater(d1, d2);
962 i = islessgreater(d1, d2);
963 i = isunordered(d1, d2);
964 ],[glibcxx_cv_c99_math=yes], [glibcxx_cv_c99_math=no])
965 ])
966 AC_MSG_RESULT($glibcxx_cv_c99_math)
967 if test x"$glibcxx_cv_c99_math" = x"yes"; then
968 AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
969 [Define if C99 functions or macros in <math.h> should be imported
970 in <cmath> in namespace std.])
971 fi
973 # Check for the existence of <complex.h> complex math functions.
974 # This is necessary even though libstdc++ uses the builtin versions
975 # of these functions, because if the builtin cannot be used, a reference
976 # to the library function is emitted.
977 AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
978 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
979 glibcxx_cv_c99_complex=no;
980 if test x"$ac_has_complex_h" = x"yes"; then
981 AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
982 GCC_TRY_COMPILE_OR_LINK(
983 [#include <complex.h>
984 typedef __complex__ float float_type;
985 typedef __complex__ double double_type;
986 typedef __complex__ long double ld_type;
987 volatile float_type tmpf;
988 volatile double_type tmpd;
989 volatile ld_type tmpld;
990 volatile float f;
991 volatile double d;
992 volatile long double ld;],
993 [f = cabsf(tmpf);
994 f = cargf(tmpf);
995 tmpf = ccosf(tmpf);
996 tmpf = ccoshf(tmpf);
997 tmpf = cexpf(tmpf);
998 tmpf = clogf(tmpf);
999 tmpf = csinf(tmpf);
1000 tmpf = csinhf(tmpf);
1001 tmpf = csqrtf(tmpf);
1002 tmpf = ctanf(tmpf);
1003 tmpf = ctanhf(tmpf);
1004 tmpf = cpowf(tmpf, tmpf);
1005 tmpf = cprojf(tmpf);
1006 d = cabs(tmpd);
1007 d = carg(tmpd);
1008 tmpd = ccos(tmpd);
1009 tmpd = ccosh(tmpd);
1010 tmpd = cexp(tmpd);
1011 tmpd = clog(tmpd);
1012 tmpd = csin(tmpd);
1013 tmpd = csinh(tmpd);
1014 tmpd = csqrt(tmpd);
1015 tmpd = ctan(tmpd);
1016 tmpd = ctanh(tmpd);
1017 tmpd = cpow(tmpd, tmpd);
1018 tmpd = cproj(tmpd);
1019 ld = cabsl(tmpld);
1020 ld = cargl(tmpld);
1021 tmpld = ccosl(tmpld);
1022 tmpld = ccoshl(tmpld);
1023 tmpld = cexpl(tmpld);
1024 tmpld = clogl(tmpld);
1025 tmpld = csinl(tmpld);
1026 tmpld = csinhl(tmpld);
1027 tmpld = csqrtl(tmpld);
1028 tmpld = ctanl(tmpld);
1029 tmpld = ctanhl(tmpld);
1030 tmpld = cpowl(tmpld, tmpld);
1031 tmpld = cprojl(tmpld);
1032 ],[glibcxx_cv_c99_complex=yes], [glibcxx_cv_c99_complex=no])
1033 fi
1034 AC_MSG_RESULT($glibcxx_cv_c99_complex)
1035 if test x"$glibcxx_cv_c99_complex" = x"yes"; then
1036 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
1037 [Define if C99 functions in <complex.h> should be used in
1038 <complex>. Using compiler builtins for these functions requires
1039 corresponding C99 library functions to be present.])
1040 fi
1042 # Check for the existence in <stdio.h> of vscanf, et. al.
1043 AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1044 AC_CACHE_VAL(glibcxx_cv_c99_stdio, [
1045 GCC_TRY_COMPILE_OR_LINK(
1046 [#include <stdio.h>
1047 #include <stdarg.h>
1048 void foo(char* fmt, ...)
1049 {
1050 va_list args; va_start(args, fmt);
1051 vfscanf(stderr, "%i", args);
1052 vscanf("%i", args);
1053 vsnprintf(fmt, 0, "%i", args);
1054 vsscanf(fmt, "%i", args);
1055 snprintf(fmt, 0, "%i");
1056 }], [],
1057 [glibcxx_cv_c99_stdio=yes], [glibcxx_cv_c99_stdio=no])
1058 ])
1059 AC_MSG_RESULT($glibcxx_cv_c99_stdio)
1061 # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1062 AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1063 AC_CACHE_VAL(glibcxx_cv_c99_stdlib, [
1064 GCC_TRY_COMPILE_OR_LINK(
1065 [#include <stdlib.h>
1066 volatile float f;
1067 volatile long double ld;
1068 volatile unsigned long long ll;
1069 lldiv_t mydivt;],
1070 [char* tmp;
1071 f = strtof("gnu", &tmp);
1072 ld = strtold("gnu", &tmp);
1073 ll = strtoll("gnu", &tmp, 10);
1074 ll = strtoull("gnu", &tmp, 10);
1075 ll = llabs(10);
1076 mydivt = lldiv(10,1);
1077 ll = mydivt.quot;
1078 ll = mydivt.rem;
1079 ll = atoll("10");
1080 _Exit(0);
1081 ],[glibcxx_cv_c99_stdlib=yes], [glibcxx_cv_c99_stdlib=no])
1082 ])
1083 AC_MSG_RESULT($glibcxx_cv_c99_stdlib)
1085 # Check for the existence in <wchar.h> of wcstold, etc.
1086 glibcxx_cv_c99_wchar=no;
1087 if test x"$ac_has_wchar_h" = xyes &&
1088 test x"$ac_has_wctype_h" = xyes; then
1089 AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1090 AC_TRY_COMPILE([#include <wchar.h>
1091 namespace test
1092 {
1093 using ::wcstold;
1094 using ::wcstoll;
1095 using ::wcstoull;
1096 }
1097 ],[],[glibcxx_cv_c99_wchar=yes], [glibcxx_cv_c99_wchar=no])
1099 # Checks for wide character functions that may not be present.
1100 # Injection of these is wrapped with guard macros.
1101 # NB: only put functions here, instead of immediately above, if
1102 # absolutely necessary.
1103 AC_TRY_COMPILE([#include <wchar.h>
1104 namespace test { using ::vfwscanf; } ], [],
1105 [AC_DEFINE(HAVE_VFWSCANF,1,
1106 [Defined if vfwscanf exists.])],[])
1108 AC_TRY_COMPILE([#include <wchar.h>
1109 namespace test { using ::vswscanf; } ], [],
1110 [AC_DEFINE(HAVE_VSWSCANF,1,
1111 [Defined if vswscanf exists.])],[])
1113 AC_TRY_COMPILE([#include <wchar.h>
1114 namespace test { using ::vwscanf; } ], [],
1115 [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1117 AC_TRY_COMPILE([#include <wchar.h>
1118 namespace test { using ::wcstof; } ], [],
1119 [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1121 AC_TRY_COMPILE([#include <wctype.h>],
1122 [ wint_t t; int i = iswblank(t);],
1123 [AC_DEFINE(HAVE_ISWBLANK,1,
1124 [Defined if iswblank exists.])],[])
1126 AC_MSG_RESULT($glibcxx_cv_c99_wchar)
1127 fi
1129 # Option parsed, now set things appropriately.
1130 if test x"$glibcxx_cv_c99_math" = x"no" ||
1131 test x"$glibcxx_cv_c99_complex" = x"no" ||
1132 test x"$glibcxx_cv_c99_stdio" = x"no" ||
1133 test x"$glibcxx_cv_c99_stdlib" = x"no" ||
1134 test x"$glibcxx_cv_c99_wchar" = x"no"; then
1135 enable_c99=no;
1136 else
1137 AC_DEFINE(_GLIBCXX_USE_C99, 1,
1138 [Define if C99 functions or macros from <wchar.h>, <math.h>,
1139 <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1140 fi
1142 gcc_no_link="$ac_save_gcc_no_link"
1143 LIBS="$ac_save_LIBS"
1144 CXXFLAGS="$ac_save_CXXFLAGS"
1145 AC_LANG_RESTORE
1146 fi
1148 AC_MSG_CHECKING([for fully enabled ISO C99 support])
1149 AC_MSG_RESULT($enable_c99)
1150 ])
1153 dnl
1154 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1155 dnl implementation of 20.11.7 [time.clock], and 30.3.2 [thread.thread.this]
1156 dnl in the C++11 standard.
1157 dnl
1158 dnl --enable-libstdcxx-time
1159 dnl --enable-libstdcxx-time=yes
1160 dnl checks for the availability of monotonic and realtime clocks,
1161 dnl nanosleep and sched_yield in libc and libposix4 and, if needed,
1162 dnl links in the latter.
1163 dnl --enable-libstdcxx-time=rt
1164 dnl also searches (and, if needed, links) librt. Note that this is
1165 dnl not always desirable because, in glibc 2.16 and earlier, for
1166 dnl example, in turn it triggers the linking of libpthread too,
1167 dnl which activates locking,
1168 dnl a large overhead for single-thread programs.
1169 dnl --enable-libstdcxx-time=no
1170 dnl --disable-libstdcxx-time
1171 dnl disables the checks completely
1172 dnl
1173 dnl N.B. Darwin provides nanosleep but doesn't support the whole POSIX
1174 dnl Timers option, so doesn't define _POSIX_TIMERS. Because the test
1175 dnl below fails Darwin unconditionally defines _GLIBCXX_USE_NANOSLEEP in
1176 dnl os_defines.h and also defines _GLIBCXX_USE_SCHED_YIELD.
1177 dnl
1178 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1180 GLIBCXX_ENABLE(libstdcxx-time,auto,[[[=KIND]]],
1181 [use KIND for check type],
1182 [permit yes|no|rt])
1184 AC_LANG_SAVE
1185 AC_LANG_CPLUSPLUS
1186 ac_save_CXXFLAGS="$CXXFLAGS"
1187 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1188 ac_save_LIBS="$LIBS"
1190 ac_has_clock_monotonic=no
1191 ac_has_clock_realtime=no
1192 ac_has_nanosleep=no
1193 ac_has_sched_yield=no
1195 if test x"$enable_libstdcxx_time" = x"auto"; then
1197 case "${target_os}" in
1198 cygwin*)
1199 ac_has_nanosleep=yes
1200 ;;
1201 darwin*)
1202 ac_has_nanosleep=yes
1203 ac_has_sched_yield=yes
1204 ;;
1205 gnu* | linux* | kfreebsd*-gnu | knetbsd*-gnu)
1206 AC_MSG_CHECKING([for at least GNU libc 2.17])
1207 AC_TRY_COMPILE(
1208 [#include <features.h>],
1209 [
1210 #if ! __GLIBC_PREREQ(2, 17)
1211 #error
1212 #endif
1213 ],
1214 [glibcxx_glibc217=yes], [glibcxx_glibc217=no])
1215 AC_MSG_RESULT($glibcxx_glibc217)
1217 if test x"$glibcxx_glibc217" = x"yes"; then
1218 ac_has_clock_monotonic=yes
1219 ac_has_clock_realtime=yes
1220 fi
1221 ac_has_nanosleep=yes
1222 ac_has_sched_yield=yes
1223 ;;
1224 freebsd*|netbsd*|dragonfly*)
1225 ac_has_clock_monotonic=yes
1226 ac_has_clock_realtime=yes
1227 ac_has_nanosleep=yes
1228 ac_has_sched_yield=yes
1229 ;;
1230 openbsd*)
1231 ac_has_clock_monotonic=yes
1232 ac_has_clock_realtime=yes
1233 ac_has_nanosleep=yes
1234 ;;
1235 solaris*)
1236 GLIBCXX_LIBS="$GLIBCXX_LIBS -lrt"
1237 ac_has_clock_monotonic=yes
1238 ac_has_clock_realtime=yes
1239 ac_has_nanosleep=yes
1240 ac_has_sched_yield=yes
1241 ;;
1242 esac
1244 elif test x"$enable_libstdcxx_time" != x"no"; then
1246 if test x"$enable_libstdcxx_time" = x"rt"; then
1247 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1248 AC_SEARCH_LIBS(nanosleep, [rt posix4])
1249 else
1250 AC_SEARCH_LIBS(clock_gettime, [posix4])
1251 AC_SEARCH_LIBS(nanosleep, [posix4])
1252 fi
1254 case "$ac_cv_search_clock_gettime" in
1255 -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1256 ;;
1257 esac
1258 case "$ac_cv_search_nanosleep" in
1259 -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1260 ;;
1261 esac
1263 AC_SEARCH_LIBS(sched_yield, [rt posix4])
1265 case "$ac_cv_search_sched_yield" in
1266 -lposix4*)
1267 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1268 ac_has_sched_yield=yes
1269 ;;
1270 -lrt*)
1271 if test x"$enable_libstdcxx_time" = x"rt"; then
1272 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1273 ac_has_sched_yield=yes
1274 fi
1275 ;;
1276 *)
1277 ac_has_sched_yield=yes
1278 ;;
1279 esac
1281 AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1283 if test x"$ac_has_unistd_h" = x"yes"; then
1284 AC_MSG_CHECKING([for monotonic clock])
1285 AC_TRY_LINK(
1286 [#include <unistd.h>
1287 #include <time.h>
1288 ],
1289 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1290 timespec tp;
1291 #endif
1292 clock_gettime(CLOCK_MONOTONIC, &tp);
1293 ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1295 AC_MSG_RESULT($ac_has_clock_monotonic)
1297 AC_MSG_CHECKING([for realtime clock])
1298 AC_TRY_LINK(
1299 [#include <unistd.h>
1300 #include <time.h>
1301 ],
1302 [#if _POSIX_TIMERS > 0
1303 timespec tp;
1304 #endif
1305 clock_gettime(CLOCK_REALTIME, &tp);
1306 ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1308 AC_MSG_RESULT($ac_has_clock_realtime)
1310 AC_MSG_CHECKING([for nanosleep])
1311 AC_TRY_LINK(
1312 [#include <unistd.h>
1313 #include <time.h>
1314 ],
1315 [#if _POSIX_TIMERS > 0
1316 timespec tp;
1317 #endif
1318 nanosleep(&tp, 0);
1319 ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1321 AC_MSG_RESULT($ac_has_nanosleep)
1322 fi
1323 fi
1325 if test x"$ac_has_clock_monotonic" != x"yes"; then
1326 case ${target_os} in
1327 linux*)
1328 AC_MSG_CHECKING([for clock_gettime syscall])
1329 AC_TRY_COMPILE(
1330 [#include <unistd.h>
1331 #include <time.h>
1332 #include <sys/syscall.h>
1333 ],
1334 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1335 timespec tp;
1336 #endif
1337 syscall(SYS_clock_gettime, CLOCK_MONOTONIC, &tp);
1338 syscall(SYS_clock_gettime, CLOCK_REALTIME, &tp);
1339 ], [ac_has_clock_monotonic_syscall=yes], [ac_has_clock_monotonic_syscall=no])
1340 AC_MSG_RESULT($ac_has_clock_monotonic_syscall)
1341 if test x"$ac_has_clock_monotonic_syscall" = x"yes"; then
1342 AC_DEFINE(_GLIBCXX_USE_CLOCK_GETTIME_SYSCALL, 1,
1343 [ Defined if clock_gettime syscall has monotonic and realtime clock support. ])
1344 ac_has_clock_monotonic=yes
1345 ac_has_clock_realtime=yes
1346 fi;;
1347 esac
1348 fi
1350 if test x"$ac_has_clock_monotonic" = x"yes"; then
1351 AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1352 [ Defined if clock_gettime has monotonic clock support. ])
1353 fi
1355 if test x"$ac_has_clock_realtime" = x"yes"; then
1356 AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1357 [ Defined if clock_gettime has realtime clock support. ])
1358 fi
1360 if test x"$ac_has_sched_yield" = x"yes"; then
1361 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1362 [ Defined if sched_yield is available. ])
1363 fi
1365 if test x"$ac_has_nanosleep" = x"yes"; then
1366 AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1367 [ Defined if nanosleep is available. ])
1368 else
1369 AC_MSG_CHECKING([for sleep])
1370 AC_TRY_COMPILE([#include <unistd.h>],
1371 [sleep(1)],
1372 [ac_has_sleep=yes],[ac_has_sleep=no])
1373 if test x"$ac_has_sleep" = x"yes"; then
1374 AC_DEFINE(HAVE_SLEEP,1, [Defined if sleep exists.])
1375 fi
1376 AC_MSG_RESULT($ac_has_sleep)
1377 AC_MSG_CHECKING([for usleep])
1378 AC_TRY_COMPILE([#include <unistd.h>],
1379 [sleep(1);
1380 usleep(100);],
1381 [ac_has_usleep=yes],[ac_has_usleep=no])
1382 if test x"$ac_has_usleep" = x"yes"; then
1383 AC_DEFINE(HAVE_USLEEP,1, [Defined if usleep exists.])
1384 fi
1385 AC_MSG_RESULT($ac_has_usleep)
1386 fi
1388 if test x"$ac_has_nanosleep$ac_has_sleep" = x"nono"; then
1389 AC_MSG_CHECKING([for Sleep])
1390 AC_TRY_COMPILE([#include <windows.h>],
1391 [Sleep(1)],
1392 [ac_has_win32_sleep=yes],[ac_has_win32_sleep=no])
1393 if test x"$ac_has_win32_sleep" = x"yes"; then
1394 AC_DEFINE(HAVE_WIN32_SLEEP,1, [Defined if Sleep exists.])
1395 fi
1396 AC_MSG_RESULT($ac_has_win32_sleep)
1397 fi
1399 AC_SUBST(GLIBCXX_LIBS)
1401 CXXFLAGS="$ac_save_CXXFLAGS"
1402 LIBS="$ac_save_LIBS"
1403 AC_LANG_RESTORE
1404 ])
1406 dnl
1407 dnl Check for gettimeofday, used in the implementation of 20.11.7
1408 dnl [time.clock] in the C++11 standard.
1409 dnl
1410 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1412 AC_MSG_CHECKING([for gettimeofday])
1414 AC_LANG_SAVE
1415 AC_LANG_CPLUSPLUS
1416 ac_save_CXXFLAGS="$CXXFLAGS"
1417 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1419 ac_has_gettimeofday=no;
1420 AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1421 if test x"$ac_has_sys_time_h" = x"yes"; then
1422 AC_MSG_CHECKING([for gettimeofday])
1423 GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1424 [timeval tv; gettimeofday(&tv, 0);],
1425 [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1427 AC_MSG_RESULT($ac_has_gettimeofday)
1428 fi
1430 if test x"$ac_has_gettimeofday" = x"yes"; then
1431 AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1432 [ Defined if gettimeofday is available. ])
1433 fi
1435 CXXFLAGS="$ac_save_CXXFLAGS"
1436 AC_LANG_RESTORE
1437 ])
1439 dnl
1440 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1441 dnl facilities in Chapter 8, "C compatibility".
1442 dnl
1443 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1445 AC_LANG_SAVE
1446 AC_LANG_CPLUSPLUS
1448 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1449 # undefined and fake C99 facilities may be spuriously enabled.
1450 ac_save_CXXFLAGS="$CXXFLAGS"
1451 CXXFLAGS="$CXXFLAGS -std=c++98"
1453 # Check for the existence of <complex.h> complex math functions used
1454 # by tr1/complex.
1455 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1456 ac_c99_complex_tr1=no;
1457 if test x"$ac_has_complex_h" = x"yes"; then
1458 AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1459 AC_TRY_COMPILE([#include <complex.h>],
1460 [typedef __complex__ float float_type; float_type tmpf;
1461 cacosf(tmpf);
1462 casinf(tmpf);
1463 catanf(tmpf);
1464 cacoshf(tmpf);
1465 casinhf(tmpf);
1466 catanhf(tmpf);
1467 typedef __complex__ double double_type; double_type tmpd;
1468 cacos(tmpd);
1469 casin(tmpd);
1470 catan(tmpd);
1471 cacosh(tmpd);
1472 casinh(tmpd);
1473 catanh(tmpd);
1474 typedef __complex__ long double ld_type; ld_type tmpld;
1475 cacosl(tmpld);
1476 casinl(tmpld);
1477 catanl(tmpld);
1478 cacoshl(tmpld);
1479 casinhl(tmpld);
1480 catanhl(tmpld);
1481 ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1482 fi
1483 AC_MSG_RESULT($ac_c99_complex_tr1)
1484 if test x"$ac_c99_complex_tr1" = x"yes"; then
1485 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1486 [Define if C99 functions in <complex.h> should be used in
1487 <tr1/complex>. Using compiler builtins for these functions
1488 requires corresponding C99 library functions to be present.])
1489 fi
1491 # Check for the existence of <ctype.h> functions.
1492 AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1493 AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1494 AC_TRY_COMPILE([#include <ctype.h>],
1495 [int ch;
1496 int ret;
1497 ret = isblank(ch);
1498 ],[glibcxx_cv_c99_ctype_tr1=yes],
1499 [glibcxx_cv_c99_ctype_tr1=no])
1500 ])
1501 AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1502 if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1503 AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1504 [Define if C99 functions in <ctype.h> should be imported in
1505 <tr1/cctype> in namespace std::tr1.])
1506 fi
1508 # Check for the existence of <fenv.h> functions.
1509 AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1510 ac_c99_fenv_tr1=no;
1511 if test x"$ac_has_fenv_h" = x"yes"; then
1512 AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1513 AC_TRY_COMPILE([#include <fenv.h>],
1514 [int except, mode;
1515 fexcept_t* pflag;
1516 fenv_t* penv;
1517 int ret;
1518 ret = feclearexcept(except);
1519 ret = fegetexceptflag(pflag, except);
1520 ret = feraiseexcept(except);
1521 ret = fesetexceptflag(pflag, except);
1522 ret = fetestexcept(except);
1523 ret = fegetround();
1524 ret = fesetround(mode);
1525 ret = fegetenv(penv);
1526 ret = feholdexcept(penv);
1527 ret = fesetenv(penv);
1528 ret = feupdateenv(penv);
1529 ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1530 fi
1531 AC_MSG_RESULT($ac_c99_fenv_tr1)
1532 if test x"$ac_c99_fenv_tr1" = x"yes"; then
1533 AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1534 [Define if C99 functions in <fenv.h> should be imported in
1535 <tr1/cfenv> in namespace std::tr1.])
1536 fi
1538 # Check for the existence of <stdint.h> types.
1539 AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1540 AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1541 AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1542 #define __STDC_CONSTANT_MACROS
1543 #include <stdint.h>],
1544 [typedef int8_t my_int8_t;
1545 my_int8_t i8 = INT8_MIN;
1546 i8 = INT8_MAX;
1547 typedef int16_t my_int16_t;
1548 my_int16_t i16 = INT16_MIN;
1549 i16 = INT16_MAX;
1550 typedef int32_t my_int32_t;
1551 my_int32_t i32 = INT32_MIN;
1552 i32 = INT32_MAX;
1553 typedef int64_t my_int64_t;
1554 my_int64_t i64 = INT64_MIN;
1555 i64 = INT64_MAX;
1556 typedef int_fast8_t my_int_fast8_t;
1557 my_int_fast8_t if8 = INT_FAST8_MIN;
1558 if8 = INT_FAST8_MAX;
1559 typedef int_fast16_t my_int_fast16_t;
1560 my_int_fast16_t if16 = INT_FAST16_MIN;
1561 if16 = INT_FAST16_MAX;
1562 typedef int_fast32_t my_int_fast32_t;
1563 my_int_fast32_t if32 = INT_FAST32_MIN;
1564 if32 = INT_FAST32_MAX;
1565 typedef int_fast64_t my_int_fast64_t;
1566 my_int_fast64_t if64 = INT_FAST64_MIN;
1567 if64 = INT_FAST64_MAX;
1568 typedef int_least8_t my_int_least8_t;
1569 my_int_least8_t il8 = INT_LEAST8_MIN;
1570 il8 = INT_LEAST8_MAX;
1571 typedef int_least16_t my_int_least16_t;
1572 my_int_least16_t il16 = INT_LEAST16_MIN;
1573 il16 = INT_LEAST16_MAX;
1574 typedef int_least32_t my_int_least32_t;
1575 my_int_least32_t il32 = INT_LEAST32_MIN;
1576 il32 = INT_LEAST32_MAX;
1577 typedef int_least64_t my_int_least64_t;
1578 my_int_least64_t il64 = INT_LEAST64_MIN;
1579 il64 = INT_LEAST64_MAX;
1580 typedef intmax_t my_intmax_t;
1581 my_intmax_t im = INTMAX_MAX;
1582 im = INTMAX_MIN;
1583 typedef intptr_t my_intptr_t;
1584 my_intptr_t ip = INTPTR_MAX;
1585 ip = INTPTR_MIN;
1586 typedef uint8_t my_uint8_t;
1587 my_uint8_t ui8 = UINT8_MAX;
1588 ui8 = UINT8_MAX;
1589 typedef uint16_t my_uint16_t;
1590 my_uint16_t ui16 = UINT16_MAX;
1591 ui16 = UINT16_MAX;
1592 typedef uint32_t my_uint32_t;
1593 my_uint32_t ui32 = UINT32_MAX;
1594 ui32 = UINT32_MAX;
1595 typedef uint64_t my_uint64_t;
1596 my_uint64_t ui64 = UINT64_MAX;
1597 ui64 = UINT64_MAX;
1598 typedef uint_fast8_t my_uint_fast8_t;
1599 my_uint_fast8_t uif8 = UINT_FAST8_MAX;
1600 uif8 = UINT_FAST8_MAX;
1601 typedef uint_fast16_t my_uint_fast16_t;
1602 my_uint_fast16_t uif16 = UINT_FAST16_MAX;
1603 uif16 = UINT_FAST16_MAX;
1604 typedef uint_fast32_t my_uint_fast32_t;
1605 my_uint_fast32_t uif32 = UINT_FAST32_MAX;
1606 uif32 = UINT_FAST32_MAX;
1607 typedef uint_fast64_t my_uint_fast64_t;
1608 my_uint_fast64_t uif64 = UINT_FAST64_MAX;
1609 uif64 = UINT_FAST64_MAX;
1610 typedef uint_least8_t my_uint_least8_t;
1611 my_uint_least8_t uil8 = UINT_LEAST8_MAX;
1612 uil8 = UINT_LEAST8_MAX;
1613 typedef uint_least16_t my_uint_least16_t;
1614 my_uint_least16_t uil16 = UINT_LEAST16_MAX;
1615 uil16 = UINT_LEAST16_MAX;
1616 typedef uint_least32_t my_uint_least32_t;
1617 my_uint_least32_t uil32 = UINT_LEAST32_MAX;
1618 uil32 = UINT_LEAST32_MAX;
1619 typedef uint_least64_t my_uint_least64_t;
1620 my_uint_least64_t uil64 = UINT_LEAST64_MAX;
1621 uil64 = UINT_LEAST64_MAX;
1622 typedef uintmax_t my_uintmax_t;
1623 my_uintmax_t uim = UINTMAX_MAX;
1624 uim = UINTMAX_MAX;
1625 typedef uintptr_t my_uintptr_t;
1626 my_uintptr_t uip = UINTPTR_MAX;
1627 uip = UINTPTR_MAX;
1628 ],[glibcxx_cv_c99_stdint_tr1=yes],
1629 [glibcxx_cv_c99_stdint_tr1=no])
1630 ])
1631 AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1632 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1633 AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1634 [Define if C99 types in <stdint.h> should be imported in
1635 <tr1/cstdint> in namespace std::tr1.])
1636 fi
1638 # Check for the existence of <math.h> functions.
1639 AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1640 AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1641 AC_TRY_COMPILE([#include <math.h>],
1642 [typedef double_t my_double_t;
1643 typedef float_t my_float_t;
1644 acosh(0.0);
1645 acoshf(0.0f);
1646 acoshl(0.0l);
1647 asinh(0.0);
1648 asinhf(0.0f);
1649 asinhl(0.0l);
1650 atanh(0.0);
1651 atanhf(0.0f);
1652 atanhl(0.0l);
1653 cbrt(0.0);
1654 cbrtf(0.0f);
1655 cbrtl(0.0l);
1656 copysign(0.0, 0.0);
1657 copysignf(0.0f, 0.0f);
1658 copysignl(0.0l, 0.0l);
1659 erf(0.0);
1660 erff(0.0f);
1661 erfl(0.0l);
1662 erfc(0.0);
1663 erfcf(0.0f);
1664 erfcl(0.0l);
1665 exp2(0.0);
1666 exp2f(0.0f);
1667 exp2l(0.0l);
1668 expm1(0.0);
1669 expm1f(0.0f);
1670 expm1l(0.0l);
1671 fdim(0.0, 0.0);
1672 fdimf(0.0f, 0.0f);
1673 fdiml(0.0l, 0.0l);
1674 fma(0.0, 0.0, 0.0);
1675 fmaf(0.0f, 0.0f, 0.0f);
1676 fmal(0.0l, 0.0l, 0.0l);
1677 fmax(0.0, 0.0);
1678 fmaxf(0.0f, 0.0f);
1679 fmaxl(0.0l, 0.0l);
1680 fmin(0.0, 0.0);
1681 fminf(0.0f, 0.0f);
1682 fminl(0.0l, 0.0l);
1683 hypot(0.0, 0.0);
1684 hypotf(0.0f, 0.0f);
1685 hypotl(0.0l, 0.0l);
1686 ilogb(0.0);
1687 ilogbf(0.0f);
1688 ilogbl(0.0l);
1689 lgamma(0.0);
1690 lgammaf(0.0f);
1691 lgammal(0.0l);
1692 llrint(0.0);
1693 llrintf(0.0f);
1694 llrintl(0.0l);
1695 llround(0.0);
1696 llroundf(0.0f);
1697 llroundl(0.0l);
1698 log1p(0.0);
1699 log1pf(0.0f);
1700 log1pl(0.0l);
1701 log2(0.0);
1702 log2f(0.0f);
1703 log2l(0.0l);
1704 logb(0.0);
1705 logbf(0.0f);
1706 logbl(0.0l);
1707 lrint(0.0);
1708 lrintf(0.0f);
1709 lrintl(0.0l);
1710 lround(0.0);
1711 lroundf(0.0f);
1712 lroundl(0.0l);
1713 nan(0);
1714 nanf(0);
1715 nanl(0);
1716 nearbyint(0.0);
1717 nearbyintf(0.0f);
1718 nearbyintl(0.0l);
1719 nextafter(0.0, 0.0);
1720 nextafterf(0.0f, 0.0f);
1721 nextafterl(0.0l, 0.0l);
1722 nexttoward(0.0, 0.0);
1723 nexttowardf(0.0f, 0.0f);
1724 nexttowardl(0.0l, 0.0l);
1725 remainder(0.0, 0.0);
1726 remainderf(0.0f, 0.0f);
1727 remainderl(0.0l, 0.0l);
1728 remquo(0.0, 0.0, 0);
1729 remquof(0.0f, 0.0f, 0);
1730 remquol(0.0l, 0.0l, 0);
1731 rint(0.0);
1732 rintf(0.0f);
1733 rintl(0.0l);
1734 round(0.0);
1735 roundf(0.0f);
1736 roundl(0.0l);
1737 scalbln(0.0, 0l);
1738 scalblnf(0.0f, 0l);
1739 scalblnl(0.0l, 0l);
1740 scalbn(0.0, 0);
1741 scalbnf(0.0f, 0);
1742 scalbnl(0.0l, 0);
1743 tgamma(0.0);
1744 tgammaf(0.0f);
1745 tgammal(0.0l);
1746 trunc(0.0);
1747 truncf(0.0f);
1748 truncl(0.0l);
1749 ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1750 ])
1751 AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1752 if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1753 AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1754 [Define if C99 functions or macros in <math.h> should be imported
1755 in <tr1/cmath> in namespace std::tr1.])
1756 fi
1758 # Check for the existence of <inttypes.h> functions (NB: doesn't make
1759 # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1760 ac_c99_inttypes_tr1=no;
1761 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1762 AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1763 AC_TRY_COMPILE([#include <inttypes.h>],
1764 [intmax_t i, numer, denom, base;
1765 const char* s;
1766 char** endptr;
1767 intmax_t ret = imaxabs(i);
1768 imaxdiv_t dret = imaxdiv(numer, denom);
1769 ret = strtoimax(s, endptr, base);
1770 uintmax_t uret = strtoumax(s, endptr, base);
1771 ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1772 fi
1773 AC_MSG_RESULT($ac_c99_inttypes_tr1)
1774 if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1775 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1776 [Define if C99 functions in <inttypes.h> should be imported in
1777 <tr1/cinttypes> in namespace std::tr1.])
1778 fi
1780 # Check for the existence of wchar_t <inttypes.h> functions (NB: doesn't
1781 # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1782 ac_c99_inttypes_wchar_t_tr1=no;
1783 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1784 AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
1785 AC_TRY_COMPILE([#include <inttypes.h>],
1786 [intmax_t base;
1787 const wchar_t* s;
1788 wchar_t** endptr;
1789 intmax_t ret = wcstoimax(s, endptr, base);
1790 uintmax_t uret = wcstoumax(s, endptr, base);
1791 ],[ac_c99_inttypes_wchar_t_tr1=yes],
1792 [ac_c99_inttypes_wchar_t_tr1=no])
1793 fi
1794 AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
1795 if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
1796 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
1797 [Define if wchar_t C99 functions in <inttypes.h> should be
1798 imported in <tr1/cinttypes> in namespace std::tr1.])
1799 fi
1801 # Check for the existence of the <stdbool.h> header.
1802 AC_CHECK_HEADERS(stdbool.h)
1804 # Check for the existence of the <stdalign.h> header.
1805 AC_CHECK_HEADERS(stdalign.h)
1807 CXXFLAGS="$ac_save_CXXFLAGS"
1808 AC_LANG_RESTORE
1809 ])
1811 dnl
1812 dnl Check for uchar.h and usability.
1813 dnl
1814 AC_DEFUN([GLIBCXX_CHECK_UCHAR_H], [
1816 # Test uchar.h.
1817 AC_CHECK_HEADERS(uchar.h, ac_has_uchar_h=yes, ac_has_uchar_h=no)
1819 AC_LANG_SAVE
1820 AC_LANG_CPLUSPLUS
1821 ac_save_CXXFLAGS="$CXXFLAGS"
1822 CXXFLAGS="$CXXFLAGS -std=c++11"
1824 if test x"$ac_has_uchar_h" = x"yes"; then
1825 AC_MSG_CHECKING([for ISO C11 support for <uchar.h>])
1826 AC_TRY_COMPILE([#include <uchar.h>
1827 #ifdef __STDC_UTF_16__
1828 long i = __STDC_UTF_16__;
1829 #endif
1830 #ifdef __STDC_UTF_32__
1831 long j = __STDC_UTF_32__;
1832 #endif
1833 namespace test
1834 {
1835 using ::c16rtomb;
1836 using ::c32rtomb;
1837 using ::mbrtoc16;
1838 using ::mbrtoc32;
1839 }
1840 ],
1841 [], [ac_c11_uchar_cxx11=yes], [ac_c11_uchar_cxx11=no])
1842 else
1843 ac_c11_uchar_cxx11=no
1844 fi
1845 AC_MSG_RESULT($ac_c11_uchar_cxx11)
1846 if test x"$ac_c11_uchar_cxx11" = x"yes"; then
1847 AC_DEFINE(_GLIBCXX_USE_C11_UCHAR_CXX11, 1,
1848 [Define if C11 functions in <uchar.h> should be imported into
1849 namespace std in <cuchar>.])
1850 fi
1852 CXXFLAGS="$ac_save_CXXFLAGS"
1853 AC_LANG_RESTORE
1854 ])
1857 dnl
1858 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
1859 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1860 dnl
1861 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1863 AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
1864 AC_CACHE_VAL(glibcxx_cv_random_tr1, [
1865 if test -r /dev/random && test -r /dev/urandom; then
1866 ## For MSys environment the test above is detect as false-positive
1867 ## on mingw-targets. So disable it explicit for them.
1868 case ${target_os} in
1869 *mingw*) glibcxx_cv_random_tr1=no ;;
1870 *) glibcxx_cv_random_tr1=yes ;;
1871 esac
1872 else
1873 glibcxx_cv_random_tr1=no;
1874 fi
1875 ])
1876 AC_MSG_RESULT($glibcxx_cv_random_tr1)
1878 if test x"$glibcxx_cv_random_tr1" = x"yes"; then
1879 AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1880 [Define if /dev/random and /dev/urandom are available for
1881 the random_device of TR1 (Chapter 5.1).])
1882 fi
1884 ])
1886 dnl
1887 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
1888 dnl
1889 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
1891 AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
1892 AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
1893 [#include <stdio.h>],
1894 [AC_MSG_ERROR([computing EOF failed])])
1895 ])
1896 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
1897 [Define to the value of the EOF integer constant.])
1899 AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
1900 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
1901 [#include <stdio.h>],
1902 [AC_MSG_ERROR([computing SEEK_CUR failed])])
1903 ])
1904 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
1905 [Define to the value of the SEEK_CUR integer constant.])
1907 AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
1908 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
1909 [#include <stdio.h>],
1910 [AC_MSG_ERROR([computing SEEK_END failed])])
1911 ])
1912 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
1913 [Define to the value of the SEEK_END integer constant.])
1914 ])
1916 dnl
1917 dnl Check whether required C++ overloads are present in <stdio.h>.
1918 dnl
1919 AC_DEFUN([GLIBCXX_CHECK_STDIO_PROTO], [
1921 AC_LANG_SAVE
1922 AC_LANG_CPLUSPLUS
1924 AC_MSG_CHECKING([for gets declaration])
1925 AC_CACHE_VAL(glibcxx_cv_gets, [
1926 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1927 [#include <stdio.h>
1928 namespace test
1929 {
1930 using ::gets;
1931 }
1932 ])],
1933 [glibcxx_cv_gets=yes],
1934 [glibcxx_cv_gets=no]
1935 )])
1937 if test $glibcxx_cv_gets = yes; then
1938 AC_DEFINE(HAVE_GETS, 1, [Define if gets is available in <stdio.h>.])
1939 fi
1940 AC_MSG_RESULT($glibcxx_cv_gets)
1942 AC_LANG_RESTORE
1943 ])
1945 dnl
1946 dnl Check whether macros, etc are present for <system_error>
1947 dnl
1948 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1950 m4_pushdef([n_syserr], [1])dnl
1951 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
1952 ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
1953 EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY,
1954 ECHILD, ENOSPC, EPERM,
1955 ETIMEDOUT, EWOULDBLOCK],
1956 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
1957 AC_MSG_CHECKING([for syserr])
1958 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
1959 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
1960 [int i = syserr;])],
1961 [glibcxx_cv_system_error[]n_syserr=yes],
1962 [glibcxx_cv_system_error[]n_syserr=no])
1963 ])
1964 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
1965 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
1966 AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
1967 fi
1968 m4_define([n_syserr], m4_incr(n_syserr))dnl
1969 m4_popdef([SYSERR])dnl
1970 ])
1971 m4_popdef([n_syserr])dnl
1972 ])
1974 dnl
1975 dnl Check for what type of C headers to use.
1976 dnl
1977 dnl --enable-cheaders= [does stuff].
1978 dnl --disable-cheaders [does not do anything, really].
1979 dnl + Usage: GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1980 dnl Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1981 dnl
1982 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1983 GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
1984 [construct "C" headers for g++], [permit c|c_std|c_global])
1985 AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1987 C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1989 # Allow overrides to configure.host here.
1990 if test $enable_cheaders = c_global; then
1991 c_compatibility=yes
1992 fi
1994 AC_SUBST(C_INCLUDE_DIR)
1995 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1996 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1997 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1998 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1999 ])
2002 dnl
2003 dnl Check for which locale library to use. The choice is mapped to
2004 dnl a subdirectory of config/locale.
2005 dnl
2006 dnl Default is generic.
2007 dnl
2008 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
2009 GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
2010 [use MODEL for target locale package],
2011 [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
2013 # Deal with gettext issues. Default to not using it (=no) until we detect
2014 # support for it later. Let the user turn it off via --e/d, but let that
2015 # default to on for easier handling.
2016 USE_NLS=no
2017 AC_ARG_ENABLE(nls,
2018 AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
2019 [],
2020 [enable_nls=yes])
2022 # Either a known package, or "auto"
2023 if test $enable_clocale = no || test $enable_clocale = yes; then
2024 enable_clocale=auto
2025 fi
2026 enable_clocale_flag=$enable_clocale
2028 # Probe for locale model to use if none specified.
2029 # Default to "generic".
2030 if test $enable_clocale_flag = auto; then
2031 case ${target_os} in
2032 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2033 enable_clocale_flag=gnu
2034 ;;
2035 darwin* | freebsd*)
2036 enable_clocale_flag=darwin
2037 ;;
2038 dragonfly*)
2039 enable_clocale_flag=dragonfly
2040 ;;
2041 openbsd*)
2042 enable_clocale_flag=newlib
2043 ;;
2044 *)
2045 if test x"$with_newlib" = x"yes"; then
2046 enable_clocale_flag=newlib
2047 else
2048 enable_clocale_flag=generic
2049 fi
2050 ;;
2051 esac
2052 fi
2054 # Sanity check model, and test for special functionality.
2055 if test $enable_clocale_flag = gnu; then
2056 AC_EGREP_CPP([_GLIBCXX_ok], [
2057 #include <features.h>
2058 #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
2059 _GLIBCXX_ok
2060 #endif
2061 ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
2063 # Set it to scream when it hurts.
2064 ac_save_CFLAGS="$CFLAGS"
2065 CFLAGS="-Wimplicit-function-declaration -Werror"
2067 # Use strxfrm_l if available.
2068 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2069 #include <string.h>
2070 #include <locale.h>],
2071 [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
2072 AC_DEFINE(HAVE_STRXFRM_L, 1,
2073 [Define if strxfrm_l is available in <string.h>.]),)
2075 # Use strerror_l if available.
2076 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2077 #include <string.h>
2078 #include <locale.h>],
2079 [__locale_t loc; strerror_l(5, loc);],
2080 AC_DEFINE(HAVE_STRERROR_L, 1,
2081 [Define if strerror_l is available in <string.h>.]),)
2083 CFLAGS="$ac_save_CFLAGS"
2084 fi
2086 # Perhaps use strerror_r if available, and strerror_l isn't.
2087 ac_save_CFLAGS="$CFLAGS"
2088 CFLAGS="-Wimplicit-function-declaration -Werror"
2089 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2090 #include <string.h>
2091 #include <locale.h>],
2092 [char s[128]; strerror_r(5, s, 128);],
2093 AC_DEFINE(HAVE_STRERROR_R, 1,
2094 [Define if strerror_r is available in <string.h>.]),)
2095 CFLAGS="$ac_save_CFLAGS"
2097 # Set configure bits for specified locale package
2098 AC_MSG_CHECKING([for C locale to use])
2099 case ${enable_clocale_flag} in
2100 generic)
2101 AC_MSG_RESULT(generic)
2103 CLOCALE_H=config/locale/generic/c_locale.h
2104 CLOCALE_CC=config/locale/generic/c_locale.cc
2105 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2106 CCOLLATE_CC=config/locale/generic/collate_members.cc
2107 CCTYPE_CC=config/locale/generic/ctype_members.cc
2108 CMESSAGES_H=config/locale/generic/messages_members.h
2109 CMESSAGES_CC=config/locale/generic/messages_members.cc
2110 CMONEY_CC=config/locale/generic/monetary_members.cc
2111 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2112 CTIME_H=config/locale/generic/time_members.h
2113 CTIME_CC=config/locale/generic/time_members.cc
2114 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2115 ;;
2116 darwin)
2117 AC_MSG_RESULT(darwin or freebsd)
2119 CLOCALE_H=config/locale/generic/c_locale.h
2120 CLOCALE_CC=config/locale/generic/c_locale.cc
2121 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2122 CCOLLATE_CC=config/locale/generic/collate_members.cc
2123 CCTYPE_CC=config/locale/darwin/ctype_members.cc
2124 CMESSAGES_H=config/locale/generic/messages_members.h
2125 CMESSAGES_CC=config/locale/generic/messages_members.cc
2126 CMONEY_CC=config/locale/generic/monetary_members.cc
2127 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2128 CTIME_H=config/locale/generic/time_members.h
2129 CTIME_CC=config/locale/generic/time_members.cc
2130 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2131 ;;
2133 dragonfly)
2134 AC_MSG_RESULT(dragonfly)
2136 CLOCALE_H=config/locale/dragonfly/c_locale.h
2137 CLOCALE_CC=config/locale/dragonfly/c_locale.cc
2138 CCODECVT_CC=config/locale/dragonfly/codecvt_members.cc
2139 CCOLLATE_CC=config/locale/dragonfly/collate_members.cc
2140 CCTYPE_CC=config/locale/dragonfly/ctype_members.cc
2141 CMESSAGES_H=config/locale/generic/messages_members.h
2142 CMESSAGES_CC=config/locale/generic/messages_members.cc
2143 CMONEY_CC=config/locale/dragonfly/monetary_members.cc
2144 CNUMERIC_CC=config/locale/dragonfly/numeric_members.cc
2145 CTIME_H=config/locale/dragonfly/time_members.h
2146 CTIME_CC=config/locale/dragonfly/time_members.cc
2147 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2148 ;;
2150 gnu)
2151 AC_MSG_RESULT(gnu)
2153 # Declare intention to use gettext, and add support for specific
2154 # languages.
2155 # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
2156 ALL_LINGUAS="de fr"
2158 # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
2159 AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
2160 if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
2161 USE_NLS=yes
2162 fi
2163 # Export the build objects.
2164 for ling in $ALL_LINGUAS; do \
2165 glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
2166 glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
2167 done
2168 AC_SUBST(glibcxx_MOFILES)
2169 AC_SUBST(glibcxx_POFILES)
2171 CLOCALE_H=config/locale/gnu/c_locale.h
2172 CLOCALE_CC=config/locale/gnu/c_locale.cc
2173 CCODECVT_CC=config/locale/gnu/codecvt_members.cc
2174 CCOLLATE_CC=config/locale/gnu/collate_members.cc
2175 CCTYPE_CC=config/locale/gnu/ctype_members.cc
2176 CMESSAGES_H=config/locale/gnu/messages_members.h
2177 CMESSAGES_CC=config/locale/gnu/messages_members.cc
2178 CMONEY_CC=config/locale/gnu/monetary_members.cc
2179 CNUMERIC_CC=config/locale/gnu/numeric_members.cc
2180 CTIME_H=config/locale/gnu/time_members.h
2181 CTIME_CC=config/locale/gnu/time_members.cc
2182 CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
2183 ;;
2184 ieee_1003.1-2001)
2185 AC_MSG_RESULT(IEEE 1003.1)
2187 CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
2188 CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
2189 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2190 CCOLLATE_CC=config/locale/generic/collate_members.cc
2191 CCTYPE_CC=config/locale/generic/ctype_members.cc
2192 CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
2193 CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
2194 CMONEY_CC=config/locale/generic/monetary_members.cc
2195 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2196 CTIME_H=config/locale/generic/time_members.h
2197 CTIME_CC=config/locale/generic/time_members.cc
2198 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2199 ;;
2200 newlib)
2201 AC_MSG_RESULT(newlib)
2203 CLOCALE_H=config/locale/generic/c_locale.h
2204 CLOCALE_CC=config/locale/generic/c_locale.cc
2205 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2206 CCOLLATE_CC=config/locale/generic/collate_members.cc
2207 CCTYPE_CC=config/locale/newlib/ctype_members.cc
2208 CMESSAGES_H=config/locale/generic/messages_members.h
2209 CMESSAGES_CC=config/locale/generic/messages_members.cc
2210 CMONEY_CC=config/locale/generic/monetary_members.cc
2211 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2212 CTIME_H=config/locale/generic/time_members.h
2213 CTIME_CC=config/locale/generic/time_members.cc
2214 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2215 ;;
2216 esac
2218 # This is where the testsuite looks for locale catalogs, using the
2219 # -DLOCALEDIR define during testsuite compilation.
2220 glibcxx_localedir=${glibcxx_builddir}/po/share/locale
2221 AC_SUBST(glibcxx_localedir)
2223 # A standalone libintl (e.g., GNU libintl) may be in use.
2224 if test $USE_NLS = yes; then
2225 AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
2226 AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
2227 fi
2228 if test $USE_NLS = yes; then
2229 AC_DEFINE(_GLIBCXX_USE_NLS, 1,
2230 [Define if NLS translations are to be used.])
2231 fi
2233 AC_SUBST(USE_NLS)
2234 AC_SUBST(CLOCALE_H)
2235 AC_SUBST(CMESSAGES_H)
2236 AC_SUBST(CCODECVT_CC)
2237 AC_SUBST(CCOLLATE_CC)
2238 AC_SUBST(CCTYPE_CC)
2239 AC_SUBST(CMESSAGES_CC)
2240 AC_SUBST(CMONEY_CC)
2241 AC_SUBST(CNUMERIC_CC)
2242 AC_SUBST(CTIME_H)
2243 AC_SUBST(CTIME_CC)
2244 AC_SUBST(CLOCALE_CC)
2245 AC_SUBST(CLOCALE_INTERNAL_H)
2246 ])
2249 dnl
2250 dnl Check for which std::allocator base class to use. The choice is
2251 dnl mapped from a subdirectory of include/ext.
2252 dnl
2253 dnl Default is new.
2254 dnl
2255 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
2256 AC_MSG_CHECKING([for std::allocator base class])
2257 GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
2258 [use KIND for target std::allocator base],
2259 [permit new|malloc|mt|bitmap|pool|yes|no|auto])
2261 # If they didn't use this option switch, or if they specified --enable
2262 # with no specific model, we'll have to look for one. If they
2263 # specified --disable (???), do likewise.
2264 if test $enable_libstdcxx_allocator = no ||
2265 test $enable_libstdcxx_allocator = yes;
2266 then
2267 enable_libstdcxx_allocator=auto
2268 fi
2270 # Either a known package, or "auto". Auto implies the default choice
2271 # for a particular platform.
2272 enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
2274 # Probe for host-specific support if no specific model is specified.
2275 # Default to "new".
2276 if test $enable_libstdcxx_allocator_flag = auto; then
2277 case ${target_os} in
2278 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2279 enable_libstdcxx_allocator_flag=new
2280 ;;
2281 *)
2282 enable_libstdcxx_allocator_flag=new
2283 ;;
2284 esac
2285 fi
2286 AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2289 # Set configure bits for specified locale package
2290 case ${enable_libstdcxx_allocator_flag} in
2291 bitmap)
2292 ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2293 ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2294 ;;
2295 malloc)
2296 ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2297 ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2298 ;;
2299 mt)
2300 ALLOCATOR_H=config/allocator/mt_allocator_base.h
2301 ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2302 ;;
2303 new)
2304 ALLOCATOR_H=config/allocator/new_allocator_base.h
2305 ALLOCATOR_NAME=__gnu_cxx::new_allocator
2306 ;;
2307 pool)
2308 ALLOCATOR_H=config/allocator/pool_allocator_base.h
2309 ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2310 ;;
2311 esac
2313 AC_SUBST(ALLOCATOR_H)
2314 AC_SUBST(ALLOCATOR_NAME)
2315 ])
2318 dnl
2319 dnl Check for whether the Boost-derived checks should be turned on.
2320 dnl
2321 dnl --enable-concept-checks turns them on.
2322 dnl --disable-concept-checks leaves them off.
2323 dnl + Usage: GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2324 dnl Where DEFAULT is either `yes' or `no'.
2325 dnl
2326 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2327 GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2328 if test $enable_concept_checks = yes; then
2329 AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2330 [Define to use concept checking code from the boost libraries.])
2331 fi
2332 ])
2334 dnl
2335 dnl Use extern templates.
2336 dnl
2337 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2338 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2340 dnl + Usage: GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2341 dnl Where DEFAULT is `yes' or `no'.
2342 dnl
2343 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2345 GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2347 AC_MSG_CHECKING([for extern template support])
2348 AC_MSG_RESULT([$enable_extern_template])
2350 GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2351 ])
2353 dnl
2354 dnl Use vtable verification.
2355 dnl
2356 dnl --enable-vtable-verify defines _GLIBCXX_VTABLE_VERIFY to 1
2357 dnl --disable-vtable-verify defines _GLIBCXX_VTABLE_VERIFY to 0
2359 dnl + Usage: GLIBCXX_ENABLE_VTABLE_VERIFY[(DEFAULT)]
2360 dnl Where DEFAULT is `yes' or `no'.
2361 dnl
2362 AC_DEFUN([GLIBCXX_ENABLE_VTABLE_VERIFY], [
2364 GLIBCXX_ENABLE(vtable-verify,$1,,[enable vtable verify])
2366 AC_MSG_CHECKING([for vtable verify support])
2367 AC_MSG_RESULT([$enable_vtable_verify])
2369 vtv_cygmin=no
2370 if test $enable_vtable_verify = yes; then
2371 case ${target_os} in
2372 cygwin*|mingw32*)
2373 VTV_CXXFLAGS="-fvtable-verify=std -Wl,-lvtv,-u_vtable_map_vars_start,-u_vtable_map_vars_end"
2374 VTV_CXXLINKFLAGS="-L${toplevel_builddir}/libvtv/.libs -Wl,--rpath -Wl,${toplevel_builddir}/libvtv/.libs"
2375 vtv_cygmin=yes
2376 ;;
2377 darwin*)
2378 VTV_CXXFLAGS="-fvtable-verify=std -Wl,-u,_vtable_map_vars_start -Wl,-u,_vtable_map_vars_end"
2379 VTV_CXXLINKFLAGS="-L${toplevel_builddir}/libvtv/.libs -Wl,-rpath,${toplevel_builddir}/libvtv/.libs"
2380 ;;
2381 *)
2382 VTV_CXXFLAGS="-fvtable-verify=std -Wl,-u_vtable_map_vars_start,-u_vtable_map_vars_end"
2383 VTV_CXXLINKFLAGS="-L${toplevel_builddir}/libvtv/.libs -Wl,--rpath -Wl,${toplevel_builddir}/libvtv/.libs"
2384 ;;
2385 esac
2386 VTV_PCH_CXXFLAGS="-fvtable-verify=std"
2387 else
2388 VTV_CXXFLAGS=
2389 VTV_PCH_CXXFLAGS=
2390 VTV_CXXLINKFLAGS=
2391 fi
2393 AC_SUBST(VTV_CXXFLAGS)
2394 AC_SUBST(VTV_PCH_CXXFLAGS)
2395 AC_SUBST(VTV_CXXLINKFLAGS)
2396 AM_CONDITIONAL(VTV_CYGMIN, test x$vtv_cygmin = xyes)
2397 GLIBCXX_CONDITIONAL(ENABLE_VTABLE_VERIFY, test $enable_vtable_verify = yes)
2398 ])
2400 dnl
2401 dnl Check for parallel mode pre-requisites, including OpenMP support.
2402 dnl
2403 dnl + Usage: GLIBCXX_ENABLE_PARALLEL
2404 dnl
2405 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2407 enable_parallel=no;
2409 # See if configured libgomp/omp.h exists. (libgomp may be in
2410 # noconfigdirs but not explicitly disabled.)
2411 if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2412 enable_parallel=yes;
2413 else
2414 AC_MSG_NOTICE([target-libgomp not built])
2415 fi
2417 AC_MSG_CHECKING([for parallel mode support])
2418 AC_MSG_RESULT([$enable_parallel])
2419 ])
2422 dnl
2423 dnl Check for which I/O library to use: stdio, or something specific.
2424 dnl
2425 dnl Default is stdio.
2426 dnl
2427 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2428 AC_MSG_CHECKING([for underlying I/O to use])
2429 GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2430 [use target-specific I/O package], [permit stdio])
2432 # Now that libio has been removed, you can have any color you want as long
2433 # as it's black. This is one big no-op until other packages are added, but
2434 # showing the framework never hurts.
2435 case ${enable_cstdio} in
2436 stdio)
2437 CSTDIO_H=config/io/c_io_stdio.h
2438 BASIC_FILE_H=config/io/basic_file_stdio.h
2439 BASIC_FILE_CC=config/io/basic_file_stdio.cc
2440 AC_MSG_RESULT(stdio)
2441 ;;
2442 esac
2444 AC_SUBST(CSTDIO_H)
2445 AC_SUBST(BASIC_FILE_H)
2446 AC_SUBST(BASIC_FILE_CC)
2447 ])
2450 dnl
2451 dnl Check for "unusual" flags to pass to the compiler while building.
2452 dnl
2453 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2454 dnl experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2455 dnl --disable-cxx-flags passes nothing.
2456 dnl + See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2457 dnl http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2458 dnl http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2459 dnl + Usage: GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2460 dnl If "default flags" is an empty string, the effect is the same
2461 dnl as --disable or --enable=no.
2462 dnl
2463 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2464 AC_MSG_CHECKING([for extra compiler flags for building])
2465 GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2466 [pass compiler FLAGS when building library],
2467 [case "x$enable_cxx_flags" in
2468 xno | x) enable_cxx_flags= ;;
2469 x-*) ;;
2470 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2471 esac])
2473 # Run through flags (either default or command-line) and set anything
2474 # extra (e.g., #defines) that must accompany particular g++ options.
2475 if test -n "$enable_cxx_flags"; then
2476 for f in $enable_cxx_flags; do
2477 case "$f" in
2478 -fhonor-std) ;;
2479 -*) ;;
2480 *) # and we're trying to pass /what/ exactly?
2481 AC_MSG_ERROR([compiler flags start with a -]) ;;
2482 esac
2483 done
2484 fi
2486 EXTRA_CXX_FLAGS="$enable_cxx_flags"
2487 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2488 AC_SUBST(EXTRA_CXX_FLAGS)
2489 ])
2492 dnl
2493 dnl Check to see if debugging libraries are to be built.
2494 dnl
2495 dnl --enable-libstdcxx-debug
2496 dnl builds a separate set of debugging libraries in addition to the
2497 dnl normal (shared, static) libstdc++ binaries.
2498 dnl
2499 dnl --disable-libstdcxx-debug
2500 dnl builds only one (non-debug) version of libstdc++.
2501 dnl
2502 dnl --enable-libstdcxx-debug-flags=FLAGS
2503 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2504 dnl
2505 dnl + Usage: GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2506 dnl Where DEFAULT is either `yes' or `no'.
2507 dnl
2508 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2509 AC_MSG_CHECKING([for additional debug build])
2510 GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2511 AC_MSG_RESULT($enable_libstdcxx_debug)
2512 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2513 ])
2516 dnl
2517 dnl Check for explicit debug flags.
2518 dnl
2519 dnl --enable-libstdcxx-debug-flags='-O1'
2520 dnl is a general method for passing flags to be used when
2521 dnl building debug libraries with --enable-debug.
2522 dnl
2523 dnl --disable-libstdcxx-debug-flags does nothing.
2524 dnl + Usage: GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2525 dnl If "default flags" is an empty string, the effect is the same
2526 dnl as --disable or --enable=no.
2527 dnl
2528 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2529 GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2530 [pass compiler FLAGS when building debug library],
2531 [case "x$enable_libstdcxx_debug_flags" in
2532 xno | x) enable_libstdcxx_debug_flags= ;;
2533 x-*) ;;
2534 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2535 esac])
2537 # Option parsed, now set things appropriately
2538 DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2539 AC_SUBST(DEBUG_FLAGS)
2541 AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2542 ])
2545 dnl
2546 dnl Check if the user only wants a freestanding library implementation.
2547 dnl
2548 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2549 dnl installing only the headers required by [17.4.1.3] and the language
2550 dnl support library. More than that will be built (to keep the Makefiles
2551 dnl conveniently clean), but not installed.
2552 dnl
2553 dnl Sets:
2554 dnl is_hosted (yes/no)
2555 dnl
2556 dnl Defines:
2557 dnl _GLIBCXX_HOSTED (always defined, either to 1 or 0)
2558 dnl
2559 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2560 AC_ARG_ENABLE([hosted-libstdcxx],
2561 AC_HELP_STRING([--disable-hosted-libstdcxx],
2562 [only build freestanding C++ runtime support]),,
2563 [case "$host" in
2564 arm*-*-symbianelf*)
2565 enable_hosted_libstdcxx=no
2566 ;;
2567 *)
2568 enable_hosted_libstdcxx=yes
2569 ;;
2570 esac])
2571 if test "$enable_hosted_libstdcxx" = no; then
2572 AC_MSG_NOTICE([Only freestanding libraries will be built])
2573 is_hosted=no
2574 hosted_define=0
2575 enable_abi_check=no
2576 enable_libstdcxx_pch=no
2577 else
2578 is_hosted=yes
2579 hosted_define=1
2580 fi
2581 GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2582 AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2583 [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2584 ])
2587 dnl
2588 dnl Check if the user wants a non-verbose library implementation.
2589 dnl
2590 dnl --disable-libstdcxx-verbose will turn off descriptive messages to
2591 dnl standard error on termination.
2592 dnl
2593 dnl Defines:
2594 dnl _GLIBCXX_VERBOSE (always defined, either to 1 or 0)
2595 dnl
2596 AC_DEFUN([GLIBCXX_ENABLE_VERBOSE], [
2597 AC_ARG_ENABLE([libstdcxx-verbose],
2598 AC_HELP_STRING([--disable-libstdcxx-verbose],
2599 [disable termination messages to standard error]),,
2600 [enable_libstdcxx_verbose=yes])
2601 if test x"$enable_libstdcxx_verbose" = xyes; then
2602 verbose_define=1
2603 else
2604 AC_MSG_NOTICE([verbose termination messages are disabled])
2605 verbose_define=0
2606 fi
2607 AC_DEFINE_UNQUOTED(_GLIBCXX_VERBOSE, $verbose_define,
2608 [Define to 1 if a verbose library is built, or 0 otherwise.])
2609 ])
2612 dnl
2613 dnl Check for template specializations for the 'long long' type.
2614 dnl The result determines only whether 'long long' I/O is enabled; things
2615 dnl like numeric_limits<> specializations are always available.
2616 dnl
2617 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2618 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2619 dnl + Usage: GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2620 dnl Where DEFAULT is either `yes' or `no'.
2621 dnl
2622 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2623 GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2624 if test $enable_long_long = yes; then
2625 AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2626 [Define if code specialized for long long should be used.])
2627 fi
2628 AC_MSG_CHECKING([for enabled long long specializations])
2629 AC_MSG_RESULT([$enable_long_long])
2630 ])
2633 dnl
2634 dnl Check for decimal floating point.
2635 dnl See:
2636 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2637 dnl
2638 dnl This checks to see if the host supports decimal floating point types.
2639 dnl
2640 dnl Defines:
2641 dnl _GLIBCXX_USE_DECIMAL_FLOAT
2642 dnl
2643 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2645 # Fake what AC_TRY_COMPILE does, without linking as this is
2646 # unnecessary for this test.
2648 cat > conftest.$ac_ext << EOF
2649 [#]line __oline__ "configure"
2650 int main()
2651 {
2652 _Decimal32 d1;
2653 _Decimal64 d2;
2654 _Decimal128 d3;
2655 return 0;
2656 }
2657 EOF
2659 AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
2660 if AC_TRY_EVAL(ac_compile); then
2661 AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
2662 [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
2663 enable_dfp=yes
2664 else
2665 enable_dfp=no
2666 fi
2667 AC_MSG_RESULT($enable_dfp)
2668 rm -f conftest*
2669 ])
2671 dnl
2672 dnl Check for GNU 128-bit integer and floating point types.
2673 dnl
2674 dnl Note: also checks that the types aren't standard types.
2675 dnl
2676 dnl Defines:
2677 dnl _GLIBCXX_USE_INT128
2678 dnl _GLIBCXX_USE_FLOAT128
2679 dnl
2680 AC_DEFUN([GLIBCXX_ENABLE_INT128_FLOAT128], [
2682 AC_LANG_SAVE
2683 AC_LANG_CPLUSPLUS
2685 # Fake what AC_TRY_COMPILE does, without linking as this is
2686 # unnecessary for this test.
2688 cat > conftest.$ac_ext << EOF
2689 [#]line __oline__ "configure"
2690 template<typename T1, typename T2>
2691 struct same
2692 { typedef T2 type; };
2694 template<typename T>
2695 struct same<T, T>;
2697 int main()
2698 {
2699 typename same<long, __int128>::type i1;
2700 typename same<long long, __int128>::type i2;
2701 }
2702 EOF
2704 AC_MSG_CHECKING([for __int128])
2705 if AC_TRY_EVAL(ac_compile); then
2706 AC_DEFINE(_GLIBCXX_USE_INT128, 1,
2707 [Define if __int128 is supported on this host.])
2708 enable_int128=yes
2709 else
2710 enable_int128=no
2711 fi
2712 AC_MSG_RESULT($enable_int128)
2713 rm -f conftest*
2715 cat > conftest.$ac_ext << EOF
2716 [#]line __oline__ "configure"
2717 template<typename T1, typename T2>
2718 struct same
2719 { typedef T2 type; };
2721 template<typename T>
2722 struct same<T, T>;
2724 int main()
2725 {
2726 typename same<double, __float128>::type f1;
2727 typename same<long double, __float128>::type f2;
2728 }
2729 EOF
2731 AC_MSG_CHECKING([for __float128])
2732 if AC_TRY_EVAL(ac_compile); then
2733 AC_DEFINE(_GLIBCXX_USE_FLOAT128, 1,
2734 [Define if __float128 is supported on this host.])
2735 enable_float128=yes
2736 else
2737 enable_float128=no
2738 fi
2739 AC_MSG_RESULT($enable_float128)
2740 rm -f conftest*
2742 AC_LANG_RESTORE
2743 ])
2745 dnl
2746 dnl Check for template specializations for the 'wchar_t' type.
2747 dnl
2748 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2749 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2750 dnl + Usage: GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2751 dnl Where DEFAULT is either `yes' or `no'.
2752 dnl
2753 dnl Necessary support must also be present.
2754 dnl
2755 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2756 GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2758 # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2759 AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2760 AC_MSG_CHECKING([for mbstate_t])
2761 AC_TRY_COMPILE([#include <wchar.h>],
2762 [mbstate_t teststate;],
2763 have_mbstate_t=yes, have_mbstate_t=no)
2764 AC_MSG_RESULT($have_mbstate_t)
2765 if test x"$have_mbstate_t" = xyes; then
2766 AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2767 fi
2769 # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2770 # ac_has_wchar_h.
2771 AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2773 if test x"$enable_wchar_t" = x"yes"; then
2775 AC_LANG_SAVE
2776 AC_LANG_CPLUSPLUS
2778 if test x"$ac_has_wchar_h" = xyes &&
2779 test x"$ac_has_wctype_h" = xyes; then
2780 AC_TRY_COMPILE([#include <wchar.h>
2781 #include <stddef.h>
2782 wint_t i;
2783 long l = WEOF;
2784 long j = WCHAR_MIN;
2785 long k = WCHAR_MAX;
2786 namespace test
2787 {
2788 using ::btowc;
2789 using ::fgetwc;
2790 using ::fgetws;
2791 using ::fputwc;
2792 using ::fputws;
2793 using ::fwide;
2794 using ::fwprintf;
2795 using ::fwscanf;
2796 using ::getwc;
2797 using ::getwchar;
2798 using ::mbrlen;
2799 using ::mbrtowc;
2800 using ::mbsinit;
2801 using ::mbsrtowcs;
2802 using ::putwc;
2803 using ::putwchar;
2804 using ::swprintf;
2805 using ::swscanf;
2806 using ::ungetwc;
2807 using ::vfwprintf;
2808 using ::vswprintf;
2809 using ::vwprintf;
2810 using ::wcrtomb;
2811 using ::wcscat;
2812 using ::wcschr;
2813 using ::wcscmp;
2814 using ::wcscoll;
2815 using ::wcscpy;
2816 using ::wcscspn;
2817 using ::wcsftime;
2818 using ::wcslen;
2819 using ::wcsncat;
2820 using ::wcsncmp;
2821 using ::wcsncpy;
2822 using ::wcspbrk;
2823 using ::wcsrchr;
2824 using ::wcsrtombs;
2825 using ::wcsspn;
2826 using ::wcsstr;
2827 using ::wcstod;
2828 using ::wcstok;
2829 using ::wcstol;
2830 using ::wcstoul;
2831 using ::wcsxfrm;
2832 using ::wctob;
2833 using ::wmemchr;
2834 using ::wmemcmp;
2835 using ::wmemcpy;
2836 using ::wmemmove;
2837 using ::wmemset;
2838 using ::wprintf;
2839 using ::wscanf;
2840 }
2841 ],[],[], [enable_wchar_t=no])
2842 else
2843 enable_wchar_t=no
2844 fi
2846 AC_LANG_RESTORE
2847 fi
2849 if test x"$enable_wchar_t" = x"yes"; then
2850 AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2851 [Define if code specialized for wchar_t should be used.])
2852 fi
2854 AC_MSG_CHECKING([for enabled wchar_t specializations])
2855 AC_MSG_RESULT([$enable_wchar_t])
2856 ])
2859 dnl
2860 dnl Check to see if building and using a C++ precompiled header can be done.
2861 dnl
2862 dnl --enable-libstdcxx-pch=yes
2863 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2864 dnl may work, after some light-hearted attempts to puzzle out compiler
2865 dnl support, flip bits on in include/Makefile.am
2866 dnl
2867 dnl --disable-libstdcxx-pch
2868 dnl turns off attempts to use or build stdc++.h.gch.
2869 dnl
2870 dnl Substs:
2871 dnl glibcxx_PCHFLAGS
2872 dnl
2873 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2874 GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2875 if test $enable_libstdcxx_pch = yes; then
2876 AC_CACHE_CHECK([for compiler with PCH support],
2877 [glibcxx_cv_prog_CXX_pch],
2878 [ac_save_CXXFLAGS="$CXXFLAGS"
2879 CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2880 AC_LANG_SAVE
2881 AC_LANG_CPLUSPLUS
2882 echo '#include <math.h>' > conftest.h
2883 if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2884 -o conftest.h.gch 1>&5 2>&1 &&
2885 echo '#error "pch failed"' > conftest.h &&
2886 echo '#include "conftest.h"' > conftest.cc &&
2887 $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2888 then
2889 glibcxx_cv_prog_CXX_pch=yes
2890 else
2891 glibcxx_cv_prog_CXX_pch=no
2892 fi
2893 rm -f conftest*
2894 CXXFLAGS=$ac_save_CXXFLAGS
2895 AC_LANG_RESTORE
2896 ])
2897 enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2898 fi
2900 AC_MSG_CHECKING([for enabled PCH])
2901 AC_MSG_RESULT([$enable_libstdcxx_pch])
2903 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2904 if test $enable_libstdcxx_pch = yes; then
2905 glibcxx_PCHFLAGS="-include bits/stdc++.h"
2906 else
2907 glibcxx_PCHFLAGS=""
2908 fi
2909 AC_SUBST(glibcxx_PCHFLAGS)
2910 ])
2913 dnl
2914 dnl Check for atomic builtins.
2915 dnl See:
2916 dnl http://gcc.gnu.org/onlinedocs/gcc/_005f_005fatomic-Builtins.html
2917 dnl
2918 dnl This checks to see if the host supports the compiler-generated
2919 dnl builtins for atomic operations for various integral sizes. Note, this
2920 dnl is intended to be an all-or-nothing switch, so all the atomic operations
2921 dnl that are used should be checked.
2922 dnl
2923 dnl Note:
2924 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
2925 dnl
2926 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2927 AC_LANG_SAVE
2928 AC_LANG_CPLUSPLUS
2929 old_CXXFLAGS="$CXXFLAGS"
2931 # Do link tests if possible, instead asm tests, limited to some platforms
2932 # see discussion in PR target/40134, PR libstdc++/40133 and the thread
2933 # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
2934 atomic_builtins_link_tests=no
2935 if test x$gcc_no_link != xyes; then
2936 # Can do link tests. Limit to some tested platforms
2937 case "$host" in
2938 *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
2939 atomic_builtins_link_tests=yes
2940 ;;
2941 esac
2942 fi
2944 if test x$atomic_builtins_link_tests = xyes; then
2946 # Do link tests.
2948 CXXFLAGS="$CXXFLAGS -fno-exceptions"
2950 AC_MSG_CHECKING([for atomic builtins for bool])
2951 AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
2952 AC_TRY_LINK(
2953 [ ],
2954 [typedef bool atomic_type;
2955 atomic_type c1;
2956 atomic_type c2;
2957 atomic_type c3(0);
2958 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2959 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2960 __ATOMIC_RELAXED);
2961 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2962 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2963 ],
2964 [glibcxx_cv_atomic_bool=yes],
2965 [glibcxx_cv_atomic_bool=no])
2966 ])
2967 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2969 AC_MSG_CHECKING([for atomic builtins for short])
2970 AC_CACHE_VAL(glibcxx_cv_atomic_short, [
2971 AC_TRY_LINK(
2972 [ ],
2973 [typedef short atomic_type;
2974 atomic_type c1;
2975 atomic_type c2;
2976 atomic_type c3(0);
2977 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2978 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2979 __ATOMIC_RELAXED);
2980 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2981 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2982 ],
2983 [glibcxx_cv_atomic_short=yes],
2984 [glibcxx_cv_atomic_short=no])
2985 ])
2986 AC_MSG_RESULT($glibcxx_cv_atomic_short)
2988 AC_MSG_CHECKING([for atomic builtins for int])
2989 AC_CACHE_VAL(glibcxx_cv_atomic_int, [
2990 AC_TRY_LINK(
2991 [ ],
2992 [typedef int atomic_type;
2993 atomic_type c1;
2994 atomic_type c2;
2995 atomic_type c3(0);
2996 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2997 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2998 __ATOMIC_RELAXED);
2999 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3000 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3001 ],
3002 [glibcxx_cv_atomic_int=yes],
3003 [glibcxx_cv_atomic_int=no])
3004 ])
3005 AC_MSG_RESULT($glibcxx_cv_atomic_int)
3007 AC_MSG_CHECKING([for atomic builtins for long long])
3008 AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
3009 AC_TRY_LINK(
3010 [ ],
3011 [typedef long long atomic_type;
3012 atomic_type c1;
3013 atomic_type c2;
3014 atomic_type c3(0);
3015 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3016 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3017 __ATOMIC_RELAXED);
3018 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3019 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3020 ],
3021 [glibcxx_cv_atomic_long_long=yes],
3022 [glibcxx_cv_atomic_long_long=no])
3023 ])
3024 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
3026 else
3028 # Do asm tests.
3030 # Compile unoptimized.
3031 CXXFLAGS='-O0 -S'
3033 # Fake what AC_TRY_COMPILE does.
3035 cat > conftest.$ac_ext << EOF
3036 [#]line __oline__ "configure"
3037 int main()
3038 {
3039 typedef bool atomic_type;
3040 atomic_type c1;
3041 atomic_type c2;
3042 atomic_type c3(0);
3043 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3044 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3045 __ATOMIC_RELAXED);
3046 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3047 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3049 return 0;
3050 }
3051 EOF
3053 AC_MSG_CHECKING([for atomic builtins for bool])
3054 if AC_TRY_EVAL(ac_compile); then
3055 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3056 glibcxx_cv_atomic_bool=no
3057 else
3058 glibcxx_cv_atomic_bool=yes
3059 fi
3060 fi
3061 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
3062 rm -f conftest*
3064 cat > conftest.$ac_ext << EOF
3065 [#]line __oline__ "configure"
3066 int main()
3067 {
3068 typedef short atomic_type;
3069 atomic_type c1;
3070 atomic_type c2;
3071 atomic_type c3(0);
3072 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3073 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3074 __ATOMIC_RELAXED);
3075 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3076 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3078 return 0;
3079 }
3080 EOF
3082 AC_MSG_CHECKING([for atomic builtins for short])
3083 if AC_TRY_EVAL(ac_compile); then
3084 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3085 glibcxx_cv_atomic_short=no
3086 else
3087 glibcxx_cv_atomic_short=yes
3088 fi
3089 fi
3090 AC_MSG_RESULT($glibcxx_cv_atomic_short)
3091 rm -f conftest*
3093 cat > conftest.$ac_ext << EOF
3094 [#]line __oline__ "configure"
3095 int main()
3096 {
3097 // NB: _Atomic_word not necessarily int.
3098 typedef int atomic_type;
3099 atomic_type c1;
3100 atomic_type c2;
3101 atomic_type c3(0);
3102 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3103 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3104 __ATOMIC_RELAXED);
3105 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3106 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3108 return 0;
3109 }
3110 EOF
3112 AC_MSG_CHECKING([for atomic builtins for int])
3113 if AC_TRY_EVAL(ac_compile); then
3114 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3115 glibcxx_cv_atomic_int=no
3116 else
3117 glibcxx_cv_atomic_int=yes
3118 fi
3119 fi
3120 AC_MSG_RESULT($glibcxx_cv_atomic_int)
3121 rm -f conftest*
3123 cat > conftest.$ac_ext << EOF
3124 [#]line __oline__ "configure"
3125 int main()
3126 {
3127 typedef long long atomic_type;
3128 atomic_type c1;
3129 atomic_type c2;
3130 atomic_type c3(0);
3131 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3132 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3133 __ATOMIC_RELAXED);
3134 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3135 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3137 return 0;
3138 }
3139 EOF
3141 AC_MSG_CHECKING([for atomic builtins for long long])
3142 if AC_TRY_EVAL(ac_compile); then
3143 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3144 glibcxx_cv_atomic_long_long=no
3145 else
3146 glibcxx_cv_atomic_long_long=yes
3147 fi
3148 fi
3149 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
3150 rm -f conftest*
3152 fi
3154 CXXFLAGS="$old_CXXFLAGS"
3155 AC_LANG_RESTORE
3157 # Set atomicity_dir to builtins if all but the long long test above passes.
3158 if test $glibcxx_cv_atomic_bool = yes \
3159 && test $glibcxx_cv_atomic_short = yes \
3160 && test $glibcxx_cv_atomic_int = yes; then
3161 AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
3162 [Define if the compiler supports C++11 atomics.])
3163 atomicity_dir=cpu/generic/atomicity_builtins
3164 fi
3166 # If still generic, set to mutex.
3167 if test $atomicity_dir = "cpu/generic" ; then
3168 atomicity_dir=cpu/generic/atomicity_mutex
3169 AC_MSG_WARN([No native atomic operations are provided for this platform.])
3170 if test "x$target_thread_file" = xsingle; then
3171 AC_MSG_WARN([They cannot be faked when thread support is disabled.])
3172 AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
3173 else
3174 AC_MSG_WARN([They will be faked using a mutex.])
3175 AC_MSG_WARN([Performance of certain classes will degrade as a result.])
3176 fi
3177 fi
3179 ])
3182 dnl
3183 dnl Allow visibility attributes to be used on namespaces, objects, etc.
3184 dnl
3185 dnl --enable-libstdcxx-visibility enables attempt to use visibility attributes.
3186 dnl --disable-libstdcxx-visibility turns off all use of visibility attributes.
3187 dnl + Usage: GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY[(DEFAULT)]
3188 dnl Where DEFAULT is 'yes'.
3189 dnl
3190 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY], [
3191 GLIBCXX_ENABLE(libstdcxx-visibility,$1,,[enables visibility safe usage])
3193 if test x$enable_libstdcxx_visibility = xyes ; then
3194 dnl all hail libgfortran
3195 dnl Check whether the target supports hidden visibility.
3196 AC_CACHE_CHECK([whether the target supports hidden visibility],
3197 glibcxx_cv_have_attribute_visibility, [
3198 save_CFLAGS="$CFLAGS"
3199 CFLAGS="$CFLAGS -Werror"
3200 AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
3201 [], glibcxx_cv_have_attribute_visibility=yes,
3202 glibcxx_cv_have_attribute_visibility=no)
3203 CFLAGS="$save_CFLAGS"])
3204 if test $glibcxx_cv_have_attribute_visibility = no; then
3205 enable_libstdcxx_visibility=no
3206 fi
3207 fi
3209 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_libstdcxx_visibility = yes)
3210 AC_MSG_NOTICE([visibility supported: $enable_libstdcxx_visibility])
3211 ])
3214 dnl
3215 dnl Add version tags to symbols in shared library (or not), additionally
3216 dnl marking other symbols as private/local (or not).
3217 dnl
3218 dnl Sets libtool_VERSION, and determines shared library SONAME.
3219 dnl
3220 dnl This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
3221 dnl
3222 dnl --enable-symvers=style adds a version script to the linker call when
3223 dnl creating the shared library. The choice of version script is
3224 dnl controlled by 'style'.
3225 dnl --disable-symvers does not.
3226 dnl
3227 dnl + Usage: GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
3228 dnl Where DEFAULT is either 'yes' or 'no'. Passing `yes' tries to
3229 dnl choose a default style based on linker characteristics. Passing
3230 dnl 'no' disables versioning.
3231 dnl
3232 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
3234 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
3235 [enables symbol versioning of the shared library],
3236 [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
3238 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
3239 # don't know enough about $LD to do tricks...
3240 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
3241 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
3242 # with extern "C++" in version scripts.
3243 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
3245 # Turn a 'yes' into a suitable default.
3246 if test x$enable_symvers = xyes ; then
3247 if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
3248 enable_symvers=no
3249 else
3250 if test $with_gnu_ld = yes ; then
3251 case ${target_os} in
3252 hpux*)
3253 enable_symvers=no ;;
3254 *)
3255 enable_symvers=gnu ;;
3256 esac
3257 else
3258 case ${target_os} in
3259 darwin*)
3260 enable_symvers=darwin ;;
3261 # Sun symbol versioning exists since Solaris 2.5.
3262 solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
3263 # make_sunver.pl needs GNU c++filt to support extern "C++" in
3264 # version scripts, so disable symbol versioning if none can be
3265 # found.
3266 if test -z "$ac_cv_path_CXXFILT"; then
3267 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3268 AC_MSG_WARN([=== no GNU c++filt could be found.])
3269 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3270 enable_symvers=no
3271 else
3272 enable_symvers=sun
3273 fi
3274 ;;
3275 *)
3276 enable_symvers=no ;;
3277 esac
3278 fi
3279 fi
3280 fi
3282 # Check to see if 'darwin' or 'darwin-export' can win.
3283 if test x$enable_symvers = xdarwin-export ; then
3284 enable_symvers=darwin
3285 fi
3287 # Check if 'sun' was requested on non-Solaris 2 platforms.
3288 if test x$enable_symvers = xsun ; then
3289 case ${target_os} in
3290 solaris2*)
3291 # All fine.
3292 ;;
3293 *)
3294 # Unlikely to work.
3295 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3296 AC_MSG_WARN([=== you are not targetting Solaris 2.])
3297 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3298 enable_symvers=no
3299 ;;
3300 esac
3301 fi
3303 # Check to see if 'gnu' can win.
3304 if test $enable_symvers = gnu ||
3305 test $enable_symvers = gnu-versioned-namespace ||
3306 test $enable_symvers = sun; then
3307 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
3308 AC_MSG_CHECKING([for shared libgcc])
3309 ac_save_CFLAGS="$CFLAGS"
3310 CFLAGS=' -lgcc_s'
3311 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
3312 CFLAGS="$ac_save_CFLAGS"
3313 if test $glibcxx_shared_libgcc = no; then
3314 cat > conftest.c <<EOF
3315 int main (void) { return 0; }
3316 EOF
3317 changequote(,)dnl
3318 glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
3319 -shared -shared-libgcc -o conftest.so \
3320 conftest.c -v 2>&1 >/dev/null \
3321 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
3322 changequote([,])dnl
3323 rm -f conftest.c conftest.so
3324 if test x${glibcxx_libgcc_s_suffix+set} = xset; then
3325 CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
3326 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
3327 CFLAGS="$ac_save_CFLAGS"
3328 fi
3329 fi
3330 AC_MSG_RESULT($glibcxx_shared_libgcc)
3332 # For GNU ld, we need at least this version. The format is described in
3333 # GLIBCXX_CHECK_LINKER_FEATURES above.
3334 glibcxx_min_gnu_ld_version=21400
3336 # If no shared libgcc, can't win.
3337 if test $glibcxx_shared_libgcc != yes; then
3338 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3339 AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3340 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3341 enable_symvers=no
3342 elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3343 : All interesting versions of Sun ld support sun style symbol versioning.
3344 elif test $with_gnu_ld != yes ; then
3345 # just fail for now
3346 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3347 AC_MSG_WARN([=== you are not using the GNU linker.])
3348 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3349 enable_symvers=no
3350 elif test $glibcxx_ld_is_gold = yes ; then
3351 : All versions of gold support symbol versioning.
3352 elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3353 # The right tools, the right setup, but too old. Fallbacks?
3354 AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3355 AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3356 AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3357 AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3358 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3359 enable_symvers=no
3360 fi
3361 fi
3363 # For libtool versioning info, format is CURRENT:REVISION:AGE
3364 libtool_VERSION=6:22:0
3366 # Everything parsed; figure out what files and settings to use.
3367 case $enable_symvers in
3368 no)
3369 SYMVER_FILE=config/abi/pre/none.ver
3370 ;;
3371 gnu)
3372 SYMVER_FILE=config/abi/pre/gnu.ver
3373 AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3374 [Define to use GNU versioning in the shared library.])
3375 ;;
3376 gnu-versioned-namespace)
3377 libtool_VERSION=7:0:0
3378 SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3379 AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3380 [Define to use GNU namespace versioning in the shared library.])
3381 ;;
3382 darwin)
3383 SYMVER_FILE=config/abi/pre/gnu.ver
3384 AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3385 [Define to use darwin versioning in the shared library.])
3386 ;;
3387 sun)
3388 SYMVER_FILE=config/abi/pre/gnu.ver
3389 AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3390 [Define to use Sun versioning in the shared library.])
3391 ;;
3392 esac
3394 if test x$enable_symvers != xno ; then
3395 AC_DEFINE(_GLIBCXX_SYMVER, 1,
3396 [Define to use symbol versioning in the shared library.])
3397 fi
3399 AC_CACHE_CHECK([whether the target supports .symver directive],
3400 glibcxx_cv_have_as_symver_directive, [
3401 AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3402 [], glibcxx_cv_have_as_symver_directive=yes,
3403 glibcxx_cv_have_as_symver_directive=no)])
3404 if test $glibcxx_cv_have_as_symver_directive = yes; then
3405 AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3406 [Define to 1 if the target assembler supports .symver directive.])
3407 fi
3409 AC_SUBST(SYMVER_FILE)
3410 AC_SUBST(port_specific_symbol_files)
3411 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3412 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3413 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3414 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3415 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3416 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3418 if test $enable_symvers != no ; then
3419 case ${target_os} in
3420 # The Solaris 2 runtime linker doesn't support the GNU extension of
3421 # binding the same symbol to different versions
3422 solaris2*)
3423 ;;
3424 # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3425 *)
3426 AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3427 [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3428 ;;
3429 esac
3430 fi
3432 # Now, set up compatibility support, if any.
3433 # In addition, need this to deal with std::size_t mangling in
3434 # src/compatibility.cc. In a perfect world, could use
3435 # typeid(std::size_t).name()[0] to do direct substitution.
3436 AC_MSG_CHECKING([for size_t as unsigned int])
3437 ac_save_CFLAGS="$CFLAGS"
3438 CFLAGS="-Werror"
3439 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3440 [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3441 CFLAGS=$ac_save_CFLAGS
3442 if test "$glibcxx_size_t_is_i" = yes; then
3443 AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3444 fi
3445 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3447 AC_MSG_CHECKING([for ptrdiff_t as int])
3448 ac_save_CFLAGS="$CFLAGS"
3449 CFLAGS="-Werror"
3450 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3451 [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3452 CFLAGS=$ac_save_CFLAGS
3453 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3454 AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3455 fi
3456 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3457 ])
3460 dnl
3461 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3462 dnl We must stage the required headers so that they will be installed
3463 dnl with the library (unlike libgcc, the STL implementation is provided
3464 dnl solely within headers). Since we must not inject random user-space
3465 dnl macro names into user-provided C++ code, we first stage into <file>-in
3466 dnl and process to <file> with an output command. The reason for a two-
3467 dnl stage process here is to correctly handle $srcdir!=$objdir without
3468 dnl having to write complex code (the sed commands to clean the macro
3469 dnl namespace are complex and fragile enough as it is). We must also
3470 dnl add a relative path so that -I- is supported properly.
3471 dnl
3472 dnl Substs:
3473 dnl thread_header
3474 dnl
3475 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3476 AC_MSG_CHECKING([for thread model used by GCC])
3477 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3478 AC_MSG_RESULT([$target_thread_file])
3479 GCC_AC_THREAD_HEADER([$target_thread_file])
3480 ])
3483 dnl
3484 dnl Check if gthread implementation defines the types and functions
3485 dnl required by the c++0x thread library. Conforming gthread
3486 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3487 dnl
3488 dnl GLIBCXX_ENABLE_SYMVERS must be done before this.
3489 dnl
3490 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3491 GLIBCXX_ENABLE(libstdcxx-threads,auto,,[enable C++11 threads support])
3493 if test x$enable_libstdcxx_threads = xauto ||
3494 test x$enable_libstdcxx_threads = xyes; then
3496 AC_LANG_SAVE
3497 AC_LANG_CPLUSPLUS
3499 ac_save_CXXFLAGS="$CXXFLAGS"
3500 CXXFLAGS="$CXXFLAGS -fno-exceptions \
3501 -I${toplevel_srcdir}/libgcc -I${toplevel_builddir}/libgcc"
3503 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3504 case $target_thread_file in
3505 posix)
3506 CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3507 esac
3509 AC_MSG_CHECKING([whether it can be safely assumed that mutex_timedlock is available])
3511 AC_TRY_COMPILE([#include <unistd.h>],
3512 [
3513 // In case of POSIX threads check _POSIX_TIMEOUTS.
3514 #if (defined(_PTHREADS) \
3515 && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3516 #error
3517 #endif
3518 ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3520 AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3521 [Define to 1 if mutex_timedlock is available.])
3523 if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3524 else res_mutex_timedlock=no ; fi
3525 AC_MSG_RESULT([$res_mutex_timedlock])
3527 AC_MSG_CHECKING([for gthreads library])
3529 AC_TRY_COMPILE([#include "gthr.h"],
3530 [
3531 #ifndef __GTHREADS_CXX0X
3532 #error
3533 #endif
3534 ], [ac_has_gthreads=yes], [ac_has_gthreads=no])
3535 else
3536 ac_has_gthreads=no
3537 fi
3539 AC_MSG_RESULT([$ac_has_gthreads])
3541 if test x"$ac_has_gthreads" = x"yes"; then
3542 AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3543 [Define if gthreads library is available.])
3545 # Also check for pthread_rwlock_t for std::shared_timed_mutex in C++14
3546 AC_CHECK_TYPE([pthread_rwlock_t],
3547 [AC_DEFINE([_GLIBCXX_USE_PTHREAD_RWLOCK_T], 1,
3548 [Define if POSIX read/write locks are available in <gthr.h>.])],
3549 [],
3550 [#include "gthr.h"])
3551 fi
3553 CXXFLAGS="$ac_save_CXXFLAGS"
3554 AC_LANG_RESTORE
3555 ])
3558 # Check whether LC_MESSAGES is available in <locale.h>.
3559 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3560 #
3561 # This file file be copied and used freely without restrictions. It can
3562 # be used in projects which are not available under the GNU Public License
3563 # but which still want to provide support for the GNU gettext functionality.
3564 # Please note that the actual code is *not* freely available.
3565 AC_DEFUN([AC_LC_MESSAGES], [
3566 AC_CHECK_HEADER(locale.h, [
3567 AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3568 [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3569 ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3570 if test $ac_cv_val_LC_MESSAGES = yes; then
3571 AC_DEFINE(HAVE_LC_MESSAGES, 1,
3572 [Define if LC_MESSAGES is available in <locale.h>.])
3573 fi
3574 ])
3575 ])
3577 dnl
3578 dnl Check whether rdrand is supported in the assembler.
3579 AC_DEFUN([GLIBCXX_CHECK_X86_RDRAND], [
3580 AC_MSG_CHECKING([for rdrand support in assembler])
3581 AC_CACHE_VAL(ac_cv_x86_rdrand, [
3582 ac_cv_x86_rdrand=no
3583 case "$target" in
3584 i?86-*-* | \
3585 x86_64-*-*)
3586 AC_TRY_COMPILE(, [asm("rdrand %eax");],
3587 [ac_cv_x86_rdrand=yes], [ac_cv_x86_rdrand=no])
3588 esac
3589 ])
3590 if test $ac_cv_x86_rdrand = yes; then
3591 AC_DEFINE(_GLIBCXX_X86_RDRAND, 1,
3592 [ Defined if as can handle rdrand. ])
3593 fi
3594 AC_MSG_RESULT($ac_cv_x86_rdrand)
3595 ])
3597 dnl
3598 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3599 dnl
3600 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3602 AC_LANG_SAVE
3603 AC_LANG_CPLUSPLUS
3604 ac_save_CXXFLAGS="$CXXFLAGS"
3605 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3607 AC_MSG_CHECKING([for get_nprocs])
3608 AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3609 GCC_TRY_COMPILE_OR_LINK(
3610 [#include <sys/sysinfo.h>],
3611 [int n = get_nprocs();],
3612 [glibcxx_cv_GET_NPROCS=yes],
3613 [glibcxx_cv_GET_NPROCS=no])
3614 ])
3615 if test $glibcxx_cv_GET_NPROCS = yes; then
3616 AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3617 fi
3618 AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3620 CXXFLAGS="$ac_save_CXXFLAGS"
3621 AC_LANG_RESTORE
3622 ])
3624 dnl
3625 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3626 dnl
3627 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3629 AC_LANG_SAVE
3630 AC_LANG_CPLUSPLUS
3631 ac_save_CXXFLAGS="$CXXFLAGS"
3632 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3634 AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3635 AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3636 GCC_TRY_COMPILE_OR_LINK(
3637 [#include <unistd.h>],
3638 [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3639 [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3640 [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3641 ])
3642 if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3643 AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN is available in <unistd.h>.])
3644 fi
3645 AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3647 CXXFLAGS="$ac_save_CXXFLAGS"
3648 AC_LANG_RESTORE
3649 ])
3651 dnl
3652 dnl Check whether sysconf(_SC_NPROC_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROC_ONLN.
3653 dnl
3654 AC_DEFUN([GLIBCXX_CHECK_SC_NPROC_ONLN], [
3656 AC_LANG_SAVE
3657 AC_LANG_CPLUSPLUS
3658 ac_save_CXXFLAGS="$CXXFLAGS"
3659 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3661 AC_MSG_CHECKING([for _SC_NPROC_ONLN])
3662 AC_CACHE_VAL(glibcxx_cv_SC_NPROC_ONLN, [
3663 GCC_TRY_COMPILE_OR_LINK(
3664 [#include <unistd.h>],
3665 [int n = sysconf(_SC_NPROC_ONLN);],
3666 [glibcxx_cv_SC_NPROC_ONLN=yes],
3667 [glibcxx_cv_SC_NPROC_ONLN=no])
3668 ])
3669 if test $glibcxx_cv_SC_NPROC_ONLN = yes; then
3670 AC_DEFINE(_GLIBCXX_USE_SC_NPROC_ONLN, 1, [Define if _SC_NPROC_ONLN is available in <unistd.h>.])
3671 fi
3672 AC_MSG_RESULT($glibcxx_cv_SC_NPROC_ONLN)
3674 CXXFLAGS="$ac_save_CXXFLAGS"
3675 AC_LANG_RESTORE
3676 ])
3678 dnl
3679 dnl Check whether pthread_num_processors_np is available in <pthread.h>, and define _GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP.
3680 dnl
3681 AC_DEFUN([GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP], [
3683 AC_LANG_SAVE
3684 AC_LANG_CPLUSPLUS
3685 ac_save_CXXFLAGS="$CXXFLAGS"
3686 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3688 AC_MSG_CHECKING([for pthreads_num_processors_np])
3689 AC_CACHE_VAL(glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP, [
3690 GCC_TRY_COMPILE_OR_LINK(
3691 [#include <pthread.h>],
3692 [int n = pthread_num_processors_np();],
3693 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=yes],
3694 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=no])
3695 ])
3696 if test $glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP = yes; then
3697 AC_DEFINE(_GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP, 1, [Define if pthreads_num_processors_np is available in <pthread.h>.])
3698 fi
3699 AC_MSG_RESULT($glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP)
3701 CXXFLAGS="$ac_save_CXXFLAGS"
3702 AC_LANG_RESTORE
3703 ])
3705 dnl
3706 dnl Check whether sysctl is available in <pthread.h>, and define _GLIBCXX_USE_SYSCTL_HW_NCPU.
3707 dnl
3708 AC_DEFUN([GLIBCXX_CHECK_SYSCTL_HW_NCPU], [
3710 AC_LANG_SAVE
3711 AC_LANG_CPLUSPLUS
3712 ac_save_CXXFLAGS="$CXXFLAGS"
3713 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3715 AC_MSG_CHECKING([for hw.ncpu sysctl])
3716 AC_CACHE_VAL(glibcxx_cv_SYSCTL_HW_NCPU, [
3717 GCC_TRY_COMPILE_OR_LINK(
3718 [
3719 #include <stddef.h>
3720 #include <sys/sysctl.h>
3721 ],
3722 [
3723 int count;
3724 size_t size = sizeof(count);
3725 int mib[] = { CTL_HW, HW_NCPU };
3726 sysctl(mib, 2, &count, &size, NULL, 0);
3727 ],
3728 [glibcxx_cv_SYSCTL_HW_NCPU=yes],
3729 [glibcxx_cv_SYSCTL_HW_NCPU=no])
3730 ])
3731 if test $glibcxx_cv_SYSCTL_HW_NCPU = yes; then
3732 AC_DEFINE(_GLIBCXX_USE_SYSCTL_HW_NCPU, 1, [Define if sysctl(), CTL_HW and HW_NCPU are available in <sys/sysctl.h>.])
3733 fi
3734 AC_MSG_RESULT($glibcxx_cv_SYSCTL_HW_NCPU)
3736 CXXFLAGS="$ac_save_CXXFLAGS"
3737 AC_LANG_RESTORE
3738 ])
3740 dnl
3741 dnl Check to see if python pretty printing can be activated.
3742 dnl
3743 dnl --with-python-dir=dir
3744 dnl installs directory into $prefix/dir
3745 AC_DEFUN([GLIBCXX_ENABLE_PYTHON], [
3747 AC_MSG_CHECKING([for custom python install directory])
3748 AC_ARG_WITH([python-dir],
3749 AS_HELP_STRING([--with-python-dir],
3750 [the location to install Python modules. This path is relative starting from the prefix.]),
3751 [with_python_dir=$withval], [with_python_dir="no"])
3752 AC_MSG_RESULT(${with_python_dir})
3754 # Needed for installing Python modules during make install.
3755 python_mod_dir="${with_python_dir}"
3756 AC_SUBST(python_mod_dir)
3757 GLIBCXX_CONDITIONAL(ENABLE_PYTHONDIR, test $python_mod_dir != no)
3758 ])
3760 dnl
3761 dnl Check to see if -Werror is disabled.
3762 dnl
3763 dnl --enable-werror/--disable-werror
3764 AC_DEFUN([GLIBCXX_ENABLE_WERROR], [
3765 AC_MSG_CHECKING([for -Werror])
3766 GLIBCXX_ENABLE(werror,$1,,[turns on -Werror])
3767 AC_MSG_RESULT($enable_werror)
3768 GLIBCXX_CONDITIONAL(ENABLE_WERROR, test $enable_werror = yes)
3769 ])
3771 dnl
3772 dnl Check whether obsolescent tmpnam is available in <stdio.h>,
3773 dnl and define _GLIBCXX_USE_TMPNAM.
3774 dnl
3775 AC_DEFUN([GLIBCXX_CHECK_TMPNAM], [dnl
3776 dnl
3777 AC_LANG_SAVE
3778 AC_LANG_CPLUSPLUS
3779 ac_save_CXXFLAGS="$CXXFLAGS"
3780 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3781 dnl
3782 AC_MSG_CHECKING([for tmpnam])
3783 AC_CACHE_VAL(glibcxx_cv_TMPNAM, [dnl
3784 GCC_TRY_COMPILE_OR_LINK(
3785 [#include <stdio.h>],
3786 [char *tmp = tmpnam(NULL);],
3787 [glibcxx_cv_TMPNAM=yes],
3788 [glibcxx_cv_TMPNAM=no])
3789 ])
3790 if test $glibcxx_cv_TMPNAM = yes; then
3791 AC_DEFINE(_GLIBCXX_USE_TMPNAM, 1, [Define if obsolescent tmpnam is available in <stdio.h>.])
3792 fi
3793 AC_MSG_RESULT($glibcxx_cv_TMPNAM)
3794 dnl
3795 CXXFLAGS="$ac_save_CXXFLAGS"
3796 AC_LANG_RESTORE
3797 ])
3799 dnl
3800 dnl Check to see if sys/sdt.h exists and that it is suitable for use.
3801 dnl Some versions of sdt.h were not compatible with C++11.
3802 dnl
3803 AC_DEFUN([GLIBCXX_CHECK_SDT_H], [
3804 AC_MSG_CHECKING([for suitable sys/sdt.h])
3805 # Note that this test has to be run with the C language.
3806 # Otherwise, sdt.h will try to include some headers from
3807 # libstdc++ itself.
3808 AC_LANG_SAVE
3809 AC_LANG_C
3810 AC_CACHE_VAL(glibcxx_cv_sys_sdt_h, [
3811 # Because we have to run the test in C, we use grep rather
3812 # than the compiler to check for the bug. The bug is that
3813 # were strings without trailing whitespace, causing g++
3814 # to look for operator"". The pattern searches for the fixed
3815 # output.
3816 AC_EGREP_CPP([ \",\" ], [
3817 #include <sys/sdt.h>
3818 int f() { STAP_PROBE(hi, bob); }
3819 ], [glibcxx_cv_sys_sdt_h=yes], [glibcxx_cv_sys_sdt_h=no])
3820 ])
3821 AC_LANG_RESTORE
3822 if test $glibcxx_cv_sys_sdt_h = yes; then
3823 AC_DEFINE(HAVE_SYS_SDT_H, 1,
3824 [Define to 1 if you have a suitable <sys/sdt.h> header file])
3825 fi
3826 AC_MSG_RESULT($glibcxx_cv_sys_sdt_h)
3827 ])
3829 dnl
3830 dnl Control whether the library should define symbols for old and new ABIs.
3831 dnl This affects definitions of strings, stringstreams and locale facets.
3832 dnl
3833 dnl --disable-libstdcxx-dual-abi will use old ABI for all types.
3834 dnl
3835 dnl Defines:
3836 dnl _GLIBCXX_USE_DUAL_ABI (always defined, either to 1 or 0)
3837 dnl
3838 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI], [
3839 GLIBCXX_ENABLE(libstdcxx-dual-abi,$1,,[support two versions of std::string])
3840 if test x$enable_symvers = xgnu-versioned-namespace; then
3841 # gnu-versioned-namespace is incompatible with the dual ABI.
3842 enable_libstdcxx_dual_abi="no"
3843 fi
3844 if test x"$enable_libstdcxx_dual_abi" != xyes; then
3845 AC_MSG_NOTICE([dual ABI is disabled])
3846 default_libstdcxx_abi="gcc4-compatible"
3847 fi
3848 GLIBCXX_CONDITIONAL(ENABLE_DUAL_ABI, test $enable_libstdcxx_dual_abi = yes)
3849 ])
3851 dnl
3852 dnl Check to see which ABI should be enabled by default.
3853 dnl
3854 dnl --with-default-libstdcxx-abi={gcc4-compatible,new}
3855 dnl
3856 dnl Defines:
3857 dnl _GLIBCXX_USE_CXX11_ABI (always defined, either to 1 or 0)
3858 dnl
3859 AC_DEFUN([GLIBCXX_DEFAULT_ABI], [
3860 if test x$enable_libstdcxx_dual_abi = xyes; then
3861 AC_MSG_CHECKING([for default std::string ABI to use])
3862 AC_ARG_WITH([default-libstdcxx-abi],
3863 AS_HELP_STRING([--with-default-libstdcxx-abi],
3864 [set the std::string ABI to use by default]),
3865 [case "$withval" in
3866 gcc4-compatible) default_libstdcxx_abi="gcc4-compatible" ;;
3867 new|cxx11) default_libstdcxx_abi="new" ;;
3868 c++*|gnu++*) AC_MSG_ERROR([Supported arguments for --with-default-libstdcxx-abi have changed, use "new" or "gcc4-compatible"]) ;;
3869 *) AC_MSG_ERROR([Invalid argument for --with-default-libstdcxx-abi]) ;;
3870 esac
3871 ],
3872 [default_libstdcxx_abi="new"])
3873 AC_MSG_RESULT(${default_libstdcxx_abi})
3874 fi
3875 if test $default_libstdcxx_abi = "new"; then
3876 glibcxx_cxx11_abi=1
3877 glibcxx_cxx98_abi=0
3878 else
3879 glibcxx_cxx11_abi=0
3880 glibcxx_cxx98_abi=1
3881 fi
3882 AC_SUBST(glibcxx_cxx98_abi)
3883 GLIBCXX_CONDITIONAL(ENABLE_CXX11_ABI, test $glibcxx_cxx11_abi = 1)
3884 ])
3886 dnl
3887 dnl Check to see whether to build libstdc++fs.a
3888 dnl
3889 dnl --enable-libstdcxx-filesystem-ts
3890 dnl
3891 AC_DEFUN([GLIBCXX_ENABLE_FILESYSTEM_TS], [
3892 GLIBCXX_ENABLE(libstdcxx-filesystem-ts,auto,,
3893 [turns on ISO/IEC TS 18822 support],
3894 [permit yes|no|auto])
3896 AC_MSG_CHECKING([whether to build Filesystem TS support])
3897 if test x"$ac_cv_header_dirent_h" != x"yes"; then
3898 enable_libstdcxx_filesystem_ts=no
3899 fi
3900 if test x"$enable_libstdcxx_filesystem_ts" = x"auto"; then
3901 case "${target_os}" in
3902 freebsd*|netbsd*|openbsd*|dragonfly*|darwin*)
3903 enable_libstdcxx_filesystem_ts=yes
3904 ;;
3905 gnu* | linux* | kfreebsd*-gnu | knetbsd*-gnu)
3906 enable_libstdcxx_filesystem_ts=yes
3907 ;;
3908 solaris*)
3909 enable_libstdcxx_filesystem_ts=yes
3910 ;;
3911 *)
3912 enable_libstdcxx_filesystem_ts=no
3913 ;;
3914 esac
3915 fi
3916 AC_MSG_RESULT($enable_libstdcxx_filesystem_ts)
3917 GLIBCXX_CONDITIONAL(ENABLE_FILESYSTEM_TS, test $enable_libstdcxx_filesystem_ts = yes)
3918 ])
3920 dnl
3921 dnl Check whether the library calls required by the Filesystem TS are present
3922 dnl and define _GLIBCXX_USE_REALPATH and _GLIBCXX_USE_UTIMENSAT.
3923 dnl
3924 AC_DEFUN([GLIBCXX_CHECK_FILESYSTEM_DEPS], [dnl
3925 dnl
3926 AC_LANG_SAVE
3927 AC_LANG_CPLUSPLUS
3928 ac_save_CXXFLAGS="$CXXFLAGS"
3929 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3930 dnl
3931 AC_MSG_CHECKING([for struct dirent.d_type])
3932 AC_CACHE_VAL(glibcxx_cv_dirent_d_type, [dnl
3933 GCC_TRY_COMPILE_OR_LINK(
3934 [#include <dirent.h>],
3935 [
3936 struct dirent d;
3937 if (sizeof d.d_type) return 0;
3938 ],
3939 [glibcxx_cv_dirent_d_type=yes],
3940 [glibcxx_cv_dirent_d_type=no])
3941 ])
3942 if test $glibcxx_cv_dirent_d_type = yes; then
3943 AC_DEFINE(HAVE_STRUCT_DIRENT_D_TYPE, 1, [Define to 1 if `d_type' is a member of `struct dirent'.])
3944 fi
3945 AC_MSG_RESULT($glibcxx_cv_dirent_d_type)
3946 dnl
3947 AC_MSG_CHECKING([for realpath])
3948 AC_CACHE_VAL(glibcxx_cv_realpath, [dnl
3949 GCC_TRY_COMPILE_OR_LINK(
3950 [
3951 #include <stdlib.h>
3952 #include <unistd.h>
3953 ],
3954 [
3955 #if _XOPEN_VERSION < 500
3956 #error
3957 #elif _XOPEN_VERSION >= 700 || defined(PATH_MAX)
3958 char *tmp = realpath((const char*)NULL, (char*)NULL);
3959 #else
3960 #error
3961 #endif
3962 ],
3963 [glibcxx_cv_realpath=yes],
3964 [glibcxx_cv_realpath=no])
3965 ])
3966 if test $glibcxx_cv_realpath = yes; then
3967 AC_DEFINE(_GLIBCXX_USE_REALPATH, 1, [Define if usable realpath is available in <stdlib.h>.])
3968 fi
3969 AC_MSG_RESULT($glibcxx_cv_realpath)
3970 dnl
3971 AC_MSG_CHECKING([for utimensat])
3972 AC_CACHE_VAL(glibcxx_cv_utimensat, [dnl
3973 GCC_TRY_COMPILE_OR_LINK(
3974 [
3975 #include <fcntl.h>
3976 #include <sys/stat.h>
3977 ],
3978 [
3979 struct timespec ts[2] = { { 0, UTIME_OMIT }, { 1, 1 } };
3980 int i = utimensat(AT_FDCWD, "path", ts, 0);
3981 ],
3982 [glibcxx_cv_utimensat=yes],
3983 [glibcxx_cv_utimensat=no])
3984 ])
3985 if test $glibcxx_cv_utimensat = yes; then
3986 AC_DEFINE(_GLIBCXX_USE_UTIMENSAT, 1, [Define if utimensat and UTIME_OMIT are available in <sys/stat.h> and AT_FDCWD in <fcntl.h>.])
3987 fi
3988 AC_MSG_RESULT($glibcxx_cv_utimensat)
3989 dnl
3990 AC_MSG_CHECKING([for struct stat.st_mtim.tv_nsec])
3991 AC_CACHE_VAL(glibcxx_cv_st_mtim, [dnl
3992 GCC_TRY_COMPILE_OR_LINK(
3993 [ #include <sys/stat.h> ],
3994 [
3995 struct stat st;
3996 return st.st_mtim.tv_nsec;
3997 ],
3998 [glibcxx_cv_st_mtim=yes],
3999 [glibcxx_cv_st_mtim=no])
4000 ])
4001 if test $glibcxx_cv_st_mtim = yes; then
4002 AC_DEFINE(_GLIBCXX_USE_ST_MTIM, 1, [Define if struct stat has timespec members.])
4003 fi
4004 AC_MSG_RESULT($glibcxx_cv_st_mtim)
4005 dnl
4006 AC_MSG_CHECKING([for fchmod])
4007 AC_CACHE_VAL(glibcxx_cv_fchmod, [dnl
4008 GCC_TRY_COMPILE_OR_LINK(
4009 [#include <sys/stat.h>],
4010 [fchmod(1, S_IWUSR);],
4011 [glibcxx_cv_fchmod=yes],
4012 [glibcxx_cv_fchmod=no])
4013 ])
4014 if test $glibcxx_cv_fchmod = yes; then
4015 AC_DEFINE(_GLIBCXX_USE_FCHMOD, 1, [Define if fchmod is available in <sys/stat.h>.])
4016 fi
4017 AC_MSG_RESULT($glibcxx_cv_fchmod)
4018 dnl
4019 AC_MSG_CHECKING([for fchmodat])
4020 AC_CACHE_VAL(glibcxx_cv_fchmodat, [dnl
4021 GCC_TRY_COMPILE_OR_LINK(
4022 [
4023 #include <fcntl.h>
4024 #include <sys/stat.h>
4025 ],
4026 [fchmodat(AT_FDCWD, "", 0, AT_SYMLINK_NOFOLLOW);],
4027 [glibcxx_cv_fchmodat=yes],
4028 [glibcxx_cv_fchmodat=no])
4029 ])
4030 if test $glibcxx_cv_fchmodat = yes; then
4031 AC_DEFINE(_GLIBCXX_USE_FCHMODAT, 1, [Define if fchmodat is available in <sys/stat.h>.])
4032 fi
4033 AC_MSG_RESULT($glibcxx_cv_fchmodat)
4034 dnl
4035 AC_MSG_CHECKING([for sendfile that can copy files])
4036 AC_CACHE_VAL(glibcxx_cv_sendfile, [dnl
4037 case "${target_os}" in
4038 gnu* | linux* | solaris*)
4039 GCC_TRY_COMPILE_OR_LINK(
4040 [#include <sys/sendfile.h>],
4041 [sendfile(1, 2, (off_t*)NULL, sizeof 1);],
4042 [glibcxx_cv_sendfile=yes],
4043 [glibcxx_cv_sendfile=no])
4044 ;;
4045 *)
4046 glibcxx_cv_sendfile=no
4047 ;;
4048 esac
4049 ])
4050 if test $glibcxx_cv_sendfile = yes; then
4051 AC_DEFINE(_GLIBCXX_USE_SENDFILE, 1, [Define if sendfile is available in <sys/stat.h>.])
4052 fi
4053 AC_MSG_RESULT($glibcxx_cv_sendfile)
4054 dnl
4055 CXXFLAGS="$ac_save_CXXFLAGS"
4056 AC_LANG_RESTORE
4057 ])
4059 # Macros from the top-level gcc directory.
4060 m4_include([../config/gc++filt.m4])
4061 m4_include([../config/tls.m4])
4062 m4_include([../config/gthr.m4])