libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(LD, ld)
 117 AC_CHECK_TOOL(AR, ar)
 118 AC_CHECK_TOOL(RANLIB, ranlib, :)
 119 AC_CHECK_PROGS(JAR, [jar fastjar], false)
 120 if test "$JAR" = false; then
 121   AC_MSG_ERROR(jar program not found)
 122 fi
 123
 124 AC_PROG_INSTALL
 125
 126 AM_MAINTAINER_MODE
 127
 128 AC_EXEEXT
 129
 130 # configure.host sets the following important variables
 131 #       libgcj_cflags    - host specific C compiler flags
 132 #       libgcj_cxxflags  - host specific C++ compiler flags
 133 #       libgcj_javaflags - host specific Java compiler flags
 134
 135 libgcj_cflags=
 136 libgcj_cxxflags=
 137 libgcj_javaflags=
 138
 139 . ${srcdir}/configure.host
 140
 141 LIBGCJ_CFLAGS="${libgcj_cflags}"
 142 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 143 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 144 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 145 AC_SUBST(LIBGCJ_CFLAGS)
 146 AC_SUBST(LIBGCJ_CXXFLAGS)
 147 AC_SUBST(LIBGCJ_JAVAFLAGS)
 148 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 149
 150 # Only use libltdl for non-newlib builds.
 151 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 152    AC_LTDL_SHLIBPATH
 153 fi
 154
 155 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 156
 157 # See if the user has requested runtime debugging.
 158 LIBGCJDEBUG="disable"
 159 AC_SUBST(LIBGCJDEBUG)
 160 AC_ARG_ENABLE(libgcj-debug,
 161   AS_HELP_STRING([--enable-libgcj-debug],
 162                  [enable runtime debugging code]),
 163   [if test "$enable_libgcj_debug" = yes; then
 164     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 165     LIBGCJDEBUG="enable"
 166   fi])
 167
 168 # Determine which AWT peer libraries to build
 169 AC_ARG_ENABLE(java-awt,
 170   AS_HELP_STRING([--enable-java-awt],
 171                  [list of AWT peer implementations to be built]))
 172
 173 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 174 use_xlib_awt=""
 175 use_gtk_awt=""
 176 use_qt_awt=""
 177 # The default toolkit to use is the first one specified.
 178 TOOLKIT=
 179 AC_SUBST(TOOLKIT)
 180
 181 for peer in $peerlibs ; do
 182   case $peer in
 183     xlib)
 184       if test "$no_x" = yes; then
 185         echo "*** xlib peers requested but no X library available" 1>&2
 186         exit 1
 187       else
 188         use_xlib_awt="yes"
 189         if test -z "$TOOLKIT"; then
 190            TOOLKIT=gnu.awt.xlib.XToolkit
 191         fi
 192       fi
 193       ;;
 194     gtk)
 195       if test "$no_x" = yes; then
 196          echo "*** gtk peers requested but no X library available" 1>&2
 197          exit 1
 198       else
 199          use_gtk_awt=yes
 200          if test -z "$TOOLKIT"; then
 201             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 202          fi
 203       fi
 204       ;;
 205     qt)
 206       if test "$no_x" = yes; then
 207          # Perhaps we should admit the possibility of embedded Qt.
 208          echo "*** Qt peers requested but no X library available" 1>&2
 209          exit 1
 210       else
 211          use_qt_awt=yes
 212          if test -z "$TOOLKIT"; then
 213             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 214          fi
 215       fi
 216       ;;
 217     no)
 218       use_xlib_awt=
 219       use_gtk_awt=
 220       use_qt_awt=
 221       break
 222       ;;
 223     *)
 224       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 225       exit 1
 226   esac
 227 done
 228
 229 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 230 AM_CONDITIONAL(QT_AWT, test "$use_qt_awt" = yes)
 231
 232 # Create standard.omit based on decisions we just made.
 233 cp $srcdir/standard.omit.in standard.omit
 234 if test "$use_xlib_awt" != yes; then
 235    echo gnu/awt/xlib >> standard.omit
 236    echo gnu/gcj/xlib >> standard.omit
 237 fi
 238 if test "$use_qt_awt" != yes; then
 239    echo gnu/java/awt/peer/qt >> standard.omit
 240 fi
 241
 242 if test -z "${with_multisubdir}"; then
 243    builddotdot=.
 244 else
 245    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 246 fi
 247
 248 NATIVE=yes
 249
 250 # Which gcj do we use?
 251 which_gcj=default
 252 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 253 if test -n "${with_cross_host}"; then
 254   # We are being configured with a cross compiler. We can't
 255   # use ac_exeext, because that is for the target platform.
 256   NATIVE=no
 257   cross_host_exeext=
 258   case "${with_cross_host}" in
 259      *mingw* | *cygwin*)
 260          cross_host_exeext=.exe
 261      ;;
 262   esac
 263   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 264      if test x"$build_noncanonical" = x"$with_cross_host"; then
 265         # Ordinary cross (host!=target and host=build)
 266         which_gcj=built
 267      else
 268         # Canadian cross (host!=target and host!=build)
 269         which_gcj=cross
 270      fi
 271   else
 272      which_gcj=cross
 273   fi
 274 else
 275   # We are being configured with a native or crossed-native compiler
 276   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 277      if test x"$build" = x"$host"; then
 278         # True native build (host=target and host=build)
 279         which_gcj=built
 280      else
 281         # Crossed-native build (host=target and host!=build)
 282         which_gcj=cross
 283      fi
 284   else
 285      which_gcj=path
 286   fi
 287 fi
 288 case "${which_gcj}" in
 289    built)
 290       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 291       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 292    ;;
 293    cross)
 294       if test "x${with_newlib}" = "xyes"; then
 295          # FIXME (comment): Why is this needed?
 296          GCC_UNWIND_INCLUDE=
 297          GCJ="${target_noncanonical}-gcj"
 298       else
 299          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 300       fi
 301       GCJH='$(target_noncanonical)-gcjh'
 302    ;;
 303    path)
 304       GCJ="gcj -B`${PWDCMD-pwd}`/"
 305       GCJH=gcjh
 306    ;;
 307 esac
 308
 309 AC_SUBST(GCJH)
 310
 311 # Create it, so that compile/link tests don't fail
 312 test -f libgcj.spec || touch libgcj.spec
 313
 314
 315
 316 # Set up to configure Classpath.
 317 # FIXME: no supported way to pass args in autoconf.
 318 ac_configure_args="$ac_configure_args --disable-load-library"
 319 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 320 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 321 dir1=`cd $srcdir && pwd`
 322 dir2=`pwd`
 323 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 324 ac_configure_args="$ac_configure_args --disable-core-jni"
 325 dnl FIXME?
 326 ac_configure_args="$ac_configure_args --disable-examples"
 327 ac_configure_args="$ac_configure_args --with-glibj=build"
 328 if test "$use_gtk_awt" != yes; then
 329   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 330 fi
 331 if test "$use_qt_awt" != yes; then
 332   ac_configure_args="$ac_configure_args --disable-qt-peer"
 333 else
 334   # We need this as qt is disabled by default in classpath.
 335   ac_configure_args="$ac_configure_args --enable-qt-peer"
 336 fi
 337 dnl --with-gcj=$GCJ
 338 dnl --with-javah=$GCJH
 339 dnl gjdoc?
 340 dnl gtk-cairo -- just export here...
 341 dnl --enable-regen-headers?
 342
 343 # Only use libltdl for non-newlib builds.
 344 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 345    AC_LIBLTDL_CONVENIENCE
 346    AC_LIBTOOL_DLOPEN
 347    DIRLTDL=libltdl
 348    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 349    # Sigh.  Libtool's macro doesn't do the right thing.
 350    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 351    # FIXME: this is a hack.
 352    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 353    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 354 fi
 355 AC_SUBST(INCLTDL)
 356 AC_SUBST(LIBLTDL)
 357 AC_SUBST(DIRLTDL)
 358 AC_PROG_LIBTOOL
 359 AM_PROG_GCJ
 360 AM_PROG_CC_C_O
 361
 362 AC_CONFIG_SUBDIRS(classpath libltdl)
 363
 364 # The -no-testsuite modules omit the test subdir.
 365 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 366
 367 # Should the runtime set system properties by examining the
 368 # environment variable GCJ_PROPERTIES?
 369 AC_ARG_ENABLE(getenv-properties,
 370   AS_HELP_STRING([--disable-getenv-properties],
 371                  [don't set system properties from GCJ_PROPERTIES]))
 372
 373 # Whether GCJ_PROPERTIES is used depends on the target.
 374 if test -z "$enable_getenv_properties"; then
 375    enable_getenv_properties=${enable_getenv_properties_default-yes}
 376 fi
 377 if test "$enable_getenv_properties" = no; then
 378    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 379      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 380 fi
 381
 382 # Whether we should use arguments to main()
 383 if test -z "$enable_main_args"; then
 384    enable_main_args=${enable_main_args_default-yes}
 385 fi
 386 if test "$enable_main_args" = no; then
 387    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 388 fi
 389
 390
 391 # Should we use hashtable-based synchronization?
 392 # Currently works only for Linux X86/ia64
 393 # Typically faster and more space-efficient
 394 AC_ARG_ENABLE(hash-synchronization,
 395   AS_HELP_STRING([--enable-hash-synchronization],
 396                  [use global hash table for monitor locks]))
 397
 398 if test -z "$enable_hash_synchronization"; then
 399    enable_hash_synchronization=$enable_hash_synchronization_default
 400 fi
 401
 402 AC_ARG_WITH(java-home,
 403   AS_HELP_STRING([--with-java-home=DIRECTORY],
 404                  [value of java.home system property]),
 405                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 406 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 407 AC_SUBST(JAVA_HOME)
 408
 409 # What is the native OS API for MinGW?
 410 AC_ARG_WITH(win32-nlsapi,
 411   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 412                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 413 [case "${withval}" in
 414   ansi) with_win32_nlsapi=ansi ;;
 415   unicows) with_win32_nlsapi=unicows ;;
 416   unicode) with_win32_nlsapi=unicode ;;
 417   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 418 esac],[with_win32_nlsapi=ansi])
 419
 420 case "${with_win32_nlsapi}" in
 421   unicows | unicode)
 422     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 423       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 424     ;;
 425 esac
 426
 427 # configure.host sets slow_pthread_self if the synchronization code should
 428 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 429 if test "${slow_pthread_self}" = "yes"; then
 430   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 431     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 432 fi
 433
 434 # Check for gc debugging.  This option is handled both here and in the GC.
 435 AC_ARG_ENABLE(gc-debug,
 436    AS_HELP_STRING([--enable-gc-debug],
 437                   [include full support for pointer backtracing etc.]),
 438 [ if test "$enable_gc_debug" = "yes"; then
 439     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 440               [Define if we want to use debug calls into the garbage collector.])
 441   fi])
 442
 443 # See if the user has the interpreter included.
 444 AC_ARG_ENABLE(interpreter,
 445   AS_HELP_STRING([--enable-interpreter],
 446                  [enable interpreter]),
 447   [if test "$enable_interpreter" = yes; then
 448     # This can also be set in configure.host.
 449     libgcj_interpreter=yes
 450   elif test "$enable_interpreter" = no; then
 451     libgcj_interpreter=no
 452   fi])
 453
 454 if test "$libgcj_interpreter" = yes; then
 455    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 456 fi
 457 INTERPRETER="$libgcj_interpreter"
 458 AC_SUBST(INTERPRETER)
 459
 460 AC_MSG_CHECKING([for exception model to use])
 461 AC_LANG_PUSH(C++)
 462 AC_ARG_ENABLE(sjlj-exceptions,
 463   AS_HELP_STRING([--enable-sjlj-exceptions],
 464                  [force use of builtin_setjmp for exceptions]),
 465 [:],
 466 [dnl Botheration.  Now we've got to detect the exception model.
 467 dnl Link tests against libgcc.a are problematic since -- at least
 468 dnl as of this writing -- we've not been given proper -L bits for
 469 dnl single-tree newlib and libgloss.
 470 dnl
 471 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 472 dnl conftest files before we got a change to grep them first.
 473 cat > conftest.$ac_ext << EOF
 474 [#]line __oline__ "configure"
 475 struct S { ~S(); };
 476 void bar();
 477 void foo()
 478 {
 479   S s;
 480   bar();
 481 }
 482 EOF
 483 old_CXXFLAGS="$CXXFLAGS"
 484 CXXFLAGS=-S
 485 if AC_TRY_EVAL(ac_compile); then
 486   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 487     enable_sjlj_exceptions=yes
 488   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 489     enable_sjlj_exceptions=no
 490   fi
 491 fi
 492 CXXFLAGS="$old_CXXFLAGS"
 493 rm -f conftest*])
 494 if test x$enable_sjlj_exceptions = xyes; then
 495   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 496         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 497   ac_exception_model_name=sjlj
 498 elif test x$enable_sjlj_exceptions = xno; then
 499   ac_exception_model_name="call frame"
 500 else
 501   AC_MSG_ERROR([unable to detect exception model])
 502 fi
 503 AC_LANG_POP(C++)
 504 AC_MSG_RESULT($ac_exception_model_name)
 505
 506 # If we are non using SJLJ exceptions, and this host does not have support
 507 # for unwinding from a signal handler, enable checked dereferences and divides.
 508 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 509   CHECKREFSPEC=-fcheck-references
 510   DIVIDESPEC=-fuse-divide-subroutine
 511   EXCEPTIONSPEC=
 512 fi
 513
 514 # See if the user wants to disable java.net.  This is the mildly
 515 # ugly way that we admit that target-side configuration sucks.
 516 AC_ARG_ENABLE(java-net,
 517   AS_HELP_STRING([--disable-java-net],
 518                  [disable java.net]))
 519
 520 # Whether java.net is built by default can depend on the target.
 521 if test -z "$enable_java_net"; then
 522    enable_java_net=${enable_java_net_default-yes}
 523 fi
 524 if test "$enable_java_net" = no; then
 525    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 526 fi
 527
 528 # See if the user wants to configure without libffi.  Some
 529 # architectures don't support it, and default values are set in
 530 # configure.host.
 531 AC_ARG_WITH(libffi,
 532   AS_HELP_STRING([--without-libffi],
 533                  [don't use libffi]),
 534   [:],
 535   [with_libffi=${with_libffi_default-yes}])
 536
 537 LIBFFI=
 538 LIBFFIINCS=
 539 if test "$with_libffi" != no; then
 540    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 541    LIBFFI=../libffi/libffi_convenience.la
 542    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 543 fi
 544 AC_SUBST(LIBFFI)
 545 AC_SUBST(LIBFFIINCS)
 546
 547 # See if the user wants to disable JVMPI support.
 548 AC_ARG_ENABLE(jvmpi,
 549   AS_HELP_STRING([--disable-jvmpi],
 550                  [disable JVMPI support]))
 551
 552 if test "$enable_jvmpi" != no; then
 553     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 554 fi
 555
 556 # If the target is an eCos system, use the appropriate eCos
 557 # I/O routines.
 558 # FIXME: this should not be a local option but a global target
 559 # system; at present there is no eCos target.
 560 TARGET_ECOS=${PROCESS-"no"}
 561 AC_ARG_WITH(ecos,
 562 [  --with-ecos             enable runtime eCos target support],
 563 TARGET_ECOS="$with_ecos"
 564 )
 565
 566 PLATFORM_INNER_NAT_HDRS=
 567 case "$TARGET_ECOS" in
 568    no) case "$host" in
 569       *mingw*)
 570             PLATFORM=Win32
 571             PLATFORMNET=Win32
 572             PLATFORMH=win32.h
 573         CHECK_FOR_BROKEN_MINGW_LD
 574       ;;
 575       *)
 576             PLATFORM=Posix
 577             PLATFORMNET=Posix
 578             PLATFORMH=posix.h
 579             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 580       ;;
 581       esac
 582       ;;
 583    *)
 584       PLATFORM=Ecos
 585       PLATFORMNET=NoNet
 586       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 587       PLATFORMH=posix.h
 588       ;;
 589 esac
 590 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 591 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 592
 593 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 594                                       [Define if you have int32_t and uint32_t.]))
 595 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 596                                         [Define if you have int32_t and uint32_t.]))
 597 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 598                                           [Define if you have u_int32_t]))
 599 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 600                                            [Define if you have u_int32_t]))
 601
 602 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 603 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 604
 605 case "$host" in
 606   *-darwin*) DARWIN_CRT=true ;;
 607   *) DARWIN_CRT=false ;;
 608 esac
 609 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 610
 611 # These may not be defined in a non-ANS conformant embedded system.
 612 # FIXME: Should these case a runtime exception in that case?
 613 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 614                                   [Define is you have 'mktime' in <time.h>]))
 615 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 616                                   [Define is you have 'localtime' in <time.h>]))
 617
 618 # Create the subdirectory for natFile.cc, or the attempt
 619 # to create the link will fail.
 620 test -d java || mkdir java
 621 test -d java/io || mkdir java/io
 622 test -d gnu || mkdir gnu
 623 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 624
 625 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 626 test -d java/lang || mkdir java/lang
 627 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 628 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 629
 630 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 631 test -d java/net || mkdir java/net
 632 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 633 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 634
 635 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 636 test -d gnu/java || mkdir gnu/java
 637 test -d gnu/java/net || mkdir gnu/java/net
 638 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 639 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 640
 641 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 642 test -d gnu/java/nio || mkdir gnu/java/nio
 643 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 644 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 645 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 646 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 647
 648 case "${host}" in
 649     *mingw*)
 650       SYSTEMSPEC="-lgdi32 -lws2_32"
 651       if test "${with_win32_nlsapi}" = "unicows"; then
 652         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 653       fi
 654     ;;
 655     *)
 656       SYSTEMSPEC=
 657     ;;
 658 esac
 659 AC_SUBST(SYSTEMSPEC)
 660
 661 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 662 AC_SUBST(LIBGCJTESTSPEC)
 663
 664 AC_ARG_WITH(system-zlib,
 665   AS_HELP_STRING([--with-system-zlib],
 666                  [use installed libz]))
 667 ZLIBSPEC=
 668 AC_SUBST(ZLIBSPEC)
 669 ZLIBTESTSPEC=
 670 AC_SUBST(ZLIBTESTSPEC)
 671
 672 AC_PATH_XTRA
 673
 674 # determine whether to enable the cairo GTK Graphics2D backend
 675 AC_ARG_ENABLE(gtk-cairo,
 676   AS_HELP_STRING([--enable-gtk-cairo],
 677                  [build the cairo Graphics2D implementation on GTK]))
 678 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 679 if test "x${enable_gtk_cairo}" = xyes
 680 then
 681         PKG_CHECK_MODULES(CAIRO, cairo)
 682         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 683 fi
 684 AC_SUBST(CAIRO_LIBS)
 685 AC_SUBST(CAIRO_CFLAGS)
 686 AC_SUBST(PANGOFT2_LIBS)
 687 AC_SUBST(PANGOFT2_CFLAGS)
 688
 689 # FIXME: this should be _libs on some hosts.
 690 libsubdir=.libs
 691
 692 # extra LD Flags which are required for targets
 693 case "${host}" in
 694 *-*-darwin[[0-7]].*)
 695     # For now we have to disable it on darwin[8-9] because it slows down
 696     # the linking phase. A possible bug in ld?
 697     # on Darwin -single_module speeds up loading of the dynamic libraries.
 698     extra_ldflags_libjava=-Wl,-single_module
 699     ;;
 700 esac
 701 AC_SUBST(extra_ldflags_libjava)
 702
 703 # Allow the GC to be disabled.  Can be useful when debugging.
 704 AC_MSG_CHECKING([for garbage collector to use])
 705 AC_ARG_ENABLE(java-gc,
 706   AS_HELP_STRING([--enable-java-gc=TYPE],
 707                  [choose garbage collector (default is boehm)]),
 708   [GC=$enableval],
 709   [GC=boehm])
 710 GCLIBS=
 711 GCINCS=
 712 GCDEPS=
 713 GCSPEC=
 714 JC1GCSPEC=
 715 GCTESTSPEC=
 716 case "$GC" in
 717  boehm)
 718     AC_MSG_RESULT(boehm)
 719     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 720     JC1GCSPEC='-fuse-boehm-gc'
 721     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 722     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 723     GCOBJS=boehm.lo
 724     GCHDR=boehm-gc.h
 725     # The POSIX thread support needs to know this.
 726     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 727     ;;
 728  no)
 729     AC_MSG_RESULT(none)
 730     GCHDR=no-gc.h
 731     ;;
 732  *)
 733     AC_MSG_ERROR([unrecognized collector "$GC"])
 734     ;;
 735 esac
 736 AC_SUBST(GCLIBS)
 737 AC_SUBST(GCINCS)
 738 AC_SUBST(GCDEPS)
 739 AC_SUBST(GCSPEC)
 740 AC_SUBST(JC1GCSPEC)
 741 AC_SUBST(GCTESTSPEC)
 742 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 743 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 744 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 745
 746
 747 AC_MSG_CHECKING([for thread model used by GCC])
 748 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 749 AC_MSG_RESULT([$THREADS])
 750
 751 case "$THREADS" in
 752  no | none | single)
 753     THREADS=none
 754     ;;
 755  posix | posix95 | pthreads)
 756     THREADS=posix
 757     case "$host" in
 758      *-*-linux*)
 759         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 760         ;;
 761     esac
 762     ;;
 763  win32)
 764     ;;
 765  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 766     AC_MSG_ERROR(thread package $THREADS not yet supported)
 767     ;;
 768  *)
 769     AC_MSG_ERROR($THREADS is an unknown thread package)
 770     ;;
 771 esac
 772
 773 THREADCXXFLAGS=
 774 THREADLDFLAGS=
 775 THREADLIBS=
 776 THREADINCS=
 777 THREADDEPS=
 778 THREADH=
 779 THREADSPEC=
 780 case "$THREADS" in
 781  posix)
 782     case "$host" in
 783      *-*-cygwin*)
 784         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 785         ;;
 786      *-*-freebsd[[1234]]*)
 787         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 788         # merely adds pthread_* functions) but it does have a -pthread switch
 789         # which is required at link-time to select -lc_r *instead* of -lc.
 790         THREADLDFLAGS=-pthread
 791         # Don't set THREADSPEC here as might be expected since -pthread is
 792         # not processed when found within a spec file, it must come from
 793         # the command line.  For now, the user must provide the -pthread
 794         # switch to link code compiled with gcj.  In future, consider adding
 795         # support for weak references to pthread_* functions ala gthr.h API.
 796         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 797         ;;
 798      *-*-freebsd*)
 799         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 800         # systems which support threads and -lpthread.
 801         THREADLDFLAGS=-pthread
 802         THREADSPEC=-lpthread
 803         ;;
 804      alpha*-dec-osf* | hppa*-hp-hpux*)
 805         THREADCXXFLAGS=-pthread
 806         # boehm-gc needs some functions from librt, so link that too.
 807         THREADLIBS='-lpthread -lrt'
 808         THREADSPEC='-lpthread -lrt'
 809         ;;
 810      *)
 811         THREADLIBS=-lpthread
 812         THREADSPEC=-lpthread
 813         ;;
 814     esac
 815     THREADH=posix-threads.h
 816     # MIT pthreads doesn't seem to have the mutexattr functions.
 817     # But for now we don't check for it.  We just assume you aren't
 818     # using MIT pthreads.
 819     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 820
 821     # If we're using the Boehm GC, then we happen to know that it
 822     # defines _REENTRANT, so we don't bother.  Eww.
 823     if test "$GC" != boehm; then
 824        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 825     fi
 826     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 827     ;;
 828
 829  win32)
 830     THREADH=win32-threads.h
 831     ;;
 832
 833  none)
 834     THREADH=no-threads.h
 835     ;;
 836 esac
 837 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 838 AC_SUBST(THREADLIBS)
 839 AC_SUBST(THREADINCS)
 840 AC_SUBST(THREADDEPS)
 841 AC_SUBST(THREADSPEC)
 842 AC_SUBST(THREADLDFLAGS)
 843 AC_SUBST(THREADCXXFLAGS)
 844 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 845 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 846 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 847
 848 if test -d sysdep; then true; else mkdir sysdep; fi
 849 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 850 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 851 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 852
 853 HASH_SYNC_SPEC=
 854 # Hash synchronization is only useful with posix threads right now.
 855 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 856    HASH_SYNC_SPEC=-fhash-synchronization
 857    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 858 fi
 859 AC_SUBST(HASH_SYNC_SPEC)
 860
 861 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 862
 863 # We're in the tree with gcc, and need to include some of its headers.
 864 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 865
 866 if test "x${with_newlib}" = "xyes"; then
 867    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 868    # may not work correctly, because the compiler may not be able to
 869    # link executables.
 870
 871    # We assume newlib.  This lets us hard-code the functions we know
 872    # we'll have.
 873    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 874    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 875    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 876    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 877    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 878    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 879    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 880    # This is only for POSIX threads.
 881    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 882    # We also assume we are using gcc, which provides alloca.
 883    AC_DEFINE(HAVE_ALLOCA)
 884
 885    # Assume we do not have getuid and friends.
 886    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 887    PLATFORMNET=NoNet
 888 else
 889    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 890                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 891                    access stat mkdir rename rmdir unlink realpath utime chmod \
 892                    nl_langinfo setlocale \
 893                    inet_pton uname inet_ntoa \
 894                    fork execvp pipe sigaction ftruncate mmap])
 895    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 896    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 897    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
 898    AC_CHECK_LIB(dl, dladdr, [
 899        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
 900        AC_CHECK_LIB(dld, dladdr, [
 901        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
 902
 903    if test x"$build" = x"$host"; then
 904      AC_CHECK_FILES(/proc/self/exe, [
 905        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 906    else
 907      case $host in
 908      *-linux*)
 909        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 910        ;;
 911      esac
 912    fi
 913
 914    AM_ICONV
 915    AM_LC_MESSAGES
 916    AC_STRUCT_TIMEZONE
 917
 918    AC_CHECK_FUNCS(gethostbyname_r, [
 919      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 920        [Define if you have the 'gethostbyname_r' function.])
 921      # There are two different kinds of gethostbyname_r.
 922      # We look for the one that returns `int'.
 923      # Hopefully this check is robust enough.
 924      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 925        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 926
 927      case " $GCINCS " in
 928      *" -D_REENTRANT "*) ;;
 929      *)
 930         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 931         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 932         [libjava_cv_gethostbyname_r_needs_reentrant],
 933         [ AC_LANG_PUSH(C++)
 934           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 935             [[gethostbyname_r("", 0, 0);]])],
 936             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 937                 CPPFLAGS_SAVE="$CPPFLAGS"
 938                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 939                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 940                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 941                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 942                 CPPFLAGS="$CPPFLAGS_SAVE"
 943           ])
 944           AC_LANG_POP(C++)
 945         ])
 946         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 947           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 948         fi
 949      ;;
 950      esac
 951
 952      AC_CACHE_CHECK([for struct hostent_data],
 953         [libjava_cv_struct_hostent_data], [dnl
 954         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 955 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 956 # define _REENTRANT 1
 957 #endif
 958 #include <netdb.h>]], [[struct hostent_data data;]])],
 959           [libjava_cv_struct_hostent_data=yes],
 960           [libjava_cv_struct_hostent_data=no])])
 961      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 962        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 963          [Define if struct hostent_data is defined in netdb.h])
 964      fi
 965    ])
 966
 967    # FIXME: libjava source code expects to find a prototype for
 968    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 969    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 970    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 971    # linkage check is enough, yet C++ code requires proper prototypes.)
 972    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 973    AC_CHECK_FUNCS(gethostbyaddr_r, [
 974      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 975        [Define if you have the 'gethostbyaddr_r' function.])
 976      # There are two different kinds of gethostbyaddr_r.
 977      # We look for the one that returns `int'.
 978      # Hopefully this check is robust enough.
 979      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 980        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 981          [Define if gethostbyaddr_r returns 'int'.])])])])
 982
 983    AC_CHECK_FUNCS(gethostname, [
 984      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 985        [Define if you have the 'gethostname' function.])
 986      AC_EGREP_HEADER(gethostname, unistd.h, [
 987        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 988          [Define if gethostname is declared in <unistd.h>.])])])
 989
 990    AC_CHECK_FUNCS(usleep, [
 991      AC_EGREP_HEADER(usleep, unistd.h, [
 992        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 993           [Define if usleep is declared in <unistd.h>.])])])
 994
 995    # Look for these functions in the thread library, but only bother
 996    # if using POSIX threads.
 997    if test "$THREADS" = posix; then
 998       save_LIBS="$LIBS"
 999       LIBS="$LIBS $THREADLIBS"
1000       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1001       # E.g., Solaris.
1002       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1003
1004       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1005       # Solaris 7 the name librt is preferred.
1006       AC_CHECK_FUNCS(sched_yield, , [
1007         AC_CHECK_LIB(rt, sched_yield, [
1008           AC_DEFINE(HAVE_SCHED_YIELD)
1009           THREADLIBS="$THREADLIBS -lrt"
1010           THREADSPEC="$THREADSPEC -lrt"], [
1011           AC_CHECK_LIB(posix4, sched_yield, [
1012             AC_DEFINE(HAVE_SCHED_YIELD)
1013             THREADLIBS="$THREADLIBS -lposix4"
1014             THREADSPEC="$THREADSPEC -lposix4"])])])
1015
1016       AC_CHECK_LIB(rt, clock_gettime, [
1017          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1018          case "$THREADSPEC" in
1019            *-lrt*) ;;
1020            *)
1021              THREADSPEC="$THREADSPEC -lrt"
1022              THREADLIBS="$THREADLIBS -lrt"
1023              ;;
1024          esac])
1025
1026       LIBS="$save_LIBS"
1027
1028       # We can save a little space at runtime if the mutex has m_count
1029       # or __m_count.  This is a nice hack for Linux.
1030       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1031           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1032         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1033              [Define if pthread_mutex_t has m_count member.]), [
1034         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1035             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1036           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1037             [Define if pthread_mutex_t has __m_count member.]))])
1038    fi
1039
1040    # We require a way to get the time.
1041    time_found=no
1042    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1043    if test "$time_found" = no; then
1044       AC_MSG_ERROR([no function found to get the time])
1045    fi
1046
1047    AC_CHECK_FUNCS(memmove)
1048
1049    # We require memcpy.
1050    memcpy_found=no
1051    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1052    if test "$memcpy_found" = no; then
1053       AC_MSG_ERROR([memcpy is required])
1054    fi
1055    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1056    AC_CHECK_LIB(dl, dlopen, [
1057        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1058        AC_CHECK_LIB(dld, dlopen, [
1059        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1060
1061    # Some library-finding code we stole from Tcl.
1062    #--------------------------------------------------------------------
1063    #    Check for the existence of the -lsocket and -lnsl libraries.
1064    #    The order here is important, so that they end up in the right
1065    #    order in the command line generated by make.  Here are some
1066    #    special considerations:
1067    #    1. Use "connect" and "accept" to check for -lsocket, and
1068    #       "gethostbyname" to check for -lnsl.
1069    #    2. Use each function name only once:  can't redo a check because
1070    #       autoconf caches the results of the last check and won't redo it.
1071    #    3. Use -lnsl and -lsocket only if they supply procedures that
1072    #       aren't already present in the normal libraries.  This is because
1073    #       IRIX 5.2 has libraries, but they aren't needed and they're
1074    #       bogus:  they goof up name resolution if used.
1075    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1076    #       To get around this problem, check for both libraries together
1077    #       if -lsocket doesn't work by itself.
1078    #--------------------------------------------------------------------
1079
1080    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1081     [gcj_cv_lib_sockets=
1082      gcj_checkBoth=0
1083      unset ac_cv_func_connect
1084      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1085      if test "$gcj_checkSocket" = 1; then
1086          unset ac_cv_func_connect
1087          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1088                       gcj_checkBoth=1)
1089      fi
1090      if test "$gcj_checkBoth" = 1; then
1091          gcj_oldLibs=$LIBS
1092          LIBS="$LIBS -lsocket -lnsl"
1093          unset ac_cv_func_accept
1094          AC_CHECK_FUNC(accept,
1095                        [gcj_checkNsl=0
1096                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1097          unset ac_cv_func_accept
1098          LIBS=$gcj_oldLibs
1099      fi
1100      unset ac_cv_func_gethostbyname
1101      gcj_oldLibs=$LIBS
1102      LIBS="$LIBS $gcj_cv_lib_sockets"
1103      AC_CHECK_FUNC(gethostbyname, ,
1104                    [AC_CHECK_LIB(nsl, main,
1105                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1106      unset ac_cv_func_gethostbyname
1107      LIBS=$gcj_oldLIBS
1108    ])
1109    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1110
1111    if test "$with_system_zlib" = yes; then
1112       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1113    fi
1114
1115    # Test for Gtk stuff, if asked for.
1116    if test "$use_gtk_awt" = yes; then
1117       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1118       AC_SUBST(GTK_CFLAGS)
1119       AC_SUBST(GTK_LIBS)
1120
1121       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1122       AC_SUBST(GLIB_CFLAGS)
1123       AC_SUBST(GLIB_LIBS)
1124
1125       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1126       AC_SUBST(LIBART_CFLAGS)
1127       AC_SUBST(LIBART_LIBS)
1128
1129       # We require the XTest Extension to support java.awt.Robot.
1130       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1131                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1132                    [${X_LIBS}])
1133    fi
1134
1135    # On Solaris, and maybe other architectures, the Boehm collector
1136    # requires -ldl.
1137    if test "$GC" = boehm; then
1138       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1139    fi
1140 fi
1141
1142 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1143 case $build in
1144     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1145     *)         CLASSPATH_SEPARATOR=':' ;;
1146 esac
1147 AC_SUBST(CLASSPATH_SEPARATOR)
1148
1149 # We must search the source tree for java.lang, since we still don't
1150 # have libgcj.jar nor java/lang/*.class
1151 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1152 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1153
1154 # Since some classes depend on this one, we need its source available
1155 # before we can do any GCJ compilation test :-(
1156 if test ! -f gnu/classpath/Configuration.java; then
1157   test -d gnu || mkdir gnu
1158   test -d gnu/classpath || mkdir gnu/classpath
1159   # Note that it is not crucial that all the values here be correct.
1160   sed -e "s,@prefix@,$prefix," \
1161       -e "s,@VERSION@,$VERSION," \
1162       -e "s,@LIBDEBUG@,false," \
1163       -e "s,@INIT_LOAD_LIBRARY@,false," \
1164       -e "s,@@,$LIBGCJDEBUG," \
1165       -e "s,@default_toolkit@,$TOOLKIT," \
1166       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1167       -e "s,@GTK_CAIRO_ENABLED@,false," \
1168         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1169         > gnu/classpath/Configuration.java
1170   # We do not want to redirect the output of the grep below to /dev/null,
1171   # but we add /dev/null to the input list so that grep will print the
1172   # filename of Configuration.java in case it finds any matches.
1173   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1174     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1175   fi
1176 fi
1177
1178 LT_AC_PROG_GCJ
1179
1180 # Now remove it.
1181 rm -f gnu/classpath/Configuration.java
1182
1183 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1184
1185 AC_CHECK_SIZEOF(void *)
1186
1187 AC_C_BIGENDIAN
1188
1189 ZLIBS=
1190 SYS_ZLIBS=
1191 ZINCS=
1192
1193 if test -z "$ZLIBSPEC"; then
1194    # Use zlib from the GCC tree.
1195    ZINCS='-I$(top_srcdir)/../zlib'
1196    ZLIBS=../zlib/libzgcj_convenience.la
1197 else
1198    # System's zlib.
1199    SYS_ZLIBS="$ZLIBSPEC"
1200 fi
1201 AC_SUBST(ZLIBS)
1202 AC_SUBST(SYS_ZLIBS)
1203 AC_SUBST(ZINCS)
1204 AC_SUBST(DIVIDESPEC)
1205 AC_SUBST(CHECKREFSPEC)
1206 AC_SUBST(EXCEPTIONSPEC)
1207 AC_SUBST(BACKTRACESPEC)
1208 AC_SUBST(IEEESPEC)
1209
1210 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1211 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1212 AC_SUBST(GCC_UNWIND_INCLUDE)
1213
1214 # Process the option "--enable-version-specific-runtime-libs"
1215 # Calculate toolexeclibdir
1216 case ${version_specific_libs} in
1217   yes)
1218     # Need the gcc compiler version to know where to install libraries
1219     # and header files if --enable-version-specific-runtime-libs option
1220     # is selected.
1221     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1222     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1223     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1224     toolexeclibdir=$toolexecmainlibdir
1225     ;;
1226   no)
1227     if test -n "$with_cross_host" &&
1228        test x"$with_cross_host" != x"no"; then
1229       # Install a library built with a cross compiler in tooldir, not libdir.
1230       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1231       toolexecmainlibdir='$(toolexecdir)/lib'
1232     else
1233       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1234       toolexecmainlibdir='$(libdir)'
1235     fi
1236     multi_os_directory=`$CC -print-multi-os-directory`
1237     case $multi_os_directory in
1238       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1239       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1240     esac
1241     ;;
1242 esac
1243 AC_SUBST(toolexecdir)
1244 AC_SUBST(toolexecmainlibdir)
1245 AC_SUBST(toolexeclibdir)
1246
1247 # Determine where the standard .db file is found.
1248 multi_os_directory=`$CC -print-multi-os-directory`
1249 case $multi_os_directory in
1250   .) dbexecdir='$(libdir)/gcj-$(gcc_version)' ;; # Avoid /.
1251   *) dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)' ;;
1252 esac
1253 AC_SUBST(dbexecdir)
1254
1255 # Determine gcj version number.
1256 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1257 GCJVERSION=$gcjversion
1258 AC_SUBST(GCJVERSION)
1259 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1260
1261 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1262 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1263
1264 TL_AC_GXX_INCLUDE_DIR
1265
1266 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1267 # On that system, sys/ioctl.h will not include sys/filio.h unless
1268 # BSD_COMP is defined; just including sys/filio.h is simpler.
1269 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1270 # for now.  If you change this, you also must update natFile.cc.
1271 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1272                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1273                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1274                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1275                   dirent.h sys/rw_lock.h])
1276 AC_CHECK_HEADERS(inttypes.h, [
1277     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1278     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1279 ])
1280 AC_HEADER_SYS_WAIT
1281
1282 AC_CHECK_TYPE([ssize_t], [int])
1283
1284 AC_MSG_CHECKING([for in_addr_t])
1285 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1286 #if STDC_HEADERS
1287 #include <stdlib.h>
1288 #include <stddef.h>
1289 #endif
1290 #if HAVE_NETINET_IN_H
1291 #include <netinet/in.h>
1292 #endif]], [[in_addr_t foo;]])],
1293   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1294      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1295    AC_MSG_RESULT(yes)],
1296   [AC_MSG_RESULT(no)])
1297
1298 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1299 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1300   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1301      [Define if struct ip_mreq is defined in netinet/in.h.])
1302    AC_MSG_RESULT(yes)],
1303   [AC_MSG_RESULT(no)])
1304
1305 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1306 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1307   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1308      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1309    AC_MSG_RESULT(yes)],
1310   [AC_MSG_RESULT(no)])
1311
1312 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1313 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1314   [AC_DEFINE(HAVE_INET6, 1,
1315      [Define if inet6 structures are defined in netinet/in.h.])
1316    AC_MSG_RESULT(yes)],
1317   [AC_MSG_RESULT(no)])
1318
1319 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1320 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1321 #include <sys/types.h>
1322 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1323   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1324    AC_MSG_RESULT(yes)],
1325   [AC_MSG_RESULT(no)])
1326
1327 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1328 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1329   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1330    AC_MSG_RESULT(yes)],
1331   [AC_MSG_RESULT(no)
1332    AC_MSG_CHECKING([for global timezone variable])
1333    dnl FIXME: we don't want a link check here because that won't work
1334    dnl when cross-compiling.  So instead we make an assumption that
1335    dnl the header file will mention timezone if it exists.
1336    dnl Don't find the win32 function timezone
1337    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1338      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1339       AC_MSG_RESULT(yes)],
1340      [AC_MSG_RESULT(no)
1341        AC_MSG_CHECKING([for global _timezone variable])
1342        dnl FIXME: As above, don't want link check
1343        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1344          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1345             [Define if your platform has the global _timezone variable.])
1346           AC_MSG_RESULT(yes)],
1347           [AC_MSG_RESULT(no)])])])
1348
1349 AC_FUNC_ALLOCA
1350
1351 AC_CHECK_PROGS(PERL, perl, false)
1352
1353 SYSDEP_SOURCES=
1354 SIGNAL_HANDLER_AUX=
1355
1356 case "${host}" in
1357  i?86-*-linux*)
1358     SIGNAL_HANDLER=include/i386-signal.h
1359     ;;
1360  sparc*-sun-solaris*)
1361     SIGNAL_HANDLER=include/sparc-signal.h
1362     ;;
1363 # ia64-*)
1364 #    SYSDEP_SOURCES=sysdep/ia64.c
1365 #    test -d sysdep || mkdir sysdep
1366 #    ;;
1367  hppa*-*-linux*)
1368     SIGNAL_HANDLER=include/pa-signal.h
1369     ;;
1370  hppa*-hp-hpux*)
1371     SIGNAL_HANDLER=include/hppa-signal.h
1372     ;;
1373  ia64-*-linux*)
1374     SIGNAL_HANDLER=include/dwarf2-signal.h
1375     ;;
1376  powerpc*-*-linux*)
1377     SIGNAL_HANDLER=include/powerpc-signal.h
1378     ;;
1379  alpha*-*-linux*)
1380     SIGNAL_HANDLER=include/dwarf2-signal.h
1381     ;;
1382  s390*-*-linux*)
1383     SIGNAL_HANDLER=include/s390-signal.h
1384     ;;
1385  x86_64*-*-linux*)
1386     SIGNAL_HANDLER=include/x86_64-signal.h
1387     SIGNAL_HANDLER_AUX=include/i386-signal.h
1388     ;;
1389  sparc*-*-linux*)
1390     SIGNAL_HANDLER=include/dwarf2-signal.h
1391     ;;
1392  sh*-*-linux*)
1393     SIGNAL_HANDLER=include/sh-signal.h
1394     ;;
1395  *mingw*)
1396     SIGNAL_HANDLER=include/win32-signal.h
1397     ;;
1398  mips*-*-linux*)
1399     SIGNAL_HANDLER=include/mips-signal.h
1400     ;;
1401  *-*-darwin*)
1402     SIGNAL_HANDLER=include/darwin-signal.h
1403     ;;
1404  *)
1405     SIGNAL_HANDLER=include/default-signal.h
1406     ;;
1407 esac
1408
1409 # If we're using sjlj exceptions, forget what we just learned.
1410 if test "$enable_sjlj_exceptions" = yes; then
1411    SIGNAL_HANDLER=include/default-signal.h
1412    SIGNAL_HANDLER_AUX=
1413 fi
1414
1415 AC_SUBST(SYSDEP_SOURCES)
1416
1417 if test -z "$SIGNAL_HANDLER_AUX"; then
1418   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1419 fi
1420
1421 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1422                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1423
1424 if test "${multilib}" = "yes"; then
1425   multilib_arg="--enable-multilib"
1426 else
1427   multilib_arg=
1428 fi
1429
1430 # See if we support thread-local storage.
1431 GCC_CHECK_TLS
1432
1433 # Check if linker supports static linking on a per library basis
1434 LD_START_STATIC_SPEC=
1435 LD_FINISH_STATIC_SPEC=
1436 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1437   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1438     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1439     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1440   fi
1441 fi
1442 AC_SUBST(LD_START_STATIC_SPEC)
1443 AC_SUBST(LD_FINISH_STATIC_SPEC)
1444
1445 here=`${PWDCMD-pwd}`
1446 AC_SUBST(here)
1447
1448 # We get this from the environment.
1449 AC_SUBST(GCJFLAGS)
1450
1451 AC_CONFIG_FILES([
1452 Makefile
1453 libgcj.pc
1454 libgcj.spec
1455 libgcj-test.spec
1456 gcj/Makefile
1457 include/Makefile
1458 testsuite/Makefile
1459 ])
1460
1461 AC_CONFIG_COMMANDS([default],
1462 [# Only add multilib support code if we just rebuilt top-level Makefile.
1463 case " $CONFIG_FILES " in
1464  *" Makefile "*)
1465    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1466    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1467    ;;
1468 esac
1469 for ac_multi_file in $CONFIG_FILES; do
1470   case $ac_multi_file in
1471   */Makefile)
1472     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1473   esac
1474 done
1475 ],
1476 srcdir=${srcdir}
1477 host=${host}
1478 target=${target}
1479 with_multisubdir=${with_multisubdir}
1480 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1481 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1482 libgcj_basedir=${libgcj_basedir}
1483 CC="${CC}"
1484 CXX="${CXX}"
1485 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1486 )
1487
1488 AC_OUTPUT