libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13
  14 AC_PREREQ(2.64)
  15 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  16 AC_CONFIG_SRCDIR([static-object.mk])
  17
  18 # The libgcc should not depend on any header files
  19 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  20   [m4_divert_text([DEFAULTS],
  21     [ac_includes_default='/* none */'])])
  22
  23 AC_ARG_WITH(target-subdir,
  24 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  25 AC_ARG_WITH(cross-host,
  26 [  --with-cross-host=HOST           Configuring with a cross compiler])
  27 AC_ARG_WITH(ld,
  28 [  --with-ld               arrange to use the specified ld (full pathname)])
  29
  30 if test "${srcdir}" = "."; then
  31   if test -n "${with_build_subdir}"; then
  32     libgcc_topdir="${srcdir}/../.."
  33     with_target_subdir=
  34   elif test -z "${with_target_subdir}"; then
  35     libgcc_topdir="${srcdir}/.."
  36   else
  37     if test "${with_target_subdir}" != "."; then
  38       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  39     else
  40       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  41     fi
  42   fi
  43 else
  44   libgcc_topdir="${srcdir}/.."
  45 fi
  46 AC_SUBST(libgcc_topdir)
  47 AC_CONFIG_AUX_DIR($libgcc_topdir)
  48 AC_CONFIG_HEADER(auto-target.h:config.in)
  49
  50 AC_ARG_ENABLE(shared,
  51 [  --disable-shared        don't provide a shared libgcc],
  52 [
  53   case $enable_shared in
  54   yes | no) ;;
  55   *)
  56     enable_shared=no
  57     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  58     for pkg in $enableval; do
  59       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  60         enable_shared=yes
  61       fi
  62     done
  63     IFS="$ac_save_ifs"
  64     ;;
  65   esac
  66 ], [enable_shared=yes])
  67 AC_SUBST(enable_shared)
  68
  69 AC_ARG_ENABLE(vtable-verify,
  70 [  --enable-vtable-verify    Enable vtable verification feature ],
  71 [case "$enableval" in
  72  yes) enable_vtable_verify=yes ;;
  73  no)  enable_vtable_verify=no ;;
  74  *)   enable_vtable_verify=no;;
  75  esac],
  76 [enable_vtable_verify=no])
  77 AC_SUBST(enable_vtable_verify)
  78
  79 GCC_PICFLAG
  80 AC_SUBST(PICFLAG)
  81
  82 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  83 AC_ARG_ENABLE(version-specific-runtime-libs,
  84 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  85 [case "$enableval" in
  86  yes) version_specific_libs=yes ;;
  87  no)  version_specific_libs=no ;;
  88  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  89  esac],
  90 [version_specific_libs=no])
  91 AC_MSG_RESULT($version_specific_libs)
  92
  93 AC_ARG_WITH(slibdir,
  94 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
  95 slibdir="$with_slibdir",
  96 if test "${version_specific_libs}" = yes; then
  97   slibdir='$(libsubdir)'
  98 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
  99   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 100 else
 101   slibdir='$(libdir)'
 102 fi)
 103 AC_SUBST(slibdir)
 104
 105 # Command-line options.
 106 # Very limited version of AC_MAINTAINER_MODE.
 107 AC_ARG_ENABLE([maintainer-mode],
 108   [AC_HELP_STRING([--enable-maintainer-mode],
 109                  [enable make rules and dependencies not useful (and
 110                   sometimes confusing) to the casual installer])],
 111   [case ${enable_maintainer_mode} in
 112      yes) MAINT='' ;;
 113      no) MAINT='#' ;;
 114      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 115    esac
 116    maintainer_mode=${enableval}],
 117   [MAINT='#'])
 118 AC_SUBST([MAINT])dnl
 119
 120 AC_PROG_INSTALL
 121
 122 AC_PROG_AWK
 123 # We need awk; bail out if it's missing.
 124 case ${AWK} in
 125   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 126 esac
 127
 128 AC_CANONICAL_HOST
 129 ACX_NONCANONICAL_HOST
 130 ACX_NONCANONICAL_TARGET
 131 GCC_TOPLEV_SUBDIRS
 132
 133 # Calculate toolexeclibdir
 134 # Also toolexecdir, though it's only used in toolexeclibdir
 135 case ${version_specific_libs} in
 136   yes)
 137     # Need the gcc compiler version to know where to install libraries
 138     # and header files if --enable-version-specific-runtime-libs option
 139     # is selected.
 140     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 141     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 142     ;;
 143   no)
 144     if test -n "$with_cross_host" &&
 145        test x"$with_cross_host" != x"no"; then
 146       # Install a library built with a cross compiler in tooldir, not libdir.
 147       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 148       toolexeclibdir='$(toolexecdir)/lib'
 149     else
 150       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 151       toolexeclibdir='$(libdir)'
 152     fi
 153     multi_os_directory=`$CC -print-multi-os-directory`
 154     case $multi_os_directory in
 155       .) ;; # Avoid trailing /.
 156       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 157     esac
 158     ;;
 159 esac
 160 AC_SUBST(toolexecdir)
 161 AC_SUBST(toolexeclibdir)
 162
 163 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 164 dnl to call AC_CHECK_PROG.
 165 AC_CHECK_TOOL(AR, ar)
 166 AC_CHECK_TOOL(LIPO, lipo, :)
 167 AC_CHECK_TOOL(NM, nm)
 168 AC_CHECK_TOOL(RANLIB, ranlib, :)
 169 AC_CHECK_TOOL(STRIP, strip, :)
 170 AC_PROG_LN_S
 171
 172 GCC_NO_EXECUTABLES
 173 AC_PROG_CC
 174 AC_PROG_CPP_WERROR
 175
 176 AC_CHECK_SIZEOF([double])
 177 AC_CHECK_SIZEOF([long double])
 178 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 179 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 180 AC_SUBST(double_type_size)
 181 AC_SUBST(long_double_type_size)
 182
 183 # Check for decimal float support.
 184 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 185                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 186 #include <fenv.h>
 187 ]], [[
 188 _Decimal32 x;
 189 int fe_except =
 190   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 191 ]])],
 192                                   [libgcc_cv_dfp=yes],
 193                                   [libgcc_cv_dfp=no])])
 194 decimal_float=$libgcc_cv_dfp
 195 AC_SUBST(decimal_float)
 196
 197 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 198
 199 # Check for fixed-point support.
 200 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 201                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 202                                   [libgcc_cv_fixed_point=no])])
 203 fixed_point=$libgcc_cv_fixed_point
 204 AC_SUBST(fixed_point)
 205
 206 # For platforms with the unwind ABI which includes an unwind library,
 207 # libunwind, we can choose to use the system libunwind.
 208 # config.gcc also contains tests of with_system_libunwind.
 209 GCC_CHECK_UNWIND_GETIPINFO
 210
 211 # The sjlj test is almost duplicated here and in libgo/configure.ac (for C),
 212 # libstdc++-v3/acinclude.m4 and libjava/configure.ac (for C++), and
 213 # libobjc/configure.ac (for Objective-C).
 214 # FIXME: This should be centralized in config/sjlj.m4.
 215 AC_ARG_ENABLE(sjlj-exceptions,
 216   AC_HELP_STRING([--enable-sjlj-exceptions],
 217                  [force use of builtin_setjmp for exceptions]),
 218   [case "$enableval" in
 219    yes|no|auto) ;;
 220    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 221    esac],
 222   [enable_sjlj_exceptions=auto])
 223
 224 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 225 [libgcc_cv_lib_sjlj_exceptions],
 226 [AC_LANG_CONFTEST(
 227   [AC_LANG_SOURCE([
 228 void bar ();
 229 void clean (int *);
 230 void foo ()
 231 {
 232   int i __attribute__ ((cleanup (clean)));
 233   bar();
 234 }
 235 ])])
 236 CFLAGS_hold=$CFLAGS
 237 CFLAGS="--save-temps -fexceptions"
 238 libgcc_cv_lib_sjlj_exceptions=unknown
 239 AS_IF([ac_fn_c_try_compile],
 240   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 241     libgcc_cv_lib_sjlj_exceptions=yes
 242   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 243     libgcc_cv_lib_sjlj_exceptions=no
 244   fi])
 245 CFLAGS=$CFLAGS_hold
 246 rm -f conftest*
 247 ])
 248
 249 if test "$enable_sjlj_exceptions" = "auto"; then
 250   enable_sjlj_exceptions=$libgcc_cv_lib_sjlj_exceptions
 251 fi
 252
 253 case $enable_sjlj_exceptions in
 254 yes)
 255   AC_DEFINE(LIBGCC_SJLJ_EXCEPTIONS, 1,
 256         [Define if the C compiler is configured for setjmp/longjmp exceptions.])
 257   ;;
 258 no)
 259   ;;
 260 *)
 261   AC_MSG_ERROR([unable to detect exception model])
 262   ;;
 263 esac
 264
 265 AC_ARG_ENABLE([explicit-exception-frame-registration],
 266   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 267      [register exception tables explicitly at module start, for use
 268       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 269 [
 270 force_explicit_eh_registry=
 271 if test "$enable_explicit_exception_frame_registration" = yes; then
 272   if test "$enable_sjlj_exceptions" = yes; then
 273     AC_MSG_ERROR([Can't enable both of --enable-sjlj-exceptions
 274                   and --enable-explicit-exception-frame-registration])
 275   fi
 276   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 277 fi
 278 ])
 279 AC_SUBST([force_explicit_eh_registry])
 280
 281 AC_LIB_PROG_LD_GNU
 282
 283 AC_MSG_CHECKING([for thread model used by GCC])
 284 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 285 AC_MSG_RESULT([$target_thread_file])
 286
 287 # Check for assembler CFI support.
 288 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 289                [AC_COMPILE_IFELSE(
 290 [asm("\n\
 291         .text\n\
 292         .cfi_startproc\n\
 293         .cfi_personality 0, symbol\n\
 294         .cfi_endproc");],
 295   [libgcc_cv_cfi=yes],
 296   [libgcc_cv_cfi=no])])
 297
 298 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 299 # word size rather than the address size.
 300 cat > conftest.c <<EOF
 301 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 302     || defined(__mips64)
 303 host_address=64
 304 #else
 305 host_address=32
 306 #endif
 307 EOF
 308 eval `${CC-cc} -E conftest.c | grep host_address=`
 309 rm -f conftest.c
 310
 311 case ${host} in
 312 mips*-*-*)
 313   AC_CACHE_CHECK([whether the target is hard-float],
 314                  [libgcc_cv_mips_hard_float],
 315                  [AC_COMPILE_IFELSE(
 316     [#ifndef __mips_hard_float
 317      #error FOO
 318      #endif],
 319     [libgcc_cv_mips_hard_float=yes],
 320     [libgcc_cv_mips_hard_float=no])])
 321 esac
 322
 323 # Collect host-machine-specific information.
 324 . ${srcdir}/config.host
 325
 326 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 327 # This is after config.host so we can augment tmake_file.
 328 # Link with -nostartfiles -nodefaultlibs since neither are present while
 329 # building libgcc.
 330 case ${host} in
 331 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 332   cat > conftest.s <<EOF
 333         .section        .eh_frame,"a",@unwind
 334         .zero   4
 335         .section        .jcr,"aw",@progbits
 336         .zero   8
 337 EOF
 338   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 339       tmake_file="${tmake_file} i386/t-crtstuff"
 340   fi
 341   ;;
 342 esac
 343
 344 # Check for visibility support.  This is after config.host so that
 345 # we can check for asm_hidden_op.
 346 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 347     libgcc_cv_hidden_visibility_attribute, [
 348         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 349         libgcc_cv_hidden_visibility_attribute=no
 350         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 351             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 352                 libgcc_cv_hidden_visibility_attribute=yes
 353             fi
 354         fi
 355         rm -f conftest.*
 356     ])
 357
 358 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 359     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 360 else
 361     vis_hide=
 362 fi
 363 AC_SUBST(vis_hide)
 364
 365 # See if we have thread-local storage.  We can only test assembler
 366 # since link-time and run-time tests require the newly built
 367 # gcc, which can't be used to build executable due to that libgcc
 368 # is yet to be built here.
 369 GCC_CHECK_CC_TLS
 370 set_have_cc_tls=
 371 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 372   set_have_cc_tls="-DHAVE_CC_TLS"
 373 fi
 374 AC_SUBST(set_have_cc_tls)
 375
 376 # See if we have emulated thread-local storage.
 377 GCC_CHECK_EMUTLS
 378 set_use_emutls=
 379 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 380   set_use_emutls="-DUSE_EMUTLS"
 381 fi
 382 AC_SUBST(set_use_emutls)
 383
 384 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 385 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 386   [[void ip (void) __attribute__ ((constructor (1)));]])],
 387   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 388 if test $libgcc_cv_init_priority = yes; then
 389   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 390   [Define if the compiler supports init priority.])
 391 fi
 392
 393 # Conditionalize the sfp-machine.h header for this target machine.
 394 if test -z "${sfp_machine_header}"; then
 395         sfp_machine_header=$cpu_type/sfp-machine.h
 396         if test -f ${srcdir}/config/${sfp_machine_header}; then
 397                 :
 398         else
 399                 sfp_machine_header=no-sfp-machine.h
 400         fi
 401 fi
 402 AC_SUBST(sfp_machine_header)
 403
 404 # Conditionalize the makefile for this target machine.
 405 tmake_file_=
 406 for f in ${tmake_file}
 407 do
 408         if test -f ${srcdir}/config/$f
 409         then
 410                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 411         fi
 412 done
 413 tmake_file="${tmake_file_}"
 414 AC_SUBST(tmake_file)
 415
 416 # Likewise export definitions for libgcc_tm.h
 417 tm_file_=
 418 for f in ${tm_file}
 419 do
 420         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 421 done
 422 tm_file="${tm_file_}"
 423 AC_SUBST(tm_file)
 424 AC_SUBST(tm_defines)
 425
 426 # Map from thread model to thread header.
 427 GCC_AC_THREAD_HEADER([$target_thread_file])
 428
 429 # Substitute configuration variables
 430 AC_SUBST(cpu_type)
 431 AC_SUBST(extra_parts)
 432 AC_SUBST(asm_hidden_op)
 433 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 434 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 435 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 436 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 437 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 438
 439 # We need multilib support.
 440 AC_CONFIG_FILES([Makefile])
 441 AC_CONFIG_COMMANDS([default],
 442   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 443 if test -n "$CONFIG_FILES"; then
 444   # FIXME: We shouldn't need to set ac_file
 445   ac_file=Makefile
 446   . ${libgcc_topdir}/config-ml.in
 447 fi]],
 448 [[srcdir=${srcdir}
 449 host=${host}
 450 with_target_subdir=${with_target_subdir}
 451 with_multisubdir=${with_multisubdir}
 452 ac_configure_args="--enable-multilib ${ac_configure_args}"
 453 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 454 libgcc_topdir=${libgcc_topdir}
 455 CC="${CC}"
 456 ]])
 457 AC_OUTPUT