old-autovect-branch/gcc/testsuite/ada/acats/tests/c3/c390a021.a

   1 -- C390A021.A
   2 --
   3 --                             Grant of Unlimited Rights
   4 --
   5 --     Under contracts F33600-87-D-0337, F33600-84-D-0280, MDA903-79-C-0687,
   6 --     F08630-91-C-0015, and DCA100-97-D-0025, the U.S. Government obtained
   7 --     unlimited rights in the software and documentation contained herein.
   8 --     Unlimited rights are defined in DFAR 252.227-7013(a)(19).  By making
   9 --     this public release, the Government intends to confer upon all
  10 --     recipients unlimited rights  equal to those held by the Government.
  11 --     These rights include rights to use, duplicate, release or disclose the
  12 --     released technical data and computer software in whole or in part, in
  13 --     any manner and for any purpose whatsoever, and to have or permit others
  14 --     to do so.
  15 --
  16 --                                    DISCLAIMER
  17 --
  18 --     ALL MATERIALS OR INFORMATION HEREIN RELEASED, MADE AVAILABLE OR
  19 --     DISCLOSED ARE AS IS.  THE GOVERNMENT MAKES NO EXPRESS OR IMPLIED
  20 --     WARRANTY AS TO ANY MATTER WHATSOEVER, INCLUDING THE CONDITIONS OF THE
  21 --     SOFTWARE, DOCUMENTATION OR OTHER INFORMATION RELEASED, MADE AVAILABLE
  22 --     OR DISCLOSED, OR THE OWNERSHIP, MERCHANTABILITY, OR FITNESS FOR A
  23 --     PARTICULAR PURPOSE OF SAID MATERIAL.
  24 --*
  25 --
  26 -- OBJECTIVE:
  27 --      See C390A022.AM.
  28 --
  29 -- TEST DESCRIPTION:
  30 --      See C390A022.AM.
  31 --
  32 -- TEST FILES:
  33 --      This test consists of the following files:
  34 --
  35 --         F390A00.A
  36 --         C390A020.A
  37 --      => C390A021.A
  38 --         C390A022.AM
  39 --
  40 --
  41 -- CHANGE HISTORY:
  42 --      06 Dec 94   SAIC    ACVC 2.0
  43 --      04 Jun 96   SAIC    ACVC 2.1: Modified prologue.
  44 --
  45 --!
  46
  47 with C390A020;  -- Extended alert abstraction.
  48 package C390A021 is
  49
  50
  51    -- Declarations used by component Action_Officer;
  52
  53    type Person_Enum is (Nobody,          Duty_Officer,
  54                         Watch_Commander, Commanding_Officer);
  55
  56
  57    type Medium_Alert_Type is new C390A020.Low_Alert_Type
  58      with private;                                      -- Private extension of
  59                                                         -- record extension.
  60
  61    -- Inherits (inherited) procedure Display from Low_Alert_Type.
  62    -- Inherits function Level_Of from Low_Alert_Type.
  63
  64    procedure Handle (MA : in out Medium_Alert_Type);    -- Override parent's
  65                                                         -- primitive subprog.
  66
  67    procedure Assign_Officer (MA : in out Medium_Alert_Type;
  68                              To : in     Person_Enum);
  69
  70
  71    -- The following two functions are needed to verify the values of the
  72    -- extension's private components.
  73
  74    function Initial_Values_Okay (MA : in Medium_Alert_Type)
  75      return Boolean;
  76
  77    function Bad_Final_Values (MA : in Medium_Alert_Type)
  78      return Boolean;
  79
  80
  81 private
  82
  83    type Medium_Alert_Type is new C390A020.Low_Alert_Type with record
  84       Action_Officer : Person_Enum := Nobody;
  85    end record;
  86
  87 end C390A021;
  88
  89
  90      --==================================================================--
  91
  92
  93 with F390A00;  -- Basic alert abstraction.
  94 use  F390A00;
  95 package body C390A021 is
  96
  97    use C390A020;  -- Extended alert abstraction.
  98
  99
 100    procedure Assign_Officer (MA : in out Medium_Alert_Type;
 101                              To : in     Person_Enum) is
 102    begin
 103       MA.Action_Officer := To;
 104    end Assign_Officer;
 105
 106
 107    procedure Handle (MA : in out Medium_Alert_Type) is
 108    begin
 109       Handle (Low_Alert_Type (MA));      -- Call parent's op (type conversion).
 110       MA.Level := Level_Of (MA);         -- Call inherited operation.
 111       Assign_Officer (MA, Duty_Officer); -- Call newly declared operation.
 112       MA.Display_On := Console;
 113       Display (MA);                      -- Call twice-inherited operation.
 114    end Handle;
 115
 116
 117    function Initial_Values_Okay (MA : in Medium_Alert_Type) return Boolean is
 118    begin
 119       return (MA = (Arrival_Time   => Default_Time,      -- Check "=" operator
 120                     Display_On     => Null_Device,       -- availability.
 121                     Level          => 0,                 -- Aggregate with
 122                     Action_Officer => Nobody));          -- named associations.
 123    end Initial_Values_Okay;
 124
 125
 126    function Bad_Final_Values (MA : in Medium_Alert_Type) return Boolean is
 127    begin
 128       return (MA /= (Alert_Time, Console,                -- Check "/=" operator
 129                      2         , Duty_Officer));         -- availability.
 130    end Bad_Final_Values;                                 -- Aggregate with
 131                                                          -- positional assoc.
 132
 133 end C390A021;