old-autovect-branch/gcc/ada/widechar.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             W I D E C H A R                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  Note: this package uses the generic subprograms in System.Wch_Cnv, which
  35 --  completely encapsulate the set of wide character encoding methods, so no
  36 --  modifications are required when adding new encoding methods.
  37
  38 with Opt; use Opt;
  39
  40 with System.WCh_Cnv; use System.WCh_Cnv;
  41 with System.WCh_Con; use System.WCh_Con;
  42
  43 package body Widechar is
  44
  45    ---------------------------
  46    -- Is_Start_Of_Wide_Char --
  47    ---------------------------
  48
  49    function Is_Start_Of_Wide_Char
  50      (S : Source_Buffer_Ptr;
  51       P : Source_Ptr) return Boolean
  52    is
  53    begin
  54       case Wide_Character_Encoding_Method is
  55          when WCEM_Hex =>
  56             return S (P) = ASCII.ESC;
  57
  58          when WCEM_Upper     |
  59               WCEM_Shift_JIS |
  60               WCEM_EUC       |
  61               WCEM_UTF8      =>
  62             return S (P) >= Character'Val (16#80#);
  63
  64          when WCEM_Brackets =>
  65             return P <= S'Last - 2
  66               and then S (P) = '['
  67               and then S (P + 1) = '"'
  68               and then S (P + 2) /= '"';
  69       end case;
  70    end Is_Start_Of_Wide_Char;
  71
  72    -----------------
  73    -- Length_Wide --
  74    -----------------
  75
  76    function Length_Wide return Nat is
  77    begin
  78       return WC_Longest_Sequence;
  79    end Length_Wide;
  80
  81    ---------------
  82    -- Scan_Wide --
  83    ---------------
  84
  85    procedure Scan_Wide
  86      (S   : Source_Buffer_Ptr;
  87       P   : in out Source_Ptr;
  88       C   : out Char_Code;
  89       Err : out Boolean)
  90    is
  91       P_Init : constant Source_Ptr := P;
  92
  93       function In_Char return Character;
  94       --  Function to obtain characters of wide character escape sequence
  95
  96       -------------
  97       -- In_Char --
  98       -------------
  99
 100       function In_Char return Character is
 101       begin
 102          P := P + 1;
 103          return S (P - 1);
 104       end In_Char;
 105
 106       function WC_In is new Char_Sequence_To_UTF_32 (In_Char);
 107
 108    --  Start of processingf for Scan_Wide
 109
 110    begin
 111       C := Char_Code (WC_In (In_Char, Wide_Character_Encoding_Method));
 112       Err := False;
 113       Wide_Char_Byte_Count := Wide_Char_Byte_Count + Nat (P - P_Init - 1);
 114
 115    exception
 116       when Constraint_Error =>
 117          C := Char_Code (0);
 118          P := P - 1;
 119          Err := True;
 120    end Scan_Wide;
 121
 122    --------------
 123    -- Set_Wide --
 124    --------------
 125
 126    procedure Set_Wide
 127      (C : Char_Code;
 128       S : in out String;
 129       P : in out Natural)
 130    is
 131       procedure Out_Char (C : Character);
 132       --  Procedure to store one character of wide character sequence
 133
 134       --------------
 135       -- Out_Char --
 136       --------------
 137
 138       procedure Out_Char (C : Character) is
 139       begin
 140          P := P + 1;
 141          S (P) := C;
 142       end Out_Char;
 143
 144       procedure WC_Out is new UTF_32_To_Char_Sequence (Out_Char);
 145
 146    --  Start of processing for Set_Wide
 147
 148    begin
 149       WC_Out (UTF_32_Code (C), Wide_Character_Encoding_Method);
 150    end Set_Wide;
 151
 152    ---------------
 153    -- Skip_Wide --
 154    ---------------
 155
 156    procedure Skip_Wide (S : String; P : in out Natural) is
 157       P_Init : constant Natural := P;
 158
 159       function Skip_Char return Character;
 160       --  Function to skip one character of wide character escape sequence
 161
 162       ---------------
 163       -- Skip_Char --
 164       ---------------
 165
 166       function Skip_Char return Character is
 167       begin
 168          P := P + 1;
 169          return S (P - 1);
 170       end Skip_Char;
 171
 172       function WC_Skip is new Char_Sequence_To_UTF_32 (Skip_Char);
 173
 174       Discard : UTF_32_Code;
 175       pragma Warnings (Off, Discard);
 176
 177    --  Start of processing for Skip_Wide
 178
 179    begin
 180       Discard := WC_Skip (Skip_Char, Wide_Character_Encoding_Method);
 181       Wide_Char_Byte_Count := Wide_Char_Byte_Count + Nat (P - P_Init - 1);
 182    end Skip_Wide;
 183
 184    ---------------
 185    -- Skip_Wide --
 186    ---------------
 187
 188    procedure Skip_Wide (S : Source_Buffer_Ptr; P : in out Source_Ptr) is
 189       P_Init : constant Source_Ptr := P;
 190
 191       function Skip_Char return Character;
 192       --  Function to skip one character of wide character escape sequence
 193
 194       ---------------
 195       -- Skip_Char --
 196       ---------------
 197
 198       function Skip_Char return Character is
 199       begin
 200          P := P + 1;
 201          return S (P - 1);
 202       end Skip_Char;
 203
 204       function WC_Skip is new Char_Sequence_To_UTF_32 (Skip_Char);
 205
 206       Discard : UTF_32_Code;
 207       pragma Warnings (Off, Discard);
 208
 209    --  Start of processing for Skip_Wide
 210
 211    begin
 212       Discard := WC_Skip (Skip_Char, Wide_Character_Encoding_Method);
 213       Wide_Char_Byte_Count := Wide_Char_Byte_Count + Nat (P - P_Init - 1);
 214    end Skip_Wide;
 215
 216 end Widechar;