old-autovect-branch/gcc/ada/s-casi32.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --        S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 3 2       --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Operations; use System.Address_Operations;
  35
  36 with Unchecked_Conversion;
  37
  38 package body System.Compare_Array_Signed_32 is
  39
  40    type Word is range -2**31 .. 2**31 - 1;
  41    for Word'Size use 32;
  42    --  Used to process operands by words
  43
  44    type Uword is record
  45       W : Word;
  46    end record;
  47    pragma Pack (Uword);
  48    for Uword'Alignment use 1;
  49    --  Used to process operands when unaligned
  50
  51    type WP is access Word;
  52    type UP is access Uword;
  53
  54    function W is new Unchecked_Conversion (Address, WP);
  55    function U is new Unchecked_Conversion (Address, UP);
  56
  57    -----------------------
  58    -- Compare_Array_S32 --
  59    -----------------------
  60
  61    function Compare_Array_S32
  62      (Left      : System.Address;
  63       Right     : System.Address;
  64       Left_Len  : Natural;
  65       Right_Len : Natural) return Integer
  66    is
  67       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  68       --  Number of elements left to compare
  69
  70       L : Address := Left;
  71       R : Address := Right;
  72       --  Pointers to next elements to compare
  73
  74    begin
  75       --  Case of going by aligned words
  76
  77       if ModA (OrA (Left, Right), 4) = 0 then
  78          while Clen /= 0 loop
  79             if W (L).all /= W (R).all then
  80                if W (L).all > W (R).all then
  81                   return +1;
  82                else
  83                   return -1;
  84                end if;
  85             end if;
  86
  87             Clen := Clen - 1;
  88             L := AddA (L, 4);
  89             R := AddA (R, 4);
  90          end loop;
  91
  92       --  Case of going by unaligned words
  93
  94       else
  95          while Clen /= 0 loop
  96             if U (L).W /= U (R).W then
  97                if U (L).W > U (R).W then
  98                   return +1;
  99                else
 100                   return -1;
 101                end if;
 102             end if;
 103
 104             Clen := Clen - 1;
 105             L := AddA (L, 4);
 106             R := AddA (R, 4);
 107          end loop;
 108       end if;
 109
 110       --  Here if common section equal, result decided by lengths
 111
 112       if Left_Len = Right_Len then
 113          return 0;
 114       elsif Left_Len > Right_Len then
 115          return +1;
 116       else
 117          return -1;
 118       end if;
 119    end Compare_Array_S32;
 120
 121 end System.Compare_Array_Signed_32;