old-autovect-branch/gcc/ada/s-carun8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --       S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 8      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Operations; use System.Address_Operations;
  35
  36 with Unchecked_Conversion;
  37
  38 package body System.Compare_Array_Unsigned_8 is
  39
  40    type Word is mod 2 ** 32;
  41    --  Used to process operands by words
  42
  43    type Big_Words is array (Natural) of Word;
  44    type Big_Words_Ptr is access Big_Words;
  45    --  Array type used to access by words
  46
  47    type Byte is mod 2 ** 8;
  48    --  Used to process operands by bytes
  49
  50    type Big_Bytes is array (Natural) of Byte;
  51    type Big_Bytes_Ptr is access Big_Bytes;
  52    --  Array type used to access by bytes
  53
  54    function To_Big_Words is new
  55      Unchecked_Conversion (System.Address, Big_Words_Ptr);
  56
  57    function To_Big_Bytes is new
  58      Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  59
  60    ----------------------
  61    -- Compare_Array_U8 --
  62    ----------------------
  63
  64    function Compare_Array_U8
  65      (Left      : System.Address;
  66       Right     : System.Address;
  67       Left_Len  : Natural;
  68       Right_Len : Natural) return Integer
  69    is
  70       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  71
  72    begin
  73       --  If operands are non-aligned, or length is too short, go by bytes
  74
  75       if (ModA (OrA (Left, Right), 4) /= 0) or else Compare_Len < 4 then
  76          return Compare_Array_U8_Unaligned (Left, Right, Left_Len, Right_Len);
  77       end if;
  78
  79       --  Here we can go by words
  80
  81       declare
  82          LeftP  : constant Big_Words_Ptr := To_Big_Words (Left);
  83          RightP : constant Big_Words_Ptr := To_Big_Words (Right);
  84          Clen4  : constant Natural       := Compare_Len / 4 - 1;
  85          Clen4F : constant Natural       := Clen4 * 4;
  86
  87       begin
  88          for J in 0 .. Clen4 loop
  89             if LeftP (J) /= RightP (J) then
  90                return Compare_Array_U8_Unaligned
  91                         (AddA (Left,  Address (4 * J)),
  92                          AddA (Right, Address (4 * J)),
  93                          4, 4);
  94             end if;
  95          end loop;
  96
  97          return Compare_Array_U8_Unaligned
  98                   (AddA (Left,  Address (Clen4F)),
  99                    AddA (Right, Address (Clen4F)),
 100                    Left_Len  - Clen4F,
 101                    Right_Len - Clen4F);
 102       end;
 103    end Compare_Array_U8;
 104
 105    --------------------------------
 106    -- Compare_Array_U8_Unaligned --
 107    --------------------------------
 108
 109    function Compare_Array_U8_Unaligned
 110      (Left      : System.Address;
 111       Right     : System.Address;
 112       Left_Len  : Natural;
 113       Right_Len : Natural) return Integer
 114    is
 115       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 116
 117       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 118       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 119
 120    begin
 121       for J in 0 .. Compare_Len - 1 loop
 122          if LeftP (J) /= RightP (J) then
 123             if LeftP (J) > RightP (J) then
 124                return +1;
 125             else
 126                return -1;
 127             end if;
 128          end if;
 129       end loop;
 130
 131       if Left_Len = Right_Len then
 132          return 0;
 133       elsif Left_Len > Right_Len then
 134          return +1;
 135       else
 136          return -1;
 137       end if;
 138    end Compare_Array_U8_Unaligned;
 139
 140 end System.Compare_Array_Unsigned_8;