old-autovect-branch/gcc/ada/prj-env.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              P R J . E N V                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2005, Free Software Foundation, Inc          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This package implements services for Project-aware tools, mostly related
  28 --  to the environment (configuration pragma files, path files, mapping files).
  29
  30 package Prj.Env is
  31
  32    procedure Initialize;
  33    --  Called by Prj.Initialize to perform required initialization steps for
  34    --  this package.
  35
  36    procedure Print_Sources (In_Tree : Project_Tree_Ref);
  37    --  Output the list of sources, after Project files have been scanned
  38
  39    procedure Create_Mapping_File
  40      (Project : Project_Id;
  41       In_Tree : Project_Tree_Ref;
  42       Name    : out Name_Id);
  43    --  Create a temporary mapping file for project Project. For each unit
  44    --  in the closure of immediate sources of Project, put the mapping of
  45    --  its spec and or body to its file name and path name in this file.
  46
  47    procedure Set_Mapping_File_Initial_State_To_Empty;
  48    --  When creating a mapping file, create an empty map. This case occurs
  49    --  when run time source files are found in the project files.
  50
  51    procedure Create_Config_Pragmas_File
  52      (For_Project          : Project_Id;
  53       Main_Project         : Project_Id;
  54       In_Tree              : Project_Tree_Ref;
  55       Include_Config_Files : Boolean := True);
  56    --  If there needs to have SFN pragmas, either for non standard naming
  57    --  schemes or for individual units, or (when Include_Config_Files is True)
  58    --  if Global_Configuration_Pragmas has been specified in package gnatmake
  59    --  of the main project, or if Local_Configuration_Pragmas has been
  60    --  specified in package Compiler of the main project, build (if needed)
  61    --  a temporary file that contains all configuration pragmas, and specify
  62    --  the configuration pragmas file in the project data.
  63
  64    function Ada_Include_Path
  65      (Project : Project_Id;
  66       In_Tree : Project_Tree_Ref) return String_Access;
  67    --  Get the ADA_INCLUDE_PATH of a Project file. For the first call, compute
  68    --  it and cache it.
  69
  70    function Ada_Include_Path
  71      (Project   : Project_Id;
  72       In_Tree   : Project_Tree_Ref;
  73       Recursive : Boolean) return String;
  74    --  Get the ADA_INCLUDE_PATH of a Project file. If Recursive it True,
  75    --  get all the source directories of the imported and modified project
  76    --  files (recursively). If Recursive is False, just get the path for the
  77    --  source directories of Project. Note: the resulting String may be empty
  78    --  if there is no source directory in the project file.
  79
  80    function Ada_Objects_Path
  81      (Project             : Project_Id;
  82       In_Tree             : Project_Tree_Ref;
  83       Including_Libraries : Boolean := True) return String_Access;
  84    --  Get the ADA_OBJECTS_PATH of a Project file. For the first call, compute
  85    --  it and cache it. When Including_Libraries is False, do not include the
  86    --  object directories of the library projects, and do not cache the result.
  87
  88    procedure Set_Ada_Paths
  89      (Project             : Project_Id;
  90       In_Tree             : Project_Tree_Ref;
  91       Including_Libraries : Boolean);
  92    --  Set the env vars for additional project path files, after
  93    --  creating the path files if necessary.
  94
  95    procedure Delete_All_Path_Files (In_Tree : Project_Tree_Ref);
  96    --  Delete all temporary path files that have been created by
  97    --  calls to Set_Ada_Paths.
  98
  99    function Path_Name_Of_Library_Unit_Body
 100      (Name    : String;
 101       Project : Project_Id;
 102       In_Tree : Project_Tree_Ref) return String;
 103    --  Returns the Path of a library unit
 104
 105    function File_Name_Of_Library_Unit_Body
 106      (Name              : String;
 107       Project           : Project_Id;
 108       In_Tree           : Project_Tree_Ref;
 109       Main_Project_Only : Boolean := True;
 110       Full_Path         : Boolean := False) return String;
 111    --  Returns the file name of a library unit, in canonical case. Name may or
 112    --  may not have an extension (corresponding to the naming scheme of the
 113    --  project). If there is no body with this name, but there is a spec, the
 114    --  name of the spec is returned.
 115    --
 116    --  If Full_Path is False (the default), the simple file name is returned.
 117    --
 118    --  If Full_Path is True, the absolute path name is returned.
 119    --
 120    --  If neither a body nor a spec can be found, an empty string is returned.
 121    --  If Main_Project_Only is True, the unit must be an immediate source of
 122    --  Project. If it is False, it may be a source of one of its imported
 123    --  projects.
 124
 125    function Project_Of
 126      (Name         : String;
 127       Main_Project : Project_Id;
 128       In_Tree      : Project_Tree_Ref) return Project_Id;
 129    --  Get the project of a source. The source file name may be truncated
 130    --  (".adb" or ".ads" may be missing). If the source is in a project being
 131    --  extended, return the ultimate extending project. If it is not a source
 132    --  of any project, return No_Project.
 133
 134    procedure Get_Reference
 135      (Source_File_Name : String;
 136       In_Tree          : Project_Tree_Ref;
 137       Project          : out Project_Id;
 138       Path             : out Name_Id);
 139    --  Returns the project of a source and its path in displayable form
 140
 141    generic
 142       with procedure Action (Path : String);
 143    procedure For_All_Source_Dirs
 144      (Project : Project_Id;
 145       In_Tree : Project_Tree_Ref);
 146    --  Iterate through all the source directories of a project, including
 147    --  those of imported or modified projects.
 148
 149    generic
 150       with procedure Action (Path : String);
 151    procedure For_All_Object_Dirs
 152      (Project : Project_Id;
 153       In_Tree : Project_Tree_Ref);
 154    --  Iterate through all the object directories of a project, including
 155    --  those of imported or modified projects.
 156
 157 end Prj.Env;