old-autovect-branch/gcc/ada/exp_ch9.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ C H 9                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  Expand routines for chapter 9 constructs
  28
  29 with Types; use Types;
  30
  31 package Exp_Ch9 is
  32
  33    type Subprogram_Protection_Mode is
  34      (Dispatching_Mode,
  35       Protected_Mode,
  36       Unprotected_Mode);
  37    --  This type is used to distinguish the different protection modes of a
  38    --  protected subprogram.
  39
  40    procedure Add_Discriminal_Declarations
  41      (Decls : List_Id;
  42       Typ   : Entity_Id;
  43       Name  : Name_Id;
  44       Loc   : Source_Ptr);
  45    --  This routine is used to add discriminal declarations to task and
  46    --  protected operation bodies. The discriminants are available by normal
  47    --  selection from the concurrent object (whose name is passed as the third
  48    --  parameter). Discriminant references inside the body have already
  49    --  been replaced by references to the corresponding discriminals. The
  50    --  declarations constructed by this procedure hook the references up with
  51    --  the objects:
  52    --
  53    --    discriminal_name : discr_type renames name.discriminant_name;
  54    --
  55    --  Obviously we could have expanded the discriminant references in the
  56    --  first place to be the appropriate selection, but this turns out to
  57    --  be hard to do because it would introduce difference in handling of
  58    --  discriminant references depending on their location.
  59
  60    procedure Add_Private_Declarations
  61      (Decls : List_Id;
  62       Typ   : Entity_Id;
  63       Name  : Name_Id;
  64       Loc : Source_Ptr);
  65    --  This routine is used to add private declarations to protected bodies.
  66    --  These are analogous to the discriminal declarations added to tasks
  67    --  and protected operations, and consist of a renaming of each private
  68    --  object to a selection from the concurrent object passed as an extra
  69    --  parameter to each such operation:
  70    --    private_name : private_type renames name.private_name;
  71    --  As with discriminals, private references inside the protected
  72    --  subprogram bodies have already been replaced by references to the
  73    --  corresponding privals.
  74
  75    procedure Build_Activation_Chain_Entity (N : Node_Id);
  76    --  Given a declaration N of an object that is a task, or contains tasks
  77    --  (other than allocators to tasks) this routine ensures that an activation
  78    --  chain has been declared in the appropriate scope, building the required
  79    --  declaration for the chain variable if not. The name of this variable
  80    --  is always _Chain and it is accessed by name. This procedure also adds
  81    --  an appropriate call to Activate_Tasks to activate the tasks for this
  82    --  activation chain. It does not however deal with the call needed in the
  83    --  case of allocators to Expunge_Unactivated_Tasks, this is separately
  84    --  handled in the Expand_Task_Allocator routine.
  85
  86    function Build_Call_With_Task (N : Node_Id; E : Entity_Id) return Node_Id;
  87    --  N is a node representing the name of a task or an access to a task.
  88    --  The value returned is a call to the function whose name is the entity
  89    --  E (typically a runtime routine entity obtained using RTE) with the
  90    --  Task_Id of the associated task as the parameter. The caller is
  91    --  responsible for analyzing and resolving the resulting tree.
  92
  93    procedure Build_Master_Entity (E : Entity_Id);
  94    --  Given an entity E for the declaration of an object containing tasks
  95    --  or of a type declaration for an allocator whose designated type is a
  96    --  task or contains tasks, this routine marks the appropriate enclosing
  97    --  context as a master, and also declares a variable called _Master in
  98    --  the current declarative part which captures the value of Current_Master
  99    --  (if not already built by a prior call). We build this object (instead
 100    --  of just calling Current_Master) for two reasons. First it is clearly
 101    --  more efficient to call Current_Master only once for a bunch of tasks
 102    --  in the same declarative part, and second it makes things easier in
 103    --  generating the initialization routines, since they can just reference
 104    --  the object _Master by name, and they will get the proper Current_Master
 105    --  value at the outer level, and copy in the parameter value for the outer
 106    --  initialization call if the call is for a nested component). Note that
 107    --  in the case of nested packages, we only really need to make one such
 108    --  object at the outer level, but it is much easier to generate one per
 109    --  declarative part.
 110
 111    function Build_Protected_Sub_Specification
 112      (N       : Node_Id;
 113       Prottyp : Entity_Id;
 114       Mode    : Subprogram_Protection_Mode) return Node_Id;
 115    --  Build specification for protected subprogram. This is called when
 116    --  expanding a protected type, and also when expanding the declaration for
 117    --  an Access_To_Protected_Subprogram type. In the latter case, Prottyp is
 118    --  empty, and the first parameter of the signature of the protected op is
 119    --  of type System.Address.
 120
 121    procedure Build_Protected_Subprogram_Call
 122      (N        : Node_Id;
 123       Name     : Node_Id;
 124       Rec      : Node_Id;
 125       External : Boolean := True);
 126    --  The node N is a subprogram or entry call to a protected subprogram.
 127    --  This procedure rewrites this call with the appropriate expansion.
 128    --  Name is the subprogram, and Rec is the record corresponding to the
 129    --  protected object. External is False if the call is to another
 130    --  protected subprogram within the same object.
 131
 132    procedure Build_Task_Activation_Call (N : Node_Id);
 133    --  This procedure is called for constructs that can be task activators
 134    --  i.e. task bodies, subprogram bodies, package bodies and blocks. If
 135    --  the construct is a task activator (as indicated by the non-empty
 136    --  setting of Activation_Chain_Entity, either in the construct, or, in
 137    --  the case of a package body, in its associated package spec), then
 138    --  a call to Activate_Tasks with this entity as the single parameter
 139    --  is inserted at the start of the statements of the activator.
 140
 141    procedure Build_Task_Allocate_Block
 142      (Actions : List_Id;
 143       N       : Node_Id;
 144       Args    : List_Id);
 145    --  This routine is used in the case of allocators where the designated
 146    --  type is a task or contains tasks. In this case, the normal initialize
 147    --  call is replaced by:
 148    --
 149    --    blockname : label;
 150    --    blockname : declare
 151    --       _Chain  : Activation_Chain;
 152    --
 153    --       procedure _Expunge is
 154    --       begin
 155    --         Expunge_Unactivated_Tasks (_Chain);
 156    --       end;
 157    --
 158    --    begin
 159    --       Init (Args);
 160    --       Activate_Tasks (_Chain);
 161    --    at end
 162    --       _Expunge;
 163    --    end;
 164    --
 165    --  to get the task or tasks created and initialized. The expunge call
 166    --  ensures that any tasks that get created but not activated due to an
 167    --  exception are properly expunged (it has no effect in the normal case)
 168    --  The argument N is the allocator, and Args is the list of arguments
 169    --  for the initialization call, constructed by the caller, which uses
 170    --  the Master_Id of the access type as the _Master parameter, and _Chain
 171    --  (defined above) as the _Chain parameter.
 172
 173    procedure Build_Task_Allocate_Block_With_Init_Stmts
 174      (Actions    : List_Id;
 175       N          : Node_Id;
 176       Init_Stmts : List_Id);
 177    --  Ada 2005 (AI-287): Similar to previous routine, but used to expand
 178    --  allocated aggregates with default initialized components. Init_Stmts
 179    --  contains the list of statements required to initialize the allocated
 180    --  aggregate. It replaces the call to Init (Args) done by
 181    --  Build_Task_Allocate_Block.
 182
 183    function Concurrent_Ref (N : Node_Id) return Node_Id;
 184    --  Given the name of a concurrent object (task or protected object), or
 185    --  the name of an access to a concurrent object, this function returns an
 186    --  expression referencing the associated Task_Id or Protection object,
 187    --  respectively. Note that a special case is when the name is a reference
 188    --  to a task type name. This can only happen within a task body, and the
 189    --  meaning is to get the Task_Id for the currently executing task.
 190
 191    function Convert_Concurrent
 192      (N    : Node_Id;
 193       Typ  : Entity_Id)
 194       return Node_Id;
 195    --  N is an expression of type Typ. If the type is not a concurrent
 196    --  type then it is returned unchanged. If it is a task or protected
 197    --  reference, Convert_Concurrent creates an unchecked conversion node
 198    --  from this expression to the corresponding concurrent record type
 199    --  value. We need this in any situation where the concurrent type is
 200    --  used, because the actual concurrent object is an object of the
 201    --  corresponding concurrent type, and manipulations on the concurrent
 202    --  object actually manipulate the corresponding object of the record
 203    --  type.
 204
 205    function Entry_Index_Expression
 206      (Sloc  : Source_Ptr;
 207       Ent   : Entity_Id;
 208       Index : Node_Id;
 209       Ttyp  : Entity_Id)
 210       return  Node_Id;
 211    --  Returns an expression to compute a task entry index given the name
 212    --  of the entry or entry family. For the case of a task entry family,
 213    --  the Index parameter contains the expression for the subscript.
 214    --  Ttyp is the task type.
 215
 216    procedure Establish_Task_Master (N : Node_Id);
 217    --  Given a subprogram body, or a block statement, or a task body, this
 218    --  proccedure makes the necessary transformations required of a task
 219    --  master (add Enter_Master call at start, and establish a cleanup
 220    --  routine to make sure Complete_Master is called on exit).
 221
 222    procedure Expand_Access_Protected_Subprogram_Type (N : Node_Id);
 223    --  Build Equivalent_Type for an Access_to_protected_Subprogram
 224
 225    procedure Expand_Accept_Declarations (N : Node_Id; Ent : Entity_Id);
 226    --  Expand declarations required for accept statement. See bodies of
 227    --  both Expand_Accept_Declarations and Expand_N_Accept_Statement for
 228    --  full details of the nature and use of these declarations, which
 229    --  are inserted immediately before the accept node N. The second
 230    --  argument is the entity for the corresponding entry.
 231
 232    procedure Expand_Entry_Barrier (N : Node_Id; Ent : Entity_Id);
 233    --  Expand the entry barrier into a function. This is called directly
 234    --  from Analyze_Entry_Body so that the discriminals and privals of the
 235    --  barrier can be attached to the function declaration list, and a new
 236    --  set prepared for the entry body procedure, bedore the entry body
 237    --  statement sequence can be expanded. The resulting function is analyzed
 238    --  now, within the context of the protected object, to resolve calls to
 239    --  other protected functions.
 240
 241    procedure Expand_Entry_Body_Declarations (N : Node_Id);
 242    --  Expand declarations required for the expansion of the
 243    --  statements of the body.
 244
 245    procedure Expand_N_Abort_Statement            (N : Node_Id);
 246    procedure Expand_N_Accept_Statement           (N : Node_Id);
 247    procedure Expand_N_Asynchronous_Select        (N : Node_Id);
 248    procedure Expand_N_Conditional_Entry_Call     (N : Node_Id);
 249    procedure Expand_N_Delay_Relative_Statement   (N : Node_Id);
 250    procedure Expand_N_Delay_Until_Statement      (N : Node_Id);
 251    procedure Expand_N_Entry_Body                 (N : Node_Id);
 252    procedure Expand_N_Entry_Call_Statement       (N : Node_Id);
 253    procedure Expand_N_Entry_Declaration          (N : Node_Id);
 254    procedure Expand_N_Protected_Body             (N : Node_Id);
 255
 256    procedure Expand_N_Protected_Type_Declaration (N : Node_Id);
 257    --  Expands protected type declarations. This results, among
 258    --  other things, in the declaration of a record type for the
 259    --  representation of protected objects and (if there are entries)
 260    --  in an entry service procedure. The Protection value used by
 261    --  the GNARL to control the object will always be the first
 262    --  field of the record, and the entry service procedure spec
 263    --  (if it exists) will always immediately follow the record
 264    --  declaration. This allows these two nodes to be found from
 265    --  the type using Corresponding_Record, without benefit of
 266    --  of further attributes.
 267
 268    procedure Expand_N_Requeue_Statement          (N : Node_Id);
 269    procedure Expand_N_Selective_Accept           (N : Node_Id);
 270    procedure Expand_N_Single_Task_Declaration    (N : Node_Id);
 271    procedure Expand_N_Task_Body                  (N : Node_Id);
 272    procedure Expand_N_Task_Type_Declaration      (N : Node_Id);
 273    procedure Expand_N_Timed_Entry_Call           (N : Node_Id);
 274
 275    procedure Expand_Protected_Body_Declarations
 276      (N       : Node_Id;
 277       Spec_Id : Entity_Id);
 278    --  Expand declarations required for a protected body. See bodies of
 279    --  both Expand_Protected_Body_Declarations and Expand_N_Protected_Body
 280    --  for full details of the nature and use of these declarations.
 281    --  The second argument is the entity for the corresponding
 282    --  protected type declaration.
 283
 284    function External_Subprogram (E : Entity_Id) return Entity_Id;
 285    --  return the external version of a protected operation, which locks
 286    --  the object before invoking the internal protected subprogram body.
 287
 288    function First_Protected_Operation (D : List_Id) return Node_Id;
 289    --  Given the declarations list for a protected body, find the
 290    --  first protected operation body.
 291
 292    function Make_Task_Create_Call (Task_Rec : Entity_Id) return Node_Id;
 293    --  Given the entity of the record type created for a task type, build
 294    --  the call to Create_Task
 295
 296    function Make_Initialize_Protection
 297      (Protect_Rec : Entity_Id)
 298       return        List_Id;
 299    --  Given the entity of the record type created for a protected type, build
 300    --  a list of statements needed for proper initialization of the object.
 301
 302    function Next_Protected_Operation (N : Node_Id) return Node_Id;
 303    --  Given a protected operation node (a subprogram or entry body),
 304    --  find the following node in the declarations list.
 305
 306    procedure Set_Discriminals (Dec : Node_Id);
 307    --  Replace discriminals in a protected type for use by the
 308    --  next protected operation on the type. Each operation needs a
 309    --  new set of discirminals, since it needs a unique renaming of
 310    --  the discriminant fields in the record used to implement the
 311    --  protected type.
 312
 313    procedure Set_Privals
 314       (Dec           : Node_Id;
 315        Op            : Node_Id;
 316        Loc           : Source_Ptr;
 317        After_Barrier : Boolean := False);
 318    --  Associates a new set of privals (placeholders for later access to
 319    --  private components of protected objects) with the private object
 320    --  declarations of a protected object. These will be used to expand
 321    --  the references to private objects in the next protected
 322    --  subprogram or entry body to be expanded.
 323    --
 324    --  The flag After_Barrier indicates whether this is called after building
 325    --  the barrier function for an entry body. This flag determines whether
 326    --  the privals should have source names (which simplifies debugging) or
 327    --  internally generated names. Entry barriers contain no debuggable code,
 328    --  and there may be visibility conflicts between an entry index and a
 329    --  a prival, so  privals for barrier function have internal names.
 330
 331 end Exp_Ch9;