old-autovect-branch/gcc/ada/a-except.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       A D A . E X C E P T I O N S                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 pragma Polling (Off);
  39 --  We must turn polling off for this unit, because otherwise we get
  40 --  elaboration circularities with ourself.
  41
  42 with System;
  43 with System.Parameters;
  44 with System.Standard_Library;
  45 with System.Traceback_Entries;
  46
  47 package Ada.Exceptions is
  48    pragma Warnings (Off);
  49    pragma Preelaborate_05;
  50    pragma Warnings (On);
  51    --  In accordance with Ada 2005 AI-362. The warnings pragmas are so that we
  52    --  can compile this using older compiler versions, which will ignore the
  53    --  pragma, which is fine for the bootstrap.
  54
  55    type Exception_Id is private;
  56    Null_Id : constant Exception_Id;
  57
  58    type Exception_Occurrence is limited private;
  59    type Exception_Occurrence_Access is access all Exception_Occurrence;
  60
  61    Null_Occurrence : constant Exception_Occurrence;
  62
  63    function Exception_Name (X : Exception_Occurrence) return String;
  64    --  Same as Exception_Name (Exception_Identity (X))
  65
  66    function Exception_Name (Id : Exception_Id) return String;
  67
  68    procedure Raise_Exception (E : Exception_Id; Message : String := "");
  69    --  Note: it would be really nice to give a pragma No_Return for this
  70    --  procedure, but it would be wrong, since Raise_Exception does return
  71    --  if given the null exception. However we do special case the name in
  72    --  the test in the compiler for issuing a warning for a missing return
  73    --  after this call. Program_Error seems reasonable enough in such a case.
  74    --  See also the routine Raise_Exception_Always in the private part.
  75
  76    function Exception_Message (X : Exception_Occurrence) return String;
  77
  78    procedure Reraise_Occurrence (X : Exception_Occurrence);
  79    --  Note: it would be really nice to give a pragma No_Return for this
  80    --  procedure, but it would be wrong, since Reraise_Occurrence does return
  81    --  if the argument is the null exception occurrence. See also procedure
  82    --  Reraise_Occurrence_Always in the private part of this package.
  83
  84    function Exception_Identity (X : Exception_Occurrence) return Exception_Id;
  85
  86    function Exception_Information (X : Exception_Occurrence) return String;
  87    --  The format of the exception information is as follows:
  88    --
  89    --    exception name (as in Exception_Name)
  90    --    message (or a null line if no message)
  91    --    PID=nnnn
  92    --    0xyyyyyyyy 0xyyyyyyyy ...
  93    --
  94    --  The lines are separated by a ASCII.LF character
  95    --  The nnnn is the partition Id given as decimal digits.
  96    --  The 0x... line represents traceback program counter locations,
  97    --  in order with the first one being the exception location.
  98
  99    --  Note on ordering: the compiler uses the Save_Occurrence procedure, but
 100    --  not the function from Rtsfind, so it is important that the procedure
 101    --  come first, since Rtsfind finds the first matching entity.
 102
 103    procedure Save_Occurrence
 104      (Target : out Exception_Occurrence;
 105       Source : Exception_Occurrence);
 106
 107    function Save_Occurrence
 108      (Source : Exception_Occurrence)
 109       return   Exception_Occurrence_Access;
 110
 111 private
 112    package SSL renames System.Standard_Library;
 113    package SP renames System.Parameters;
 114
 115    subtype EOA is Exception_Occurrence_Access;
 116
 117    Exception_Msg_Max_Length : constant := SP.Default_Exception_Msg_Max_Length;
 118
 119    ------------------
 120    -- Exception_Id --
 121    ------------------
 122
 123    subtype Code_Loc is System.Address;
 124    --  Code location used in building exception tables and for call addresses
 125    --  when propagating an exception. Values of this type are created by using
 126    --  Label'Address or extracted from machine states using Get_Code_Loc.
 127
 128    Null_Loc : constant Code_Loc := System.Null_Address;
 129    --  Null code location, used to flag outer level frame
 130
 131    type Exception_Id is new SSL.Exception_Data_Ptr;
 132
 133    function EId_To_String (X : Exception_Id) return String;
 134    function String_To_EId (S : String) return Exception_Id;
 135    pragma Stream_Convert (Exception_Id, String_To_EId, EId_To_String);
 136    --  Functions for implementing Exception_Id stream attributes
 137
 138    Null_Id : constant Exception_Id := null;
 139
 140    -------------------------
 141    -- Private Subprograms --
 142    -------------------------
 143
 144    function Current_Target_Exception return Exception_Occurrence;
 145    pragma Export
 146      (Ada, Current_Target_Exception,
 147       "__gnat_current_target_exception");
 148    --  This routine should return the current raised exception on targets
 149    --  which have built-in exception handling such as the Java Virtual
 150    --  Machine. For other targets this routine is simply ignored. Currently,
 151    --  only JGNAT uses this. See 4jexcept.ads for details. The pragma Export
 152    --  allows this routine to be accessed elsewhere in the run-time, even
 153    --  though it is in the private part of this package (it is not allowed
 154    --  to be in the visible part, since this is set by the reference manual).
 155
 156    function Exception_Name_Simple (X : Exception_Occurrence) return String;
 157    --  Like Exception_Name, but returns the simple non-qualified name of the
 158    --  exception. This is used to implement the Exception_Name function in
 159    --  Current_Exceptions (the DEC compatible unit). It is called from the
 160    --  compiler generated code (using Rtsfind, which does not respect the
 161    --  private barrier, so we can place this function in the private part
 162    --  where the compiler can find it, but the spec is unchanged.)
 163
 164    procedure Raise_Exception_Always (E : Exception_Id; Message : String := "");
 165    pragma No_Return (Raise_Exception_Always);
 166    pragma Export (Ada, Raise_Exception_Always, "__gnat_raise_exception");
 167    --  This differs from Raise_Exception only in that the caller has determined
 168    --  that for sure the parameter E is not null, and that therefore the call
 169    --  to this procedure cannot return. The expander converts Raise_Exception
 170    --  calls to Raise_Exception_Always if it can determine this is the case.
 171    --  The Export allows this routine to be accessed from Pure units.
 172
 173    procedure Raise_From_Signal_Handler
 174      (E : Exception_Id;
 175       M : System.Address);
 176    pragma Export
 177      (Ada, Raise_From_Signal_Handler,
 178            "ada__exceptions__raise_from_signal_handler");
 179    pragma No_Return (Raise_From_Signal_Handler);
 180    --  This routine is used to raise an exception from a signal handler. The
 181    --  signal handler has already stored the machine state (i.e. the state that
 182    --  corresponds to the location at which the signal was raised). E is the
 183    --  Exception_Id specifying what exception is being raised, and M is a
 184    --  pointer to a null-terminated string which is the message to be raised.
 185    --  Note that this routine never returns, so it is permissible to simply
 186    --  jump to this routine, rather than call it. This may be appropriate for
 187    --  systems where the right way to get out of signal handler is to alter the
 188    --  PC value in the machine state or in some other way ask the operating
 189    --  system to return here rather than to the original location.
 190
 191    procedure Reraise_Occurrence_Always (X : Exception_Occurrence);
 192    pragma No_Return (Reraise_Occurrence_Always);
 193    --  This differs from Raise_Occurrence only in that the caller guarantees
 194    --  that for sure the parameter X is not the null occurrence, and that
 195    --  therefore this procedure cannot return. The expander uses this routine
 196    --  in the translation of a raise statement with no parameter (reraise).
 197
 198    procedure Reraise_Occurrence_No_Defer (X : Exception_Occurrence);
 199    pragma No_Return (Reraise_Occurrence_No_Defer);
 200    --  Exactly like Reraise_Occurrence, except that abort is not deferred
 201    --  before the call and the parameter X is known not to be the null
 202    --  occurrence. This is used in generated code when it is known that
 203    --  abort is already deferred.
 204
 205    -----------------------
 206    -- Polling Interface --
 207    -----------------------
 208
 209    --  The GNAT compiler has an option to generate polling calls to the Poll
 210    --  routine in this package. Specifying the -gnatP option for a compilation
 211    --  causes a call to Ada.Exceptions.Poll to be generated on every subprogram
 212    --  entry and on every iteration of a loop, thus avoiding the possibility of
 213    --  a case of unbounded time between calls.
 214
 215    --  This polling interface may be used for instrumentation or debugging
 216    --  purposes (e.g. implementing watchpoints in software or in the debugger).
 217
 218    --  In the GNAT technology itself, this interface is used to implement
 219    --  immediate aynschronous transfer of control and immediate abort on
 220    --  targets which do not provide for one thread interrupting another.
 221
 222    --  Note: this used to be in a separate unit called System.Poll, but that
 223    --  caused horrible circular elaboration problems between System.Poll and
 224    --  Ada.Exceptions. One way of solving such circularities is unification!
 225
 226    procedure Poll;
 227    --  Check for asynchronous abort. Note that we do not inline the body.
 228    --  This makes the interface more useful for debugging purposes.
 229
 230    --------------------------
 231    -- Exception_Occurrence --
 232    --------------------------
 233
 234    package TBE renames System.Traceback_Entries;
 235
 236    Max_Tracebacks : constant := 50;
 237    --  Maximum number of trace backs stored in exception occurrence
 238
 239    type Tracebacks_Array is array (1 .. Max_Tracebacks) of TBE.Traceback_Entry;
 240    --  Traceback array stored in exception occurrence
 241
 242    type Exception_Occurrence is record
 243       Id : Exception_Id;
 244       --  Exception_Identity for this exception occurrence
 245       --  WARNING System.System.Finalization_Implementation.Finalize_List
 246       --  relies on the fact that this field is always first in the exception
 247       --  occurrence
 248
 249       Msg_Length : Natural := 0;
 250       --  Length of message (zero = no message)
 251
 252       Msg : String (1 .. Exception_Msg_Max_Length);
 253       --  Characters of message
 254
 255       Cleanup_Flag : Boolean := False;
 256       --  The cleanup flag is normally False, it is set True for an exception
 257       --  occurrence passed to a cleanup routine, and will still be set True
 258       --  when the cleanup routine does a Reraise_Occurrence call using this
 259       --  exception occurrence. This is used to avoid recording a bogus trace
 260       --  back entry from this reraise call.
 261
 262       Exception_Raised : Boolean := False;
 263       --  Set to true to indicate that this exception occurrence has actually
 264       --  been raised. When an exception occurrence is first created, this is
 265       --  set to False, then when it is processed by Raise_Current_Exception,
 266       --  it is set to True. If Raise_Current_Exception is used to raise an
 267       --  exception for which this flag is already True, then it knows that
 268       --  it is dealing with the reraise case (which is useful to distinguish
 269       --  for exception tracing purposes).
 270
 271       Pid : Natural := 0;
 272       --  Partition_Id for partition raising exception
 273
 274       Num_Tracebacks : Natural range 0 .. Max_Tracebacks := 0;
 275       --  Number of traceback entries stored
 276
 277       Tracebacks : Tracebacks_Array;
 278       --  Stored tracebacks (in Tracebacks (1 .. Num_Tracebacks))
 279
 280       Private_Data : System.Address := System.Null_Address;
 281       --  Field used by low level exception mechanism to store specific data.
 282       --  Currently used by the GCC exception mechanism to store a pointer to
 283       --  a GNAT_GCC_Exception.
 284    end record;
 285
 286    function "=" (Left, Right : Exception_Occurrence) return Boolean
 287      is abstract;
 288    --  Don't allow comparison on exception occurrences, we should not need
 289    --  this, and it would not work right, because of the Msg and Tracebacks
 290    --  fields which have unused entries not copied by Save_Occurrence.
 291
 292    function EO_To_String (X : Exception_Occurrence) return String;
 293    function String_To_EO (S : String) return Exception_Occurrence;
 294    pragma Stream_Convert (Exception_Occurrence, String_To_EO, EO_To_String);
 295    --  Functions for implementing Exception_Occurrence stream attributes
 296
 297    Null_Occurrence : constant Exception_Occurrence := (
 298      Id               => null,
 299      Msg_Length       => 0,
 300      Msg              => (others => ' '),
 301      Cleanup_Flag     => False,
 302      Exception_Raised => False,
 303      Pid              => 0,
 304      Num_Tracebacks   => 0,
 305      Tracebacks       => (others => TBE.Null_TB_Entry),
 306      Private_Data     => System.Null_Address);
 307
 308 end Ada.Exceptions;