gcc/config/ia64/crtend.asm

   1 /* Copyright (C) 2000, 2001, 2003 Free Software Foundation, Inc.
   2    Contributed by Jes Sorensen, <Jes.Sorensen@cern.ch>
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Library General Public License as
   6    published by the Free Software Foundation; either version 2 of the
   7    License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Library General Public License for more details.
  13
  14    You should have received a copy of the GNU Library General Public
  15    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17    Boston, MA 02111-1307, USA.  */
  18
  19 #include "auto-host.h"
  20
  21 .section .ctors,"aw","progbits"
  22         .align  8
  23 __CTOR_END__:
  24         data8   0
  25
  26 .section .dtors,"aw","progbits"
  27         .align 8
  28 __DTOR_END__:
  29         data8   0
  30
  31 .section .jcr,"aw","progbits"
  32         .align 8
  33 __JCR_END__:
  34         data8   0
  35
  36 #ifdef HAVE_INITFINI_ARRAY
  37
  38 .section .init_array, "a"
  39         data8 @fptr(__do_global_ctors_aux)
  40
  41 #else /* !HAVE_INITFINI_ARRAY */
  42 /*
  43  * Fragment of the ELF _init routine that invokes our dtor cleanup.
  44  *
  45  * We make the call by indirection, because in large programs the
  46  * .fini and .init sections are not in range of the destination, and
  47  * we cannot allow the linker to insert a stub at the end of this
  48  * fragment of the _fini function.  Further, Itanium does not implement
  49  * the long branch instructions, and we do not wish every program to
  50  * trap to the kernel for emulation.
  51  *
  52  * Note that we require __do_global_ctors_aux to preserve the GP,
  53  * so that the next fragment in .fini gets the right value.
  54  */
  55 .section .init,"ax","progbits"
  56         { .mlx
  57           movl r2 = @pcrel(__do_global_ctors_aux - 16)
  58         }
  59         { .mii
  60           mov r3 = ip
  61           ;;
  62           add r2 = r2, r3
  63           ;;
  64         }
  65         { .mib
  66           mov b6 = r2
  67           br.call.sptk.many b0 = b6
  68           ;;
  69         }
  70 #endif /* !HAVE_INITFINI_ARRAY */
  71
  72 .text
  73         .align 32
  74         .proc __do_global_ctors_aux
  75 __do_global_ctors_aux:
  76         .prologue
  77         /*
  78                 for (loc0 = __CTOR_END__-1; *p != -1; --p)
  79                   (*p) ();
  80         */
  81         .save ar.pfs, r34
  82         alloc loc2 = ar.pfs, 0, 5, 0, 0
  83         movl loc0 = @gprel(__CTOR_END__ - 8)
  84         ;;
  85
  86         add loc0 = loc0, gp
  87         ;;
  88         ld8 loc3 = [loc0], -8
  89         .save rp, loc1
  90         mov loc1 = rp
  91         .body
  92         ;;
  93
  94         cmp.eq p6, p0 = -1, loc3
  95         mov loc4 = gp
  96 (p6)    br.cond.spnt.few .exit
  97
  98 .loop:  ld8 r15 = [loc3], 8
  99         ;;
 100         ld8 gp = [loc3]
 101         mov b6 = r15
 102
 103         ld8 loc3 = [loc0], -8
 104         nop 0
 105         br.call.sptk.many rp = b6
 106         ;;
 107
 108         cmp.ne p6, p0 = -1, loc3
 109         nop 0
 110 (p6)    br.cond.sptk.few .loop
 111
 112 .exit:  mov gp = loc3
 113         mov rp = loc1
 114         mov ar.pfs = loc2
 115
 116         br.ret.sptk.many rp
 117         .endp __do_global_ctors_aux