gcc/ada/lib.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  L I B                                   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Style_Checks (All_Checks);
  35 --  Subprogram ordering not enforced in this unit
  36 --  (because of some logical groupings).
  37
  38 with Atree;   use Atree;
  39 with Einfo;   use Einfo;
  40 with Fname;   use Fname;
  41 with Namet;   use Namet;
  42 with Namet;   use Namet;
  43 with Output;  use Output;
  44 with Sinfo;   use Sinfo;
  45 with Sinput;  use Sinput;
  46 with Stand;   use Stand;
  47 with Stringt; use Stringt;
  48 with Tree_IO; use Tree_IO;
  49 with Uname;   use Uname;
  50
  51 package body Lib is
  52
  53    -----------------------
  54    -- Local Subprograms --
  55    -----------------------
  56
  57    type SEU_Result is (
  58       Yes_Before, -- S1 is in same extended unit as S2 and appears before it
  59       Yes_Same,   -- S1 is in same extended unit as S2, Slocs are the same
  60       Yes_After,  -- S1 is in same extended unit as S2, and appears after it
  61       No);        -- S2 is not in same extended unit as S2
  62
  63    function Check_Same_Extended_Unit (S1, S2 : Source_Ptr) return SEU_Result;
  64    --  Used by In_Same_Extended_Unit and Earlier_In_Extended_Unit. Returns
  65    --  value as described above.
  66
  67    --------------------------------------------
  68    -- Access Functions for Unit Table Fields --
  69    --------------------------------------------
  70
  71    function Cunit (U : Unit_Number_Type) return Node_Id is
  72    begin
  73       return Units.Table (U).Cunit;
  74    end Cunit;
  75
  76    function Cunit_Entity (U : Unit_Number_Type) return Entity_Id is
  77    begin
  78       return Units.Table (U).Cunit_Entity;
  79    end Cunit_Entity;
  80
  81    function Dependency_Num (U : Unit_Number_Type) return Nat is
  82    begin
  83       return Units.Table (U).Dependency_Num;
  84    end Dependency_Num;
  85
  86    function Dependent_Unit (U : Unit_Number_Type) return Boolean is
  87    begin
  88       return Units.Table (U).Dependent_Unit;
  89    end Dependent_Unit;
  90
  91    function Dynamic_Elab (U : Unit_Number_Type) return Boolean is
  92    begin
  93       return Units.Table (U).Dynamic_Elab;
  94    end Dynamic_Elab;
  95
  96    function Error_Location (U : Unit_Number_Type) return Source_Ptr is
  97    begin
  98       return Units.Table (U).Error_Location;
  99    end Error_Location;
 100
 101    function Expected_Unit (U : Unit_Number_Type) return Unit_Name_Type is
 102    begin
 103       return Units.Table (U).Expected_Unit;
 104    end Expected_Unit;
 105
 106    function Fatal_Error (U : Unit_Number_Type) return Boolean is
 107    begin
 108       return Units.Table (U).Fatal_Error;
 109    end Fatal_Error;
 110
 111    function Generate_Code (U : Unit_Number_Type) return Boolean is
 112    begin
 113       return Units.Table (U).Generate_Code;
 114    end Generate_Code;
 115
 116    function Has_RACW (U : Unit_Number_Type) return Boolean is
 117    begin
 118       return Units.Table (U).Has_RACW;
 119    end Has_RACW;
 120
 121    function Ident_String (U : Unit_Number_Type) return Node_Id is
 122    begin
 123       return Units.Table (U).Ident_String;
 124    end Ident_String;
 125
 126    function Loading (U : Unit_Number_Type) return Boolean is
 127    begin
 128       return Units.Table (U).Loading;
 129    end Loading;
 130
 131    function Main_Priority (U : Unit_Number_Type) return Int is
 132    begin
 133       return Units.Table (U).Main_Priority;
 134    end Main_Priority;
 135
 136    function Source_Index (U : Unit_Number_Type) return Source_File_Index is
 137    begin
 138       return Units.Table (U).Source_Index;
 139    end Source_Index;
 140
 141    function Unit_File_Name (U : Unit_Number_Type) return File_Name_Type is
 142    begin
 143       return Units.Table (U).Unit_File_Name;
 144    end Unit_File_Name;
 145
 146    function Unit_Name (U : Unit_Number_Type) return Unit_Name_Type is
 147    begin
 148       return Units.Table (U).Unit_Name;
 149    end Unit_Name;
 150
 151    ------------------------------------------
 152    -- Subprograms to Set Unit Table Fields --
 153    ------------------------------------------
 154
 155    procedure Set_Cunit (U : Unit_Number_Type; N : Node_Id) is
 156    begin
 157       Units.Table (U).Cunit := N;
 158    end Set_Cunit;
 159
 160    procedure Set_Cunit_Entity (U : Unit_Number_Type; E : Entity_Id) is
 161    begin
 162       Units.Table (U).Cunit_Entity := E;
 163       Set_Is_Compilation_Unit (E);
 164    end Set_Cunit_Entity;
 165
 166    procedure Set_Dynamic_Elab (U : Unit_Number_Type; B : Boolean := True) is
 167    begin
 168       Units.Table (U).Dynamic_Elab := B;
 169    end Set_Dynamic_Elab;
 170
 171    procedure Set_Error_Location (U : Unit_Number_Type; W : Source_Ptr) is
 172    begin
 173       Units.Table (U).Error_Location := W;
 174    end Set_Error_Location;
 175
 176    procedure Set_Fatal_Error (U : Unit_Number_Type; B : Boolean := True) is
 177    begin
 178       Units.Table (U).Fatal_Error := B;
 179    end Set_Fatal_Error;
 180
 181    procedure Set_Generate_Code (U : Unit_Number_Type; B : Boolean := True) is
 182    begin
 183       Units.Table (U).Generate_Code := B;
 184    end Set_Generate_Code;
 185
 186    procedure Set_Has_RACW (U : Unit_Number_Type; B : Boolean := True) is
 187    begin
 188       Units.Table (U).Has_RACW := B;
 189    end Set_Has_RACW;
 190
 191    procedure Set_Ident_String (U : Unit_Number_Type; N : Node_Id) is
 192    begin
 193       Units.Table (U).Ident_String := N;
 194    end Set_Ident_String;
 195
 196    procedure Set_Loading (U : Unit_Number_Type; B : Boolean := True) is
 197    begin
 198       Units.Table (U).Loading := B;
 199    end Set_Loading;
 200
 201    procedure Set_Main_Priority (U : Unit_Number_Type; P : Int) is
 202    begin
 203       Units.Table (U).Main_Priority := P;
 204    end Set_Main_Priority;
 205
 206    procedure Set_Unit_Name (U : Unit_Number_Type; N : Unit_Name_Type) is
 207    begin
 208       Units.Table (U).Unit_Name := N;
 209    end Set_Unit_Name;
 210
 211    ------------------------------
 212    -- Check_Same_Extended_Unit --
 213    ------------------------------
 214
 215    function Check_Same_Extended_Unit (S1, S2 : Source_Ptr) return SEU_Result is
 216       Sloc1  : Source_Ptr;
 217       Sloc2  : Source_Ptr;
 218       Sind1  : Source_File_Index;
 219       Sind2  : Source_File_Index;
 220       Inst1  : Source_Ptr;
 221       Inst2  : Source_Ptr;
 222       Unum1  : Unit_Number_Type;
 223       Unum2  : Unit_Number_Type;
 224       Unit1  : Node_Id;
 225       Unit2  : Node_Id;
 226       Depth1 : Nat;
 227       Depth2 : Nat;
 228
 229    begin
 230       if S1 = No_Location or else S2 = No_Location then
 231          return No;
 232
 233       elsif S1 = Standard_Location then
 234          if S2 = Standard_Location then
 235             return Yes_Same;
 236          else
 237             return No;
 238          end if;
 239
 240       elsif S2 = Standard_Location then
 241          return No;
 242       end if;
 243
 244       Sloc1 := S1;
 245       Sloc2 := S2;
 246       Unum1 := Get_Code_Unit (Sloc1);
 247       Unum2 := Get_Code_Unit (Sloc2);
 248
 249       loop
 250          Sind1 := Get_Source_File_Index (Sloc1);
 251          Sind2 := Get_Source_File_Index (Sloc2);
 252
 253          if Sind1 = Sind2 then
 254             if Sloc1 < Sloc2 then
 255                return Yes_Before;
 256             elsif Sloc1 > Sloc2 then
 257                return Yes_After;
 258             else
 259                return Yes_Same;
 260             end if;
 261          end if;
 262
 263          --  OK, the two nodes are in separate source elements, but this is not
 264          --  decisive, because of the issue of subunits and instantiations.
 265
 266          --  First we deal with subunits, since if the subunit is in an
 267          --  instantiation, we know that the parent is in the corresponding
 268          --  instantiation, since that is the only way we can have a subunit
 269          --  that is part of an instantiation.
 270
 271          Unit1 := Unit (Cunit (Unum1));
 272          Unit2 := Unit (Cunit (Unum2));
 273
 274          if Nkind (Unit1) = N_Subunit
 275            and then Present (Corresponding_Stub (Unit1))
 276          then
 277             --  Both in subunits. They could have a common ancestor. If they
 278             --  do, then the deeper one must have a longer unit name. Replace
 279             --  the deeper one with its corresponding stub, in order to find
 280             --  nearest common ancestor, if any.
 281
 282             if Nkind (Unit2) = N_Subunit
 283               and then Present (Corresponding_Stub (Unit2))
 284             then
 285                if Length_Of_Name (Unit_Name (Unum1)) <
 286                   Length_Of_Name (Unit_Name (Unum2))
 287                then
 288                   Sloc2 := Sloc (Corresponding_Stub (Unit2));
 289                   Unum2 := Get_Source_Unit (Sloc2);
 290                   goto Continue;
 291
 292                else
 293                   Sloc1 := Sloc (Corresponding_Stub (Unit1));
 294                   Unum1 := Get_Source_Unit (Sloc1);
 295                   goto Continue;
 296                end if;
 297
 298             --  Nod1 in subunit, Nod2 not
 299
 300             else
 301                Sloc1 := Sloc (Corresponding_Stub (Unit1));
 302                Unum1 := Get_Source_Unit (Sloc1);
 303                goto Continue;
 304             end if;
 305
 306          --  Nod2 in subunit, Nod1 not
 307
 308          elsif Nkind (Unit2) = N_Subunit
 309            and then Present (Corresponding_Stub (Unit2))
 310          then
 311             Sloc2 := Sloc (Corresponding_Stub (Unit2));
 312             Unum2 := Get_Source_Unit (Sloc2);
 313             goto Continue;
 314          end if;
 315
 316          --  At this stage we know that neither is a subunit, so we deal
 317          --  with instantiations, since we culd have a common ancestor
 318
 319          Inst1 := Instantiation (Sind1);
 320          Inst2 := Instantiation (Sind2);
 321
 322          if Inst1 /= No_Location then
 323
 324             --  Both are instantiations
 325
 326             if Inst2 /= No_Location then
 327
 328                Depth1 := Instantiation_Depth (Sloc1);
 329                Depth2 := Instantiation_Depth (Sloc2);
 330
 331                if Depth1 < Depth2 then
 332                   Sloc2 := Inst2;
 333                   Unum2 := Get_Source_Unit (Sloc2);
 334                   goto Continue;
 335
 336                elsif Depth1 > Depth2 then
 337                   Sloc1 := Inst1;
 338                   Unum1 := Get_Source_Unit (Sloc1);
 339                   goto Continue;
 340
 341                else
 342                   Sloc1 := Inst1;
 343                   Sloc2 := Inst2;
 344                   Unum1 := Get_Source_Unit (Sloc1);
 345                   Unum2 := Get_Source_Unit (Sloc2);
 346                   goto Continue;
 347                end if;
 348
 349             --  Only first node is in instantiation
 350
 351             else
 352                Sloc1 := Inst1;
 353                Unum1 := Get_Source_Unit (Sloc1);
 354                goto Continue;
 355             end if;
 356
 357          --  Only second node is instantiation
 358
 359          elsif Inst2 /= No_Location then
 360             Sloc2 := Inst2;
 361             Unum2 := Get_Source_Unit (Sloc2);
 362             goto Continue;
 363          end if;
 364
 365          --  No instantiations involved, so we are not in the same unit
 366          --  However, there is one case still to check, namely the case
 367          --  where one location is in the spec, and the other in the
 368          --  corresponding body (the spec location is earlier).
 369
 370          if Nkind (Unit1) = N_Subprogram_Body
 371               or else
 372             Nkind (Unit1) = N_Package_Body
 373          then
 374             if Library_Unit (Cunit (Unum1)) = Cunit (Unum2) then
 375                return Yes_After;
 376             end if;
 377
 378          elsif Nkind (Unit2) = N_Subprogram_Body
 379                  or else
 380                Nkind (Unit2) = N_Package_Body
 381          then
 382             if Library_Unit (Cunit (Unum2)) = Cunit (Unum1) then
 383                return Yes_Before;
 384             end if;
 385          end if;
 386
 387          --  If that special case does not occur, then we are certain that
 388          --  the two locations are really in separate units.
 389
 390          return No;
 391
 392          <<Continue>>
 393             null;
 394       end loop;
 395    end Check_Same_Extended_Unit;
 396
 397    -------------------------------
 398    -- Compilation_Switches_Last --
 399    -------------------------------
 400
 401    function Compilation_Switches_Last return Nat is
 402    begin
 403       return Compilation_Switches.Last;
 404    end Compilation_Switches_Last;
 405
 406    ------------------------------
 407    -- Earlier_In_Extended_Unit --
 408    ------------------------------
 409
 410    function Earlier_In_Extended_Unit (S1, S2 : Source_Ptr) return Boolean is
 411    begin
 412       return Check_Same_Extended_Unit (S1, S2) = Yes_Before;
 413    end Earlier_In_Extended_Unit;
 414
 415    ----------------------------
 416    -- Entity_Is_In_Main_Unit --
 417    ----------------------------
 418
 419    function Entity_Is_In_Main_Unit (E : Entity_Id) return Boolean is
 420       S : Entity_Id;
 421
 422    begin
 423       S := Scope (E);
 424
 425       while S /= Standard_Standard loop
 426          if S = Main_Unit_Entity then
 427             return True;
 428          elsif Ekind (S) = E_Package and then Is_Child_Unit (S) then
 429             return False;
 430          else
 431             S := Scope (S);
 432          end if;
 433       end loop;
 434
 435       return False;
 436    end Entity_Is_In_Main_Unit;
 437
 438    ---------------------------------
 439    -- Generic_Separately_Compiled --
 440    ---------------------------------
 441
 442    function Generic_Separately_Compiled (E : Entity_Id) return Boolean is
 443    begin
 444       --  We do not generate object files for internal generics, because
 445       --  the only thing they would contain is the elaboration boolean, and
 446       --  we are careful to elaborate all predefined units first anyway, so
 447       --  this boolean is not needed.
 448
 449       if Is_Internal_File_Name
 450           (Fname => Unit_File_Name (Get_Source_Unit (E)),
 451            Renamings_Included => True)
 452       then
 453          return False;
 454
 455       --  All other generic units do generate object files
 456
 457       else
 458          return True;
 459       end if;
 460    end Generic_Separately_Compiled;
 461
 462    function Generic_Separately_Compiled
 463      (Sfile : File_Name_Type) return Boolean
 464    is
 465    begin
 466       --  Exactly the same as previous function, but works directly on a file
 467       --  name.
 468
 469       if Is_Internal_File_Name
 470           (Fname              => Sfile,
 471            Renamings_Included => True)
 472       then
 473          return False;
 474
 475       --  All other generic units do generate object files
 476
 477       else
 478          return True;
 479       end if;
 480    end Generic_Separately_Compiled;
 481
 482    -------------------
 483    -- Get_Code_Unit --
 484    -------------------
 485
 486    function Get_Code_Unit (S : Source_Ptr) return Unit_Number_Type is
 487    begin
 488       --  Search table unless we have No_Location, which can happen if the
 489       --  relevant location has not been set yet. Happens for example when
 490       --  we obtain Sloc (Cunit (Main_Unit)) before it is set.
 491
 492       if S /= No_Location then
 493          declare
 494             Source_File : constant Source_File_Index :=
 495                             Get_Source_File_Index (Top_Level_Location (S));
 496
 497          begin
 498             for U in Units.First .. Units.Last loop
 499                if Source_Index (U) = Source_File then
 500                   return U;
 501                end if;
 502             end loop;
 503          end;
 504       end if;
 505
 506       --  If S was No_Location, or was not in the table, we must be in the
 507       --  main source unit (and the value has not been placed in the table yet)
 508
 509       return Main_Unit;
 510    end Get_Code_Unit;
 511
 512    function Get_Code_Unit (N : Node_Or_Entity_Id) return Unit_Number_Type is
 513    begin
 514       return Get_Code_Unit (Sloc (N));
 515    end Get_Code_Unit;
 516
 517    ----------------------------
 518    -- Get_Compilation_Switch --
 519    ----------------------------
 520
 521    function Get_Compilation_Switch (N : Pos) return String_Ptr is
 522    begin
 523       if N <= Compilation_Switches.Last then
 524          return Compilation_Switches.Table (N);
 525
 526       else
 527          return null;
 528       end if;
 529    end Get_Compilation_Switch;
 530
 531    ----------------------------------
 532    -- Get_Cunit_Entity_Unit_Number --
 533    ----------------------------------
 534
 535    function Get_Cunit_Entity_Unit_Number
 536      (E : Entity_Id) return Unit_Number_Type
 537    is
 538    begin
 539       for U in Units.First .. Units.Last loop
 540          if Cunit_Entity (U) = E then
 541             return U;
 542          end if;
 543       end loop;
 544
 545       --  If not in the table, must be the main source unit, and we just
 546       --  have not got it put into the table yet.
 547
 548       return Main_Unit;
 549    end Get_Cunit_Entity_Unit_Number;
 550
 551    ---------------------------
 552    -- Get_Cunit_Unit_Number --
 553    ---------------------------
 554
 555    function Get_Cunit_Unit_Number (N : Node_Id) return Unit_Number_Type is
 556    begin
 557       for U in Units.First .. Units.Last loop
 558          if Cunit (U) = N then
 559             return U;
 560          end if;
 561       end loop;
 562
 563       --  If not in the table, must be the main source unit, and we just
 564       --  have not got it put into the table yet.
 565
 566       return Main_Unit;
 567    end Get_Cunit_Unit_Number;
 568
 569    ---------------------
 570    -- Get_Source_Unit --
 571    ---------------------
 572
 573    function Get_Source_Unit (S : Source_Ptr) return Unit_Number_Type is
 574    begin
 575       --  Search table unless we have No_Location, which can happen if the
 576       --  relevant location has not been set yet. Happens for example when
 577       --  we obtain Sloc (Cunit (Main_Unit)) before it is set.
 578
 579       if S /= No_Location then
 580          declare
 581             Source_File : Source_File_Index :=
 582                             Get_Source_File_Index (Top_Level_Location (S));
 583
 584          begin
 585             Source_File := Get_Source_File_Index (S);
 586             while Template (Source_File) /= No_Source_File loop
 587                Source_File := Template (Source_File);
 588             end loop;
 589
 590             for U in Units.First .. Units.Last loop
 591                if Source_Index (U) = Source_File then
 592                   return U;
 593                end if;
 594             end loop;
 595          end;
 596       end if;
 597
 598       --  If S was No_Location, or was not in the table, we must be in the
 599       --  main source unit (and the value is not got put into the table yet)
 600
 601       return Main_Unit;
 602    end Get_Source_Unit;
 603
 604    function Get_Source_Unit (N : Node_Or_Entity_Id) return Unit_Number_Type is
 605    begin
 606       return Get_Source_Unit (Sloc (N));
 607    end Get_Source_Unit;
 608
 609    --------------------------------
 610    -- In_Extended_Main_Code_Unit --
 611    --------------------------------
 612
 613    function In_Extended_Main_Code_Unit
 614      (N : Node_Or_Entity_Id) return Boolean
 615    is
 616    begin
 617       if Sloc (N) = Standard_Location then
 618          return True;
 619
 620       elsif Sloc (N) = No_Location then
 621          return False;
 622
 623       --  Special case Itypes to test the Sloc of the associated node. The
 624       --  reason we do this is for possible calls from gigi after -gnatD
 625       --  processing is complete in sprint. This processing updates the
 626       --  sloc fields of all nodes in the tree, but itypes are not in the
 627       --  tree so their slocs do not get updated.
 628
 629       elsif Nkind (N) = N_Defining_Identifier
 630         and then Is_Itype (N)
 631       then
 632          return In_Extended_Main_Code_Unit (Associated_Node_For_Itype (N));
 633
 634       --  Otherwise see if we are in the main unit
 635
 636       elsif Get_Code_Unit (Sloc (N)) = Get_Code_Unit (Cunit (Main_Unit)) then
 637          return True;
 638
 639       --  Node may be in spec (or subunit etc) of main unit
 640
 641       else
 642          return
 643            In_Same_Extended_Unit (Sloc (N), Sloc (Cunit (Main_Unit)));
 644       end if;
 645    end In_Extended_Main_Code_Unit;
 646
 647    function In_Extended_Main_Code_Unit (Loc : Source_Ptr) return Boolean is
 648    begin
 649       if Loc = Standard_Location then
 650          return True;
 651
 652       elsif Loc = No_Location then
 653          return False;
 654
 655       --  Otherwise see if we are in the main unit
 656
 657       elsif Get_Code_Unit (Loc) = Get_Code_Unit (Cunit (Main_Unit)) then
 658          return True;
 659
 660       --  Location may be in spec (or subunit etc) of main unit
 661
 662       else
 663          return
 664            In_Same_Extended_Unit (Loc, Sloc (Cunit (Main_Unit)));
 665       end if;
 666    end In_Extended_Main_Code_Unit;
 667
 668    ----------------------------------
 669    -- In_Extended_Main_Source_Unit --
 670    ----------------------------------
 671
 672    function In_Extended_Main_Source_Unit
 673      (N : Node_Or_Entity_Id) return Boolean
 674    is
 675       Nloc : constant Source_Ptr := Sloc (N);
 676       Mloc : constant Source_Ptr := Sloc (Cunit (Main_Unit));
 677
 678    begin
 679       --  If Mloc is not set, it means we are still parsing the main unit,
 680       --  so everything so far is in the extended main source unit.
 681
 682       if Mloc = No_Location then
 683          return True;
 684
 685       --  Special value cases
 686
 687       elsif Nloc = Standard_Location then
 688          return True;
 689
 690       elsif Nloc = No_Location then
 691          return False;
 692
 693       --  Special case Itypes to test the Sloc of the associated node. The
 694       --  reason we do this is for possible calls from gigi after -gnatD
 695       --  processing is complete in sprint. This processing updates the
 696       --  sloc fields of all nodes in the tree, but itypes are not in the
 697       --  tree so their slocs do not get updated.
 698
 699       elsif Nkind (N) = N_Defining_Identifier
 700         and then Is_Itype (N)
 701       then
 702          return In_Extended_Main_Source_Unit (Associated_Node_For_Itype (N));
 703
 704       --  Otherwise compare original locations to see if in same unit
 705
 706       else
 707          return
 708            In_Same_Extended_Unit
 709              (Original_Location (Nloc), Original_Location (Mloc));
 710       end if;
 711    end In_Extended_Main_Source_Unit;
 712
 713    function In_Extended_Main_Source_Unit
 714      (Loc : Source_Ptr) return Boolean
 715    is
 716       Mloc : constant Source_Ptr := Sloc (Cunit (Main_Unit));
 717
 718    begin
 719       --  If Mloc is not set, it means we are still parsing the main unit,
 720       --  so everything so far is in the extended main source unit.
 721
 722       if Mloc = No_Location then
 723          return True;
 724
 725       --  Special value cases
 726
 727       elsif Loc = Standard_Location then
 728          return True;
 729
 730       elsif Loc = No_Location then
 731          return False;
 732
 733       --  Otherwise compare original locations to see if in same unit
 734
 735       else
 736          return
 737            In_Same_Extended_Unit
 738              (Original_Location (Loc), Original_Location (Mloc));
 739       end if;
 740    end In_Extended_Main_Source_Unit;
 741
 742    -----------------------
 743    -- In_Same_Code_Unit --
 744    -----------------------
 745
 746    function In_Same_Code_Unit (N1, N2 : Node_Or_Entity_Id) return Boolean is
 747       S1 : constant Source_Ptr := Sloc (N1);
 748       S2 : constant Source_Ptr := Sloc (N2);
 749
 750    begin
 751       if S1 = No_Location or else S2 = No_Location then
 752          return False;
 753
 754       elsif S1 = Standard_Location then
 755          return S2 = Standard_Location;
 756
 757       elsif S2 = Standard_Location then
 758          return False;
 759       end if;
 760
 761       return Get_Code_Unit (N1) = Get_Code_Unit (N2);
 762    end In_Same_Code_Unit;
 763
 764    ---------------------------
 765    -- In_Same_Extended_Unit --
 766    ---------------------------
 767
 768    function In_Same_Extended_Unit (S1, S2 : Source_Ptr) return Boolean is
 769    begin
 770       return Check_Same_Extended_Unit (S1, S2) /= No;
 771    end In_Same_Extended_Unit;
 772
 773    -------------------------
 774    -- In_Same_Source_Unit --
 775    -------------------------
 776
 777    function In_Same_Source_Unit (N1, N2 : Node_Or_Entity_Id) return Boolean is
 778       S1 : constant Source_Ptr := Sloc (N1);
 779       S2 : constant Source_Ptr := Sloc (N2);
 780
 781    begin
 782       if S1 = No_Location or else S2 = No_Location then
 783          return False;
 784
 785       elsif S1 = Standard_Location then
 786          return S2 = Standard_Location;
 787
 788       elsif S2 = Standard_Location then
 789          return False;
 790       end if;
 791
 792       return Get_Source_Unit (N1) = Get_Source_Unit (N2);
 793    end In_Same_Source_Unit;
 794
 795    -----------------------------
 796    -- Increment_Serial_Number --
 797    -----------------------------
 798
 799    function Increment_Serial_Number return Nat is
 800       TSN : Int renames Units.Table (Current_Sem_Unit).Serial_Number;
 801
 802    begin
 803       TSN := TSN + 1;
 804       return TSN;
 805    end Increment_Serial_Number;
 806
 807    ----------------
 808    -- Initialize --
 809    ----------------
 810
 811    procedure Initialize is
 812    begin
 813       Linker_Option_Lines.Init;
 814       Load_Stack.Init;
 815       Units.Init;
 816       Unit_Exception_Table_Present := False;
 817       Compilation_Switches.Init;
 818    end Initialize;
 819
 820    ---------------
 821    -- Is_Loaded --
 822    ---------------
 823
 824    function Is_Loaded (Uname : Unit_Name_Type) return Boolean is
 825    begin
 826       for Unum in Units.First .. Units.Last loop
 827          if Uname = Unit_Name (Unum) then
 828             return True;
 829          end if;
 830       end loop;
 831
 832       return False;
 833    end Is_Loaded;
 834
 835    ---------------
 836    -- Last_Unit --
 837    ---------------
 838
 839    function Last_Unit return Unit_Number_Type is
 840    begin
 841       return Units.Last;
 842    end Last_Unit;
 843
 844    ----------
 845    -- List --
 846    ----------
 847
 848    procedure List (File_Names_Only : Boolean := False) is separate;
 849
 850    ----------
 851    -- Lock --
 852    ----------
 853
 854    procedure Lock is
 855    begin
 856       Linker_Option_Lines.Locked := True;
 857       Load_Stack.Locked := True;
 858       Units.Locked := True;
 859       Linker_Option_Lines.Release;
 860       Load_Stack.Release;
 861       Units.Release;
 862    end Lock;
 863
 864    ---------------
 865    -- Num_Units --
 866    ---------------
 867
 868    function Num_Units return Nat is
 869    begin
 870       return Int (Units.Last) - Int (Main_Unit) + 1;
 871    end Num_Units;
 872
 873    -----------------
 874    -- Remove_Unit --
 875    -----------------
 876
 877    procedure Remove_Unit (U : Unit_Number_Type) is
 878    begin
 879       if U = Units.Last then
 880          Units.Decrement_Last;
 881       end if;
 882    end Remove_Unit;
 883
 884    ----------------------------------
 885    -- Replace_Linker_Option_String --
 886    ----------------------------------
 887
 888    procedure Replace_Linker_Option_String
 889      (S : String_Id; Match_String : String)
 890    is
 891    begin
 892       if Match_String'Length > 0 then
 893          for J in 1 .. Linker_Option_Lines.Last loop
 894             String_To_Name_Buffer (Linker_Option_Lines.Table (J).Option);
 895
 896             if Match_String = Name_Buffer (1 .. Match_String'Length) then
 897                Linker_Option_Lines.Table (J).Option := S;
 898                return;
 899             end if;
 900          end loop;
 901       end if;
 902
 903       Store_Linker_Option_String (S);
 904    end Replace_Linker_Option_String;
 905
 906    ----------
 907    -- Sort --
 908    ----------
 909
 910    procedure Sort (Tbl : in out Unit_Ref_Table) is separate;
 911
 912    ------------------------------
 913    -- Store_Compilation_Switch --
 914    ------------------------------
 915
 916    procedure Store_Compilation_Switch (Switch : String) is
 917    begin
 918       Compilation_Switches.Increment_Last;
 919       Compilation_Switches.Table (Compilation_Switches.Last) :=
 920         new String'(Switch);
 921
 922       --  Fix up --RTS flag which has been transformed by the gcc driver
 923       --  into -fRTS
 924
 925       if Switch'Last >= Switch'First + 4
 926         and then Switch (Switch'First .. Switch'First + 4) = "-fRTS"
 927       then
 928          Compilation_Switches.Table
 929            (Compilation_Switches.Last) (Switch'First + 1) := '-';
 930       end if;
 931    end Store_Compilation_Switch;
 932
 933    --------------------------------
 934    -- Store_Linker_Option_String --
 935    --------------------------------
 936
 937    procedure Store_Linker_Option_String (S : String_Id) is
 938    begin
 939       Linker_Option_Lines.Increment_Last;
 940       Linker_Option_Lines.Table (Linker_Option_Lines.Last) :=
 941         (Option => S, Unit => Current_Sem_Unit);
 942    end Store_Linker_Option_String;
 943
 944    ---------------
 945    -- Tree_Read --
 946    ---------------
 947
 948    procedure Tree_Read is
 949       N : Nat;
 950       S : String_Ptr;
 951
 952    begin
 953       Units.Tree_Read;
 954
 955       --  Read Compilation_Switches table
 956
 957       Tree_Read_Int (N);
 958       Compilation_Switches.Set_Last (N);
 959
 960       for J in 1 .. N loop
 961          Tree_Read_Str (S);
 962          Compilation_Switches.Table (J) := S;
 963       end loop;
 964    end Tree_Read;
 965
 966    ----------------
 967    -- Tree_Write --
 968    ----------------
 969
 970    procedure Tree_Write is
 971    begin
 972       Units.Tree_Write;
 973
 974       --  Write Compilation_Switches table
 975
 976       Tree_Write_Int (Compilation_Switches.Last);
 977
 978       for J in 1 .. Compilation_Switches.Last loop
 979          Tree_Write_Str (Compilation_Switches.Table (J));
 980       end loop;
 981    end Tree_Write;
 982
 983    -----------------
 984    -- Version_Get --
 985    -----------------
 986
 987    function Version_Get (U : Unit_Number_Type) return Word_Hex_String is
 988    begin
 989       return Get_Hex_String (Units.Table (U).Version);
 990    end Version_Get;
 991
 992    ------------------------
 993    -- Version_Referenced --
 994    ------------------------
 995
 996    procedure Version_Referenced (S : String_Id) is
 997    begin
 998       Version_Ref.Append (S);
 999    end Version_Referenced;
1000
1001 end Lib;