gcc/ada/6vcstrea.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                 I N T E R F A C E S . C _ S T R E A M S                  --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1996-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the Alpha/VMS version.
  35
  36 with Unchecked_Conversion;
  37 package body Interfaces.C_Streams is
  38
  39    use type System.CRTL.size_t;
  40
  41    ------------
  42    -- fread --
  43    ------------
  44
  45    function fread
  46      (buffer : voids;
  47       size   : size_t;
  48       count  : size_t;
  49       stream : FILEs)
  50       return   size_t
  51    is
  52       Get_Count : size_t := 0;
  53       type Buffer_Type is array (size_t range 1 .. count,
  54                                  size_t range 1 .. size) of Character;
  55       type Buffer_Access is access Buffer_Type;
  56       function To_BA is new Unchecked_Conversion (voids, Buffer_Access);
  57       BA : Buffer_Access := To_BA (buffer);
  58       Ch : int;
  59    begin
  60
  61       --  This Fread goes with the Fwrite below.
  62       --  The C library fread sometimes can't read fputc generated files.
  63
  64       for C in 1 .. count loop
  65          for S in 1 .. size loop
  66             Ch := fgetc (stream);
  67             if Ch = EOF then
  68                return Get_Count;
  69             end if;
  70             BA.all (C, S) := Character'Val (Ch);
  71          end loop;
  72          Get_Count := Get_Count + 1;
  73       end loop;
  74       return Get_Count;
  75    end fread;
  76
  77    ------------
  78    -- fread --
  79    ------------
  80
  81    function fread
  82      (buffer : voids;
  83       index  : size_t;
  84       size   : size_t;
  85       count  : size_t;
  86       stream : FILEs)
  87       return   size_t
  88    is
  89       Get_Count : size_t := 0;
  90       type Buffer_Type is array (size_t range 1 .. count,
  91                                  size_t range 1 .. size) of Character;
  92       type Buffer_Access is access Buffer_Type;
  93       function To_BA is new Unchecked_Conversion (voids, Buffer_Access);
  94       BA : Buffer_Access := To_BA (buffer);
  95       Ch : int;
  96    begin
  97
  98       --  This Fread goes with the Fwrite below.
  99       --  The C library fread sometimes can't read fputc generated files.
 100
 101       for C in 1 + index .. count + index loop
 102          for S in 1 .. size loop
 103             Ch := fgetc (stream);
 104             if Ch = EOF then
 105                return Get_Count;
 106             end if;
 107             BA.all (C, S) := Character'Val (Ch);
 108          end loop;
 109          Get_Count := Get_Count + 1;
 110       end loop;
 111       return Get_Count;
 112    end fread;
 113
 114    ------------
 115    -- fwrite --
 116    ------------
 117
 118    function fwrite
 119      (buffer : voids;
 120       size   : size_t;
 121       count  : size_t;
 122       stream : FILEs)
 123       return   size_t
 124    is
 125       Put_Count : size_t := 0;
 126       type Buffer_Type is array (size_t range 1 .. count,
 127                                  size_t range 1 .. size) of Character;
 128       type Buffer_Access is access Buffer_Type;
 129       function To_BA is new Unchecked_Conversion (voids, Buffer_Access);
 130       BA : Buffer_Access := To_BA (buffer);
 131    begin
 132
 133       --  Fwrite on VMS has the undesirable effect of always generating at
 134       --  least one record of output per call, regardless of buffering.  To
 135       --  get around this, we do multiple fputc calls instead.
 136
 137       for C in 1 .. count loop
 138          for S in 1 .. size loop
 139             if fputc (Character'Pos (BA.all (C, S)), stream) = EOF then
 140                return Put_Count;
 141             end if;
 142          end loop;
 143          Put_Count := Put_Count + 1;
 144       end loop;
 145       return Put_Count;
 146    end fwrite;
 147
 148    -------------
 149    -- setvbuf --
 150    -------------
 151
 152    function setvbuf
 153      (stream : FILEs;
 154       buffer : chars;
 155       mode   : int;
 156       size   : size_t)
 157       return   int
 158    is
 159       use type System.Address;
 160    begin
 161
 162       --  In order for the above fwrite hack to work, we must always buffer
 163       --  stdout and stderr. Is_regular_file on VMS cannot detect when
 164       --  these are redirected to a file, so checking for that condition
 165       --  doesnt help.
 166
 167       if mode = IONBF
 168         and then (stream = stdout or else stream = stderr)
 169       then
 170          return System.CRTL.setvbuf
 171            (stream, buffer, IOLBF, System.CRTL.size_t (size));
 172       else
 173          return System.CRTL.setvbuf
 174            (stream, buffer, mode, System.CRTL.size_t (size));
 175       end if;
 176    end setvbuf;
 177
 178 end Interfaces.C_Streams;